CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix
  36
  37 PROJECT(SUPERTUX)
  38
  39
  40 ### CMake configuration
  41
  42 # allow building with CMake 2.6. Set compatibility options. Use some bundled modules as a fallback
  43 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  44 IF(COMMAND cmake_policy)
  45         CMAKE_POLICY(SET CMP0003 NEW)
  46 ENDIF(COMMAND cmake_policy)
  47
  48 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/mk/cmake)
  49
  50 ## For autopackage
  51 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  52 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2")
  53
  54 ## Check endianess
  55
  56 INCLUDE(TestBigEndian)
  57 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  58
  59 ## Add lots of dependencies to compiler switches
  60
  61 FIND_PACKAGE(Boost REQUIRED)
  62 INCLUDE_DIRECTORIES(${Boost_INCLUDE_DIR})
  63 LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
  64
  65 FIND_PACKAGE(SDL REQUIRED)
  66 INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR})
  67 SET(HAVE_SDL TRUE)
  68
  69 FIND_PACKAGE(SDL_image REQUIRED)
  70 INCLUDE_DIRECTORIES(${SDLIMAGE_INCLUDE_DIR})
  71
  72 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  73 IF(ENABLE_OPENGL)
  74   FIND_PACKAGE(OpenGL)
  75   IF(OPENGL_FOUND)
  76     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  77     SET(HAVE_OPENGL TRUE)
  78   ENDIF(OPENGL_FOUND)
  79
  80   FIND_PACKAGE(GLEW)
  81   IF(GLEW_FOUND)
  82     INCLUDE_DIRECTORIES(${GLEW_INCLUDE_DIR})
  83   ENDIF(GLEW_FOUND)
  84 ENDIF(ENABLE_OPENGL)
  85
  86 FIND_PACKAGE(OpenAL REQUIRED)
  87 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
  88
  89 FIND_PACKAGE(OggVorbis REQUIRED)
  90 INCLUDE_DIRECTORIES(${OGGVORBIS_INCLUDE_DIR})
  91
  92 FIND_PACKAGE(PhysFS REQUIRED)
  93 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
  94
  95 FIND_PACKAGE(CURL)
  96 IF(CURL_FOUND)
  97   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
  98   SET(HAVE_LIBCURL TRUE)
  99 ENDIF(CURL_FOUND)
 100
 101 #FIND_PACKAGE(ICONV REQUIRED)
 102 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 103 #LINK_LIBRARIES(${ICONV_LIBRARY})
 104
 105 ## Find revision of WC
 106 MARK_AS_ADVANCED(SVNVERSION_EXECUTABLE)
 107 FIND_PROGRAM(SVNVERSION_EXECUTABLE svnversion)
 108 IF(SVNVERSION_EXECUTABLE)
 109   EXECUTE_PROCESS(COMMAND svnversion -n ${CMAKE_CURRENT_SOURCE_DIR}
 110                   OUTPUT_VARIABLE SUPERTUX_WC_REVISION)
 111   SET(REVISION " r${SUPERTUX_WC_REVISION}")
 112 ENDIF(SVNVERSION_EXECUTABLE)
 113
 114 ## Check platform-dependent build options
 115
 116 INCLUDE(ConfigureChecks)
 117
 118 ## Create config.h and version.h
 119
 120 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 121 configure_file(version.h.cmake ${CMAKE_BINARY_DIR}/version.h )
 122 include_directories (${CMAKE_BINARY_DIR}/)
 123
 124 ## Also execute instructions in src/squirrel/CMakeLists.txt
 125
 126 ADD_SUBDIRECTORY(external/squirrel)
 127
 128 ## Add squirrel lib dir to search path
 129
 130 LINK_DIRECTORIES(external/squirrel)
 131
 132 ## Some additional include paths
 133
 134 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/src/)
 135 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel/include/)
 136 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/tinygettext/)
 137 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/findlocale/)
 138 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/obstack/)
 139 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/)
 140
 141 ## Build list of sources for supertux binary
 142
 143 FILE(GLOB SUPERTUX_SOURCES_C RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/obstack/*.c external/findlocale/findlocale.c)
 144
 145 FILE(GLOB SUPERTUX_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/main.cpp src/*/*.cpp src/supertux/menu/*.cpp src/video/sdl/*.cpp)
 146
 147 FILE(GLOB TINYGETTEXT_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/tinygettext/tinygettext/*.cpp)
 148 SET_SOURCE_FILES_PROPERTIES(${TINYGETTEXT_SOURCES_CXX} PROPERTIES COMPILE_DEFINITIONS HAVE_SDL)
 149
 150 IF(HAVE_OPENGL)
 151   FILE(GLOB SUPERTUX_OPENGL_SOURCES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/video/gl/*.cpp)
 152   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_OPENGL_SOURCES})
 153 ENDIF(HAVE_OPENGL)
 154
 155 ## Precompile "a few" headers in GCC
 156 OPTION(PRECOMPILE_HEADERS "Precompile headers (experimental)" OFF)
 157 IF(PRECOMPILE_HEADERS)
 158   FILE(GLOB PRECOMPILED_HEADERS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/badguy/badguy.hpp
 159            src/scripting/wrapper.hpp src/video/*.hpp src/math/*.hpp)
 160   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh "// Precompiled headers\n")
 161   FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh "#ifndef __SUPERTUX_PRECOMPILED_HEADER\n")
 162   FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh "#define __SUPERTUX_PRECOMPILED_HEADER\n")
 163   FOREACH(PRECOMPILED_HEADER ${PRECOMPILED_HEADERS})
 164     FILE(RELATIVE_PATH PRECOMPILED_HEADER ${CMAKE_CURRENT_SOURCE_DIR}/src "${CMAKE_CURRENT_SOURCE_DIR}/${PRECOMPILED_HEADER}")
 165     FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh "#include \"${PRECOMPILED_HEADER}\"\n")
 166   ENDFOREACH(PRECOMPILED_HEADER)
 167   FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh "#endif /*__SUPERTUX_PRECOMPILED_HEADER*/\n")
 168   ADD_CUSTOM_COMMAND(
 169     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh.gch
 170     COMMAND ${CMAKE_CXX_COMPILER} -x "c++-header" $(CXX_FLAGS) ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh
 171     DEPENDS ${PRECOMPILED_HEADERS}
 172     COMMENT "Building precompiled header..."
 173   )
 174   ## Make certain it is built
 175   SET(SUPERTUX_SOURCES_CXX ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh.gch ${SUPERTUX_SOURCES_CXX})
 176   SET(CMAKE_CXX_FLAGS "-include ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh ${CMAKE_CXX_FLAGS}")
 177 ELSE(PRECOMPILE_HEADERS)
 178   IF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh)
 179     FILE(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh)
 180   ENDIF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh)
 181   IF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh.gch)
 182     FILE(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh.gch)
 183   ENDIF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/precompile.hh.gch)
 184 ENDIF(PRECOMPILE_HEADERS)
 185
 186
 187 ## Debug options
 188
 189 OPTION(WERROR "Stop on first compiler warning" OFF)
 190 OPTION(WARNINGS "Enable long list of warnings for compiler to check" ON)
 191 IF(CMAKE_COMPILER_IS_GNUCC)
 192   SET(CMAKE_CXX_FLAGS_DEBUG "-O0 -g")
 193   SET(CMAKE_C_FLAGS_DEBUG "-O0 -g")
 194   SET(CMAKE_CXX_FLAGS_PROFILE "${CMAKE_CXX_FLAGS_DEBUG} -pg")
 195   SET(CMAKE_C_FLAGS_PROFILE "${CMAKE_C_FLAGS_DEBUG} -pg")
 196   SET(CMAKE_LD_FLAGS_PROFILE "${CMAKE_LD_FLAGS_DEBUG} -pg")
 197   ADD_DEFINITIONS(-Wall -Wextra -funit-at-a-time)
 198   IF(WERROR)
 199     ADD_DEFINITIONS(-Werror)
 200   ELSE(WERROR)
 201     REMOVE_DEFINITIONS(-Werror)
 202   ENDIF(WERROR)
 203   IF(WARNINGS)
 204     ADD_DEFINITIONS(-fdiagnostics-show-option -pedantic -Wno-long-long -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wlogical-op -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector)
 205     SET(CMAKE_CXX_FLAGS "-Weffc++ -Wabi -Wctor-dtor-privacy -Wstrict-null-sentinel ${CMAKE_CXX_FLAGS}")
 206     # -ansi fails in MinGW
 207     # still left:  -Wold-style-cast -Wpadded -Wconversion -Wundef -Wsign-conversion -Wshadow -Winline -Wunsafe-loop-optimizations -Wfloat-equal -Wswitch-default -Wswitch-enum -Wcast-qual -Wsign-promo -Woverloaded-virtual -Wmissing-format-attribute -Wstrict-overflow=5 -Wformat=2
 208   ENDIF(WARNINGS)
 209 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 210
 211 ## Build miniswig and generate miniswig wrapper
 212
 213 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" ${DEBUG})
 214 IF(GENERATE_WRAPPER)
 215   ADD_SUBDIRECTORY(tools/miniswig)
 216   ADD_CUSTOM_COMMAND(
 217     OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp
 218     COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 219     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${CMAKE_CURRENT_BINARY_DIR}/miniswig.tmp -I${CMAKE_CURRENT_SOURCE_DIR}/src
 220     COMMAND tools/miniswig/miniswig
 221     ARGS --input miniswig.tmp --output-cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace scripting
 222     DEPENDS tools/miniswig/miniswig
 223     IMPLICIT_DEPENDS CXX ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.interface.hpp
 224   )
 225 ENDIF(GENERATE_WRAPPER)
 226
 227 IF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 228   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 229 ENDIF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 230
 231 ## If xgettext is available, generate messages.pot for sources
 232
 233 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" ${DEBUG})
 234 IF(GENERATE_MESSAGESPOT)
 235   MARK_AS_ADVANCED(
 236     XGETTEXT_EXECUTABLE
 237   )
 238   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 239   IF(NOT XGETTEXT_EXECUTABLE)
 240     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 241   ELSE(NOT XGETTEXT_EXECUTABLE)
 242     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 243
 244     SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/data/locale/messages.pot)
 245     ADD_CUSTOM_COMMAND(
 246       OUTPUT ${MESSAGES_POT_FILE}
 247       COMMAND ${XGETTEXT_EXECUTABLE}
 248       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES_CXX}
 249       DEPENDS ${SUPERTUX_SOURCES_CXX}
 250       WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 251       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 252     )
 253     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 254
 255     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} data/levels/*)
 256     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 257     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 258       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 259
 260       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 261       IF(SUPERTUX_LEVELS)
 262       SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 263       ADD_CUSTOM_COMMAND(
 264         OUTPUT ${MESSAGES_POT_FILE}
 265         COMMAND ${XGETTEXT_EXECUTABLE}
 266         ARGS --keyword="_:1" --language=Lisp --force-po --sort-by-file "--output=${MESSAGES_POT_FILE}" ${SUPERTUX_LEVELS}
 267         DEPENDS ${SUPERTUX_LEVELS}
 268         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 269         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 270       )
 271       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 272       ENDIF(SUPERTUX_LEVELS)
 273
 274     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 275
 276     ADD_CUSTOM_TARGET(
 277       supertux2-messages ALL
 278       DEPENDS ${MESSAGES_POT_FILES}
 279     )
 280
 281   ENDIF(NOT XGETTEXT_EXECUTABLE)
 282 ENDIF(GENERATE_MESSAGESPOT)
 283
 284 ## Some additional compiler switches
 285 IF(CMAKE_COMPILER_IS_GNUCC)
 286   ADD_DEFINITIONS(-fno-strict-aliasing)
 287 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 288
 289 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 290   ADD_DEFINITIONS(-DMACOSX)
 291 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 292
 293
 294 ## On Windows, add an icon
 295
 296 IF(WIN32)
 297   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 298   IF(MINGW)
 299     ADD_CUSTOM_COMMAND(
 300     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 301     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 302     SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 303   ELSE(MINGW)
 304     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 305   ENDIF(MINGW)
 306 ENDIF(WIN32)
 307
 308 ## Add binreloc.c if enabled
 309 IF(ENABLE_BINRELOC)
 310   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/binreloc.c)
 311 ENDIF(ENABLE_BINRELOC)
 312
 313
 314 ## Generate supertux executable in the right place
 315
 316 SET(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 317
 318 ## Add target for supertux binary
 319
 320 ADD_EXECUTABLE(supertux2 ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCES_CXX} ${TINYGETTEXT_SOURCES_CXX})
 321
 322 ## Link supertux binary with squirrel and other libraries
 323
 324 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 325 TARGET_LINK_LIBRARIES(supertux2 ${SDL_LIBRARY})
 326 TARGET_LINK_LIBRARIES(supertux2 ${SDLIMAGE_LIBRARY})
 327 TARGET_LINK_LIBRARIES(supertux2 ${OPENAL_LIBRARY})
 328 TARGET_LINK_LIBRARIES(supertux2 ${OGGVORBIS_LIBRARIES})
 329 TARGET_LINK_LIBRARIES(supertux2 ${PHYSFS_LIBRARY})
 330 IF(HAVE_OPENGL)
 331     TARGET_LINK_LIBRARIES(supertux2 ${OPENGL_LIBRARY})
 332     TARGET_LINK_LIBRARIES(supertux2 ${GLEW_LIBRARY})
 333 ENDIF(HAVE_OPENGL)
 334 IF(HAVE_LIBCURL)
 335   TARGET_LINK_LIBRARIES(supertux2 ${CURL_LIBRARY})
 336 ENDIF(HAVE_LIBCURL)
 337
 338 ## Install stuff
 339
 340 IF(WIN32 AND NOT UNIX)
 341
 342   SET(INSTALL_SUBDIR_BIN "." CACHE STRING "Installation subdir for binaries")
 343   SET(INSTALL_SUBDIR_SHARE "data" CACHE STRING "Installation subdir for data")
 344   SET(INSTALL_SUBDIR_DOC "." CACHE STRING "Installation subdir for docs")
 345
 346   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/SDL.dll
 347                 ${CMAKE_CURRENT_SOURCE_DIR}/SDL_image.dll
 348                 ${CMAKE_CURRENT_SOURCE_DIR}/iconv.dll
 349                 ${CMAKE_CURRENT_SOURCE_DIR}/libogg-0.dll
 350                 ${CMAKE_CURRENT_SOURCE_DIR}/libphysfs-1-0-0.dll
 351                 ${CMAKE_CURRENT_SOURCE_DIR}/OpenAl32.dll
 352                 ${CMAKE_CURRENT_SOURCE_DIR}/wrap_oal.dll
 353                 ${CMAKE_CURRENT_SOURCE_DIR}/libcurl-4.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 354
 355   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 356
 357 ELSE(WIN32 AND NOT UNIX)
 358 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 359
 360   SET(INSTALL_SUBDIR_BIN "SuperTux.app/Contents/MacOS" CACHE STRING "Installation subdir for binaries")
 361   SET(INSTALL_SUBDIR_SHARE "SuperTux.app/Contents/Resources/data" CACHE STRING "Installation subdir for data")
 362   SET(INSTALL_SUBDIR_DOC "SuperTux.app/Contents/Resources" CACHE STRING "Installation subdir for docs")
 363
 364   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 365
 366   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 367
 368 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 369
 370   SET(INSTALL_SUBDIR_BIN "games" CACHE STRING "Installation subdir for binaries")
 371   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2" CACHE STRING "Installation subdir for data")
 372   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2" CACHE STRING "Installation subdir for docs")
 373
 374   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 375
 376   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 377
 378 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 379 ENDIF(WIN32 AND NOT UNIX)
 380
 381 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 382
 383 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/INSTALL ${CMAKE_CURRENT_SOURCE_DIR}/README ${CMAKE_CURRENT_SOURCE_DIR}/COPYING ${CMAKE_CURRENT_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 384
 385 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/credits.txt DESTINATION ${INSTALL_SUBDIR_SHARE})
 386
 387 INSTALL(DIRECTORY data/images
 388                   data/fonts
 389                   data/levels
 390                   data/music
 391                   data/scripts
 392                   data/speech
 393                   data/sounds
 394                   data/locale
 395                                DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 396
 397
 398 ## CPack/Installation-specific stuff
 399
 400 INCLUDE(InstallRequiredSystemLibraries)
 401 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 402 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 403 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 404 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 405 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 406 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 407 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 408 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 409 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 410 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 411 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 412 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 413   # The OS X PackageMaker doesn't seem to like files with no extension
 414 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 415   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README")
 416   SET(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 417 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 418 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 419 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 420 SET(CPACK_PACKAGE_VERSION_PATCH "2-SVN")
 421 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 422 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 423 IF(WIN32 AND NOT UNIX)
 424   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 425   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 426 ELSE(WIN32 AND NOT UNIX)
 427 ENDIF(WIN32 AND NOT UNIX)
 428 INCLUDE(CPack)
 429
 430 # move some config clutter to the advanced section
 431 MARK_AS_ADVANCED(
 432   INSTALL_SUBDIR_BIN
 433   INSTALL_SUBDIR_SHARE
 434   INSTALL_SUBDIR_DOC
 435 )
 436
 437 MARK_AS_ADVANCED(
 438         CMAKE_BACKWARDS_COMPATIBILITY
 439         CMAKE_BUILD_TYPE
 440         CMAKE_INSTALL_PREFIX
 441         EXECUTABLE_OUTPUT_PATH
 442         LIBRARY_OUTPUT_PATH
 443         CMAKE_OSX_ARCHITECTURES
 444         CMAKE_OSX_SYSROOT
 445 )
 446
 447 MARK_AS_ADVANCED(
 448         ENABLE_BINRELOC
 449         APPDATADIR
 450 )
 451
 452 MARK_AS_ADVANCED(
 453         Boost_INCLUDE_DIR
 454         Boost_LIBRARIES
 455 )
 456
 457 MARK_AS_ADVANCED(
 458         SDLMAIN_LIBRARY
 459         SDL_INCLUDE_DIR
 460         SDL_LIBRARY
 461 )
 462
 463 MARK_AS_ADVANCED(
 464         SDLIMAGE_INCLUDE_DIR
 465         SDLIMAGE_LIBRARY
 466 )
 467
 468 MARK_AS_ADVANCED(
 469         OPENAL_INCLUDE_DIR
 470         OPENAL_LIBRARY
 471 )
 472
 473 MARK_AS_ADVANCED(
 474         OGG_LIBRARY
 475         VORBISENC_LIBRARY
 476         VORBISFILE_LIBRARY
 477         VORBIS_INCLUDE_DIR
 478         VORBIS_LIBRARY
 479 )
 480
 481 MARK_AS_ADVANCED(
 482         PHYSFS_INCLUDE_DIR
 483         PHYSFS_LIBRARY
 484 )