CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix
  36
  37 PROJECT(SUPERTUX)
  38
  39
  40 ### CMake configuration
  41
  42 # allow building with CMake 2.6. Set compatibility options. Use some bundled modules as a fallback
  43 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  44 IF(COMMAND cmake_policy)
  45         CMAKE_POLICY(SET CMP0003 NEW)
  46 ENDIF(COMMAND cmake_policy)
  47
  48 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${SUPERTUX_SOURCE_DIR}/mk/cmake)
  49
  50 ## For autopackage
  51 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  52 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2")
  53
  54 ## Check endianess
  55
  56 INCLUDE(TestBigEndian)
  57 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  58
  59 ## Add lots of dependencies to compiler switches
  60
  61 FIND_PACKAGE(SDL REQUIRED)
  62 INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR})
  63 SET(HAVE_SDL TRUE)
  64
  65 FIND_PACKAGE(SDL_image REQUIRED)
  66 INCLUDE_DIRECTORIES(${SDLIMAGE_INCLUDE_DIR})
  67
  68 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  69 IF(ENABLE_OPENGL)
  70   FIND_PACKAGE(OpenGL)
  71   IF(OPENGL_FOUND)
  72     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  73     SET(HAVE_OPENGL TRUE)
  74   ENDIF(OPENGL_FOUND)
  75
  76   FIND_PACKAGE(GLEW)
  77   IF(GLEW_FOUND)
  78     INCLUDE_DIRECTORIES(${GLEW_INCLUDE_DIR})
  79   ENDIF(GLEW_FOUND)
  80 ENDIF(ENABLE_OPENGL)
  81
  82 FIND_PACKAGE(OpenAL REQUIRED)
  83 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
  84
  85 FIND_PACKAGE(OggVorbis REQUIRED)
  86 INCLUDE_DIRECTORIES(${OGGVORBIS_INCLUDE_DIR})
  87
  88 FIND_PACKAGE(PhysFS REQUIRED)
  89 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
  90
  91 FIND_PACKAGE(CURL)
  92 IF(CURL_FOUND)
  93   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
  94   SET(HAVE_LIBCURL TRUE)
  95 ENDIF(CURL_FOUND)
  96
  97 #FIND_PACKAGE(ICONV REQUIRED)
  98 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
  99 #LINK_LIBRARIES(${ICONV_LIBRARY})
 100
 101 ## Find revision of WC
 102 MARK_AS_ADVANCED(SVNVERSION_EXECUTABLE)
 103 FIND_PROGRAM(SVNVERSION_EXECUTABLE svnversion)
 104 IF(SVNVERSION_EXECUTABLE)
 105   EXECUTE_PROCESS(COMMAND svnversion -n ${SUPERTUX_SOURCE_DIR}
 106                   OUTPUT_VARIABLE SUPERTUX_WC_REVISION)
 107   SET(REVISION " r${SUPERTUX_WC_REVISION}")
 108 ENDIF(SVNVERSION_EXECUTABLE)
 109
 110 ## Check platform-dependent build options
 111
 112 INCLUDE(ConfigureChecks)
 113
 114 ## Create config.h and version.h
 115
 116 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 117 configure_file(version.h.cmake ${CMAKE_BINARY_DIR}/version.h )
 118 include_directories (${CMAKE_BINARY_DIR}/)
 119
 120 ## Also execute instructions in src/squirrel/CMakeLists.txt
 121
 122 ADD_SUBDIRECTORY(external/squirrel)
 123
 124 ## Add squirrel lib dir to search path
 125
 126 LINK_DIRECTORIES(external/squirrel)
 127
 128 ## Some additional include paths
 129
 130 include_directories (${SUPERTUX_SOURCE_DIR}/src/)
 131 include_directories (${SUPERTUX_SOURCE_DIR}/external/squirrel/include/)
 132 include_directories (${SUPERTUX_SOURCE_DIR}/external/tinygettext/)
 133 include_directories (${SUPERTUX_SOURCE_DIR}/external/findlocale/)
 134 include_directories (${SUPERTUX_SOURCE_DIR}/external/obstack/)
 135 include_directories (${SUPERTUX_SOURCE_DIR}/external/binreloc/)
 136
 137 ## Build list of sources for supertux binary
 138
 139 FILE(GLOB SUPERTUX_SOURCES_C RELATIVE ${SUPERTUX_SOURCE_DIR} external/obstack/*.c external/findlocale/findlocale.c)
 140
 141 FILE(GLOB SUPERTUX_SOURCES_CXX RELATIVE ${SUPERTUX_SOURCE_DIR} src/main.cpp src/*/*.cpp src/supertux/menu/*.cpp src/video/sdl/*.cpp external/tinygettext/tinygettext/*.cpp)
 142
 143 IF(HAVE_OPENGL)
 144   FILE(GLOB SUPERTUX_OPENGL_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} src/video/gl/*.cpp)
 145   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_OPENGL_SOURCES})
 146 ENDIF(HAVE_OPENGL)
 147
 148 ## Precompile "a few" headers in GCC
 149 OPTION(PRECOMPILE_HEADERS "Precompile headers (experimental)" OFF)
 150 IF(PRECOMPILE_HEADERS)
 151   FILE(GLOB PRECOMPILED_HEADERS RELATIVE ${SUPERTUX_SOURCE_DIR} src/badguy/badguy.hpp
 152            src/scripting/wrapper.hpp src/video/*.hpp src/math/*.hpp)
 153   FILE(WRITE ${SUPERTUX_BINARY_DIR}/precompile.hh "// Precompiled headers\n")
 154   FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#ifndef __SUPERTUX_PRECOMPILED_HEADER\n")
 155   FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#define __SUPERTUX_PRECOMPILED_HEADER\n")
 156   FOREACH(PRECOMPILED_HEADER ${PRECOMPILED_HEADERS})
 157     FILE(RELATIVE_PATH PRECOMPILED_HEADER ${SUPERTUX_SOURCE_DIR}/src "${SUPERTUX_SOURCE_DIR}/${PRECOMPILED_HEADER}")
 158     FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#include \"${PRECOMPILED_HEADER}\"\n")
 159   ENDFOREACH(PRECOMPILED_HEADER)
 160   FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#endif /*__SUPERTUX_PRECOMPILED_HEADER*/\n")
 161   ADD_CUSTOM_COMMAND(
 162     OUTPUT ${SUPERTUX_BINARY_DIR}/precompile.hh.gch
 163     COMMAND ${CMAKE_CXX_COMPILER} -x "c++-header" $(CXX_FLAGS) ${SUPERTUX_BINARY_DIR}/precompile.hh
 164     DEPENDS ${PRECOMPILED_HEADERS}
 165     COMMENT "Building precompiled header..."
 166   )
 167   ## Make certain it is built
 168   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_BINARY_DIR}/precompile.hh.gch ${SUPERTUX_SOURCES_CXX})
 169   SET(CMAKE_CXX_FLAGS "-include ${SUPERTUX_BINARY_DIR}/precompile.hh" ${CMAKE_CXX_FLAGS})
 170 ELSE(PRECOMPILE_HEADERS)
 171   IF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh)
 172     FILE(REMOVE ${SUPERTUX_BINARY_DIR}/precompile.hh)
 173   ENDIF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh)
 174   IF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh.gch)
 175     FILE(REMOVE ${SUPERTUX_BINARY_DIR}/precompile.hh.gch)
 176   ENDIF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh.gch)
 177 ENDIF(PRECOMPILE_HEADERS)
 178
 179
 180 ## Debug options
 181
 182 OPTION(WERROR "Stop on first compiler warning" OFF)
 183 OPTION(WARNINGS "Enable long list of warnings for compiler to check" ON)
 184 IF(CMAKE_COMPILER_IS_GNUCC)
 185   ADD_DEFINITIONS(-Wall -Wextra -funit-at-a-time)
 186   SET(CMAKE_CXX_FLAGS_DEBUG "-O0 -g")
 187   SET(CMAKE_C_FLAGS_DEBUG "-O0 -g")
 188   SET(CMAKE_CXX_FLAGS_PROFILE "-pg")
 189   SET(CMAKE_C_FLAGS_PROFILE "-pg")
 190   SET(CMAKE_LD_FLAGS_PROFILE "-pg")
 191   IF(WERROR)
 192     ADD_DEFINITIONS(-Werror)
 193   ELSE(WERROR)
 194     REMOVE_DEFINITIONS(-Werror)
 195   ENDIF(WERROR)
 196   IF(WARNINGS)
 197     SET(CMAKE_C_FLAGS "-fdiagnostics-show-option -pedantic -Wno-long-long -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wlogical-op -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector")
 198     SET(CMAKE_CXX_FLAGS "-fdiagnostics-show-option -pedantic -Wno-long-long -Weffc++ -Wabi -Wctor-dtor-privacy -Wstrict-null-sentinel -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wlogical-op -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector")
 199     # -ansi fails in MinGW
 200     # still left:  -Wold-style-cast -Wpadded -Wconversion -Wundef -Wsign-conversion -Wshadow -Winline -Wunsafe-loop-optimizations -Wfloat-equal -Wswitch-default -Wswitch-enum -Wcast-qual -Wsign-promo -Woverloaded-virtual -Wmissing-format-attribute -Wstrict-overflow=5 -Wformat=2
 201   ENDIF(WARNINGS)
 202 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 203
 204 ## Add in squirrel debug stuff
 205
 206 OPTION(ENABLE_SQDBG "Build squirrel script interpreter with debugging options" OFF)
 207 IF(ENABLE_SQDBG)
 208   include_directories (${SUPERTUX_SOURCE_DIR}/external/squirrel/)
 209   FILE(GLOB SQDBG_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} external/squirrel/sqdbg/*.cpp)
 210   SET(SUPERTUX_SOURCES_CXX ${SQDBG_SOURCES} ${SUPERTUX_SOURCES_CXX})
 211 ENDIF(ENABLE_SQDBG)
 212
 213 ## Build miniswig and generate miniswig wrapper
 214
 215 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" ${DEBUG})
 216 IF(GENERATE_WRAPPER)
 217   ADD_SUBDIRECTORY(tools/miniswig)
 218   ADD_CUSTOM_COMMAND(
 219     OUTPUT ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp
 220     COMMAND cd ${SUPERTUX_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 221     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${SUPERTUX_BINARY_DIR}/miniswig.tmp -I${SUPERTUX_SOURCE_DIR}/src
 222     COMMAND tools/miniswig/miniswig
 223     ARGS --input miniswig.tmp --output-cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace scripting
 224     DEPENDS tools/miniswig/miniswig
 225     IMPLICIT_DEPENDS CXX ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.interface.hpp
 226   )
 227 ENDIF(GENERATE_WRAPPER)
 228
 229 IF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 230   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 231 ENDIF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 232
 233 ## If xgettext is available, generate messages.pot for sources
 234
 235 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" ${DEBUG})
 236 IF(GENERATE_MESSAGESPOT)
 237   MARK_AS_ADVANCED(
 238     XGETTEXT_EXECUTABLE
 239   )
 240   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 241   IF(NOT XGETTEXT_EXECUTABLE)
 242     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 243   ELSE(NOT XGETTEXT_EXECUTABLE)
 244     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 245
 246     SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/data/locale/messages.pot)
 247     ADD_CUSTOM_COMMAND(
 248       OUTPUT ${MESSAGES_POT_FILE}
 249       COMMAND ${XGETTEXT_EXECUTABLE}
 250       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES_CXX}
 251       DEPENDS ${SUPERTUX_SOURCES_CXX}
 252       WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 253       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 254     )
 255     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 256
 257     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${SUPERTUX_SOURCE_DIR} data/levels/*)
 258     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 259     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 260       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${SUPERTUX_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 261
 262       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 263       IF(SUPERTUX_LEVELS)
 264       SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 265       ADD_CUSTOM_COMMAND(
 266         OUTPUT ${MESSAGES_POT_FILE}
 267         COMMAND ${XGETTEXT_EXECUTABLE}
 268         ARGS --keyword="_:1" --language=Lisp --force-po --sort-by-file "--output=${MESSAGES_POT_FILE}" ${SUPERTUX_LEVELS}
 269         DEPENDS ${SUPERTUX_LEVELS}
 270         WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 271         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 272       )
 273       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 274       ENDIF(SUPERTUX_LEVELS)
 275
 276     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 277
 278     ADD_CUSTOM_TARGET(
 279       supertux2-messages ALL
 280       DEPENDS ${MESSAGES_POT_FILES}
 281     )
 282
 283   ENDIF(NOT XGETTEXT_EXECUTABLE)
 284 ENDIF(GENERATE_MESSAGESPOT)
 285
 286 ## Some additional compiler switches
 287 IF(CMAKE_COMPILER_IS_GNUCC)
 288   ADD_DEFINITIONS(-fno-strict-aliasing)
 289 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 290
 291 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 292   ADD_DEFINITIONS(-DMACOSX)
 293 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 294
 295
 296 ## On Windows, add an icon
 297
 298 IF(WIN32)
 299   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 300   IF(MINGW)
 301     ADD_CUSTOM_COMMAND(
 302     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 303     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 304     SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 305   ELSE(MINGW)
 306     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 307   ENDIF(MINGW)
 308 ENDIF(WIN32)
 309
 310 ## Add binreloc.c if enabled
 311 IF(ENABLE_BINRELOC)
 312   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCE_DIR}/external/binreloc/binreloc.c)
 313 ENDIF(ENABLE_BINRELOC)
 314
 315
 316 ## Generate supertux executable in the right place
 317
 318 SET(EXECUTABLE_OUTPUT_PATH ${SUPERTUX_SOURCE_DIR})
 319
 320 ## Add target for supertux binary
 321
 322 ADD_EXECUTABLE(supertux2 ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCES_CXX})
 323
 324 ## Link supertux binary with squirrel and other libraries
 325
 326 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 327 TARGET_LINK_LIBRARIES(supertux2 ${SDL_LIBRARY})
 328 TARGET_LINK_LIBRARIES(supertux2 ${SDLIMAGE_LIBRARY})
 329 TARGET_LINK_LIBRARIES(supertux2 ${OPENAL_LIBRARY})
 330 TARGET_LINK_LIBRARIES(supertux2 ${OGGVORBIS_LIBRARIES})
 331 TARGET_LINK_LIBRARIES(supertux2 ${PHYSFS_LIBRARY})
 332 IF(HAVE_OPENGL)
 333     TARGET_LINK_LIBRARIES(supertux2 ${OPENGL_LIBRARY})
 334     TARGET_LINK_LIBRARIES(supertux2 ${GLEW_LIBRARY})
 335 ENDIF(HAVE_OPENGL)
 336 IF(HAVE_LIBCURL)
 337   TARGET_LINK_LIBRARIES(supertux2 ${CURL_LIBRARY})
 338 ENDIF(HAVE_LIBCURL)
 339
 340 ## Install stuff
 341
 342 IF(WIN32 AND NOT UNIX)
 343
 344   OPTION(INSTALL_SUBDIR_BIN "Installation subdir for binaries" ".")
 345   OPTION(INSTALL_SUBDIR_SHARE "Installation subdir for data" "data/")
 346   OPTION(INSTALL_SUBDIR_DOC "Installation subdir for docs" ".")
 347
 348   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/SDL.dll
 349                 ${SUPERTUX_SOURCE_DIR}/SDL_image.dll
 350                 ${SUPERTUX_SOURCE_DIR}/iconv.dll
 351                 ${SUPERTUX_SOURCE_DIR}/libogg-0.dll
 352                 ${SUPERTUX_SOURCE_DIR}/libphysfs-1-0-0.dll
 353                 ${SUPERTUX_SOURCE_DIR}/OpenAl32.dll
 354                 ${SUPERTUX_SOURCE_DIR}/wrap_oal.dll
 355                 ${SUPERTUX_SOURCE_DIR}/libcurl-4.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 356
 357   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 358
 359 ELSE(WIN32 AND NOT UNIX)
 360 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 361
 362   OPTION(INSTALL_SUBDIR_BIN "Installation subdir for binaries" "SuperTux.app/Contents/MacOS/")
 363   OPTION(INSTALL_SUBDIR_SHARE "Installation subdir for data" "SuperTux.app/Contents/Resources/data/")
 364   OPTION(INSTALL_SUBDIR_DOC "Installation subdir for docs" "SuperTux.app/Contents/Resources/")
 365
 366   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 367
 368   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 369
 370 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 371
 372   OPTION(INSTALL_SUBDIR_BIN "Installation subdir for binaries" "games/")
 373   OPTION(INSTALL_SUBDIR_SHARE "Installation subdir for data" "share/games/supertux2/")
 374   OPTION(INSTALL_SUBDIR_DOC "Installation subdir for docs" "share/doc/supertux2/")
 375
 376   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 377
 378   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 379
 380 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 381 ENDIF(WIN32 AND NOT UNIX)
 382
 383 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 384
 385 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/INSTALL ${SUPERTUX_SOURCE_DIR}/README ${SUPERTUX_SOURCE_DIR}/COPYING ${SUPERTUX_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 386
 387 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/credits.txt DESTINATION ${INSTALL_SUBDIR_SHARE})
 388
 389 INSTALL(DIRECTORY data/images
 390                   data/fonts
 391                   data/levels
 392                   data/music
 393                   data/scripts
 394                   data/speech
 395                   data/sounds
 396                   data/locale
 397                                DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 398
 399
 400 ## CPack/Installation-specific stuff
 401
 402 INCLUDE(InstallRequiredSystemLibraries)
 403 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 404 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 405 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 406 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 407 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 408 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 409 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 410 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 411 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 412 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 413 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 414 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 415   # The OS X PackageMaker doesn't seem to like files with no extension
 416 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 417   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${SUPERTUX_SOURCE_DIR}/README")
 418   SET(CPACK_RESOURCE_FILE_LICENSE "${SUPERTUX_SOURCE_DIR}/COPYING")
 419 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 420 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 421 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 422 SET(CPACK_PACKAGE_VERSION_PATCH "2-SVN")
 423 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 424 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 425 IF(WIN32 AND NOT UNIX)
 426   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 427   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 428 ELSE(WIN32 AND NOT UNIX)
 429 ENDIF(WIN32 AND NOT UNIX)
 430 INCLUDE(CPack)
 431
 432 # move some config clutter to the advanced section
 433 MARK_AS_ADVANCED(
 434   INSTALL_SUBDIR_BIN
 435   INSTALL_SUBDIR_SHARE
 436   INSTALL_SUBDIR_DOC
 437 )
 438
 439 MARK_AS_ADVANCED(
 440         CMAKE_BACKWARDS_COMPATIBILITY
 441         CMAKE_BUILD_TYPE
 442         CMAKE_INSTALL_PREFIX
 443         EXECUTABLE_OUTPUT_PATH
 444         LIBRARY_OUTPUT_PATH
 445         CMAKE_OSX_ARCHITECTURES
 446         CMAKE_OSX_SYSROOT
 447 )
 448
 449 MARK_AS_ADVANCED(
 450         ENABLE_BINRELOC
 451         APPDATADIR
 452 )
 453
 454 MARK_AS_ADVANCED(
 455         SDLMAIN_LIBRARY
 456         SDL_INCLUDE_DIR
 457         SDL_LIBRARY
 458 )
 459
 460 MARK_AS_ADVANCED(
 461         SDLIMAGE_INCLUDE_DIR
 462         SDLIMAGE_LIBRARY
 463 )
 464
 465 MARK_AS_ADVANCED(
 466         OPENAL_INCLUDE_DIR
 467         OPENAL_LIBRARY
 468 )
 469
 470 MARK_AS_ADVANCED(
 471         OGG_LIBRARY
 472         VORBISENC_LIBRARY
 473         VORBISFILE_LIBRARY
 474         VORBIS_INCLUDE_DIR
 475         VORBIS_LIBRARY
 476 )
 477
 478 MARK_AS_ADVANCED(
 479         PHYSFS_INCLUDE_DIR
 480         PHYSFS_LIBRARY
 481 )