acinclude.m4

   1 dnl Helper Functions for the RRDtool configure.ac script
   2 dnl
   3 dnl this file gets included into aclocal.m4 when runnning aclocal
   4 dnl
   5 dnl
   6 dnl
   7 dnl Check for the presence of a particular library and its header files
   8 dnl if this check fails set the environment variable EX_CHECK_ALL_ERR to YES
   9 dnl and prints out a helful message
  10 dnl
  11 dnl
  12 dnl EX_CHECK_ALL(library, function, header, pkgconf name, tested-version, homepage, cppflags)
  13 dnl              $1       $2        $3      $4            $5              $6        $7
  14 dnl
  15 dnl
  16 AC_DEFUN([EX_CHECK_ALL],
  17 [
  18  AC_LANG_PUSH(C)
  19  EX_CHECK_STATE=NO
  20  ex_check_save_LIBS=${LIBS}
  21  ex_check_save_CPPFLAGS=${CPPFLAGS}
  22  ex_check_save_LDFLAGS=${LDPFLAGS}
  23  if test "x$7" != "x"; then
  24    CPPFLAGS="$CPPFLAGS -I$7"
  25  fi
  26  dnl try compiling naked first
  27  AC_CHECK_LIB($1,$2, [
  28     AC_CHECK_HEADER($3,[LIBS="-l$1 ${LIBS}";EX_CHECK_STATE=YES],[])],[])
  29  if test $EX_CHECK_STATE = NO; then
  30     dnl now asking pkg-config for help
  31     AC_CHECK_PROGS(PKGCONFIG,[pkg-config],no)
  32     if test "$PKGCONFIG" != "no"; then
  33           if $PKGCONFIG --exists $4; then
  34              CPPFLAGS=${CPPFLAGS}" "`$PKGCONFIG --cflags $4`
  35              LDFLAGS=${LDFLAGS}" "`$PKGCONFIG --libs-only-L $4`
  36              LDFLAGS=${LDFLAGS}" "`$PKGCONFIG --libs-only-other $4`
  37              LIBS=${LIBS}" "`$PKGCONFIG --libs-only-l $4`
  38              dnl remove the cached value and test again
  39              unset ac_cv_lib_$1_$2
  40              AC_CHECK_LIB($1,$2,[
  41                  unset ac_cv_header_`echo $3 | sed "s/[^a-z]/_/g"`
  42                  AC_CHECK_HEADER($3,[EX_CHECK_STATE=YES],[])
  43              ],[])
  44           else
  45              AC_MSG_WARN([
  46 ----------------------------------------------------------------------------
  47 * I found a copy of pkgconfig, but there is no $4.pc file around.
  48   You may want to set the PKG_CONFIG_PATH variable to point to its
  49   location.
  50 ----------------------------------------------------------------------------
  51                         ])
  52            fi
  53      fi
  54   fi
  55
  56   if test ${EX_CHECK_STATE} = NO; then
  57      AC_MSG_WARN([
  58 ----------------------------------------------------------------------------
  59 * I could not find a working copy of $4. Check config.log for hints on why
  60   this is the case. Maybe you need to set LDFLAGS and CPPFLAGS appropriately
  61   so that compiler and the linker can find lib$1 and its header files. If
  62   you have not installed $4, you can get it either from its original home on
  63
  64      $6
  65
  66   You can find also find an archive copy on
  67
  68      http://people.ee.ethz.ch/~oetiker/webtools/rrdtool/pub/libs
  69
  70   The last tested version of $4 is $5.
  71
  72        LIBS=$LIBS
  73    LDFLAGS=$LDFLAGS
  74   CPPFLAGS=$CPPFLAGS
  75
  76 ----------------------------------------------------------------------------
  77                 ])
  78        EX_CHECK_ALL_ERR=YES
  79        LIBS="${ex_check_save_LIBS}"
  80        CPPFLAGS="${ex_check_save_CPPFLAGS}"
  81        LDFLAGS="${ex_check_save_LDFLAGS}"
  82     fi
  83     AC_LANG_POP(C)
  84 ]
  85 )
  86
  87 dnl
  88 dnl  Ptherad check from http://autoconf-archive.cryp.to/acx_pthread.m4
  89 dnl
  90 dnl @synopsis ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
  91 dnl
  92 dnl This macro figures out how to build C programs using POSIX threads.
  93 dnl It sets the PTHREAD_LIBS output variable to the threads library and
  94 dnl linker flags, and the PTHREAD_CFLAGS output variable to any special
  95 dnl C compiler flags that are needed. (The user can also force certain
  96 dnl compiler flags/libs to be tested by setting these environment
  97 dnl variables.)
  98 dnl
  99 dnl Also sets PTHREAD_CC to any special C compiler that is needed for
 100 dnl multi-threaded programs (defaults to the value of CC otherwise).
 101 dnl (This is necessary on AIX to use the special cc_r compiler alias.)
 102 dnl
 103 dnl NOTE: You are assumed to not only compile your program with these
 104 dnl flags, but also link it with them as well. e.g. you should link
 105 dnl with $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS
 106 dnl $LIBS
 107 dnl
 108 dnl If you are only building threads programs, you may wish to use
 109 dnl these variables in your default LIBS, CFLAGS, and CC:
 110 dnl
 111 dnl        LIBS="$PTHREAD_LIBS $LIBS"
 112 dnl        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 113 dnl        CC="$PTHREAD_CC"
 114 dnl
 115 dnl In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
 116 dnl constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to
 117 dnl that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
 118 dnl
 119 dnl ACTION-IF-FOUND is a list of shell commands to run if a threads
 120 dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands to
 121 dnl run it if it is not found. If ACTION-IF-FOUND is not specified, the
 122 dnl default action will define HAVE_PTHREAD.
 123 dnl
 124 dnl Please let the authors know if this macro fails on any platform, or
 125 dnl if you have any other suggestions or comments. This macro was based
 126 dnl on work by SGJ on autoconf scripts for FFTW (www.fftw.org) (with
 127 dnl help from M. Frigo), as well as ac_pthread and hb_pthread macros
 128 dnl posted by Alejandro Forero Cuervo to the autoconf macro repository.
 129 dnl We are also grateful for the helpful feedback of numerous users.
 130 dnl
 131 dnl @category InstalledPackages
 132 dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
 133 dnl @version 2005-01-14
 134 dnl @license GPLWithACException
 135
 136 AC_DEFUN([ACX_PTHREAD], [
 137 AC_REQUIRE([AC_CANONICAL_HOST])
 138 AC_LANG_PUSH(C)
 139 acx_pthread_ok=no
 140
 141 # We used to check for pthread.h first, but this fails if pthread.h
 142 # requires special compiler flags (e.g. on True64 or Sequent).
 143 # It gets checked for in the link test anyway.
 144
 145 # First of all, check if the user has set any of the PTHREAD_LIBS,
 146 # etcetera environment variables, and if threads linking works using
 147 # them:
 148 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
 149         save_CFLAGS="$CFLAGS"
 150         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 151         save_LIBS="$LIBS"
 152         LIBS="$PTHREAD_LIBS $LIBS"
 153         AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
 154         AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
 155         AC_MSG_RESULT($acx_pthread_ok)
 156         if test x"$acx_pthread_ok" = xno; then
 157                 PTHREAD_LIBS=""
 158                 PTHREAD_CFLAGS=""
 159         fi
 160         LIBS="$save_LIBS"
 161         CFLAGS="$save_CFLAGS"
 162 fi
 163
 164 # We must check for the threads library under a number of different
 165 # names; the ordering is very important because some systems
 166 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 167 # libraries is broken (non-POSIX).
 168
 169 # Create a list of thread flags to try.  Items starting with a "-" are
 170 # C compiler flags, and other items are library names, except for "none"
 171 # which indicates that we try without any flags at all, and "pthread-config"
 172 # which is a program returning the flags for the Pth emulation library.
 173
 174 acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
 175
 176 # The ordering *is* (sometimes) important.  Some notes on the
 177 # individual items follow:
 178
 179 # pthreads: AIX (must check this before -lpthread)
 180 # none: in case threads are in libc; should be tried before -Kthread and
 181 #       other compiler flags to prevent continual compiler warnings
 182 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 183 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 184 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 185 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
 186 # -pthreads: Solaris/gcc
 187 # -mthreads: Mingw32/gcc, Lynx/gcc
 188 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 189 #      doesn't hurt to check since this sometimes defines pthreads too;
 190 #      also defines -D_REENTRANT)
 191 # pthread: Linux, etcetera
 192 # --thread-safe: KAI C++
 193 # pthread-config: use pthread-config program (for GNU Pth library)
 194
 195 case "${host_cpu}-${host_os}" in
 196         *solaris*)
 197
 198         # On Solaris (at least, for some versions), libc contains stubbed
 199         # (non-functional) versions of the pthreads routines, so link-based
 200         # tests will erroneously succeed.  (We need to link with -pthread or
 201         # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
 202         # a function called by this macro, so we could check for that, but
 203         # who knows whether they'll stub that too in a future libc.)  So,
 204         # we'll just look for -pthreads and -lpthread first:
 205
 206         acx_pthread_flags="-pthread -pthreads pthread -mt $acx_pthread_flags"
 207         ;;
 208 esac
 209
 210 if test x"$acx_pthread_ok" = xno; then
 211 for flag in $acx_pthread_flags; do
 212
 213         case $flag in
 214                 none)
 215                 AC_MSG_CHECKING([whether pthreads work without any flags])
 216                 ;;
 217
 218                 -*)
 219                 AC_MSG_CHECKING([whether pthreads work with $flag])
 220                 PTHREAD_CFLAGS="$flag"
 221                 ;;
 222
 223                 pthread-config)
 224                 AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
 225                 if test x"$acx_pthread_config" = xno; then continue; fi
 226                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 227                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 228                 ;;
 229
 230                 *)
 231                 AC_MSG_CHECKING([for the pthreads library -l$flag])
 232                 PTHREAD_LIBS="-l$flag"
 233                 ;;
 234         esac
 235
 236         save_LIBS="$LIBS"
 237         save_CFLAGS="$CFLAGS"
 238         LIBS="$PTHREAD_LIBS $LIBS"
 239         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 240
 241         # Check for various functions.  We must include pthread.h,
 242         # since some functions may be macros.  (On the Sequent, we
 243         # need a special flag -Kthread to make this header compile.)
 244         # We check for pthread_join because it is in -lpthread on IRIX
 245         # while pthread_create is in libc.  We check for pthread_attr_init
 246         # due to DEC craziness with -lpthreads.  We check for
 247         # pthread_cleanup_push because it is one of the few pthread
 248         # functions on Solaris that doesn't have a non-functional libc stub.
 249         # We try pthread_create on general principles.
 250         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[pthread_t th; pthread_join(th, 0);
 251                      pthread_attr_init(0); pthread_cleanup_push(0, 0);
 252                      pthread_create(0,0,0,0); pthread_cleanup_pop(0); ]])],[acx_pthread_ok=yes],[])
 253
 254         LIBS="$save_LIBS"
 255         CFLAGS="$save_CFLAGS"
 256
 257         AC_MSG_RESULT($acx_pthread_ok)
 258         if test "x$acx_pthread_ok" = xyes; then
 259                 break;
 260         fi
 261
 262         PTHREAD_LIBS=""
 263         PTHREAD_CFLAGS=""
 264 done
 265 fi
 266
 267 # Various other checks:
 268 if test "x$acx_pthread_ok" = xyes; then
 269         save_LIBS="$LIBS"
 270         LIBS="$PTHREAD_LIBS $LIBS"
 271         save_CFLAGS="$CFLAGS"
 272         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 273
 274         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 275         AC_MSG_CHECKING([for joinable pthread attribute])
 276         attr_name=unknown
 277         for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 278             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[int attr=$attr;]])],[attr_name=$attr; break],[])
 279         done
 280         AC_MSG_RESULT($attr_name)
 281         if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
 282             AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
 283                                [Define to necessary symbol if this constant
 284                                 uses a non-standard name on your system.])
 285         fi
 286
 287         AC_MSG_CHECKING([if more special flags are required for pthreads])
 288         x_rflag=no
 289         case "${host_cpu}-${host_os}" in
 290             *-aix* | *-freebsd* | *-darwin*) x_rflag="-D_THREAD_SAFE";;
 291             *solaris* | *-osf* | *-hpux*) x_rflag="-D_REENTRANT";;
 292         esac
 293         AC_MSG_RESULT(${x_rflag})
 294         if test "x$x_rflag" != xno; then
 295             PTHREAD_CFLAGS="$x_rflag $PTHREAD_CFLAGS"
 296         fi
 297
 298         LIBS="$save_LIBS"
 299         CFLAGS="$save_CFLAGS"
 300
 301         # More AIX lossage: must compile with cc_r
 302         AC_CHECK_PROG(PTHREAD_CC, cc_r, cc_r, ${CC})
 303 else
 304         PTHREAD_CC="$CC"
 305 fi
 306
 307 AC_SUBST(PTHREAD_LIBS)
 308 AC_SUBST(PTHREAD_CFLAGS)
 309 AC_SUBST(PTHREAD_CC)
 310
 311 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 312 if test x"$acx_pthread_ok" = xyes; then
 313         ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
 314         :
 315 else
 316         acx_pthread_ok=no
 317         $2
 318 fi
 319 AC_LANG_POP(C)
 320 ])dnl ACX_PTHREAD
 321
 322
 323 dnl
 324 dnl determine how to get IEEE math working
 325 dnl AC_IEEE(MESSAGE, set rd_cv_ieee_[var] variable, INCLUDES,
 326 dnl   FUNCTION-BODY, [ACTION-IF-FOUND [,ACTION-IF-NOT-FOUND]])
 327 dnl
 328
 329 dnl substitute them in all the files listed in AC_OUTPUT
 330 AC_SUBST(PERLFLAGS)
 331
 332 AC_DEFUN([AC_IEEE], [
 333 AC_MSG_CHECKING([if IEEE math works $1])
 334 AC_CACHE_VAL([rd_cv_ieee_$2],
 335 [AC_RUN_IFELSE([AC_LANG_SOURCE([[$3
 336
 337 #if HAVE_MATH_H
 338 #  include <math.h>
 339 #endif
 340
 341 #if HAVE_FLOAT_H
 342 #  include <float.h>
 343 #endif
 344
 345 #if HAVE_IEEEFP_H
 346 #  include <ieeefp.h>
 347 #endif
 348
 349 #if HAVE_FP_CLASS_H
 350 #  include <fp_class.h>
 351 #endif
 352
 353 /* Solaris */
 354 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 355 #  define HAVE_ISINF 1
 356 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 357 #endif
 358
 359 /* Digital UNIX */
 360 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 361 #  define HAVE_ISINF 1
 362 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 363 #endif
 364
 365 /* AIX */
 366 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 367 #  define HAVE_ISINF 1
 368 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 369 #endif
 370
 371 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 372 #  define HAVE_ISINF 1
 373 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 374 #endif
 375
 376 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 377 #  define HAVE_ISINF 1
 378 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 379 #endif
 380
 381 #include <stdio.h>
 382 int main(void){
 383     double nan,inf,c,zero;
 384     $4;
 385     /* some math to see if we get a floating point exception */
 386     zero=sin(0.0); /* don't let the compiler optimize us away */
 387     nan=0.0/zero; /* especially here */
 388     inf=1.0/zero; /* and here. I want to know if it can do the magic */
 389                   /* at run time without sig fpe */
 390     c = inf + nan;
 391     c = inf / nan;
 392     if (! isnan(nan)) {printf ("not isnan(NaN) ... "); return 1;}
 393     if (nan == nan) {printf ("nan == nan ... "); return 1;}
 394     if (! isinf(inf)) {printf ("not isinf(oo) ... "); return 1;}
 395     if (! isinf(-inf)) {printf ("not isinf(-oo) ... "); return 1;}
 396     if (! inf > 0) {printf ("not inf > 0 ... "); return 1;}
 397     if (! -inf < 0) {printf ("not -inf < 0 ... "); return 1;}
 398     return 0;
 399  }]])],[rd_cv_ieee_$2=yes],[rd_cv_ieee_$2=no],[:])])
 400 dnl these we run regardles is cached or not
 401 if test x${rd_cv_ieee_$2} = "xyes"; then
 402  AC_MSG_RESULT(yes)
 403  $5
 404 else
 405  AC_MSG_RESULT(no)
 406  $6
 407 fi
 408
 409 ])
 410
 411 AC_DEFUN([AC_FULL_IEEE],[
 412 AC_LANG_PUSH(C)
 413 _cflags=${CFLAGS}
 414 AC_IEEE([out of the box], works, , , ,
 415   [CFLAGS="$_cflags -ieee"
 416   AC_IEEE([with the -ieee switch], switch, , , ,
 417     [CFLAGS="$_cflags -qfloat=nofold"
 418     AC_IEEE([with the -qfloat=nofold switch], nofold, , , ,
 419       [CFLAGS="$_cflags -w -qflttrap=enable:zerodivide"
 420       AC_IEEE([with the -w -qflttrap=enable:zerodivide], flttrap, , , ,
 421        [CFLAGS="$_cflags -mieee"
 422        AC_IEEE([with the -mieee switch], mswitch, , , ,
 423          [CFLAGS="$_cflags -q float=rndsngl"
 424          AC_IEEE([with the -q float=rndsngl switch], qswitch, , , ,
 425            [CFLAGS="$_cflags -OPT:IEEE_NaN_inf=ON"
 426            AC_IEEE([with the -OPT:IEEE_NaN_inf=ON switch], ieeenaninfswitch, , , ,
 427              [CFLAGS="$_cflags -OPT:IEEE_comparisons=ON"
 428              AC_IEEE([with the -OPT:IEEE_comparisons=ON switch], ieeecmpswitch, , , ,
 429                [CFLAGS=$_cflags
 430                AC_IEEE([with fpsetmask(0)], mask,
 431                  [#include <floatingpoint.h>], [fpsetmask(0)],
 432                  [AC_DEFINE(MUST_DISABLE_FPMASK)
 433                  PERLFLAGS="CCFLAGS=-DMUST_DISABLE_FPMASK"],
 434                  [AC_IEEE([with signal(SIGFPE,SIG_IGN)], sigfpe,
 435                    [#include <signal.h>], [signal(SIGFPE,SIG_IGN)],
 436                    [AC_DEFINE(MUST_DISABLE_SIGFPE)
 437                    PERLFLAGS="CCFLAGS=-DMUST_DISABLE_SIGFPE"],
 438                    AC_MSG_ERROR([
 439 Your Compiler does not do propper IEEE math ... Please find out how to
 440 make IEEE math work with your compiler and let me know (oetiker@ee.ethz.ch).
 441 Check config.log to see what went wrong ...
 442 ]))])])])])])])])])])
 443
 444 AC_LANG_POP(C)
 445
 446 ])
 447
 448
 449 dnl a macro to check for ability to create python extensions
 450 dnl  AM_CHECK_PYTHON_HEADERS([ACTION-IF-POSSIBLE], [ACTION-IF-NOT-POSSIBLE])
 451 dnl function also defines PYTHON_INCLUDES
 452 AC_DEFUN([AM_CHECK_PYTHON_HEADERS],
 453 [AC_REQUIRE([AM_PATH_PYTHON])
 454 AC_MSG_CHECKING(for headers required to compile python extensions)
 455 dnl deduce PYTHON_INCLUDES
 456 py_prefix=`$PYTHON -c "import sys; print sys.prefix"`
 457 py_exec_prefix=`$PYTHON -c "import sys; print sys.exec_prefix"`
 458 PYTHON_INCLUDES="-I${py_prefix}/include/python${PYTHON_VERSION}"
 459 if test "$py_prefix" != "$py_exec_prefix"; then
 460   PYTHON_INCLUDES="$PYTHON_INCLUDES -I${py_exec_prefix}/include/python${PYTHON_VERSION}"
 461 fi
 462 AC_SUBST(PYTHON_INCLUDES)
 463 dnl check if the headers exist:
 464 save_CPPFLAGS="$CPPFLAGS"
 465 CPPFLAGS="$CPPFLAGS $PYTHON_INCLUDES"
 466 AC_TRY_CPP([#include <Python.h>],dnl
 467 [AC_MSG_RESULT(found)
 468 $1],dnl
 469 [AC_MSG_RESULT(not found)
 470 $2])
 471 CPPFLAGS="$save_CPPFLAGS"
 472 ])
 473
 474