configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 AC_INIT([rrdtool],[1.1.9901])
  10 AC_CANONICAL_TARGET
  11 AM_INIT_AUTOMAKE
  12 AC_CONFIG_HEADERS([config.h])
  13
  14 dnl all our local stuff like install scripts and include files
  15 dnl is in there
  16
  17
  18 dnl determine the type of system we are running on
  19
  20
  21 AC_SUBST(VERSION)
  22
  23 dnl where we install our stuff ...
  24 AC_PREFIX_DEFAULT( /usr/local/rrdtool-1.1.0 )
  25
  26 dnl Minimum Autoconf version required.
  27 AC_PREREQ(2.59)
  28
  29 dnl At the TOP of the HEADER
  30
  31 AH_TOP([
  32
  33 #ifndef CONFIG_H
  34 #define CONFIG_H
  35 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  36 #undef MUST_DISABLE_FPMASK
  37
  38 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  39
  40 #undef MUST_DISABLE_SIGFPE
  41
  42 /* realloc does not support NULL as argument */
  43 #undef NO_NULL_REALLOC
  44  ])
  45
  46 AH_BOTTOM([
  47
  48 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  49    make sure you are NOT using bcopy, index or rindex in the code */
  50
  51 #if STDC_HEADERS
  52 # include <string.h>
  53 #else
  54 # ifndef HAVE_STRCHR
  55 #  define strchr index
  56 #  define strrchr rindex
  57 # endif
  58 char *strchr (), *strrchr ();
  59 # ifndef HAVE_MEMMOVE
  60 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  61 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  62 # endif
  63 #endif
  64
  65
  66 #if NO_NULL_REALLOC
  67 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  68 #else
  69 # define rrd_realloc(a,b) realloc((a), (b))
  70 #endif
  71
  72 #if HAVE_MATH_H
  73 #  include <math.h>
  74 #endif
  75
  76 #if HAVE_FLOAT_H
  77 #  include <float.h>
  78 #endif
  79
  80 #if HAVE_IEEEFP_H
  81 #  include <ieeefp.h>
  82 #endif
  83
  84 #if HAVE_FP_CLASS_H
  85 #  include <fp_class.h>
  86 #endif
  87
  88 /* for Solaris */
  89 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
  90 #  define HAVE_ISINF 1
  91 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
  92 #endif
  93
  94 /* for OSF1 Digital Unix */
  95 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
  96 #  define HAVE_ISINF 1
  97 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
  98 #endif
  99
 100 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 101 #  define HAVE_ISINF 1
 102 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 103 #endif
 104
 105 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 106 #  define HAVE_ISINF 1
 107 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 108 #endif
 109
 110 /* for AIX */
 111 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 112 #  define HAVE_ISINF 1
 113 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 114 #endif
 115
 116 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 117 #  define HAVE_FINITE 1
 118 #  define finite(a) isfinite(a)
 119 #endif
 120
 121 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 122 #  define HAVE_FINITE 1
 123 #  define finite(a) (! isnan(a) && ! isinf(a))
 124 #endif
 125
 126 #ifndef HAVE_FINITE
 127 #error "Can't compile without finite function"
 128 #endif
 129
 130 #ifndef HAVE_ISINF
 131 #error "Can't compile without isinf function"
 132 #endif
 133
 134 #endif /* CONFIG_H */
 135 ])
 136
 137
 138
 139 dnl Check for the compiler and static/shared library creation.
 140 AC_PROG_CC
 141 AC_PROG_CPP
 142 AC_PROG_LIBTOOL
 143
 144 dnl Checks for header files.
 145 AC_HEADER_STDC
 146 AC_HEADER_DIRENT
 147 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 148
 149 dnl Checks for typedefs, structures, and compiler characteristics.
 150 AC_C_CONST
 151 AC_HEADER_TIME
 152 AC_STRUCT_TM
 153
 154 dnl substitute them in all the files listed in AC_OUTPUT
 155 AC_SUBST(PERLFLAGS)
 156
 157 dnl Checks for libraries.
 158 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 159
 160 dnl add pic flag in any case this makes sure all our code is relocatable
 161 eval `./libtool --config | grep pic_flag`
 162 CFLAGS="$CFLAGS $pic_flag"
 163
 164 dnl Checks for library functions.
 165 AC_FUNC_STRFTIME
 166 AC_FUNC_VPRINTF
 167
 168 AC_C_BIGENDIAN
 169
 170 dnl for each function found we get a definition in config.h
 171 dnl of the form HAVE_FUNCTION
 172
 173 AC_CHECK_FUNCS(tzset opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 174
 175 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 176 dnl actual code to check if this works
 177 AC_CHECK_FUNCS(fpclassify, ,
 178   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 179     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
 180       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 181 AC_CHECK_FUNCS(finite, ,
 182   [AC_CHECK_FUNCS(isfinite, ,
 183     [AC_MSG_CHECKING(for isfinite with <math.h>)
 184     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
 185       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 186 AC_CHECK_FUNCS(isinf, ,
 187   [AC_MSG_CHECKING(for isinf with <math.h>)
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
 189       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 190
 191 AC_FULL_IEEE
 192
 193 dnl How the vertical axis label is printed
 194 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 195  [Vertical label angle: 90.0 (default) or 270.0])
 196 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 197  [Vertical label angle: 90.0 (default) or 270.0])
 198
 199
 200 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 201 [],[enable_rrdcgi=yes])
 202 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 203
 204 if test $enable_rrdcgi != no; then
 205 EX_CHECK_ALL(cgi,        cgiInit,                   cgi.h,                  cgilib,      0.5,    http://www.infodrom.org/projects/cgilib)
 206 fi
 207 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/)
 208 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.1,  http://www.gzip.org/zlib/)
 209 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/)
 210 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,              freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/)
 211
 212 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 213   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 214 fi
 215
 216 AC_LANG_PUSH(C)
 217 dnl solaris has some odd define it need in order to propperly compile ctime_r
 218 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 219 AC_LINK_IFELSE(
 220     AC_LANG_PROGRAM(
 221            [[#include <time.h>]],
 222            [[ctime_r(NULL,NULL,0)]]
 223                    ),
 224     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 225       AC_LINK_IFELSE(
 226           AC_LANG_PROGRAM(
 227                 [[#include <time.h>]],
 228                 [[ctime_r(NULL,NULL)]]
 229                          ),
 230           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 231           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 232       )
 233     ],
 234     [ AC_LINK_IFELSE(
 235           AC_LANG_PROGRAM(
 236                 [[#include <time.h>]],
 237                 [[ctime_r(NULL,NULL)]]
 238                          ),
 239           [AC_MSG_RESULT(yes)],
 240           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 241       )
 242     ]
 243 )
 244 AC_LANG_POP(C)
 245
 246 dnl Check for pthreads
 247 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 248
 249 AC_SUBST(MULTITHREAD_CFLAGS)
 250 AC_SUBST(MULTITHREAD_LDFLAGS)
 251
 252
 253 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 254 [],[enable_pthread=yes])
 255
 256 if test $enable_pthread != no; then
 257  ACX_PTHREAD([
 258     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 259     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 260              ],
 261              [])
 262 fi
 263
 264
 265
 266 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 267
 268 dnl Check for Perl.
 269 AC_PATH_PROG(PERL, perl, no)
 270 if test "x$PERL" = "xno"; then
 271         COMP_PERL=
 272 else
 273         COMP_PERL="perl_piped perl_shared"
 274         AC_MSG_CHECKING(for shared library extension)
 275         SO_EXT=`$PERL -e 'use Config; if (defined $Config{so} and $Config{so} ne 'a') {print "$Config{so}\n"} else {print "so\n"};'`
 276         AC_MSG_RESULT($SO_EXT)
 277         AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 278         PROBLEMCC=`$PERL -e 'use Config; ($cc = $Config{cc}) =~ s/\s.*//; exit 0 if -x $cc; map {if (-x "$_/$cc"){exit 0}} split /:/, $ENV{PATH};print $Config{cc}'`
 279         if test x$PROBLEMCC != x; then
 280                 AC_MSG_RESULT(no)
 281                 echo Could not find the Compiler: '"'$PROBLEMCC'"'
 282                 echo which has been used to build perl. You may have to compile
 283                 echo your own copy of perl to make this work. Binary perls often
 284                 echo exhibit this problem
 285                 exit 1
 286         else
 287                 AC_MSG_RESULT(found)
 288         fi
 289 fi
 290 AC_SUBST(COMP_PERL)
 291 AC_SUBST(SO_EXT)
 292
 293 dnl Check for Tcl.
 294 withval=""
 295 AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 296 found=0
 297 AC_MSG_CHECKING(for tclConfig.sh in $withval)
 298 if test -f "$withval/tclConfig.sh" ; then
 299         tcl_config=$withval/tclConfig.sh
 300         found=1
 301         AC_MSG_RESULT(yes)
 302         break
 303 else
 304         AC_MSG_RESULT(no)
 305 fi
 306
 307 if test $found -eq 0 ; then
 308         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 309 else
 310         . $tcl_config
 311 fi
 312
 313 dnl Pass additional perl options when generating Makefile from Makefile.PL
 314 # Options to pass when configuring perl module
 315 AC_ARG_WITH(perl-options,
 316 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 317                           generating Makefile from Makefile.PL],
 318 [PERL_MAKE_OPTIONS=$withval])
 319 AC_SUBST(PERL_MAKE_OPTIONS)
 320
 321 AM_CONDITIONAL(COMP_TCL, test x$found = x1 )
 322
 323 AC_SUBST(TCL_PREFIX)
 324 AC_SUBST(TCL_SHLIB_CFLAGS)
 325 AC_SUBST(TCL_SHLIB_LD)
 326 AC_SUBST(TCL_SHLIB_SUFFIX)
 327 AC_SUBST(TCL_PACKAGE_PATH)
 328 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 329
 330
 331
 332 dnl Check for nroff
 333 AC_PATH_PROGS(NROFF, gnroff nroff)
 334 AC_PATH_PROGS(TROFF, groff troff)
 335
 336 dnl Does the compiler like -Wall and -pedantic?
 337 if test "x$GCC" = "xyes"; then
 338   oCFLAGS=$CFLAGS
 339   CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 340   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 341                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 342                ]
 343         )
 344   if test $rd_cv_gcc_opt = no; then
 345          CFLAGS=$oCFLAGS
 346   fi
 347 fi
 348
 349 dnl what does realloc do if it gets called with a NULL pointer
 350
 351 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 352 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 353               int main(void){
 354               char *x = NULL;
 355               x = realloc (x,10);
 356               if (x==NULL) return 1;
 357               return 0;
 358              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 359
 360 if test x"$rd_cv_null_realloc" = xnope; then
 361 AC_DEFINE(NO_NULL_REALLOC)
 362 fi
 363
 364 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 365           examples/piped-demo.pl                        \
 366           examples/stripes.pl                           \
 367           examples/bigtops.pl                           \
 368           examples/minmax.pl                            \
 369           examples/cgi-demo.cgi                         \
 370           examples/4charts.pl                           \
 371           examples/Makefile                             \
 372           doc/Makefile                                  \
 373           src/Makefile                                  \
 374           bindings/Makefile                             \
 375           bindings/tcl/Makefile                         \
 376           Makefile])
 377 AC_CONFIG_COMMANDS([default],[[\
 378           chmod +x examples/*.cgi examples/*.pl]],[[]])
 379 AC_OUTPUT
 380
 381 AC_MSG_CHECKING(in)
 382 AC_MSG_RESULT(and out again)
 383
 384 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 385 sleep 1
 386 echo $ECHO_N ".$ECHO_C" 1>&6
 387 sleep 1
 388 echo $ECHO_N ".$ECHO_C" 1>&6
 389 sleep 1
 390 echo $ECHO_N ".$ECHO_C" 1>&6
 391 sleep 1
 392 echo $ECHO_N ".$ECHO_C" 1>&6
 393 sleep 1
 394 AC_MSG_RESULT([ just kidding ;-)])
 395 echo
 396 echo "----------------------------------------------------------------"
 397 echo "Config is DONE!"
 398 echo
 399 echo "Type 'make' to compile the software and use 'make install' to "
 400 echo "install everything to: $prefix."
 401 echo
 402 echo "If you want to install the perl"
 403 echo "modules in site-perl, try 'make site-perl-install'."
 404 echo
 405 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 406 echo "make me happy. Go to http://people.ee.ethz.ch/~oetiker/wish and"
 407 echo "place an order."
 408 echo
 409 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 410 echo "----------------------------------------------------------------"