configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3.2])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.3002
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which versions the library are compatible with
  23 dnl each other we must keep a separate library version cout of the format c:r:a.
  24 dnl - if only implementation changed but all interfaces are kept, do r++
  25 dnl - if only functionality was added do c++,r=0,a++
  26 dnl - if any functionality was removed do c++,r=0,a=0.
  27 dnl
  28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  29 dnl
  30 LIBVERS=4:1:0
  31 AC_SUBST(LIBVERS)
  32
  33 AC_CANONICAL_TARGET
  34 AM_INIT_AUTOMAKE
  35 AM_MAINTAINER_MODE
  36
  37 AC_CONFIG_HEADERS([rrd_config.h])
  38
  39 dnl all our local stuff like install scripts and include files
  40 dnl is in there
  41
  42
  43 dnl determine the type of system we are running on
  44
  45 AC_SUBST(VERSION)
  46
  47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  48
  49 dnl Minimum Autoconf version required.
  50 AC_PREREQ(2.59)
  51
  52 dnl At the TOP of the HEADER
  53
  54 AH_TOP([
  55 #ifndef RRD_CONFIG_H
  56 #define RRD_CONFIG_H
  57
  58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  59 #undef MUST_DISABLE_FPMASK
  60
  61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  62 #undef MUST_DISABLE_SIGFPE
  63
  64 /* realloc does not support NULL as argument */
  65 #undef NO_NULL_REALLOC
  66
  67 /* lets enable madvise defines in NetBSD */
  68 #if defined(__NetBSD__)
  69 # if !defined(_NETBSD_SOURCE)
  70 #  define _NETBSD_SOURCE
  71 # endif
  72 #endif
  73
  74 ])
  75
  76 AH_BOTTOM([
  77
  78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  79 #  include <malloc/malloc.h>
  80 #endif
  81
  82 #include <rrd_config_bottom.h>
  83
  84 #endif
  85 ])
  86
  87 dnl Process Special Options
  88 dnl -----------------------------------
  89
  90 dnl How the vertical axis label is printed
  91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  92  [Vertical label angle: -90.0 (default) or 90.0])
  93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
  94  [Vertical label angle: -90.0 (default) or 90.0])
  95
  96 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
  97 [],[enable_rrdcgi=yes])
  98
  99 dnl Check if we run on a system that has fonts
 100 AC_ARG_WITH(rrd-default-font,
 101 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 102 [RRD_DEFAULT_FONT=$withval],[
 103   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 104         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 105   else
 106         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 107   fi
 108 ])
 109
 110 dnl Use mmap in rrd_update instead of seek+write
 111 AC_ARG_ENABLE([mmap],
 112 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 113 [],
 114 [enable_mmap=yes])
 115
 116 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 117 [],[enable_pthread=yes])
 118
 119 AC_ARG_ENABLE(static-programs,
 120      [  --enable-static-programs  Build static programs],
 121      [case "${enableval}" in
 122        yes) staticprogs=yes ;;
 123        no)  staticprogs=no ;;
 124        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 125      esac],[staticprogs=no])
 126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 127
 128
 129 CONFIGURE_PART(Audit Compilation Environment)
 130
 131
 132 dnl Check for the compiler and static/shared library creation.
 133 AC_PROG_CPP
 134 AC_PROG_CC
 135 AM_PROG_CC_C_O
 136 AC_PROG_LIBTOOL
 137
 138 dnl Try to detect/use GNU features
 139 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 140
 141 dnl check for -Werror separatly
 142 dnl (quite a few autotool checks don't work with -Werror; also, the
 143 dnl check for -Werror fails after checking and adding the other flags)
 144 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 145   [AC_COMPILE_IFELSE(
 146     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 147     [rd_cv_gcc_flag__Werror="yes"],
 148     [rd_cv_gcc_flag__Werror="no"])])
 149 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 150   WERROR="-Werror"
 151 else
 152   WERROR=""
 153 fi
 154 AC_SUBST(WERROR)
 155
 156 dnl which flags does the compiler support?
 157 if test "x$GCC" = "xyes"; then
 158   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 159     oCFLAGS="$CFLAGS"
 160     CFLAGS="$CFLAGS $flag"
 161     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 162     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 163        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 164     if eval test \$$cachename = no; then
 165          CFLAGS="$oCFLAGS"
 166     fi
 167   done
 168 fi
 169
 170
 171
 172 AC_SUBST(RRD_DEFAULT_FONT)
 173
 174 CONFIGURE_PART(Checking for Header Files)
 175
 176 dnl Checks for header files.
 177 AC_HEADER_STDC
 178 AC_HEADER_DIRENT
 179 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 180
 181 dnl Checks for typedefs, structures, and compiler characteristics.
 182 AC_C_CONST
 183 AC_HEADER_TIME
 184 AC_STRUCT_TM
 185
 186 CONFIGURE_PART(Test Library Functions)
 187
 188 dnl Checks for libraries.
 189 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 190
 191
 192 dnl add pic flag in any case this makes sure all our code is relocatable
 193 eval `./libtool --config | grep pic_flag`
 194 CFLAGS="$CFLAGS $pic_flag"
 195
 196
 197 dnl Checks for library functions.
 198 AC_FUNC_STRFTIME
 199 AC_FUNC_VPRINTF
 200
 201 AC_C_BIGENDIAN
 202
 203 dnl for each function found we get a definition in config.h
 204 dnl of the form HAVE_FUNCTION
 205
 206 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 207
 208 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 209
 210 dnl Could use these to know if we need to provide a prototype
 211 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 212
 213 dnl check for fdatasync. Solaris has fdatasync in the librt
 214
 215 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 216 dnl if there is no fdatasync we may get lucky with fsync
 217 AC_CHECK_FUNCS(fsync)
 218
 219
 220 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 221 if test "x$enable_mmap" = "xyes"; then
 222   case "$host" in
 223   *cygwin*)
 224     # the normal mmap test does not work in cygwin
 225     AC_CHECK_FUNCS(mmap)
 226     if test "x$ac_cv_func_mmap" = "xyes"; then
 227       ac_cv_func_mmap_fixed_mapped=yes
 228     fi
 229   ;;
 230   *)
 231     AC_CHECK_HEADERS(sys/mman.h)
 232     AC_FUNC_MMAP
 233     AC_CHECK_FUNCS(mmap munmap msync)
 234     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 235                                      # include <sys/mman.h>
 236                                      #endif])
 237     if test "x$ac_cv_have_decl_madvise" = "xyes";
 238     then
 239       AC_CHECK_FUNCS(madvise)
 240     else
 241       AC_CHECK_FUNCS(posix_madvise)
 242       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 243         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 244       fi
 245     fi
 246   ;;
 247   esac
 248   if test "x$ac_cv_func_mmap" != "xyes";
 249   then
 250     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 251 dnl enable_mmap="no"
 252   fi
 253 fi
 254
 255 dnl can we use posix_fadvise
 256 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 257 #include <fcntl.h>])
 258 AC_CHECK_FUNCS(posix_fadvise)
 259
 260 CONFIGURE_PART(Libintl Processing)
 261
 262
 263 dnl gettext
 264 GETTEXT_PACKAGE=rrdtool
 265 AC_SUBST(GETTEXT_PACKAGE)
 266 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 267
 268 AM_GLIB_GNU_GETTEXT()
 269
 270 AC_ARG_ENABLE(libintl,[  --disable-libintl        i18n support (libintl)],
 271 [],[enable_libintl=yes])
 272
 273 if test x$enable_libintl = xyes; then
 274   IT_PROG_INTLTOOL([0.35.0],[no-xml])
 275 fi
 276
 277 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
 278   AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
 279   enable_libintl=no
 280 fi
 281
 282 if test x$enable_libintl = xyes; then
 283   AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
 284 fi
 285
 286 if test x$enable_libintl = xyes ; then
 287   dnl it seems bsd synstems need to link against libintl
 288   dnl when compiling rrdupdate. lets check
 289   AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
 290 fi
 291
 292 dnl use for linking rrdupdate
 293 AC_SUBST(LIB_LIBINTL)
 294
 295 dnl do not touch the po stuff if we are not going to build intl
 296 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
 297
 298 if test x$enable_libintl = xyes; then
 299    AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
 300 fi
 301
 302 CONFIGURE_PART(IEEE Math Checks)
 303
 304
 305 dnl actual code to check if this works
 306 AC_CHECK_FUNCS(fpclassify, ,
 307   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 308     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 309 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 310       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 311
 312 AC_CHECK_FUNCS(isinf, ,
 313   [AC_MSG_CHECKING(for isinf with <math.h>)
 314     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 315 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 316       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 317
 318 dnl finite is BSD, isfinite is C99, so prefer the latter
 319 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 320 AC_TRY_RUN([
 321 #ifdef HAVE_MATH_H
 322 #include <math.h>
 323 #endif
 324 #ifdef HAVE_FLOAT_H
 325 #include <float.h>
 326 #endif
 327 int main ()
 328 {
 329 #ifdef isfinite
 330 #ifdef LDBL_MAX
 331   if (!isfinite(LDBL_MAX)) return 1;
 332 #endif
 333 #ifdef DBL_MAX
 334   if (!isfinite(DBL_MAX)) return 1;
 335 #endif
 336 #endif
 337 return 0;
 338 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 339 case "${target}" in
 340   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 341   *-sun-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 342   *) ac_cv_have_broken_isfinite=no ;;
 343 esac])
 344 ])
 345
 346 dnl the test does not seem to work on solaris 2.8
 347 dnl so lets fix this by hand
 348 case "${target}" in
 349   *-sun-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 350 esac
 351
 352 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 353   AC_DEFINE(HAVE_ISFINITE)
 354 else
 355   AC_CHECK_FUNCS(finite,[],
 356       [AC_CHECK_FUNCS(isfinite,[],
 357          [AC_MSG_CHECKING(for isfinite with <math.h>)
 358           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 359 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 360                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 361 fi
 362
 363 AC_FULL_IEEE
 364
 365 CONFIGURE_PART(Resolve Portability Issues)
 366
 367 dnl Do we need getopt_long
 368
 369 build_getopt=no
 370 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 371 AC_CHECK_FUNC(getopt_long,[],[
 372 RRD_GETOPT_LONG="getopt_long"
 373 build_getopt=yes
 374 ])
 375 AC_SUBST(RRD_GETOPT_LONG)
 376 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 377
 378 dnl what does realloc do if it gets called with a NULL pointer
 379
 380 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 381 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 382               int main(void){
 383               char *x = NULL;
 384               x = realloc (x,10);
 385               if (x==NULL) return 1;
 386               return 0;
 387              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 388
 389 if test x"$rd_cv_null_realloc" = xnope; then
 390 AC_DEFINE(NO_NULL_REALLOC)
 391 fi
 392
 393 AC_LANG_PUSH(C)
 394 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 395 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 396 AC_LINK_IFELSE(
 397     AC_LANG_PROGRAM(
 398            [[#include <time.h>]],
 399            [[ctime_r(NULL,NULL,0)]]
 400                    ),
 401     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 402       AC_LINK_IFELSE(
 403           AC_LANG_PROGRAM(
 404                 [[#include <time.h>]],
 405                 [[ctime_r(NULL,NULL)]]
 406                          ),
 407           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 408           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 409       )
 410     ],
 411     [ AC_LINK_IFELSE(
 412           AC_LANG_PROGRAM(
 413                 [[#include <time.h>]],
 414                 [[ctime_r(NULL,NULL)]]
 415                          ),
 416           [AC_MSG_RESULT(no)],
 417           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 418       )
 419     ]
 420 )
 421 AC_LANG_POP(C)
 422
 423 dnl Check for pthreads
 424 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 425
 426 AC_SUBST(MULTITHREAD_CFLAGS)
 427 AC_SUBST(MULTITHREAD_LDFLAGS)
 428
 429 if test $enable_pthread != no; then
 430  ACX_PTHREAD([
 431     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 432     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 433              ],
 434              [])
 435 fi
 436
 437 dnl since we use lots of *_r functions all over the code we better
 438 dnl make sure they are known
 439
 440 if test  "x$x_rflag" != "xno"; then
 441    CPPFLAGS="$CPPFLAGS $x_rflag"
 442 fi
 443
 444 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 445
 446 AC_LANG_PUSH(C)
 447 dnl see if we have to include malloc/malloc.h
 448 AC_MSG_CHECKING([do we need malloc/malloc.h])
 449 AC_LINK_IFELSE(
 450     AC_LANG_PROGRAM(
 451            [[#include <stdlib.h>]],
 452            [[malloc(1)]]
 453                    ),
 454     [ AC_MSG_RESULT([nope, works out of the box]) ],
 455     [ AC_LINK_IFELSE(
 456           AC_LANG_PROGRAM(
 457                 [[#include <stdlib.h>
 458                   #include <malloc/malloc.h>]],
 459                 [[malloc(1)]]
 460                          ),[
 461            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 462            AC_MSG_RESULT([yes we do])],
 463           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 464       )
 465     ]
 466 )
 467 AC_LANG_POP(C)
 468
 469 CONFIGURE_PART(Find 3rd-Party Libraries)
 470
 471 AC_ARG_ENABLE(libdbi,[  --disable-libdbi        do not build in support for libdbi],[have_libdbi=no],[
 472   XXX=$LIBS
 473   LIBS="$LIBS -ldbi -ldl"
 474   AC_MSG_CHECKING(for libdbi)
 475   AC_LINK_IFELSE(
 476     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 477                      [[dbi_initialize(NULL)]]
 478                     )
 479     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 480        AC_MSG_RESULT([yes])
 481        have_libdbi=yes
 482     ],[LIBS=$XXX
 483        AC_MSG_RESULT([no])
 484        have_libdbi=no
 485        exit 1
 486     ]
 487   )
 488 ])
 489 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 490
 491 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 492
 493
 494 CORE_LIBS="$LIBS"
 495
 496 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 497 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 498 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 499 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 500 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 501 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 502 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 503 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 504 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 505 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 506 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 507
 508 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 509   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 510 fi
 511
 512 ALL_LIBS="$LIBS"
 513 LIBS=
 514
 515 AC_SUBST(CORE_LIBS)
 516 AC_SUBST(ALL_LIBS)
 517
 518 CONFIGURE_PART(Prep for Building Language Bindings)
 519
 520 dnl Check for Perl and friends
 521 PATH=$PATH:/usr/perl5/bin
 522 export PATH
 523 AC_PATH_PROG(PERL, perl, no)
 524 AC_PATH_PROG(POD2MAN, pod2man, no)
 525 AC_PATH_PROG(POD2HTML, pod2html, no)
 526
 527
 528 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 529 [],[enable_perl=yes])
 530
 531
 532 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 533 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 534 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 535 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 536
 537 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 538         COMP_PERL=
 539 else
 540         COMP_PERL="perl_piped perl_shared"
 541         AC_MSG_CHECKING(for the perl version you are running)
 542         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 543         AC_MSG_RESULT($PERL_VERSION)
 544         if test -z "$PERLCC"; then
 545             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 546             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 547             AC_MSG_RESULT($perlcc)
 548             if test ! -x "$perlcc"; then
 549                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 550                 if test "$PERL_CC" = "no"; then
 551                     AC_MSG_WARN([
 552 I would not find the Compiler ($perlcc) that was originally used to compile
 553 your perl binary. You should either make sure that this compiler is
 554 available on your system, pick an other compiler and set PERLCC
 555 appropriately, or use a different perl setup that was compiled locally.
 556
 557 I will disable the compilation of the RRDs perl module for now.
 558 ])
 559                     COMP_PERL="perl_piped"
 560                 fi
 561             fi
 562         fi
 563 fi
 564
 565 AC_MSG_CHECKING(Perl Modules to build)
 566 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 567
 568 # Options to pass when configuring perl module
 569 langpref=$prefix
 570 test "$langpref" = "$(DESTDIR)NONE" && langpref='$(DESTDIR)'$ac_default_prefix
 571 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 572
 573 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 574
 575 dnl pass additional perl options when generating Makefile from Makefile.PL
 576 AC_ARG_ENABLE(perl-site-install,
 577 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 578                           together with rrdtool in $prefix/lib/perl. You have to
 579                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 580                           when you want to use them. When you set this option
 581                           the perl modules will get installed wherever
 582                           your perl setup thinks it is best.],
 583 [PERL_MAKE_OPTIONS=],[])
 584
 585 if test ! -z "$PERLCC"; then
 586    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 587
 588    if test ! -z "$PERLCCFLAGS"; then
 589        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 590    fi
 591
 592    if test -z "$PERLLD"; then
 593        PERLLD=$PERLCC
 594    fi
 595    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 596
 597    if test ! -z "$PERLLDFLAGS"; then
 598        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 599    fi
 600 fi
 601
 602 AC_ARG_WITH(perl-options,
 603 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 604                           generating Makefile from Makefile.PL. If you set this
 605                           option, interesting things may happen unless you know
 606                           what you are doing!],
 607 [PERL_MAKE_OPTIONS=$withval])
 608
 609 AC_SUBST(PERL_MAKE_OPTIONS)
 610 AC_SUBST(PERL)
 611 AC_SUBST(COMP_PERL)
 612 AC_SUBST(PERL_VERSION)
 613
 614 dnl Check for Ruby.
 615 AC_PATH_PROG(RUBY, ruby, no)
 616
 617 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 618 [],[enable_ruby=yes])
 619
 620 AC_MSG_CHECKING(if ruby modules can be built)
 621
 622 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 623         COMP_RUBY=
 624         AC_MSG_RESULT(No .. Ruby not found or disabled)
 625 else
 626         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 627                 COMP_RUBY="ruby"
 628                 AC_MSG_RESULT(YES)
 629         else
 630                 COMP_RUBY=
 631                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 632         fi
 633 fi
 634
 635 dnl pass additional ruby options when generating Makefile from Makefile.PL
 636 AC_ARG_ENABLE(ruby-site-install,
 637 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 638                           together with rrdtool in $prefix/lib/ruby. You have to
 639                           add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable
 640                           for ruby to find the RRD.so file.],
 641 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 642
 643
 644 AC_ARG_WITH(ruby-options,
 645 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 646                           generating Makefile from extconf.rb. If you set this
 647                           option, interesting things may happen unless you know
 648                           what you are doing!],
 649 [RUBY_MAKE_OPTIONS=$withval])
 650
 651 AC_SUBST(RUBY_MAKE_OPTIONS)
 652 AC_SUBST(RUBY)
 653 AC_SUBST(COMP_RUBY)
 654
 655 dnl Check for Lua.
 656 AC_PATH_PROG(LUA, lua, no)
 657
 658 AC_ARG_ENABLE(lua,[  --disable-lua           do not build the lua modules],
 659 [],[enable_lua=yes])
 660
 661 COMP_LUA=
 662 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 663   enable_lua=no
 664 else
 665   AC_MSG_CHECKING(for lua >= 5.0)
 666   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 667     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 668 LUA_EOF
 669   if test 0$LUA_MAJOR -lt 5; then
 670     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 671   else
 672     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 673     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 674     lua_vndot=$LUA_MAJOR$LUA_MINOR
 675     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 676     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 677       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 678         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 679           [lua_headerdir=lua$lua_vndot],
 680           [])],
 681         [])],
 682       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 683         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 684           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 685             [lua_headerdir=lua$lua_vdot],
 686             [])],
 687           [])],
 688         [AC_CHECK_HEADERS(lua.h,
 689           [AC_CHECK_HEADERS(lualib.h,
 690             [AC_CHECK_HEADER(lauxlib.h,
 691               [lua_headerdir=""],
 692               [lua_headerdir="no"])],
 693             [])],
 694           [])])])
 695
 696     if test "$lua_headerdir" = "no"; then
 697       enable_lua=no
 698     else
 699       COMP_LUA=lua
 700     fi
 701
 702     if test "$COMP_LUA" != "lua"; then
 703       enable_lua=no
 704       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 705     else
 706       # OK, headers found, let's check the libraries (LIBS is not used)
 707       LIBS=
 708       lua_havelib=no
 709       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 710       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 711         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 712           [lua_havelib=LUA$lua_vndot],
 713           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 714             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 715              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 716             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 717               [lua_havelib=$lua_vndot],
 718               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 719         [COMP_LUA=], [-lm])
 720       lua_libs=$LIBS
 721       LIBS=
 722
 723       # Options to pass when configuring Lua module
 724       if test  "$lua_havelib" != "no"; then
 725         # OK, headers and libs found. Try to set lua flags
 726         # and modules installation dirs with pkg-config
 727         if test "$PKGCONFIG" != "no"; then
 728           if test "$lua_vndot" = "50"; then
 729             lua_pkg_prefix=lualib
 730           else
 731             lua_pkg_prefix=lua
 732           fi
 733           # try with dot, without dot and finally without version
 734           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 735             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 736             # same binaries?
 737             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 738                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 739                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 740                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 741                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 742                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 743                 break
 744             fi
 745           done
 746         fi
 747
 748         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 749         # if lua 5.0 can't find compat-5.1, force installation of
 750         # compat-5.1.lua together with RRDtool.
 751         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 752           lua_need_compat51=1
 753           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 754         fi
 755
 756         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 757         if test "$LUA_CFLAGS" = ""; then
 758           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 759           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 760           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 761           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 762         fi
 763
 764         dnl pass additional lua options
 765         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 766         dnl found and install together with RRDtool, under $langpref.
 767         AC_ARG_ENABLE(lua-site-install,
 768         [  --enable-lua-site-install   by default the lua module is installed
 769                           together with rrdtool in $prefix/lib/lua/$lua_version.
 770                           You have to add $prefix/lib/lua/$lua_version/?.so to
 771                           package.cpath for lua to find 'rrd.so'. For lua 5.0
 772                           you may also need to change LUA_PATH to the same dir,
 773                           to require 'compat-5.1'. When you set this option the
 774                           lua modules will get installed wherever your Lua
 775                           setup thinks it is best.
 776                           WARNING: if you set this option, system lua modules
 777                           compat-5.1.lua and rrd.so, if any, may be overwritten.],
 778         [],
 779         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 780
 781         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 782         AC_SUBST(LUA)
 783         AC_SUBST(COMP_LUA)
 784         AC_SUBST(LUA_INSTALL_CMOD)
 785         AC_SUBST(LUA_INSTALL_LMOD)
 786         AC_SUBST(LUA_CFLAGS)
 787         AC_SUBST(LUA_LFLAGS)
 788         AC_SUBST(LUA_DEFINES)
 789       else
 790         enable_lua=no
 791         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 792       fi
 793     fi
 794   fi
 795 fi
 796 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 797 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 798 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 799       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 800 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 801 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 802 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 803 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 804
 805 enable_tcl_site=no
 806
 807 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 808 [],[enable_tcl=yes])
 809
 810 if test  "$enable_tcl" = "yes"; then
 811   dnl Check for Tcl.
 812   withval=""
 813   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 814   enable_tcl=no
 815   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 816     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 817     if test -f "$dir/tclConfig.sh" ; then
 818         tcl_config=$dir/tclConfig.sh
 819         enable_tcl=yes
 820         AC_MSG_RESULT(yes)
 821         break
 822     else
 823         AC_MSG_RESULT(no)
 824     fi
 825   done
 826
 827   if test "$enable_tcl" = "no"; then
 828         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 829   else
 830         . $tcl_config
 831         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 832         if test -n "$TCL_INC_DIR"; then
 833           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 834         fi
 835   fi
 836   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 837   [],[enable_tcl_site=yes])
 838
 839 fi
 840
 841 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 842 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 843
 844
 845 AC_SUBST(TCL_PREFIX)
 846 AC_SUBST(TCL_SHLIB_CFLAGS)
 847 AC_SUBST(TCL_SHLIB_LD)
 848 AC_SUBST(TCL_SHLIB_SUFFIX)
 849 AC_SUBST(TCL_PACKAGE_PATH)
 850 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 851 AC_SUBST(TCL_STUB_LIB_SPEC)
 852 AC_SUBST(TCL_VERSION)
 853 AC_SUBST(TCL_PACKAGE_DIR)
 854 AC_SUBST(TCL_INCLUDE_SPEC)
 855
 856 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 857 [],[enable_python=yes])
 858
 859 if test  "$enable_python" = "yes"; then
 860 dnl Check for python
 861 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 862 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 863 fi
 864
 865 if test  x$enable_python = xno; then
 866         COMP_PYTHON=
 867 else
 868         COMP_PYTHON="python"
 869 fi
 870
 871 AC_SUBST(COMP_PYTHON)
 872
 873 dnl Check for nroff
 874 AC_PATH_PROGS(NROFF, gnroff nroff)
 875 AC_PATH_PROGS(TROFF, groff troff)
 876
 877 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 878 if test -z "$RRDDOCDIR"; then
 879    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 880
 881
 882 CONFIGURE_PART(Apply Configuration Information)
 883
 884 AC_CONFIG_FILES([examples/shared-demo.pl])
 885 AC_CONFIG_FILES([examples/piped-demo.pl])
 886 AC_CONFIG_FILES([examples/stripes.pl])
 887 AC_CONFIG_FILES([examples/bigtops.pl])
 888 AC_CONFIG_FILES([examples/minmax.pl])
 889 AC_CONFIG_FILES([examples/4charts.pl])
 890 AC_CONFIG_FILES([examples/perftest.pl])
 891 AC_CONFIG_FILES([examples/Makefile])
 892 AC_CONFIG_FILES([doc/Makefile])
 893 AC_CONFIG_FILES([po/Makefile.in])
 894 AC_CONFIG_FILES([src/Makefile])
 895 AC_CONFIG_FILES([src/librrd.sym.in])
 896 AC_CONFIG_FILES([src/librrd.pc])
 897 AC_CONFIG_FILES([bindings/Makefile])
 898 AC_CONFIG_FILES([bindings/tcl/Makefile])
 899 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 900 AC_CONFIG_FILES([Makefile])
 901 AC_CONFIG_FILES([bindings/lua/Makefile])
 902
 903 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 904 AC_OUTPUT
 905
 906 AC_MSG_CHECKING(in)
 907 AC_MSG_RESULT(and out again)
 908
 909 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 910 sleep 1
 911 echo $ECHO_N ".$ECHO_C" 1>&6
 912 sleep 1
 913 echo $ECHO_N ".$ECHO_C" 1>&6
 914 sleep 1
 915 echo $ECHO_N ".$ECHO_C" 1>&6
 916 sleep 1
 917 echo $ECHO_N ".$ECHO_C" 1>&6
 918 sleep 1
 919 AC_MSG_RESULT([ just kidding ;-)])
 920 echo
 921 echo "----------------------------------------------------------------"
 922 echo "Config is DONE!"
 923 echo
 924 echo "          With MMAP IO: $enable_mmap"
 925 echo "      Build rrd_getopt: $build_getopt"
 926 echo "       Static programs: $staticprogs"
 927 echo "          Perl Modules: $COMP_PERL"
 928 echo "           Perl Binary: $PERL"
 929 echo "          Perl Version: $PERL_VERSION"
 930 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 931 echo "          Ruby Modules: $COMP_RUBY"
 932 echo "           Ruby Binary: $RUBY"
 933 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 934 echo "    Build Lua Bindings: $enable_lua"
 935 if test "$enable_lua" = "yes"; then
 936 echo "            Lua Binary: $LUA"
 937 echo "           Lua Version: $lua_version"
 938 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 939 if test "$lua_need_compat51" = "1"; then
 940 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 941 fi
 942 fi
 943 echo "    Build Tcl Bindings: $enable_tcl"
 944 echo " Build Python Bindings: $enable_python"
 945 echo "          Build rrdcgi: $enable_rrdcgi"
 946 echo "       Build librrd MT: $enable_pthread"
 947 echo "     Link with libintl: $enable_libintl"
 948 echo "           With libDBI: $have_libdbi"
 949 echo
 950 echo "             Libraries: $ALL_LIBS"
 951 echo
 952 echo "Type 'make' to compile the software and use 'make install' to "
 953 echo "install everything to: $prefix."
 954 echo
 955 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 956 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 957 echo "place an order."
 958 echo
 959 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 960 echo "----------------------------------------------------------------"