configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3.999])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.3999
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which versions the library are compatible with
  23 dnl each other we must keep a separate library version cout of the format c:r:a.
  24 dnl - if only implementation changed but all interfaces are kept, do r++
  25 dnl - if only functionality was added do c++,r=0,a++
  26 dnl - if any functionality was removed do c++,r=0,a=0.
  27 dnl
  28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  29 dnl
  30 LIBVERS=5:0:1
  31 AC_SUBST(LIBVERS)
  32
  33 AC_CANONICAL_TARGET
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AM_INIT_AUTOMAKE([silent-rules])
  36 AM_MAINTAINER_MODE
  37 AM_SILENT_RULES([yes])
  38 AC_CONFIG_HEADERS([rrd_config.h])
  39 AC_CONFIG_MACRO_DIR([m4])
  40
  41 dnl all our local stuff like install scripts and include files
  42 dnl is in there
  43
  44
  45 dnl determine the type of system we are running on
  46
  47 AC_SUBST(VERSION)
  48
  49 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  50
  51 dnl Minimum Autoconf version required.
  52 AC_PREREQ(2.59)
  53
  54 dnl At the TOP of the HEADER
  55
  56 AH_TOP([
  57 #ifndef RRD_CONFIG_H
  58 #define RRD_CONFIG_H
  59
  60 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  61 #undef MUST_DISABLE_FPMASK
  62
  63 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  64 #undef MUST_DISABLE_SIGFPE
  65
  66 /* realloc does not support NULL as argument */
  67 #undef NO_NULL_REALLOC
  68
  69 /* lets enable madvise defines in NetBSD */
  70 #if defined(__NetBSD__)
  71 # if !defined(_NETBSD_SOURCE)
  72 #  define _NETBSD_SOURCE
  73 # endif
  74 #endif
  75
  76 ])
  77
  78 AH_BOTTOM([
  79
  80 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  81 #  include <malloc/malloc.h>
  82 #endif
  83
  84 #include <rrd_config_bottom.h>
  85
  86 #endif
  87 ])
  88
  89 dnl Process Special Options
  90 dnl -----------------------------------
  91
  92 dnl How the vertical axis label is printed
  93 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  94  [Vertical label angle: -90.0 (default) or 90.0])
  95 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
  96  [Vertical label angle: -90.0 (default) or 90.0])
  97
  98 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
  99 [],[enable_rrdcgi=yes])
 100
 101 dnl Check if we run on a system that has fonts
 102 AC_ARG_WITH(rrd-default-font,
 103 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 104 [RRD_DEFAULT_FONT=$withval],[
 105   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 106         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 107   else
 108         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 109   fi
 110 ])
 111
 112 dnl Use mmap in rrd_update instead of seek+write
 113 AC_ARG_ENABLE([mmap],
 114 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 115 [],
 116 [enable_mmap=yes])
 117
 118 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 119 [],[enable_pthread=yes])
 120
 121 AC_ARG_ENABLE(static-programs,
 122      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 123      [case "${enableval}" in
 124        yes) staticprogs=yes ;;
 125        no)  staticprogs=no ;;
 126        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 127      esac],[staticprogs=no])
 128 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 129
 130
 131 CONFIGURE_PART(Audit Compilation Environment)
 132
 133
 134 dnl Check for the compiler and static/shared library creation.
 135 AC_PROG_CPP
 136 AC_PROG_CC
 137 AM_PROG_CC_C_O
 138 AC_PROG_LIBTOOL
 139
 140 dnl Try to detect/use GNU features
 141 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 142
 143 dnl check for -Werror separatly
 144 dnl (quite a few autotool checks do not work with -Werror; also, the
 145 dnl check for -Werror fails after checking and adding the other flags)
 146 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 147   [AC_COMPILE_IFELSE(
 148     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 149     [rd_cv_gcc_flag__Werror="yes"],
 150     [rd_cv_gcc_flag__Werror="no"])])
 151 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 152   WERROR="-Werror"
 153 else
 154   WERROR=""
 155 fi
 156 AC_SUBST(WERROR)
 157
 158 dnl which flags does the compiler support?
 159 if test "x$GCC" = "xyes"; then
 160   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 161     oCFLAGS="$CFLAGS"
 162     CFLAGS="$CFLAGS $flag"
 163     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 164     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 165        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 166     if eval test \$$cachename = no; then
 167          CFLAGS="$oCFLAGS"
 168     fi
 169   done
 170 fi
 171
 172
 173
 174 AC_SUBST(RRD_DEFAULT_FONT)
 175
 176 CONFIGURE_PART(Checking for Header Files)
 177
 178 dnl Checks for header files.
 179 AC_HEADER_STDC
 180 AC_HEADER_DIRENT
 181 AC_CHECK_HEADERS(libgen.h features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 182
 183 dnl Checks for typedefs, structures, and compiler characteristics.
 184 AC_C_CONST
 185 AC_HEADER_TIME
 186 AC_STRUCT_TM
 187
 188 CONFIGURE_PART(Test Library Functions)
 189
 190 dnl Checks for libraries.
 191 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 192
 193
 194 dnl add pic flag in any case this makes sure all our code is relocatable
 195 eval `./libtool --config | grep pic_flag`
 196 CFLAGS="$CFLAGS $pic_flag"
 197
 198
 199 dnl Checks for library functions.
 200 AC_FUNC_STRFTIME
 201 AC_FUNC_VPRINTF
 202
 203 AC_C_BIGENDIAN
 204
 205 dnl for each function found we get a definition in config.h
 206 dnl of the form HAVE_FUNCTION
 207
 208 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 209
 210 AC_FUNC_STRERROR_R
 211
 212 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 213
 214 dnl Could use these to know if we need to provide a prototype
 215 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 216
 217 dnl check for fdatasync. Solaris has fdatasync in the librt
 218
 219 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 220 dnl if there is no fdatasync we may get lucky with fsync
 221 AC_CHECK_FUNCS(fsync)
 222
 223
 224 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 225 if test "x$enable_mmap" = "xyes"; then
 226   case "$host" in
 227   *cygwin*)
 228     # the normal mmap test does not work in cygwin
 229     AC_CHECK_FUNCS(mmap)
 230     if test "x$ac_cv_func_mmap" = "xyes"; then
 231       ac_cv_func_mmap_fixed_mapped=yes
 232     fi
 233   ;;
 234   *)
 235     AC_CHECK_HEADERS(sys/mman.h)
 236     AC_FUNC_MMAP
 237     AC_CHECK_FUNCS(mmap munmap msync)
 238     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 239                                      # include <sys/mman.h>
 240                                      #endif])
 241     if test "x$ac_cv_have_decl_madvise" = "xyes";
 242     then
 243       AC_CHECK_FUNCS(madvise)
 244     else
 245       AC_CHECK_FUNCS(posix_madvise)
 246       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 247         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 248       fi
 249     fi
 250   ;;
 251   esac
 252   if test "x$ac_cv_func_mmap" != "xyes";
 253   then
 254     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 255 dnl enable_mmap="no"
 256   fi
 257 fi
 258
 259 dnl can we use posix_fadvise
 260 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 261 #include <fcntl.h>])
 262 AC_CHECK_FUNCS(posix_fadvise)
 263
 264 CONFIGURE_PART(Libintl Processing)
 265
 266 AM_GNU_GETTEXT_VERSION(0.14.4)
 267 AM_GNU_GETTEXT()
 268
 269 CONFIGURE_PART(IEEE Math Checks)
 270
 271
 272 dnl actual code to check if this works
 273 AC_CHECK_FUNCS(fpclassify, ,
 274   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 275     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 276 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 277       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 278
 279 AC_CHECK_FUNCS(isinf, ,
 280   [AC_MSG_CHECKING(for isinf with <math.h>)
 281     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 282 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 283       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 284
 285 dnl finite is BSD, isfinite is C99, so prefer the latter
 286 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 287 AC_TRY_RUN([
 288 #ifdef HAVE_MATH_H
 289 #include <math.h>
 290 #endif
 291 #ifdef HAVE_FLOAT_H
 292 #include <float.h>
 293 #endif
 294 int main ()
 295 {
 296 #ifdef isfinite
 297 #ifdef LDBL_MAX
 298   if (!isfinite(LDBL_MAX)) return 1;
 299 #endif
 300 #ifdef DBL_MAX
 301   if (!isfinite(DBL_MAX)) return 1;
 302 #endif
 303 #endif
 304 return 0;
 305 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 306 case "${target}" in
 307   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 308   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 309   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 310   *) ac_cv_have_broken_isfinite=no ;;
 311 esac])
 312 ])
 313
 314 dnl the test does not seem to work on solaris 2.8
 315 dnl so lets fix this by hand
 316 case "${target}" in
 317   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 318   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 319 esac
 320
 321 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 322   AC_DEFINE(HAVE_ISFINITE)
 323 else
 324   AC_CHECK_FUNCS(finite,[],
 325       [AC_CHECK_FUNCS(isfinite,[],
 326          [AC_MSG_CHECKING(for isfinite with <math.h>)
 327           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 328 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 329                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 330 fi
 331
 332 AC_FULL_IEEE
 333
 334 CONFIGURE_PART(Resolve Portability Issues)
 335
 336 CHECK_FOR_WORKING_MS_ASYNC
 337
 338 dnl Do we need getopt_long
 339
 340 dnl even when including our own getopt implementation
 341 dnl we may want to make sure we use the external
 342 dnl defined by libc to not run into linker resolve trouble
 343
 344 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 345 [AC_TRY_LINK([#include <unistd.h>],
 346   [extern int opterr; opterr = 1;],
 347   [rd_cv_var_int_opterr=yes],
 348   [rd_cv_var_int_opterr=no])])
 349 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 350   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 351 fi
 352
 353 build_getopt=no
 354 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 355 AC_CHECK_FUNC(getopt_long,[],[
 356 RRD_GETOPT_LONG="getopt_long"
 357 build_getopt=yes
 358 ])
 359 AC_SUBST(RRD_GETOPT_LONG)
 360 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 361
 362 dnl what does realloc do if it gets called with a NULL pointer
 363
 364 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 365 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 366               int main(void){
 367               char *x = NULL;
 368               x = realloc (x,10);
 369               if (x==NULL) return 1;
 370               return 0;
 371              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 372
 373 if test x"$rd_cv_null_realloc" = xnope; then
 374 AC_DEFINE(NO_NULL_REALLOC)
 375 fi
 376
 377 AC_LANG_PUSH(C)
 378 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 379 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 380 AC_LINK_IFELSE(
 381     AC_LANG_PROGRAM(
 382            [[#include <time.h>]],
 383            [[ctime_r(NULL,NULL,0)]]
 384                    ),
 385     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 386       AC_LINK_IFELSE(
 387           AC_LANG_PROGRAM(
 388                 [[#include <time.h>]],
 389                 [[ctime_r(NULL,NULL)]]
 390                          ),
 391           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 392           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 393       )
 394     ],
 395     [ AC_LINK_IFELSE(
 396           AC_LANG_PROGRAM(
 397                 [[#include <time.h>]],
 398                 [[ctime_r(NULL,NULL)]]
 399                          ),
 400           [AC_MSG_RESULT(no)],
 401           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 402       )
 403     ]
 404 )
 405 AC_LANG_POP(C)
 406
 407 dnl Check for pthreads
 408 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 409
 410 AC_SUBST(MULTITHREAD_CFLAGS)
 411 AC_SUBST(MULTITHREAD_LDFLAGS)
 412
 413 if test $enable_pthread != no; then
 414  ACX_PTHREAD([
 415     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 416     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 417              ],
 418              [])
 419 fi
 420
 421 dnl since we use lots of *_r functions all over the code we better
 422 dnl make sure they are known
 423
 424 if test  "x$x_rflag" != "xno"; then
 425    CPPFLAGS="$CPPFLAGS $x_rflag"
 426 fi
 427
 428 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 429
 430 AC_LANG_PUSH(C)
 431 dnl see if we have to include malloc/malloc.h
 432 AC_MSG_CHECKING([do we need malloc/malloc.h])
 433 AC_LINK_IFELSE(
 434     AC_LANG_PROGRAM(
 435            [[#include <stdlib.h>]],
 436            [[malloc(1)]]
 437                    ),
 438     [ AC_MSG_RESULT([nope, works out of the box]) ],
 439     [ AC_LINK_IFELSE(
 440           AC_LANG_PROGRAM(
 441                 [[#include <stdlib.h>
 442                   #include <malloc/malloc.h>]],
 443                 [[malloc(1)]]
 444                          ),[
 445            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 446            AC_MSG_RESULT([yes we do])],
 447           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 448       )
 449     ]
 450 )
 451 AC_LANG_POP(C)
 452
 453 CONFIGURE_PART(Find 3rd-Party Libraries)
 454
 455 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
 456   XXX=$LIBS
 457   LIBS="$LIBS -ldbi -ldl"
 458   AC_MSG_CHECKING(for libdbi)
 459   AC_LINK_IFELSE(
 460     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 461                      [[dbi_initialize(NULL)]]
 462                     )
 463     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 464        AC_MSG_RESULT([yes])
 465        have_libdbi=yes
 466     ],[LIBS=$XXX
 467        AC_MSG_RESULT([no])
 468        have_libdbi=no
 469     ]
 470   )
 471 ])
 472 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 473
 474 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 475
 476
 477 CORE_LIBS="$LIBS"
 478
 479 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 480 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 481 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 482 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 483 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 484 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 485 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 486 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 487 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 488 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 489 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 490
 491 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 492   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 493 fi
 494
 495 ALL_LIBS="$LIBS"
 496 LIBS=
 497
 498 AC_SUBST(CORE_LIBS)
 499 AC_SUBST(ALL_LIBS)
 500
 501 CONFIGURE_PART(Prep for Building Language Bindings)
 502
 503 dnl Check for Perl and friends
 504 PATH=$PATH:/usr/perl5/bin
 505 export PATH
 506 AC_PATH_PROG(PERL, perl, no)
 507 AC_PATH_PROG(POD2MAN, pod2man, no)
 508 AC_PATH_PROG(POD2HTML, pod2html, no)
 509
 510
 511 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 512 [],[enable_perl=yes])
 513
 514
 515 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 516 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 517 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 518 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 519
 520 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 521         COMP_PERL=
 522 else
 523         COMP_PERL="perl_piped perl_shared"
 524         AC_MSG_CHECKING(for the perl version you are running)
 525         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 526         AC_MSG_RESULT($PERL_VERSION)
 527         if test -z "$PERLCC"; then
 528             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 529             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 530             AC_MSG_RESULT($perlcc)
 531             if test ! -x "$perlcc"; then
 532                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 533                 if test "$PERL_CC" = "no"; then
 534                     AC_MSG_WARN([
 535 I would not find the Compiler ($perlcc) that was originally used to compile
 536 your perl binary. You should either make sure that this compiler is
 537 available on your system, pick an other compiler and set PERLCC
 538 appropriately, or use a different perl setup that was compiled locally.
 539
 540 I will disable the compilation of the RRDs perl module for now.
 541 ])
 542                     COMP_PERL="perl_piped"
 543                 fi
 544             fi
 545         fi
 546 fi
 547
 548 AC_MSG_CHECKING(Perl Modules to build)
 549 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 550
 551 # Options to pass when configuring perl module
 552 langpref=$prefix
 553 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 554 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 555
 556 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 557
 558 dnl pass additional perl options when generating Makefile from Makefile.PL
 559 AC_ARG_ENABLE(perl-site-install,
 560 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 561 [PERL_MAKE_OPTIONS=],[])
 562
 563 if test ! -z "$PERLCC"; then
 564    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 565
 566    if test ! -z "$PERLCCFLAGS"; then
 567        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 568    fi
 569
 570    if test -z "$PERLLD"; then
 571        PERLLD=$PERLCC
 572    fi
 573    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 574
 575    if test ! -z "$PERLLDFLAGS"; then
 576        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 577    fi
 578 fi
 579
 580 AC_ARG_WITH(perl-options,
 581 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 582                           generating Makefile from Makefile.PL. If you set this
 583                           option, interesting things may happen unless you know
 584                           what you are doing!],
 585 [PERL_MAKE_OPTIONS=$withval])
 586
 587 AC_SUBST(PERL_MAKE_OPTIONS)
 588 AC_SUBST(PERL)
 589 AC_SUBST(COMP_PERL)
 590 AC_SUBST(PERL_VERSION)
 591
 592 dnl Check for Ruby.
 593 AC_PATH_PROG(RUBY, ruby, no)
 594
 595 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 596 [],[enable_ruby=yes])
 597
 598 AC_MSG_CHECKING(if ruby modules can be built)
 599
 600 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 601         COMP_RUBY=
 602         AC_MSG_RESULT(No .. Ruby not found or disabled)
 603 else
 604         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 605                 COMP_RUBY="ruby"
 606                 AC_MSG_RESULT(YES)
 607         else
 608                 COMP_RUBY=
 609                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 610         fi
 611 fi
 612
 613 dnl pass additional ruby options when generating Makefile from Makefile.PL
 614 AC_ARG_ENABLE(ruby-site-install,
 615 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 616 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 617
 618
 619 AC_ARG_WITH(ruby-options,
 620 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 621                           generating Makefile from extconf.rb. If you set this
 622                           option, interesting things may happen unless you know
 623                           what you are doing!],
 624 [RUBY_MAKE_OPTIONS=$withval])
 625
 626 AC_SUBST(RUBY_MAKE_OPTIONS)
 627 AC_SUBST(RUBY)
 628 AC_SUBST(COMP_RUBY)
 629
 630 dnl Check for Lua.
 631 AC_PATH_PROG(LUA, lua, no)
 632
 633 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 634 [],[enable_lua=yes])
 635
 636 COMP_LUA=
 637 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 638   enable_lua=no
 639 else
 640   AC_MSG_CHECKING(for lua >= 5.0)
 641   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 642     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 643 LUA_EOF
 644   if test 0$LUA_MAJOR -lt 5; then
 645     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 646   else
 647     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 648     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 649     lua_vndot=$LUA_MAJOR$LUA_MINOR
 650     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 651     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 652       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 653         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 654           [lua_headerdir=lua$lua_vndot],
 655           [])],
 656         [])],
 657       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 658         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 659           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 660             [lua_headerdir=lua$lua_vdot],
 661             [])],
 662           [])],
 663         [AC_CHECK_HEADERS(lua.h,
 664           [AC_CHECK_HEADERS(lualib.h,
 665             [AC_CHECK_HEADER(lauxlib.h,
 666               [lua_headerdir=""],
 667               [lua_headerdir="no"])],
 668             [])],
 669           [])])])
 670
 671     if test "$lua_headerdir" = "no"; then
 672       enable_lua=no
 673     else
 674       COMP_LUA=lua
 675     fi
 676
 677     if test "$COMP_LUA" != "lua"; then
 678       enable_lua=no
 679       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 680     else
 681       # OK, headers found, let's check the libraries (LIBS is not used)
 682       LIBS=
 683       lua_havelib=no
 684       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 685       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 686         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 687           [lua_havelib=LUA$lua_vndot],
 688           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 689             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 690              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 691             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 692               [lua_havelib=$lua_vndot],
 693               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 694         [COMP_LUA=], [-lm])
 695       lua_libs=$LIBS
 696       LIBS=
 697
 698       # Options to pass when configuring Lua module
 699       if test  "$lua_havelib" != "no"; then
 700         # OK, headers and libs found. Try to set lua flags
 701         # and modules installation dirs with pkg-config
 702         if test "$PKGCONFIG" != "no"; then
 703           if test "$lua_vndot" = "50"; then
 704             lua_pkg_prefix=lualib
 705           else
 706             lua_pkg_prefix=lua
 707           fi
 708           # try with dot, without dot and finally without version
 709           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 710             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 711             # same binaries?
 712             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 713                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 714                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 715                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 716                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 717                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 718                 break
 719             fi
 720           done
 721         fi
 722
 723         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 724         # if lua 5.0 can't find compat-5.1, force installation of
 725         # compat-5.1.lua together with RRDtool.
 726         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 727           lua_need_compat51=1
 728           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 729         fi
 730
 731         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 732         if test "$LUA_CFLAGS" = ""; then
 733           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 734           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 735           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 736           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 737         fi
 738
 739         dnl pass additional lua options
 740         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 741         dnl found and install together with RRDtool, under $langpref.
 742         AC_ARG_ENABLE(lua-site-install,
 743         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 744         [],
 745         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 746
 747         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 748         AC_SUBST(LUA)
 749         AC_SUBST(COMP_LUA)
 750         AC_SUBST(LUA_INSTALL_CMOD)
 751         AC_SUBST(LUA_INSTALL_LMOD)
 752         AC_SUBST(LUA_CFLAGS)
 753         AC_SUBST(LUA_LFLAGS)
 754         AC_SUBST(LUA_DEFINES)
 755       else
 756         enable_lua=no
 757         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 758       fi
 759     fi
 760   fi
 761 fi
 762 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 763 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 764 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 765       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 766 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 767 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 768 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 769 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 770
 771 enable_tcl_site=no
 772
 773 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 774 [],[enable_tcl=yes])
 775
 776 if test  "$enable_tcl" = "yes"; then
 777   dnl Check for Tcl.
 778   withval=""
 779   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 780   enable_tcl=no
 781   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 782     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 783     if test -f "$dir/tclConfig.sh" ; then
 784         tcl_config=$dir/tclConfig.sh
 785         enable_tcl=yes
 786         AC_MSG_RESULT(yes)
 787         break
 788     else
 789         AC_MSG_RESULT(no)
 790     fi
 791   done
 792
 793   if test "$enable_tcl" = "no"; then
 794         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 795   else
 796         . $tcl_config
 797         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 798         if test -n "$TCL_INC_DIR"; then
 799           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 800         fi
 801   fi
 802   AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 803   [],[enable_tcl_site=yes])
 804
 805 fi
 806
 807 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 808 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 809
 810
 811 AC_SUBST(TCL_PREFIX)
 812 AC_SUBST(TCL_SHLIB_CFLAGS)
 813 AC_SUBST(TCL_SHLIB_LD)
 814 AC_SUBST(TCL_SHLIB_SUFFIX)
 815 AC_SUBST(TCL_PACKAGE_PATH)
 816 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 817 AC_SUBST(TCL_STUB_LIB_SPEC)
 818 AC_SUBST(TCL_VERSION)
 819 AC_SUBST(TCL_PACKAGE_DIR)
 820 AC_SUBST(TCL_INCLUDE_SPEC)
 821
 822 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 823 [],[enable_python=yes])
 824
 825 if test  "$enable_python" = "yes"; then
 826 dnl Check for python
 827 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 828 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 829 fi
 830
 831 if test  x$enable_python = xno; then
 832         COMP_PYTHON=
 833 else
 834         COMP_PYTHON="python"
 835 fi
 836
 837 AC_SUBST(COMP_PYTHON)
 838
 839 dnl Check for nroff
 840 AC_PATH_PROGS(NROFF, gnroff nroff)
 841 AC_PATH_PROGS(TROFF, groff troff)
 842
 843 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 844 if test -z "$RRDDOCDIR"; then
 845    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 846
 847
 848 CONFIGURE_PART(Apply Configuration Information)
 849
 850 AC_CONFIG_FILES([examples/shared-demo.pl])
 851 AC_CONFIG_FILES([examples/piped-demo.pl])
 852 AC_CONFIG_FILES([examples/stripes.pl])
 853 AC_CONFIG_FILES([examples/bigtops.pl])
 854 AC_CONFIG_FILES([examples/minmax.pl])
 855 AC_CONFIG_FILES([examples/4charts.pl])
 856 AC_CONFIG_FILES([examples/perftest.pl])
 857 AC_CONFIG_FILES([examples/Makefile])
 858 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 859 AC_CONFIG_FILES([doc/Makefile])
 860 AC_CONFIG_FILES([po/Makefile.in])
 861 AC_CONFIG_FILES([intl/Makefile])
 862 AC_CONFIG_FILES([src/Makefile])
 863 AC_CONFIG_FILES([src/librrd.sym.in])
 864 AC_CONFIG_FILES([src/librrd.pc])
 865 AC_CONFIG_FILES([bindings/Makefile])
 866 AC_CONFIG_FILES([bindings/tcl/Makefile])
 867 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 868 AC_CONFIG_FILES([Makefile])
 869 AC_CONFIG_FILES([bindings/lua/Makefile])
 870
 871 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 872 AC_OUTPUT
 873
 874 AC_MSG_CHECKING(in)
 875 AC_MSG_RESULT(and out again)
 876
 877 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 878 sleep 1
 879 echo $ECHO_N ".$ECHO_C" 1>&6
 880 sleep 1
 881 echo $ECHO_N ".$ECHO_C" 1>&6
 882 sleep 1
 883 echo $ECHO_N ".$ECHO_C" 1>&6
 884 sleep 1
 885 echo $ECHO_N ".$ECHO_C" 1>&6
 886 sleep 1
 887 AC_MSG_RESULT([ just kidding ;-)])
 888 echo
 889 echo "----------------------------------------------------------------"
 890 echo "Config is DONE!"
 891 echo
 892 echo "          With MMAP IO: $enable_mmap"
 893 echo "      Build rrd_getopt: $build_getopt"
 894 echo "       Static programs: $staticprogs"
 895 echo "          Perl Modules: $COMP_PERL"
 896 echo "           Perl Binary: $PERL"
 897 echo "          Perl Version: $PERL_VERSION"
 898 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 899 echo "          Ruby Modules: $COMP_RUBY"
 900 echo "           Ruby Binary: $RUBY"
 901 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 902 echo "    Build Lua Bindings: $enable_lua"
 903 if test "$enable_lua" = "yes"; then
 904 echo "            Lua Binary: $LUA"
 905 echo "           Lua Version: $lua_version"
 906 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 907 if test "$lua_need_compat51" = "1"; then
 908 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 909 fi
 910 fi
 911 echo "    Build Tcl Bindings: $enable_tcl"
 912 echo " Build Python Bindings: $enable_python"
 913 echo "          Build rrdcgi: $enable_rrdcgi"
 914 echo "       Build librrd MT: $enable_pthread"
 915 echo "           Use gettext: $USE_NLS"
 916 echo "           With libDBI: $have_libdbi"
 917 echo
 918 echo "             Libraries: $ALL_LIBS"
 919 echo
 920 echo "Type 'make' to compile the software and use 'make install' to "
 921 echo "install everything to: $prefix."
 922 echo
 923 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 924 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 925 echo "place an order."
 926 echo
 927 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 928 echo "----------------------------------------------------------------"