rename ntmake.pl to ntmake.PL so that it does not get installed
[rrdtool.git] / configure.ac
1 dnl RRDtool AutoConf script ... 
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
7  
8 dnl tell automake the this script is for rrdtool
9
10 dnl the official version number is
11 dnl a.b.c
12 AC_INIT([rrdtool],[1.3.2])
13
14 dnl for testing a numberical version number comes handy
15 dnl the released version are
16 dnl a.bccc
17 dnl the devel versions will be something like
18 dnl a.b999yymmddhh 
19 NUMVERS=1.3002
20 AC_SUBST(NUMVERS)
21
22 dnl for the linker to understand which versions the library are compatible with
23 dnl each other we must keep a separate library version cout of the format c:r:a.
24 dnl - if only implementation changed but all interfaces are kept, do r++
25 dnl - if only functionality was added do c++,r=0,a++
26 dnl - if any functionality was removed do c++,r=0,a=0.
27 dnl
28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
29 dnl 
30 LIBVERS=4:1:0
31 AC_SUBST(LIBVERS)
32
33 AC_CANONICAL_TARGET
34 AM_INIT_AUTOMAKE
35 AM_MAINTAINER_MODE
36
37 AC_CONFIG_HEADERS([rrd_config.h])
38
39 dnl all our local stuff like install scripts and include files
40 dnl is in there
41
42
43 dnl determine the type of system we are running on
44
45 AC_SUBST(VERSION)
46
47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
48
49 dnl Minimum Autoconf version required.
50 AC_PREREQ(2.59)
51
52 dnl At the TOP of the HEADER
53
54 AH_TOP([
55 #ifndef RRD_CONFIG_H
56 #define RRD_CONFIG_H
57
58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
59 #undef MUST_DISABLE_FPMASK
60
61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
62 #undef MUST_DISABLE_SIGFPE
63
64 /* realloc does not support NULL as argument */
65 #undef NO_NULL_REALLOC
66
67 /* lets enable madvise defines in NetBSD */ 
68 #if defined(__NetBSD__)
69 # if !defined(_NETBSD_SOURCE)
70 #  define _NETBSD_SOURCE
71 # endif
72 #endif
73
74 ])
75
76 AH_BOTTOM([
77
78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
79 #  include <malloc/malloc.h>
80 #endif
81
82 #include <rrd_config_bottom.h>
83
84 #endif
85 ])
86
87 dnl Process Special Options
88 dnl -----------------------------------
89
90 dnl How the vertical axis label is printed
91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE, 
92  [Vertical label angle: -90.0 (default) or 90.0])
93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
94  [Vertical label angle: -90.0 (default) or 90.0])
95
96 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
97 [],[enable_rrdcgi=yes])
98
99 dnl Check if we run on a system that has fonts
100 AC_ARG_WITH(rrd-default-font,
101 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
102 [RRD_DEFAULT_FONT=$withval],[
103   if test -d ${WINDIR:-nodir}/cour.ttf ; then
104         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
105   else
106         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
107   fi
108 ])
109
110 dnl Use mmap in rrd_update instead of seek+write
111 AC_ARG_ENABLE([mmap],
112 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
113 [],
114 [enable_mmap=yes])
115
116 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
117 [],[enable_pthread=yes])
118
119 AC_ARG_ENABLE(static-programs,
120      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
121      [case "${enableval}" in
122        yes) staticprogs=yes ;;
123        no)  staticprogs=no ;;
124        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
125      esac],[staticprogs=no])
126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
127
128
129 CONFIGURE_PART(Audit Compilation Environment)
130
131
132 dnl Check for the compiler and static/shared library creation.
133 AC_PROG_CPP
134 AC_PROG_CC
135 AM_PROG_CC_C_O
136 AC_PROG_LIBTOOL
137
138 dnl Try to detect/use GNU features
139 CFLAGS="$CFLAGS -D_GNU_SOURCE"
140
141 dnl check for -Werror separatly
142 dnl (quite a few autotool checks don't work with -Werror; also, the
143 dnl check for -Werror fails after checking and adding the other flags)
144 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
145   [AC_COMPILE_IFELSE(
146     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
147     [rd_cv_gcc_flag__Werror="yes"],
148     [rd_cv_gcc_flag__Werror="no"])])
149 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
150   WERROR="-Werror"
151 else
152   WERROR=""
153 fi
154 AC_SUBST(WERROR)
155
156 dnl which flags does the compiler support?
157 if test "x$GCC" = "xyes"; then
158   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
159     oCFLAGS="$CFLAGS"
160     CFLAGS="$CFLAGS $flag"
161     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
162     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
163        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
164     if eval test \$$cachename = no; then
165          CFLAGS="$oCFLAGS"
166     fi
167   done
168 fi
169
170
171
172 AC_SUBST(RRD_DEFAULT_FONT)
173
174 CONFIGURE_PART(Checking for Header Files)
175  
176 dnl Checks for header files.
177 AC_HEADER_STDC
178 AC_HEADER_DIRENT
179 AC_CHECK_HEADERS(libgen.h features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
180
181 dnl Checks for typedefs, structures, and compiler characteristics.
182 AC_C_CONST
183 AC_HEADER_TIME
184 AC_STRUCT_TM
185
186 CONFIGURE_PART(Test Library Functions)
187
188 dnl Checks for libraries.
189 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
190
191
192 dnl add pic flag in any case this makes sure all our code is relocatable
193 eval `./libtool --config | grep pic_flag`
194 CFLAGS="$CFLAGS $pic_flag"
195
196
197 dnl Checks for library functions.
198 AC_FUNC_STRFTIME
199 AC_FUNC_VPRINTF
200
201 AC_C_BIGENDIAN
202
203 dnl for each function found we get a definition in config.h 
204 dnl of the form HAVE_FUNCTION
205
206 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
207
208 CONFIGURE_PART(Map/Fadvis/Madvise checking)
209
210 dnl Could use these to know if we need to provide a prototype
211 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
212
213 dnl check for fdatasync. Solaris has fdatasync in the librt
214
215 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
216 dnl if there is no fdatasync we may get lucky with fsync
217 AC_CHECK_FUNCS(fsync)
218
219
220 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
221 if test "x$enable_mmap" = "xyes"; then
222   case "$host" in
223   *cygwin*)
224     # the normal mmap test does not work in cygwin
225     AC_CHECK_FUNCS(mmap)
226     if test "x$ac_cv_func_mmap" = "xyes"; then
227       ac_cv_func_mmap_fixed_mapped=yes
228     fi
229   ;;
230   *)
231     AC_CHECK_HEADERS(sys/mman.h)
232     AC_FUNC_MMAP
233     AC_CHECK_FUNCS(mmap munmap msync)
234     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
235                                      # include <sys/mman.h>
236                                      #endif])
237     if test "x$ac_cv_have_decl_madvise" = "xyes";
238     then
239       AC_CHECK_FUNCS(madvise)
240     else
241       AC_CHECK_FUNCS(posix_madvise)
242       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
243         AC_MSG_WARN([madvise() nor posix_madvise() found.])
244       fi
245     fi
246   ;;
247   esac
248   if test "x$ac_cv_func_mmap" != "xyes";
249   then
250     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
251 dnl enable_mmap="no"
252   fi
253 fi
254
255 dnl can we use posix_fadvise
256 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
257 #include <fcntl.h>])
258 AC_CHECK_FUNCS(posix_fadvise)
259
260 CONFIGURE_PART(Libintl Processing)
261
262
263 dnl gettext
264 GETTEXT_PACKAGE=rrdtool
265 AC_SUBST(GETTEXT_PACKAGE)
266 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
267
268 AM_GLIB_GNU_GETTEXT()
269
270 AC_ARG_ENABLE(libintl,AS_HELP_STRING([--disable-libintl],[i18n support (libintl)]),
271 [],[enable_libintl=yes])
272
273 if test x$enable_libintl = xyes; then
274   IT_PROG_INTLTOOL([0.35.0],[no-xml])
275 fi
276
277 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
278   AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
279   enable_libintl=no
280 fi
281
282 if test x$enable_libintl = xyes; then
283   AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
284 fi
285
286 if test x$enable_libintl = xyes ; then
287   dnl it seems bsd synstems need to link against libintl
288   dnl when compiling rrdupdate. lets check        
289   AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
290 fi
291
292 dnl use for linking rrdupdate
293 AC_SUBST(LIB_LIBINTL)
294
295 dnl do not touch the po stuff if we are not going to build intl
296 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
297
298 if test x$enable_libintl = xyes; then
299    AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
300 fi
301
302 CONFIGURE_PART(IEEE Math Checks)
303  
304
305 dnl actual code to check if this works
306 AC_CHECK_FUNCS(fpclassify, ,
307   [AC_MSG_CHECKING(for fpclassify with <math.h>)
308     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
309 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
310       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
311
312 AC_CHECK_FUNCS(isinf, ,
313   [AC_MSG_CHECKING(for isinf with <math.h>)
314     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
315 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
316       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
317
318 dnl finite is BSD, isfinite is C99, so prefer the latter
319 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
320 AC_TRY_RUN([
321 #ifdef HAVE_MATH_H
322 #include <math.h>
323 #endif
324 #ifdef HAVE_FLOAT_H
325 #include <float.h>
326 #endif
327 int main ()
328 {
329 #ifdef isfinite
330 #ifdef LDBL_MAX
331   if (!isfinite(LDBL_MAX)) return 1;
332 #endif
333 #ifdef DBL_MAX
334   if (!isfinite(DBL_MAX)) return 1;
335 #endif
336 #endif
337 return 0;
338 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
339 case "${target}" in
340   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
341   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
342   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
343   *) ac_cv_have_broken_isfinite=no ;;
344 esac])
345 ])
346
347 dnl the test does not seem to work on solaris 2.8
348 dnl so lets fix this by hand
349 case "${target}" in
350   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
351   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
352 esac
353
354 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
355   AC_DEFINE(HAVE_ISFINITE)
356 else
357   AC_CHECK_FUNCS(finite,[],
358       [AC_CHECK_FUNCS(isfinite,[],
359          [AC_MSG_CHECKING(for isfinite with <math.h>)
360           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
361 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
362                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
363 fi  
364
365 AC_FULL_IEEE
366
367 CONFIGURE_PART(Resolve Portability Issues)
368
369 CHECK_FOR_WORKING_MS_ASYNC
370
371 dnl Do we need getopt_long
372
373 build_getopt=no
374 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
375 AC_CHECK_FUNC(getopt_long,[],[
376 RRD_GETOPT_LONG="getopt_long"
377 build_getopt=yes
378 ])
379 AC_SUBST(RRD_GETOPT_LONG)
380 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
381
382 dnl what does realloc do if it gets called with a NULL pointer
383
384 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
385 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
386               int main(void){
387               char *x = NULL;
388               x = realloc (x,10);
389               if (x==NULL) return 1;
390               return 0;
391              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
392
393 if test x"$rd_cv_null_realloc" = xnope; then
394 AC_DEFINE(NO_NULL_REALLOC)
395 fi
396
397 AC_LANG_PUSH(C)
398 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
399 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
400 AC_LINK_IFELSE(
401     AC_LANG_PROGRAM(
402            [[#include <time.h>]],
403            [[ctime_r(NULL,NULL,0)]]
404                    ),
405     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
406       AC_LINK_IFELSE(
407           AC_LANG_PROGRAM(
408                 [[#include <time.h>]],
409                 [[ctime_r(NULL,NULL)]]
410                          ),
411           [AC_MSG_RESULT([yes, this seems to be solaris style])],
412           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
413       )
414     ],  
415     [ AC_LINK_IFELSE(
416           AC_LANG_PROGRAM(
417                 [[#include <time.h>]],
418                 [[ctime_r(NULL,NULL)]]
419                          ),
420           [AC_MSG_RESULT(no)],
421           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
422       )
423     ]  
424 )
425 AC_LANG_POP(C)
426
427 dnl Check for pthreads
428 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
429  
430 AC_SUBST(MULTITHREAD_CFLAGS)
431 AC_SUBST(MULTITHREAD_LDFLAGS)
432
433 if test $enable_pthread != no; then 
434  ACX_PTHREAD([
435     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
436     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
437              ],
438              [])
439 fi
440
441 dnl since we use lots of *_r functions all over the code we better
442 dnl make sure they are known
443
444 if test  "x$x_rflag" != "xno"; then
445    CPPFLAGS="$CPPFLAGS $x_rflag"
446 fi
447
448 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
449
450 AC_LANG_PUSH(C)
451 dnl see if we have to include malloc/malloc.h
452 AC_MSG_CHECKING([do we need malloc/malloc.h])
453 AC_LINK_IFELSE(
454     AC_LANG_PROGRAM(
455            [[#include <stdlib.h>]],
456            [[malloc(1)]]
457                    ),
458     [ AC_MSG_RESULT([nope, works out of the box]) ],
459     [ AC_LINK_IFELSE(
460           AC_LANG_PROGRAM(
461                 [[#include <stdlib.h>
462                   #include <malloc/malloc.h>]],
463                 [[malloc(1)]]
464                          ),[
465            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
466            AC_MSG_RESULT([yes we do])],
467           [AC_MSG_ERROR([Can not figure how to compile malloc])]
468       )
469     ]  
470 )
471 AC_LANG_POP(C)
472
473 CONFIGURE_PART(Find 3rd-Party Libraries)
474
475 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
476   XXX=$LIBS
477   LIBS="$LIBS -ldbi -ldl"
478   AC_MSG_CHECKING(for libdbi)
479   AC_LINK_IFELSE(
480     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]], 
481                      [[dbi_initialize(NULL)]]
482                     )
483     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
484        AC_MSG_RESULT([yes])
485        have_libdbi=yes
486     ],[LIBS=$XXX
487        AC_MSG_RESULT([no])
488        have_libdbi=no
489     ]
490   )
491 ])
492 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
493
494 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
495
496
497 CORE_LIBS="$LIBS"
498
499 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
500 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
501 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
502 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
503 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
504 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
505 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
506 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
507 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
508 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
509 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
510
511 if test "$EX_CHECK_ALL_ERR" = "YES"; then
512   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
513 fi
514
515 ALL_LIBS="$LIBS"
516 LIBS=
517
518 AC_SUBST(CORE_LIBS)
519 AC_SUBST(ALL_LIBS)
520
521 CONFIGURE_PART(Prep for Building Language Bindings)
522   
523 dnl Check for Perl and friends
524 PATH=$PATH:/usr/perl5/bin
525 export PATH
526 AC_PATH_PROG(PERL, perl, no)
527 AC_PATH_PROG(POD2MAN, pod2man, no)
528 AC_PATH_PROG(POD2HTML, pod2html, no)
529
530
531 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
532 [],[enable_perl=yes])
533
534
535 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
536 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
537 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
538 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
539
540 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
541         COMP_PERL=
542 else
543         COMP_PERL="perl_piped perl_shared"
544         AC_MSG_CHECKING(for the perl version you are running)
545         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
546         AC_MSG_RESULT($PERL_VERSION)
547         if test -z "$PERLCC"; then
548             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
549             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
550             AC_MSG_RESULT($perlcc)
551             if test ! -x "$perlcc"; then
552                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
553                 if test "$PERL_CC" = "no"; then
554                     AC_MSG_WARN([
555 I would not find the Compiler ($perlcc) that was originally used to compile
556 your perl binary. You should either make sure that this compiler is
557 available on your system, pick an other compiler and set PERLCC
558 appropriately, or use a different perl setup that was compiled locally.
559
560 I will disable the compilation of the RRDs perl module for now.
561 ])
562                     COMP_PERL="perl_piped"
563                 fi
564             fi    
565         fi
566 fi
567
568 AC_MSG_CHECKING(Perl Modules to build)
569 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
570
571 # Options to pass when configuring perl module
572 langpref=$prefix
573 test "$langpref" = "$(DESTDIR)NONE" && langpref='$(DESTDIR)'$ac_default_prefix
574 test "$langpref" = "NONE" && langpref=$ac_default_prefix
575
576 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
577
578 dnl pass additional perl options when generating Makefile from Makefile.PL
579 AC_ARG_ENABLE(perl-site-install,
580 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
581 [PERL_MAKE_OPTIONS=],[])
582
583 if test ! -z "$PERLCC"; then
584    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
585
586    if test ! -z "$PERLCCFLAGS"; then
587        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
588    fi
589    
590    if test -z "$PERLLD"; then
591        PERLLD=$PERLCC
592    fi
593    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
594   
595    if test ! -z "$PERLLDFLAGS"; then
596        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
597    fi
598 fi
599         
600 AC_ARG_WITH(perl-options,
601 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
602                           generating Makefile from Makefile.PL. If you set this
603                           option, interesting things may happen unless you know
604                           what you are doing!],
605 [PERL_MAKE_OPTIONS=$withval])
606
607 AC_SUBST(PERL_MAKE_OPTIONS)
608 AC_SUBST(PERL)
609 AC_SUBST(COMP_PERL)
610 AC_SUBST(PERL_VERSION)
611
612 dnl Check for Ruby.
613 AC_PATH_PROG(RUBY, ruby, no)
614
615 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
616 [],[enable_ruby=yes])
617
618 AC_MSG_CHECKING(if ruby modules can be built)
619
620 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
621         COMP_RUBY=
622         AC_MSG_RESULT(No .. Ruby not found or disabled)
623 else
624         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
625                 COMP_RUBY="ruby"
626                 AC_MSG_RESULT(YES)
627         else
628                 COMP_RUBY=
629                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)         
630         fi                              
631 fi
632
633 dnl pass additional ruby options when generating Makefile from Makefile.PL
634 AC_ARG_ENABLE(ruby-site-install,
635 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
636 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
637
638     
639 AC_ARG_WITH(ruby-options,
640 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
641                           generating Makefile from extconf.rb. If you set this
642                           option, interesting things may happen unless you know
643                           what you are doing!],
644 [RUBY_MAKE_OPTIONS=$withval])
645
646 AC_SUBST(RUBY_MAKE_OPTIONS)
647 AC_SUBST(RUBY)
648 AC_SUBST(COMP_RUBY)
649
650 dnl Check for Lua.
651 AC_PATH_PROG(LUA, lua, no)
652
653 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
654 [],[enable_lua=yes])
655
656 COMP_LUA=
657 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
658   enable_lua=no
659 else
660   AC_MSG_CHECKING(for lua >= 5.0)
661   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
662     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
663 LUA_EOF
664   if test 0$LUA_MAJOR -lt 5; then
665     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
666   else
667     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
668     lua_vdot=$LUA_MAJOR.$LUA_MINOR
669     lua_vndot=$LUA_MAJOR$LUA_MINOR
670     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
671     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
672       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
673         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
674           [lua_headerdir=lua$lua_vndot],
675           [])],
676         [])],
677       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
678         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
679           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
680             [lua_headerdir=lua$lua_vdot],
681             [])],
682           [])],
683         [AC_CHECK_HEADERS(lua.h,
684           [AC_CHECK_HEADERS(lualib.h,
685             [AC_CHECK_HEADER(lauxlib.h,
686               [lua_headerdir=""],
687               [lua_headerdir="no"])],
688             [])],
689           [])])])
690
691     if test "$lua_headerdir" = "no"; then
692       enable_lua=no
693     else
694       COMP_LUA=lua
695     fi
696
697     if test "$COMP_LUA" != "lua"; then
698       enable_lua=no
699       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
700     else
701       # OK, headers found, let's check the libraries (LIBS is not used)
702       LIBS=
703       lua_havelib=no
704       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
705       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
706         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
707           [lua_havelib=LUA$lua_vndot],
708           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
709             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
710              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
711             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
712               [lua_havelib=$lua_vndot],
713               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
714         [COMP_LUA=], [-lm])
715       lua_libs=$LIBS
716       LIBS=
717
718       # Options to pass when configuring Lua module
719       if test  "$lua_havelib" != "no"; then
720         # OK, headers and libs found. Try to set lua flags
721         # and modules installation dirs with pkg-config
722         if test "$PKGCONFIG" != "no"; then
723           if test "$lua_vndot" = "50"; then
724             lua_pkg_prefix=lualib
725           else
726             lua_pkg_prefix=lua
727           fi
728           # try with dot, without dot and finally without version
729           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
730             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
731             # same binaries?
732             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then 
733                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
734                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
735                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
736                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
737                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
738                 break
739             fi
740           done
741         fi
742
743         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
744         # if lua 5.0 can't find compat-5.1, force installation of
745         # compat-5.1.lua together with RRDtool.
746         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
747           lua_need_compat51=1 
748           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
749         fi
750
751         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
752         if test "$LUA_CFLAGS" = ""; then
753           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
754           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
755           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
756           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
757         fi
758
759         dnl pass additional lua options
760         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
761         dnl found and install together with RRDtool, under $langpref.
762         AC_ARG_ENABLE(lua-site-install,
763         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
764         [],
765         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
766
767         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
768         AC_SUBST(LUA)
769         AC_SUBST(COMP_LUA)
770         AC_SUBST(LUA_INSTALL_CMOD)
771         AC_SUBST(LUA_INSTALL_LMOD)
772         AC_SUBST(LUA_CFLAGS)
773         AC_SUBST(LUA_LFLAGS)
774         AC_SUBST(LUA_DEFINES)
775       else
776         enable_lua=no
777         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
778       fi
779     fi
780   fi
781 fi
782 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
783 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
784 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
785       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
786 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
787 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
788 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
789 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
790
791 enable_tcl_site=no
792
793 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
794 [],[enable_tcl=yes])
795
796 if test  "$enable_tcl" = "yes"; then
797   dnl Check for Tcl.
798   withval=""
799   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
800   enable_tcl=no
801   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
802     AC_MSG_CHECKING(for tclConfig.sh in $dir)
803     if test -f "$dir/tclConfig.sh" ; then
804         tcl_config=$dir/tclConfig.sh
805         enable_tcl=yes
806         AC_MSG_RESULT(yes)
807         break
808     else
809         AC_MSG_RESULT(no)
810     fi
811   done
812
813   if test "$enable_tcl" = "no"; then
814         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
815   else
816         . $tcl_config
817         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
818         if test -n "$TCL_INC_DIR"; then
819           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
820         fi
821   fi
822   AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
823   [],[enable_tcl_site=yes])
824
825 fi
826
827 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
828 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
829
830
831 AC_SUBST(TCL_PREFIX)
832 AC_SUBST(TCL_SHLIB_CFLAGS)
833 AC_SUBST(TCL_SHLIB_LD)
834 AC_SUBST(TCL_SHLIB_SUFFIX)
835 AC_SUBST(TCL_PACKAGE_PATH)
836 AC_SUBST(TCL_LD_SEARCH_FLAGS)
837 AC_SUBST(TCL_STUB_LIB_SPEC)
838 AC_SUBST(TCL_VERSION)
839 AC_SUBST(TCL_PACKAGE_DIR)
840 AC_SUBST(TCL_INCLUDE_SPEC)
841
842 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
843 [],[enable_python=yes])
844
845 if test  "$enable_python" = "yes"; then
846 dnl Check for python
847 AM_PATH_PYTHON(2.3,[],[enable_python=no])
848 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
849 fi
850
851 if test  x$enable_python = xno; then
852         COMP_PYTHON=
853 else
854         COMP_PYTHON="python"
855 fi
856
857 AC_SUBST(COMP_PYTHON)
858
859 dnl Check for nroff
860 AC_PATH_PROGS(NROFF, gnroff nroff)
861 AC_PATH_PROGS(TROFF, groff troff)
862
863 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
864 if test -z "$RRDDOCDIR"; then
865    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
866
867
868 CONFIGURE_PART(Apply Configuration Information)
869  
870 AC_CONFIG_FILES([examples/shared-demo.pl])
871 AC_CONFIG_FILES([examples/piped-demo.pl])
872 AC_CONFIG_FILES([examples/stripes.pl])
873 AC_CONFIG_FILES([examples/bigtops.pl])
874 AC_CONFIG_FILES([examples/minmax.pl])
875 AC_CONFIG_FILES([examples/4charts.pl])
876 AC_CONFIG_FILES([examples/perftest.pl])
877 AC_CONFIG_FILES([examples/Makefile])
878 AC_CONFIG_FILES([examples/rrdcached/Makefile])
879 AC_CONFIG_FILES([doc/Makefile])
880 AC_CONFIG_FILES([po/Makefile.in])
881 AC_CONFIG_FILES([src/Makefile])
882 AC_CONFIG_FILES([src/librrd.sym.in])
883 AC_CONFIG_FILES([src/librrd.pc])
884 AC_CONFIG_FILES([bindings/Makefile])
885 AC_CONFIG_FILES([bindings/tcl/Makefile])
886 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
887 AC_CONFIG_FILES([Makefile])          
888 AC_CONFIG_FILES([bindings/lua/Makefile])
889
890 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
891 AC_OUTPUT
892
893 AC_MSG_CHECKING(in)
894 AC_MSG_RESULT(and out again)
895
896 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
897 sleep 1
898 echo $ECHO_N ".$ECHO_C" 1>&6
899 sleep 1
900 echo $ECHO_N ".$ECHO_C" 1>&6
901 sleep 1
902 echo $ECHO_N ".$ECHO_C" 1>&6
903 sleep 1
904 echo $ECHO_N ".$ECHO_C" 1>&6
905 sleep 1
906 AC_MSG_RESULT([ just kidding ;-)])
907 echo
908 echo "----------------------------------------------------------------"
909 echo "Config is DONE!"
910 echo
911 echo "          With MMAP IO: $enable_mmap"
912 echo "      Build rrd_getopt: $build_getopt"
913 echo "       Static programs: $staticprogs"
914 echo "          Perl Modules: $COMP_PERL"
915 echo "           Perl Binary: $PERL"
916 echo "          Perl Version: $PERL_VERSION"
917 echo "          Perl Options: $PERL_MAKE_OPTIONS"
918 echo "          Ruby Modules: $COMP_RUBY"
919 echo "           Ruby Binary: $RUBY"
920 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
921 echo "    Build Lua Bindings: $enable_lua"
922 if test "$enable_lua" = "yes"; then
923 echo "            Lua Binary: $LUA"
924 echo "           Lua Version: $lua_version"
925 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
926 if test "$lua_need_compat51" = "1"; then
927 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
928 fi
929 fi
930 echo "    Build Tcl Bindings: $enable_tcl"
931 echo " Build Python Bindings: $enable_python"
932 echo "          Build rrdcgi: $enable_rrdcgi"
933 echo "       Build librrd MT: $enable_pthread"
934 echo "     Link with libintl: $enable_libintl"
935 echo "           With libDBI: $have_libdbi"
936 echo
937 echo "             Libraries: $ALL_LIBS"
938 echo
939 echo "Type 'make' to compile the software and use 'make install' to "
940 echo "install everything to: $prefix."
941 echo 
942 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
943 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
944 echo "place an order."
945 echo 
946 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
947 echo "----------------------------------------------------------------"