configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3.2])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.3002
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which versions the library are compatible with
  23 dnl each other we must keep a separate library version cout of the format c:r:a.
  24 dnl - if only implementation changed but all interfaces are kept, do r++
  25 dnl - if only functionality was added do c++,r=0,a++
  26 dnl - if any functionality was removed do c++,r=0,a=0.
  27 dnl
  28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  29 dnl
  30 LIBVERS=4:1:0
  31 AC_SUBST(LIBVERS)
  32
  33 AC_CANONICAL_TARGET
  34 AM_INIT_AUTOMAKE
  35 AM_MAINTAINER_MODE
  36
  37 AC_CONFIG_HEADERS([rrd_config.h])
  38
  39 dnl all our local stuff like install scripts and include files
  40 dnl is in there
  41
  42
  43 dnl determine the type of system we are running on
  44
  45 AC_SUBST(VERSION)
  46
  47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  48
  49 dnl Minimum Autoconf version required.
  50 AC_PREREQ(2.59)
  51
  52 dnl At the TOP of the HEADER
  53
  54 AH_TOP([
  55 #ifndef RRD_CONFIG_H
  56 #define RRD_CONFIG_H
  57
  58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  59 #undef MUST_DISABLE_FPMASK
  60
  61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  62 #undef MUST_DISABLE_SIGFPE
  63
  64 /* realloc does not support NULL as argument */
  65 #undef NO_NULL_REALLOC
  66
  67 /* lets enable madvise defines in NetBSD */
  68 #if defined(__NetBSD__)
  69 # if !defined(_NETBSD_SOURCE)
  70 #  define _NETBSD_SOURCE
  71 # endif
  72 #endif
  73
  74 ])
  75
  76 AH_BOTTOM([
  77
  78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  79 #  include <malloc/malloc.h>
  80 #endif
  81
  82 #include <rrd_config_bottom.h>
  83
  84 #endif
  85 ])
  86
  87 dnl Process Special Options
  88 dnl -----------------------------------
  89
  90 dnl How the vertical axis label is printed
  91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  92  [Vertical label angle: -90.0 (default) or 90.0])
  93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
  94  [Vertical label angle: -90.0 (default) or 90.0])
  95
  96 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
  97 [],[enable_rrdcgi=yes])
  98
  99 dnl Check if we run on a system that has fonts
 100 AC_ARG_WITH(rrd-default-font,
 101 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 102 [RRD_DEFAULT_FONT=$withval],[
 103   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 104         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 105   else
 106         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 107   fi
 108 ])
 109
 110 dnl Use mmap in rrd_update instead of seek+write
 111 AC_ARG_ENABLE([mmap],
 112 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 113 [],
 114 [enable_mmap=yes])
 115
 116 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread][disable multithread support]),
 117 [],[enable_pthread=yes])
 118
 119 AC_ARG_ENABLE(static-programs,
 120      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 121      [case "${enableval}" in
 122        yes) staticprogs=yes ;;
 123        no)  staticprogs=no ;;
 124        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 125      esac],[staticprogs=no])
 126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 127
 128
 129 CONFIGURE_PART(Audit Compilation Environment)
 130
 131
 132 dnl Check for the compiler and static/shared library creation.
 133 AC_PROG_CPP
 134 AC_PROG_CC
 135 AM_PROG_CC_C_O
 136 AC_PROG_LIBTOOL
 137
 138 dnl Try to detect/use GNU features
 139 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 140
 141 dnl check for -Werror separatly
 142 dnl (quite a few autotool checks don't work with -Werror; also, the
 143 dnl check for -Werror fails after checking and adding the other flags)
 144 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 145   [AC_COMPILE_IFELSE(
 146     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 147     [rd_cv_gcc_flag__Werror="yes"],
 148     [rd_cv_gcc_flag__Werror="no"])])
 149 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 150   WERROR="-Werror"
 151 else
 152   WERROR=""
 153 fi
 154 AC_SUBST(WERROR)
 155
 156 dnl which flags does the compiler support?
 157 if test "x$GCC" = "xyes"; then
 158   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 159     oCFLAGS="$CFLAGS"
 160     CFLAGS="$CFLAGS $flag"
 161     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 162     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 163        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 164     if eval test \$$cachename = no; then
 165          CFLAGS="$oCFLAGS"
 166     fi
 167   done
 168 fi
 169
 170
 171
 172 AC_SUBST(RRD_DEFAULT_FONT)
 173
 174 CONFIGURE_PART(Checking for Header Files)
 175
 176 dnl Checks for header files.
 177 AC_HEADER_STDC
 178 AC_HEADER_DIRENT
 179 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 180
 181 dnl Checks for typedefs, structures, and compiler characteristics.
 182 AC_C_CONST
 183 AC_HEADER_TIME
 184 AC_STRUCT_TM
 185
 186 CONFIGURE_PART(Test Library Functions)
 187
 188 dnl Checks for libraries.
 189 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 190
 191
 192 dnl add pic flag in any case this makes sure all our code is relocatable
 193 eval `./libtool --config | grep pic_flag`
 194 CFLAGS="$CFLAGS $pic_flag"
 195
 196
 197 dnl Checks for library functions.
 198 AC_FUNC_STRFTIME
 199 AC_FUNC_VPRINTF
 200
 201 AC_C_BIGENDIAN
 202
 203 dnl for each function found we get a definition in config.h
 204 dnl of the form HAVE_FUNCTION
 205
 206 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 207
 208 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 209
 210 dnl Could use these to know if we need to provide a prototype
 211 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 212
 213 dnl check for fdatasync. Solaris has fdatasync in the librt
 214
 215 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 216 dnl if there is no fdatasync we may get lucky with fsync
 217 AC_CHECK_FUNCS(fsync)
 218
 219
 220 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 221 if test "x$enable_mmap" = "xyes"; then
 222   case "$host" in
 223   *cygwin*)
 224     # the normal mmap test does not work in cygwin
 225     AC_CHECK_FUNCS(mmap)
 226     if test "x$ac_cv_func_mmap" = "xyes"; then
 227       ac_cv_func_mmap_fixed_mapped=yes
 228     fi
 229   ;;
 230   *)
 231     AC_CHECK_HEADERS(sys/mman.h)
 232     AC_FUNC_MMAP
 233     AC_CHECK_FUNCS(mmap munmap msync)
 234     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 235                                      # include <sys/mman.h>
 236                                      #endif])
 237     if test "x$ac_cv_have_decl_madvise" = "xyes";
 238     then
 239       AC_CHECK_FUNCS(madvise)
 240     else
 241       AC_CHECK_FUNCS(posix_madvise)
 242       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 243         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 244       fi
 245     fi
 246   ;;
 247   esac
 248   if test "x$ac_cv_func_mmap" != "xyes";
 249   then
 250     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 251 dnl enable_mmap="no"
 252   fi
 253 fi
 254
 255 dnl can we use posix_fadvise
 256 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 257 #include <fcntl.h>])
 258 AC_CHECK_FUNCS(posix_fadvise)
 259
 260 CONFIGURE_PART(Libintl Processing)
 261
 262
 263 dnl gettext
 264 GETTEXT_PACKAGE=rrdtool
 265 AC_SUBST(GETTEXT_PACKAGE)
 266 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 267
 268 AM_GLIB_GNU_GETTEXT()
 269
 270 AC_ARG_ENABLE(libintl,AS_HELP_STRING([--disable-libintl],[i18n support (libintl)]),
 271 [],[enable_libintl=yes])
 272
 273 if test x$enable_libintl = xyes; then
 274   IT_PROG_INTLTOOL([0.35.0],[no-xml])
 275 fi
 276
 277 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
 278   AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
 279   enable_libintl=no
 280 fi
 281
 282 if test x$enable_libintl = xyes; then
 283   AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
 284 fi
 285
 286 if test x$enable_libintl = xyes ; then
 287   dnl it seems bsd synstems need to link against libintl
 288   dnl when compiling rrdupdate. lets check
 289   AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
 290 fi
 291
 292 dnl use for linking rrdupdate
 293 AC_SUBST(LIB_LIBINTL)
 294
 295 dnl do not touch the po stuff if we are not going to build intl
 296 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
 297
 298 if test x$enable_libintl = xyes; then
 299    AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
 300 fi
 301
 302 CONFIGURE_PART(IEEE Math Checks)
 303
 304
 305 dnl actual code to check if this works
 306 AC_CHECK_FUNCS(fpclassify, ,
 307   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 308     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 309 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 310       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 311
 312 AC_CHECK_FUNCS(isinf, ,
 313   [AC_MSG_CHECKING(for isinf with <math.h>)
 314     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 315 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 316       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 317
 318 dnl finite is BSD, isfinite is C99, so prefer the latter
 319 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 320 AC_TRY_RUN([
 321 #ifdef HAVE_MATH_H
 322 #include <math.h>
 323 #endif
 324 #ifdef HAVE_FLOAT_H
 325 #include <float.h>
 326 #endif
 327 int main ()
 328 {
 329 #ifdef isfinite
 330 #ifdef LDBL_MAX
 331   if (!isfinite(LDBL_MAX)) return 1;
 332 #endif
 333 #ifdef DBL_MAX
 334   if (!isfinite(DBL_MAX)) return 1;
 335 #endif
 336 #endif
 337 return 0;
 338 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 339 case "${target}" in
 340   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 341   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 342   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 343   *) ac_cv_have_broken_isfinite=no ;;
 344 esac])
 345 ])
 346
 347 dnl the test does not seem to work on solaris 2.8
 348 dnl so lets fix this by hand
 349 case "${target}" in
 350   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 351   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 352 esac
 353
 354 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 355   AC_DEFINE(HAVE_ISFINITE)
 356 else
 357   AC_CHECK_FUNCS(finite,[],
 358       [AC_CHECK_FUNCS(isfinite,[],
 359          [AC_MSG_CHECKING(for isfinite with <math.h>)
 360           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 361 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 362                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 363 fi
 364
 365 AC_FULL_IEEE
 366
 367 CONFIGURE_PART(Resolve Portability Issues)
 368
 369 dnl Do we need getopt_long
 370
 371 build_getopt=no
 372 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 373 AC_CHECK_FUNC(getopt_long,[],[
 374 RRD_GETOPT_LONG="getopt_long"
 375 build_getopt=yes
 376 ])
 377 AC_SUBST(RRD_GETOPT_LONG)
 378 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 379
 380 dnl what does realloc do if it gets called with a NULL pointer
 381
 382 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 383 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 384               int main(void){
 385               char *x = NULL;
 386               x = realloc (x,10);
 387               if (x==NULL) return 1;
 388               return 0;
 389              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 390
 391 if test x"$rd_cv_null_realloc" = xnope; then
 392 AC_DEFINE(NO_NULL_REALLOC)
 393 fi
 394
 395 AC_LANG_PUSH(C)
 396 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 397 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 398 AC_LINK_IFELSE(
 399     AC_LANG_PROGRAM(
 400            [[#include <time.h>]],
 401            [[ctime_r(NULL,NULL,0)]]
 402                    ),
 403     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 404       AC_LINK_IFELSE(
 405           AC_LANG_PROGRAM(
 406                 [[#include <time.h>]],
 407                 [[ctime_r(NULL,NULL)]]
 408                          ),
 409           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 410           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 411       )
 412     ],
 413     [ AC_LINK_IFELSE(
 414           AC_LANG_PROGRAM(
 415                 [[#include <time.h>]],
 416                 [[ctime_r(NULL,NULL)]]
 417                          ),
 418           [AC_MSG_RESULT(no)],
 419           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 420       )
 421     ]
 422 )
 423 AC_LANG_POP(C)
 424
 425 dnl Check for pthreads
 426 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 427
 428 AC_SUBST(MULTITHREAD_CFLAGS)
 429 AC_SUBST(MULTITHREAD_LDFLAGS)
 430
 431 if test $enable_pthread != no; then
 432  ACX_PTHREAD([
 433     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 434     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 435              ],
 436              [])
 437 fi
 438
 439 dnl since we use lots of *_r functions all over the code we better
 440 dnl make sure they are known
 441
 442 if test  "x$x_rflag" != "xno"; then
 443    CPPFLAGS="$CPPFLAGS $x_rflag"
 444 fi
 445
 446 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 447
 448 AC_LANG_PUSH(C)
 449 dnl see if we have to include malloc/malloc.h
 450 AC_MSG_CHECKING([do we need malloc/malloc.h])
 451 AC_LINK_IFELSE(
 452     AC_LANG_PROGRAM(
 453            [[#include <stdlib.h>]],
 454            [[malloc(1)]]
 455                    ),
 456     [ AC_MSG_RESULT([nope, works out of the box]) ],
 457     [ AC_LINK_IFELSE(
 458           AC_LANG_PROGRAM(
 459                 [[#include <stdlib.h>
 460                   #include <malloc/malloc.h>]],
 461                 [[malloc(1)]]
 462                          ),[
 463            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 464            AC_MSG_RESULT([yes we do])],
 465           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 466       )
 467     ]
 468 )
 469 AC_LANG_POP(C)
 470
 471 CONFIGURE_PART(Find 3rd-Party Libraries)
 472
 473 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
 474   XXX=$LIBS
 475   LIBS="$LIBS -ldbi -ldl"
 476   AC_MSG_CHECKING(for libdbi)
 477   AC_LINK_IFELSE(
 478     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 479                      [[dbi_initialize(NULL)]]
 480                     )
 481     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 482        AC_MSG_RESULT([yes])
 483        have_libdbi=yes
 484     ],[LIBS=$XXX
 485        AC_MSG_RESULT([no])
 486        have_libdbi=no
 487     ]
 488   )
 489 ])
 490 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 491
 492 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 493
 494
 495 CORE_LIBS="$LIBS"
 496
 497 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 498 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 499 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 500 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 501 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 502 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 503 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 504 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 505 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 506 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 507 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 508
 509 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 510   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 511 fi
 512
 513 ALL_LIBS="$LIBS"
 514 LIBS=
 515
 516 AC_SUBST(CORE_LIBS)
 517 AC_SUBST(ALL_LIBS)
 518
 519 CONFIGURE_PART(Prep for Building Language Bindings)
 520
 521 dnl Check for Perl and friends
 522 PATH=$PATH:/usr/perl5/bin
 523 export PATH
 524 AC_PATH_PROG(PERL, perl, no)
 525 AC_PATH_PROG(POD2MAN, pod2man, no)
 526 AC_PATH_PROG(POD2HTML, pod2html, no)
 527
 528
 529 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 530 [],[enable_perl=yes])
 531
 532
 533 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 534 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 535 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 536 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 537
 538 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 539         COMP_PERL=
 540 else
 541         COMP_PERL="perl_piped perl_shared"
 542         AC_MSG_CHECKING(for the perl version you are running)
 543         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 544         AC_MSG_RESULT($PERL_VERSION)
 545         if test -z "$PERLCC"; then
 546             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 547             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 548             AC_MSG_RESULT($perlcc)
 549             if test ! -x "$perlcc"; then
 550                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 551                 if test "$PERL_CC" = "no"; then
 552                     AC_MSG_WARN([
 553 I would not find the Compiler ($perlcc) that was originally used to compile
 554 your perl binary. You should either make sure that this compiler is
 555 available on your system, pick an other compiler and set PERLCC
 556 appropriately, or use a different perl setup that was compiled locally.
 557
 558 I will disable the compilation of the RRDs perl module for now.
 559 ])
 560                     COMP_PERL="perl_piped"
 561                 fi
 562             fi
 563         fi
 564 fi
 565
 566 AC_MSG_CHECKING(Perl Modules to build)
 567 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 568
 569 # Options to pass when configuring perl module
 570 langpref=$prefix
 571 test "$langpref" = "$(DESTDIR)NONE" && langpref='$(DESTDIR)'$ac_default_prefix
 572 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 573
 574 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 575
 576 dnl pass additional perl options when generating Makefile from Makefile.PL
 577 AC_ARG_ENABLE(perl-site-install,
 578 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 579 [PERL_MAKE_OPTIONS=],[])
 580
 581 if test ! -z "$PERLCC"; then
 582    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 583
 584    if test ! -z "$PERLCCFLAGS"; then
 585        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 586    fi
 587
 588    if test -z "$PERLLD"; then
 589        PERLLD=$PERLCC
 590    fi
 591    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 592
 593    if test ! -z "$PERLLDFLAGS"; then
 594        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 595    fi
 596 fi
 597
 598 AC_ARG_WITH(perl-options,
 599 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 600                           generating Makefile from Makefile.PL. If you set this
 601                           option, interesting things may happen unless you know
 602                           what you are doing!],
 603 [PERL_MAKE_OPTIONS=$withval])
 604
 605 AC_SUBST(PERL_MAKE_OPTIONS)
 606 AC_SUBST(PERL)
 607 AC_SUBST(COMP_PERL)
 608 AC_SUBST(PERL_VERSION)
 609
 610 dnl Check for Ruby.
 611 AC_PATH_PROG(RUBY, ruby, no)
 612
 613 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 614 [],[enable_ruby=yes])
 615
 616 AC_MSG_CHECKING(if ruby modules can be built)
 617
 618 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 619         COMP_RUBY=
 620         AC_MSG_RESULT(No .. Ruby not found or disabled)
 621 else
 622         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 623                 COMP_RUBY="ruby"
 624                 AC_MSG_RESULT(YES)
 625         else
 626                 COMP_RUBY=
 627                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 628         fi
 629 fi
 630
 631 dnl pass additional ruby options when generating Makefile from Makefile.PL
 632 AC_ARG_ENABLE(ruby-site-install,
 633 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 634 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 635
 636
 637 AC_ARG_WITH(ruby-options,
 638 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 639                           generating Makefile from extconf.rb. If you set this
 640                           option, interesting things may happen unless you know
 641                           what you are doing!],
 642 [RUBY_MAKE_OPTIONS=$withval])
 643
 644 AC_SUBST(RUBY_MAKE_OPTIONS)
 645 AC_SUBST(RUBY)
 646 AC_SUBST(COMP_RUBY)
 647
 648 dnl Check for Lua.
 649 AC_PATH_PROG(LUA, lua, no)
 650
 651 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 652 [],[enable_lua=yes])
 653
 654 COMP_LUA=
 655 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 656   enable_lua=no
 657 else
 658   AC_MSG_CHECKING(for lua >= 5.0)
 659   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 660     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 661 LUA_EOF
 662   if test 0$LUA_MAJOR -lt 5; then
 663     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 664   else
 665     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 666     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 667     lua_vndot=$LUA_MAJOR$LUA_MINOR
 668     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 669     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 670       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 671         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 672           [lua_headerdir=lua$lua_vndot],
 673           [])],
 674         [])],
 675       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 676         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 677           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 678             [lua_headerdir=lua$lua_vdot],
 679             [])],
 680           [])],
 681         [AC_CHECK_HEADERS(lua.h,
 682           [AC_CHECK_HEADERS(lualib.h,
 683             [AC_CHECK_HEADER(lauxlib.h,
 684               [lua_headerdir=""],
 685               [lua_headerdir="no"])],
 686             [])],
 687           [])])])
 688
 689     if test "$lua_headerdir" = "no"; then
 690       enable_lua=no
 691     else
 692       COMP_LUA=lua
 693     fi
 694
 695     if test "$COMP_LUA" != "lua"; then
 696       enable_lua=no
 697       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 698     else
 699       # OK, headers found, let's check the libraries (LIBS is not used)
 700       LIBS=
 701       lua_havelib=no
 702       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 703       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 704         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 705           [lua_havelib=LUA$lua_vndot],
 706           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 707             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 708              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 709             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 710               [lua_havelib=$lua_vndot],
 711               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 712         [COMP_LUA=], [-lm])
 713       lua_libs=$LIBS
 714       LIBS=
 715
 716       # Options to pass when configuring Lua module
 717       if test  "$lua_havelib" != "no"; then
 718         # OK, headers and libs found. Try to set lua flags
 719         # and modules installation dirs with pkg-config
 720         if test "$PKGCONFIG" != "no"; then
 721           if test "$lua_vndot" = "50"; then
 722             lua_pkg_prefix=lualib
 723           else
 724             lua_pkg_prefix=lua
 725           fi
 726           # try with dot, without dot and finally without version
 727           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 728             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 729             # same binaries?
 730             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 731                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 732                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 733                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 734                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 735                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 736                 break
 737             fi
 738           done
 739         fi
 740
 741         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 742         # if lua 5.0 can't find compat-5.1, force installation of
 743         # compat-5.1.lua together with RRDtool.
 744         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 745           lua_need_compat51=1
 746           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 747         fi
 748
 749         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 750         if test "$LUA_CFLAGS" = ""; then
 751           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 752           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 753           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 754           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 755         fi
 756
 757         dnl pass additional lua options
 758         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 759         dnl found and install together with RRDtool, under $langpref.
 760         AC_ARG_ENABLE(lua-site-install,
 761         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 762         [],
 763         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 764
 765         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 766         AC_SUBST(LUA)
 767         AC_SUBST(COMP_LUA)
 768         AC_SUBST(LUA_INSTALL_CMOD)
 769         AC_SUBST(LUA_INSTALL_LMOD)
 770         AC_SUBST(LUA_CFLAGS)
 771         AC_SUBST(LUA_LFLAGS)
 772         AC_SUBST(LUA_DEFINES)
 773       else
 774         enable_lua=no
 775         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 776       fi
 777     fi
 778   fi
 779 fi
 780 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 781 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 782 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 783       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 784 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 785 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 786 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 787 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 788
 789 enable_tcl_site=no
 790
 791 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 792 [],[enable_tcl=yes])
 793
 794 if test  "$enable_tcl" = "yes"; then
 795   dnl Check for Tcl.
 796   withval=""
 797   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 798   enable_tcl=no
 799   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 800     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 801     if test -f "$dir/tclConfig.sh" ; then
 802         tcl_config=$dir/tclConfig.sh
 803         enable_tcl=yes
 804         AC_MSG_RESULT(yes)
 805         break
 806     else
 807         AC_MSG_RESULT(no)
 808     fi
 809   done
 810
 811   if test "$enable_tcl" = "no"; then
 812         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 813   else
 814         . $tcl_config
 815         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 816         if test -n "$TCL_INC_DIR"; then
 817           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 818         fi
 819   fi
 820   AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 821   [],[enable_tcl_site=yes])
 822
 823 fi
 824
 825 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 826 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 827
 828
 829 AC_SUBST(TCL_PREFIX)
 830 AC_SUBST(TCL_SHLIB_CFLAGS)
 831 AC_SUBST(TCL_SHLIB_LD)
 832 AC_SUBST(TCL_SHLIB_SUFFIX)
 833 AC_SUBST(TCL_PACKAGE_PATH)
 834 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 835 AC_SUBST(TCL_STUB_LIB_SPEC)
 836 AC_SUBST(TCL_VERSION)
 837 AC_SUBST(TCL_PACKAGE_DIR)
 838 AC_SUBST(TCL_INCLUDE_SPEC)
 839
 840 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 841 [],[enable_python=yes])
 842
 843 if test  "$enable_python" = "yes"; then
 844 dnl Check for python
 845 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 846 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 847 fi
 848
 849 if test  x$enable_python = xno; then
 850         COMP_PYTHON=
 851 else
 852         COMP_PYTHON="python"
 853 fi
 854
 855 AC_SUBST(COMP_PYTHON)
 856
 857 dnl Check for nroff
 858 AC_PATH_PROGS(NROFF, gnroff nroff)
 859 AC_PATH_PROGS(TROFF, groff troff)
 860
 861 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 862 if test -z "$RRDDOCDIR"; then
 863    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 864
 865
 866 CONFIGURE_PART(Apply Configuration Information)
 867
 868 AC_CONFIG_FILES([examples/shared-demo.pl])
 869 AC_CONFIG_FILES([examples/piped-demo.pl])
 870 AC_CONFIG_FILES([examples/stripes.pl])
 871 AC_CONFIG_FILES([examples/bigtops.pl])
 872 AC_CONFIG_FILES([examples/minmax.pl])
 873 AC_CONFIG_FILES([examples/4charts.pl])
 874 AC_CONFIG_FILES([examples/perftest.pl])
 875 AC_CONFIG_FILES([examples/Makefile])
 876 AC_CONFIG_FILES([doc/Makefile])
 877 AC_CONFIG_FILES([po/Makefile.in])
 878 AC_CONFIG_FILES([src/Makefile])
 879 AC_CONFIG_FILES([src/librrd.sym.in])
 880 AC_CONFIG_FILES([src/librrd.pc])
 881 AC_CONFIG_FILES([bindings/Makefile])
 882 AC_CONFIG_FILES([bindings/tcl/Makefile])
 883 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 884 AC_CONFIG_FILES([Makefile])
 885 AC_CONFIG_FILES([bindings/lua/Makefile])
 886
 887 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 888 AC_OUTPUT
 889
 890 AC_MSG_CHECKING(in)
 891 AC_MSG_RESULT(and out again)
 892
 893 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 894 sleep 1
 895 echo $ECHO_N ".$ECHO_C" 1>&6
 896 sleep 1
 897 echo $ECHO_N ".$ECHO_C" 1>&6
 898 sleep 1
 899 echo $ECHO_N ".$ECHO_C" 1>&6
 900 sleep 1
 901 echo $ECHO_N ".$ECHO_C" 1>&6
 902 sleep 1
 903 AC_MSG_RESULT([ just kidding ;-)])
 904 echo
 905 echo "----------------------------------------------------------------"
 906 echo "Config is DONE!"
 907 echo
 908 echo "          With MMAP IO: $enable_mmap"
 909 echo "      Build rrd_getopt: $build_getopt"
 910 echo "       Static programs: $staticprogs"
 911 echo "          Perl Modules: $COMP_PERL"
 912 echo "           Perl Binary: $PERL"
 913 echo "          Perl Version: $PERL_VERSION"
 914 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 915 echo "          Ruby Modules: $COMP_RUBY"
 916 echo "           Ruby Binary: $RUBY"
 917 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 918 echo "    Build Lua Bindings: $enable_lua"
 919 if test "$enable_lua" = "yes"; then
 920 echo "            Lua Binary: $LUA"
 921 echo "           Lua Version: $lua_version"
 922 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 923 if test "$lua_need_compat51" = "1"; then
 924 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 925 fi
 926 fi
 927 echo "    Build Tcl Bindings: $enable_tcl"
 928 echo " Build Python Bindings: $enable_python"
 929 echo "          Build rrdcgi: $enable_rrdcgi"
 930 echo "       Build librrd MT: $enable_pthread"
 931 echo "     Link with libintl: $enable_libintl"
 932 echo "           With libDBI: $have_libdbi"
 933 echo
 934 echo "             Libraries: $ALL_LIBS"
 935 echo
 936 echo "Type 'make' to compile the software and use 'make install' to "
 937 echo "install everything to: $prefix."
 938 echo
 939 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 940 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 941 echo "place an order."
 942 echo
 943 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 944 echo "----------------------------------------------------------------"