configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.999])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4999
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=5:3:1
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 have_libwrap=no
 106
 107 AC_ARG_ENABLE(libwrap,
 108   AS_HELP_STRING([--disable-libwrap],
 109     [do not build in support for libwrap (tcp wrapper)]
 110   ),
 111   [],
 112   [
 113       AC_CHECK_FUNCS(hosts_access, [],
 114           AC_CHECK_LIB(wrap, hosts_access, [
 115               LIBS="${LIBS} -lwrap"
 116               AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 117               have_libwrap=yes
 118           ],[])
 119       )
 120   ]
 121 )
 122
 123 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
 124
 125 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 126
 127 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
 128 [enable_rrdcgi=no],[enable_rrd_graph=yes])
 129
 130 if test $enable_rrd_graph != no; then
 131  AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
 132 fi
 133
 134 dnl Check if we run on a system that has fonts
 135 AC_ARG_WITH(rrd-default-font,
 136 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 137 [RRD_DEFAULT_FONT=$withval],[
 138   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 139         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 140   else
 141         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 142   fi
 143 ])
 144
 145 dnl Use mmap in rrd_update instead of seek+write
 146 AC_ARG_ENABLE([mmap],
 147 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 148 [],
 149 [enable_mmap=yes])
 150
 151 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 152 [],[enable_pthread=yes])
 153
 154 AC_ARG_ENABLE(static-programs,
 155      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 156      [case "${enableval}" in
 157        yes) staticprogs=yes ;;
 158        no)  staticprogs=no ;;
 159        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 160      esac],[staticprogs=no])
 161 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 162
 163
 164 CONFIGURE_PART(Audit Compilation Environment)
 165
 166
 167 dnl Check for the compiler and static/shared library creation.
 168 AC_PROG_CPP
 169 AC_PROG_CC
 170 AM_PROG_CC_C_O
 171 AC_PROG_LIBTOOL
 172
 173 dnl Try to detect/use GNU features
 174 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 175
 176 dnl check for -Werror separatly
 177 dnl (quite a few autotool checks do not work with -Werror; also, the
 178 dnl check for -Werror fails after checking and adding the other flags)
 179 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 180   [AC_COMPILE_IFELSE(
 181     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 182     [rd_cv_gcc_flag__Werror="yes"],
 183     [rd_cv_gcc_flag__Werror="no"])])
 184 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 185   WERROR="-Werror"
 186 else
 187   WERROR=""
 188 fi
 189 AC_SUBST(WERROR)
 190
 191 dnl which flags does the compiler support?
 192 if test "x$GCC" = "xyes"; then
 193   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 194     oCFLAGS="$CFLAGS"
 195     CFLAGS="$CFLAGS $flag"
 196     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 197     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 198        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 199     if eval test \$$cachename = no; then
 200          CFLAGS="$oCFLAGS"
 201     fi
 202   done
 203 fi
 204
 205
 206
 207 AC_SUBST(RRD_DEFAULT_FONT)
 208
 209 CONFIGURE_PART(Checking for Header Files)
 210
 211 dnl Checks for header files.
 212 AC_HEADER_STDC
 213 AC_HEADER_DIRENT
 214 AC_CHECK_HEADERS(tcpd.h dbi/dbi.h langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 215
 216 dnl Checks for typedefs, structures, and compiler characteristics.
 217 AC_C_CONST
 218 AC_HEADER_TIME
 219 AC_STRUCT_TM
 220
 221 CONFIGURE_PART(Test Library Functions)
 222
 223 dnl Checks for libraries.
 224 AC_CHECK_FUNC(acos,  , AC_CHECK_LIB(m, acos))
 225 AC_CHECK_FUNC(round, , AC_CHECK_LIB(m, round))
 226
 227
 228 dnl add pic flag in any case this makes sure all our code is relocatable
 229 eval `./libtool --config | grep pic_flag`
 230 CFLAGS="$CFLAGS $pic_flag"
 231
 232
 233 dnl Checks for library functions.
 234 AC_FUNC_STRFTIME
 235 AC_FUNC_VPRINTF
 236
 237 AC_C_BIGENDIAN
 238
 239 dnl for each function found we get a definition in config.h
 240 dnl of the form HAVE_FUNCTION
 241
 242 AC_CHECK_FUNCS(nl_langinfo tzset fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 243
 244 AC_FUNC_STRERROR_R
 245
 246 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 247
 248 dnl Could use these to know if we need to provide a prototype
 249 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 250
 251 dnl check for fdatasync. Solaris has fdatasync in the librt
 252
 253 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 254 dnl if there is no fdatasync we may get lucky with fsync
 255 AC_CHECK_FUNCS(fsync)
 256
 257 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 258
 259 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 260 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 261
 262
 263
 264 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 265 if test "x$enable_mmap" = "xyes"; then
 266   case "$host" in
 267   *cygwin*)
 268     # the normal mmap test does not work in cygwin
 269     AC_CHECK_FUNCS(mmap)
 270     if test "x$ac_cv_func_mmap" = "xyes"; then
 271       ac_cv_func_mmap_fixed_mapped=yes
 272     fi
 273   ;;
 274   *)
 275     AC_CHECK_HEADERS(sys/mman.h)
 276     AC_FUNC_MMAP
 277     AC_CHECK_FUNCS(mmap munmap msync)
 278     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 279                                      # include <sys/mman.h>
 280                                      #endif])
 281     if test "x$ac_cv_have_decl_madvise" = "xyes";
 282     then
 283       AC_CHECK_FUNCS(madvise)
 284     else
 285       AC_CHECK_FUNCS(posix_madvise)
 286       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 287         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 288       fi
 289     fi
 290   ;;
 291   esac
 292   if test "x$ac_cv_func_mmap" != "xyes";
 293   then
 294     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 295 dnl enable_mmap="no"
 296   fi
 297 fi
 298
 299 dnl can we use posix_fadvise
 300 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 301 #include <fcntl.h>])
 302 AC_CHECK_FUNCS(posix_fadvise)
 303
 304 CONFIGURE_PART(Libintl Processing)
 305
 306 AM_GNU_GETTEXT_VERSION(0.17)
 307 AM_GNU_GETTEXT(external)
 308
 309 CONFIGURE_PART(IEEE Math Checks)
 310
 311
 312 dnl actual code to check if this works
 313 AC_CHECK_FUNCS(fpclassify, ,
 314   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 315     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 316 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 317       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 318
 319 AC_CHECK_FUNCS(isinf, ,
 320   [AC_MSG_CHECKING(for isinf with <math.h>)
 321     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 322 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 323       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 324
 325 dnl finite is BSD, isfinite is C99, so prefer the latter
 326 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 327 AC_TRY_RUN([
 328 #ifdef HAVE_MATH_H
 329 #include <math.h>
 330 #endif
 331 #ifdef HAVE_FLOAT_H
 332 #include <float.h>
 333 #endif
 334 int main ()
 335 {
 336 #ifdef isfinite
 337 #ifdef LDBL_MAX
 338   if (!isfinite(LDBL_MAX)) return 1;
 339 #endif
 340 #ifdef DBL_MAX
 341   if (!isfinite(DBL_MAX)) return 1;
 342 #endif
 343 #endif
 344 return 0;
 345 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 346 case "${target}" in
 347   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 348   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 349   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 350   *) ac_cv_have_broken_isfinite=no ;;
 351 esac])
 352 ])
 353
 354 dnl the test does not seem to work on solaris 2.8
 355 dnl so lets fix this by hand
 356 case "${target}" in
 357   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 358   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 359 esac
 360
 361 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 362   AC_DEFINE(HAVE_ISFINITE)
 363 else
 364   AC_CHECK_FUNCS(finite,[],
 365       [AC_CHECK_FUNCS(isfinite,[],
 366          [AC_MSG_CHECKING(for isfinite with <math.h>)
 367           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 368 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 369                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 370 fi
 371
 372 AC_FULL_IEEE
 373
 374 CONFIGURE_PART(Resolve Portability Issues)
 375
 376 CHECK_FOR_WORKING_MS_ASYNC
 377
 378 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
 379 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
 380   [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
 381     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
 382       AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
 383
 384 dnl Do we need getopt_long
 385
 386 dnl even when including our own getopt implementation
 387 dnl we may want to make sure we use the external
 388 dnl defined by libc to not run into linker resolve trouble
 389
 390 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 391 [AC_TRY_LINK([#include <unistd.h>],
 392   [extern int opterr; opterr = 1;],
 393   [rd_cv_var_int_opterr=yes],
 394   [rd_cv_var_int_opterr=no])])
 395 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 396   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 397 fi
 398
 399 build_getopt=no
 400 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 401 AC_CHECK_FUNC(getopt_long,[],[
 402 RRD_GETOPT_LONG="getopt_long"
 403 build_getopt=yes
 404 ])
 405 AC_SUBST(RRD_GETOPT_LONG)
 406 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 407
 408 dnl what does realloc do if it gets called with a NULL pointer
 409
 410 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 411 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 412               int main(void){
 413               char *x = NULL;
 414               x = realloc (x,10);
 415               if (x==NULL) return 1;
 416               return 0;
 417              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 418
 419 if test x"$rd_cv_null_realloc" = xnope; then
 420 AC_DEFINE(NO_NULL_REALLOC)
 421 fi
 422
 423 AC_LANG_PUSH(C)
 424 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 425 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 426 AC_LINK_IFELSE(
 427     AC_LANG_PROGRAM(
 428            [[#include <time.h>]],
 429            [[ctime_r(NULL,NULL,0)]]
 430                    ),
 431     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 432       AC_LINK_IFELSE(
 433           AC_LANG_PROGRAM(
 434                 [[#include <time.h>]],
 435                 [[ctime_r(NULL,NULL)]]
 436                          ),
 437           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 438           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 439       )
 440     ],
 441     [ AC_LINK_IFELSE(
 442           AC_LANG_PROGRAM(
 443                 [[#include <time.h>]],
 444                 [[ctime_r(NULL,NULL)]]
 445                          ),
 446           [AC_MSG_RESULT(no)],
 447           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 448       )
 449     ]
 450 )
 451 AC_LANG_POP(C)
 452
 453 dnl Check for pthreads
 454 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 455
 456 AC_SUBST(MULTITHREAD_CFLAGS)
 457 AC_SUBST(MULTITHREAD_LDFLAGS)
 458
 459 if test $enable_pthread != no; then
 460  ACX_PTHREAD([
 461     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 462     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 463              ],
 464              [])
 465 fi
 466
 467 dnl since we use lots of *_r functions all over the code we better
 468 dnl make sure they are known
 469
 470 if test  "x$x_rflag" != "xno"; then
 471    CPPFLAGS="$CPPFLAGS $x_rflag"
 472 fi
 473
 474 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 475
 476 AC_LANG_PUSH(C)
 477 dnl see if we have to include malloc/malloc.h
 478 AC_MSG_CHECKING([do we need malloc/malloc.h])
 479 AC_LINK_IFELSE(
 480     AC_LANG_PROGRAM(
 481            [[#include <stdlib.h>]],
 482            [[malloc(1)]]
 483                    ),
 484     [ AC_MSG_RESULT([nope, works out of the box]) ],
 485     [ AC_LINK_IFELSE(
 486           AC_LANG_PROGRAM(
 487                 [[#include <stdlib.h>
 488                   #include <malloc/malloc.h>]],
 489                 [[malloc(1)]]
 490                          ),[
 491            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 492            AC_MSG_RESULT([yes we do])],
 493           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 494       )
 495     ]
 496 )
 497
 498 dnl is time_t 32 of 64 bit ?
 499 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
 500 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
 501 AC_MSG_CHECKING([the type of time_t])
 502 AC_CHECK_SIZEOF([time_t])
 503 if test "x$ac_cv_sizeof_time_t" = "x4"; then
 504   AC_MSG_RESULT([time_t is 32 bit])
 505   AC_DEFINE([TIME_T_IS_32BIT])
 506 elif test "x$ac_cv_sizeof_time_t" = "x8"; then
 507   AC_MSG_RESULT([time_t is 64 bit])
 508   AC_DEFINE([TIME_T_IS_64BIT])
 509 else
 510   AC_MSG_ERROR([can not figure type of time_t])
 511 fi
 512
 513 AC_LANG_POP(C)
 514
 515 CONFIGURE_PART(Find 3rd-Party Libraries)
 516
 517 have_libdbi=no
 518
 519 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[],[
 520     AC_CHECK_LIB(dbi, dbi_initialize, [
 521         LIBS="${LIBS} -ldbi -ldl"
 522         AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 523         have_libdbi=yes
 524     ],[],[-ldl])
 525 ])
 526
 527 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 528
 529
 530 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
 531
 532
 533 CORE_LIBS="$LIBS"
 534
 535 if test $enable_rrd_graph != no; then
 536 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.5,  http://zlib.net/, "")
 537 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.4.8,  ftp://ftp.simplesystems.org/pub/libpng/png/src/, "")
 538 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.4.6,  http://download.savannah.gnu.org/releases/freetype/, /usr/include/freetype2)
 539 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.8.0,  http://www.freedesktop.org/software/fontconfig/release/, /usr/include)
 540 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.10.2,  http://cairographics.org/releases/, "")
 541 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.10.2,  http://cairographics.org/releases/, "")
 542 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.10.2,  http://cairographics.org/releases/, "")
 543 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.10.2,  http://cairographics.org/releases/, "")
 544 EX_CHECK_ALL(pangocairo-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.28.4,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.28, "")
 545
 546 fi
 547 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.28.7, ftp://ftp.gtk.org/pub/glib/2.28/, "")
 548 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.7.8,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 549
 550 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 551   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 552 fi
 553
 554 ALL_LIBS="$LIBS"
 555 LIBS=
 556
 557 AC_SUBST(CORE_LIBS)
 558 AC_SUBST(ALL_LIBS)
 559
 560 CONFIGURE_PART(Prep for Building Language Bindings)
 561
 562 dnl Check for Perl and friends
 563 PATH=$PATH:/usr/perl5/bin
 564 export PATH
 565 AC_PATH_PROG(PERL, perl, no)
 566 AC_PATH_PROG(POD2MAN, pod2man, no)
 567 AC_PATH_PROG(POD2HTML, pod2html, no)
 568
 569
 570 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 571 [],[enable_perl=yes])
 572
 573
 574 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 575 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 576 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 577 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 578
 579 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 580         COMP_PERL=
 581 else
 582         COMP_PERL="perl_piped perl_shared"
 583         AC_MSG_CHECKING(for the perl version you are running)
 584         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 585         AC_MSG_RESULT($PERL_VERSION)
 586         if test -z "$PERLCC"; then
 587             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 588             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 589             AC_MSG_RESULT($perlcc)
 590             if test ! -x "$perlcc"; then
 591                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 592                 if test "$PERL_CC" = "no"; then
 593                     AC_MSG_WARN([
 594 I would not find the Compiler ($perlcc) that was originally used to compile
 595 your perl binary. You should either make sure that this compiler is
 596 available on your system, pick an other compiler and set PERLCC
 597 appropriately, or use a different perl setup that was compiled locally.
 598
 599 I will disable the compilation of the RRDs perl module for now.
 600 ])
 601                     COMP_PERL="perl_piped"
 602                 fi
 603             fi
 604         fi
 605 fi
 606
 607 AC_MSG_CHECKING(Perl Modules to build)
 608 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 609
 610 # Options to pass when configuring perl module
 611 langpref=$prefix
 612 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 613 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 614
 615 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 616
 617 dnl pass additional perl options when generating Makefile from Makefile.PL
 618 AC_ARG_ENABLE(perl-site-install,
 619 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 620 [PERL_MAKE_OPTIONS=],[])
 621
 622 if test ! -z "$PERLCC"; then
 623    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 624
 625    if test ! -z "$PERLCCFLAGS"; then
 626        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 627    fi
 628
 629    if test -z "$PERLLD"; then
 630        PERLLD=$PERLCC
 631    fi
 632    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 633
 634    if test ! -z "$PERLLDFLAGS"; then
 635        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 636    fi
 637 fi
 638
 639 AC_ARG_WITH(perl-options,
 640 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 641                           generating Makefile from Makefile.PL. If you set this
 642                           option, interesting things may happen unless you know
 643                           what you are doing!],
 644 [PERL_MAKE_OPTIONS=$withval])
 645
 646 AC_SUBST(PERL_MAKE_OPTIONS)
 647 AC_SUBST(PERL)
 648 AC_SUBST(COMP_PERL)
 649 AC_SUBST(PERL_VERSION)
 650
 651 dnl Check for Ruby.
 652 AC_PATH_PROG(RUBY, ruby, no)
 653
 654 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 655 [],[enable_ruby=yes])
 656
 657 AC_MSG_CHECKING(if ruby modules can be built)
 658
 659 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 660         COMP_RUBY=
 661         AC_MSG_RESULT(No .. Ruby not found or disabled)
 662 else
 663         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 664                 COMP_RUBY="ruby"
 665                 AC_MSG_RESULT(YES)
 666         else
 667                 COMP_RUBY=
 668                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 669         fi
 670 fi
 671
 672 dnl pass additional ruby options when generating Makefile from Makefile.PL
 673 AC_ARG_ENABLE(ruby-site-install,
 674 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 675 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 676
 677
 678 AC_ARG_WITH(ruby-options,
 679 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 680                           generating Makefile from extconf.rb. If you set this
 681                           option, interesting things may happen unless you know
 682                           what you are doing!],
 683 [RUBY_MAKE_OPTIONS=$withval])
 684
 685 AC_SUBST(RUBY_MAKE_OPTIONS)
 686 AC_SUBST(RUBY)
 687 AC_SUBST(COMP_RUBY)
 688
 689 dnl Check for Lua.
 690 AC_PATH_PROG(LUA, lua, no)
 691
 692 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 693 [],[enable_lua=yes])
 694
 695 COMP_LUA=
 696 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 697   enable_lua=no
 698 else
 699   AC_MSG_CHECKING(for lua >= 5.0)
 700   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 701     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 702 LUA_EOF
 703   if test 0$LUA_MAJOR -lt 5; then
 704     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 705   else
 706     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 707     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 708     lua_vndot=$LUA_MAJOR$LUA_MINOR
 709     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 710     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 711       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 712         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 713           [lua_headerdir=lua$lua_vndot],
 714           [])],
 715         [])],
 716       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 717         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 718           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 719             [lua_headerdir=lua$lua_vdot],
 720             [])],
 721           [])],
 722         [AC_CHECK_HEADERS(lua.h,
 723           [AC_CHECK_HEADERS(lualib.h,
 724             [AC_CHECK_HEADER(lauxlib.h,
 725               [lua_headerdir=""],
 726               [lua_headerdir="no"])],
 727             [])],
 728           [])])])
 729
 730     if test "$lua_headerdir" = "no"; then
 731       enable_lua=no
 732     else
 733       COMP_LUA=lua
 734     fi
 735
 736     if test "$COMP_LUA" != "lua"; then
 737       enable_lua=no
 738       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 739     else
 740       # OK, headers found, let's check the libraries (LIBS is not used)
 741       LIBS=
 742       lua_havelib=no
 743       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 744       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 745         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 746           [lua_havelib=LUA$lua_vndot],
 747           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 748             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 749              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 750             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 751               [lua_havelib=$lua_vndot],
 752               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 753         [COMP_LUA=], [-lm])
 754       lua_libs=$LIBS
 755       LIBS=
 756
 757       # Options to pass when configuring Lua module
 758       if test  "$lua_havelib" != "no"; then
 759         # OK, headers and libs found. Try to set lua flags
 760         # and modules installation dirs with pkg-config
 761         if test "$PKGCONFIG" != "no"; then
 762           if test "$lua_vndot" = "50"; then
 763             lua_pkg_prefix=lualib
 764           else
 765             lua_pkg_prefix=lua
 766           fi
 767           # try with dot, without dot and finally without version
 768           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 769             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 770             # same binaries?
 771             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 772                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 773                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 774                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 775                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 776                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 777                 break
 778             fi
 779           done
 780         fi
 781
 782         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 783         # if lua 5.0 can't find compat-5.1, force installation of
 784         # compat-5.1.lua together with RRDtool.
 785         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 786           lua_need_compat51=1
 787           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 788         fi
 789
 790         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 791         if test "$LUA_CFLAGS" = ""; then
 792           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 793           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 794           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 795           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 796         fi
 797
 798         dnl pass additional lua options
 799         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 800         dnl found and install together with RRDtool, under $langpref.
 801         AC_ARG_ENABLE(lua-site-install,
 802         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 803         [],
 804         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 805
 806         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 807         AC_SUBST(LUA)
 808         AC_SUBST(COMP_LUA)
 809         AC_SUBST(LUA_INSTALL_CMOD)
 810         AC_SUBST(LUA_INSTALL_LMOD)
 811         AC_SUBST(LUA_CFLAGS)
 812         AC_SUBST(LUA_LFLAGS)
 813         AC_SUBST(LUA_DEFINES)
 814       else
 815         enable_lua=no
 816         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 817       fi
 818     fi
 819   fi
 820 fi
 821 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 822 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 823 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 824       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 825 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 826 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 827 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 828 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 829
 830 enable_tcl_site=no
 831
 832 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 833 [],[enable_tcl=yes])
 834
 835 if test  "$enable_tcl" = "yes"; then
 836   dnl Check for Tcl.
 837   withval=""
 838   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 839   enable_tcl=no
 840   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 841     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 842     if test -f "$dir/tclConfig.sh" ; then
 843         tcl_config=$dir/tclConfig.sh
 844         enable_tcl=yes
 845         AC_MSG_RESULT(yes)
 846         break
 847     else
 848         AC_MSG_RESULT(no)
 849     fi
 850   done
 851
 852   if test "$enable_tcl" = "no"; then
 853         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 854   else
 855         . $tcl_config
 856         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 857         if test -n "$TCL_INC_DIR"; then
 858           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 859         fi
 860   fi
 861   AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 862   [],[enable_tcl_site=yes])
 863
 864 fi
 865
 866 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 867 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 868
 869
 870 AC_SUBST(TCL_PREFIX)
 871 AC_SUBST(TCL_SHLIB_CFLAGS)
 872 AC_SUBST(TCL_SHLIB_LD)
 873 AC_SUBST(TCL_SHLIB_SUFFIX)
 874 AC_SUBST(TCL_PACKAGE_PATH)
 875 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 876 AC_SUBST(TCL_STUB_LIB_SPEC)
 877 AC_SUBST(TCL_VERSION)
 878 AC_SUBST(TCL_PACKAGE_DIR)
 879 AC_SUBST(TCL_INCLUDE_SPEC)
 880
 881 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 882 [],[enable_python=yes])
 883
 884 if test  "$enable_python" = "yes"; then
 885 dnl Check for python
 886 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 887 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 888 fi
 889
 890 if test  x$enable_python = xno; then
 891         COMP_PYTHON=
 892 else
 893         COMP_PYTHON="python"
 894 fi
 895
 896 AC_SUBST(COMP_PYTHON)
 897
 898 dnl Check for nroff
 899 AC_ARG_VAR(NROFF, [path to the local nroff version])
 900 AC_PATH_PROGS(NROFF, [gnroff nroff])
 901 if test x$NROFF = x; then
 902   AC_MSG_ERROR([I need a copy of *nroff to format the documentation])
 903 fi
 904 AC_ARG_VAR(TROFF, [path to the local troff version])
 905 AC_PATH_PROGS(TROFF, [groff troff])
 906 if test x$TROFF = x; then
 907   AC_MSG_ERROR([I need a copy of *troff to format the documentation])
 908 fi
 909
 910 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 911 if test -z "$RRDDOCDIR"; then
 912    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 913
 914
 915 CONFIGURE_PART(Apply Configuration Information)
 916
 917 AC_CONFIG_FILES([examples/shared-demo.pl])
 918 AC_CONFIG_FILES([examples/piped-demo.pl])
 919 AC_CONFIG_FILES([examples/stripes.pl])
 920 AC_CONFIG_FILES([examples/bigtops.pl])
 921 AC_CONFIG_FILES([examples/minmax.pl])
 922 AC_CONFIG_FILES([examples/4charts.pl])
 923 AC_CONFIG_FILES([examples/perftest.pl])
 924 AC_CONFIG_FILES([examples/Makefile])
 925 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 926 AC_CONFIG_FILES([doc/Makefile])
 927 AC_CONFIG_FILES([po/Makefile.in])
 928 AC_CONFIG_FILES([src/Makefile])
 929 AC_CONFIG_FILES([src/librrd.sym.in])
 930 AC_CONFIG_FILES([src/librrd.pc])
 931 AC_CONFIG_FILES([bindings/Makefile])
 932 AC_CONFIG_FILES([bindings/tcl/Makefile])
 933 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 934 AC_CONFIG_FILES([Makefile])
 935 AC_CONFIG_FILES([bindings/lua/Makefile])
 936
 937 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 938
 939 dnl intl requires our config to be called config.h. indulge it.
 940 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 941
 942 AC_OUTPUT
 943
 944 AC_MSG_CHECKING(in)
 945 AC_MSG_RESULT(and out again)
 946
 947 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 948 sleep 1
 949 echo $ECHO_N ".$ECHO_C" 1>&6
 950 sleep 1
 951 echo $ECHO_N ".$ECHO_C" 1>&6
 952 sleep 1
 953 echo $ECHO_N ".$ECHO_C" 1>&6
 954 sleep 1
 955 echo $ECHO_N ".$ECHO_C" 1>&6
 956 sleep 1
 957 AC_MSG_RESULT([ just kidding ;-)])
 958 echo
 959 echo "----------------------------------------------------------------"
 960 echo "Config is DONE!"
 961 echo
 962 echo "          With MMAP IO: $enable_mmap"
 963 echo "      Build rrd_getopt: $build_getopt"
 964 echo "       Build rrd_graph: $enable_rrd_graph"
 965 echo "       Static programs: $staticprogs"
 966 echo "          Perl Modules: $COMP_PERL"
 967 echo "           Perl Binary: $PERL"
 968 echo "          Perl Version: $PERL_VERSION"
 969 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 970 echo "          Ruby Modules: $COMP_RUBY"
 971 echo "           Ruby Binary: $RUBY"
 972 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 973 echo "    Build Lua Bindings: $enable_lua"
 974 if test "$enable_lua" = "yes"; then
 975 echo "            Lua Binary: $LUA"
 976 echo "           Lua Version: $lua_version"
 977 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 978 if test "$lua_need_compat51" = "1"; then
 979 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 980 fi
 981 fi
 982 echo "    Build Tcl Bindings: $enable_tcl"
 983 echo " Build Python Bindings: $enable_python"
 984 echo "          Build rrdcgi: $enable_rrdcgi"
 985 echo "       Build librrd MT: $enable_pthread"
 986 echo "           Use gettext: $USE_NLS"
 987 echo "           With libDBI: $have_libdbi"
 988 echo "          With libwrap: $have_libwrap"
 989 echo
 990 echo "             Libraries: $ALL_LIBS"
 991 echo
 992 echo "Type 'make' to compile the software and use 'make install' to "
 993 echo "install everything to: $prefix."
 994 echo
 995 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 996 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 997 echo "place an order."
 998 echo
 999 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
1000 echo "----------------------------------------------------------------"