configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3.2])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.3002
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which versions the library are compatible with
  23 dnl each other we must keep a separate library version cout of the format c:r:a.
  24 dnl - if only implementation changed but all interfaces are kept, do r++
  25 dnl - if only functionality was added do c++,r=0,a++
  26 dnl - if any functionality was removed do c++,r=0,a=0.
  27 dnl
  28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  29 dnl
  30 LIBVERS=4:1:0
  31 AC_SUBST(LIBVERS)
  32
  33 AC_CANONICAL_TARGET
  34 AM_INIT_AUTOMAKE
  35 AM_MAINTAINER_MODE
  36
  37 AC_CONFIG_HEADERS([rrd_config.h])
  38
  39 dnl all our local stuff like install scripts and include files
  40 dnl is in there
  41
  42
  43 dnl determine the type of system we are running on
  44
  45 AC_SUBST(VERSION)
  46
  47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  48
  49 dnl Minimum Autoconf version required.
  50 AC_PREREQ(2.59)
  51
  52 dnl At the TOP of the HEADER
  53
  54 AH_TOP([
  55 #ifndef RRD_CONFIG_H
  56 #define RRD_CONFIG_H
  57
  58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  59 #undef MUST_DISABLE_FPMASK
  60
  61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  62 #undef MUST_DISABLE_SIGFPE
  63
  64 /* realloc does not support NULL as argument */
  65 #undef NO_NULL_REALLOC
  66
  67 /* lets enable madvise defines in NetBSD */
  68 #if defined(__NetBSD__)
  69 # if !defined(_NETBSD_SOURCE)
  70 #  define _NETBSD_SOURCE
  71 # endif
  72 #endif
  73
  74 ])
  75
  76 AH_BOTTOM([
  77
  78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  79 #  include <malloc/malloc.h>
  80 #endif
  81
  82 #include <rrd_config_bottom.h>
  83
  84 #endif
  85 ])
  86
  87 dnl Process Special Options
  88 dnl -----------------------------------
  89
  90 dnl How the vertical axis label is printed
  91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  92  [Vertical label angle: -90.0 (default) or 90.0])
  93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
  94  [Vertical label angle: -90.0 (default) or 90.0])
  95
  96 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
  97 [],[enable_rrdcgi=yes])
  98
  99 dnl Check if we run on a system that has fonts
 100 AC_ARG_WITH(rrd-default-font,
 101 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 102 [RRD_DEFAULT_FONT=$withval],[
 103   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 104         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 105   else
 106         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 107   fi
 108 ])
 109
 110 dnl Use mmap in rrd_update instead of seek+write
 111 AC_ARG_ENABLE([mmap],
 112 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 113 [],
 114 [enable_mmap=yes])
 115
 116 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 117 [],[enable_pthread=yes])
 118
 119 AC_ARG_ENABLE(static-programs,
 120      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 121      [case "${enableval}" in
 122        yes) staticprogs=yes ;;
 123        no)  staticprogs=no ;;
 124        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 125      esac],[staticprogs=no])
 126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 127
 128
 129 CONFIGURE_PART(Audit Compilation Environment)
 130
 131
 132 dnl Check for the compiler and static/shared library creation.
 133 AC_PROG_CPP
 134 AC_PROG_CC
 135 AM_PROG_CC_C_O
 136 AC_PROG_LIBTOOL
 137
 138 dnl Try to detect/use GNU features
 139 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 140
 141 dnl check for -Werror separatly
 142 dnl (quite a few autotool checks don't work with -Werror; also, the
 143 dnl check for -Werror fails after checking and adding the other flags)
 144 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 145   [AC_COMPILE_IFELSE(
 146     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 147     [rd_cv_gcc_flag__Werror="yes"],
 148     [rd_cv_gcc_flag__Werror="no"])])
 149 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 150   WERROR="-Werror"
 151 else
 152   WERROR=""
 153 fi
 154 AC_SUBST(WERROR)
 155
 156 dnl which flags does the compiler support?
 157 if test "x$GCC" = "xyes"; then
 158   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 159     oCFLAGS="$CFLAGS"
 160     CFLAGS="$CFLAGS $flag"
 161     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 162     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 163        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 164     if eval test \$$cachename = no; then
 165          CFLAGS="$oCFLAGS"
 166     fi
 167   done
 168 fi
 169
 170
 171
 172 AC_SUBST(RRD_DEFAULT_FONT)
 173
 174 CONFIGURE_PART(Checking for Header Files)
 175
 176 dnl Checks for header files.
 177 AC_HEADER_STDC
 178 AC_HEADER_DIRENT
 179 AC_CHECK_HEADERS(libgen.h features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 180
 181 dnl Checks for typedefs, structures, and compiler characteristics.
 182 AC_C_CONST
 183 AC_HEADER_TIME
 184 AC_STRUCT_TM
 185
 186 CONFIGURE_PART(Test Library Functions)
 187
 188 dnl Checks for libraries.
 189 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 190
 191
 192 dnl add pic flag in any case this makes sure all our code is relocatable
 193 eval `./libtool --config | grep pic_flag`
 194 CFLAGS="$CFLAGS $pic_flag"
 195
 196
 197 dnl Checks for library functions.
 198 AC_FUNC_STRFTIME
 199 AC_FUNC_VPRINTF
 200
 201 AC_C_BIGENDIAN
 202
 203 dnl for each function found we get a definition in config.h
 204 dnl of the form HAVE_FUNCTION
 205
 206 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 207
 208 AC_FUNC_STRERROR_R
 209
 210 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 211
 212 dnl Could use these to know if we need to provide a prototype
 213 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 214
 215 dnl check for fdatasync. Solaris has fdatasync in the librt
 216
 217 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 218 dnl if there is no fdatasync we may get lucky with fsync
 219 AC_CHECK_FUNCS(fsync)
 220
 221
 222 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 223 if test "x$enable_mmap" = "xyes"; then
 224   case "$host" in
 225   *cygwin*)
 226     # the normal mmap test does not work in cygwin
 227     AC_CHECK_FUNCS(mmap)
 228     if test "x$ac_cv_func_mmap" = "xyes"; then
 229       ac_cv_func_mmap_fixed_mapped=yes
 230     fi
 231   ;;
 232   *)
 233     AC_CHECK_HEADERS(sys/mman.h)
 234     AC_FUNC_MMAP
 235     AC_CHECK_FUNCS(mmap munmap msync)
 236     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 237                                      # include <sys/mman.h>
 238                                      #endif])
 239     if test "x$ac_cv_have_decl_madvise" = "xyes";
 240     then
 241       AC_CHECK_FUNCS(madvise)
 242     else
 243       AC_CHECK_FUNCS(posix_madvise)
 244       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 245         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 246       fi
 247     fi
 248   ;;
 249   esac
 250   if test "x$ac_cv_func_mmap" != "xyes";
 251   then
 252     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 253 dnl enable_mmap="no"
 254   fi
 255 fi
 256
 257 dnl can we use posix_fadvise
 258 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 259 #include <fcntl.h>])
 260 AC_CHECK_FUNCS(posix_fadvise)
 261
 262 CONFIGURE_PART(Libintl Processing)
 263
 264
 265 dnl gettext
 266 GETTEXT_PACKAGE=rrdtool
 267 AC_SUBST(GETTEXT_PACKAGE)
 268 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 269
 270 AM_GLIB_GNU_GETTEXT()
 271
 272 AC_ARG_ENABLE(libintl,AS_HELP_STRING([--disable-libintl],[i18n support (libintl)]),
 273 [],[enable_libintl=yes])
 274
 275 if test x$enable_libintl = xyes; then
 276   IT_PROG_INTLTOOL([0.35.0],[no-xml])
 277 fi
 278
 279 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
 280   AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
 281   enable_libintl=no
 282 fi
 283
 284 if test x$enable_libintl = xyes; then
 285   AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
 286 fi
 287
 288 if test x$enable_libintl = xyes ; then
 289   dnl it seems bsd synstems need to link against libintl
 290   dnl when compiling rrdupdate. lets check
 291   AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
 292 fi
 293
 294 dnl use for linking rrdupdate
 295 AC_SUBST(LIB_LIBINTL)
 296
 297 dnl do not touch the po stuff if we are not going to build intl
 298 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
 299
 300 if test x$enable_libintl = xyes; then
 301    AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
 302 fi
 303
 304 CONFIGURE_PART(IEEE Math Checks)
 305
 306
 307 dnl actual code to check if this works
 308 AC_CHECK_FUNCS(fpclassify, ,
 309   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 310     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 311 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 312       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 313
 314 AC_CHECK_FUNCS(isinf, ,
 315   [AC_MSG_CHECKING(for isinf with <math.h>)
 316     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 317 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 318       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 319
 320 dnl finite is BSD, isfinite is C99, so prefer the latter
 321 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 322 AC_TRY_RUN([
 323 #ifdef HAVE_MATH_H
 324 #include <math.h>
 325 #endif
 326 #ifdef HAVE_FLOAT_H
 327 #include <float.h>
 328 #endif
 329 int main ()
 330 {
 331 #ifdef isfinite
 332 #ifdef LDBL_MAX
 333   if (!isfinite(LDBL_MAX)) return 1;
 334 #endif
 335 #ifdef DBL_MAX
 336   if (!isfinite(DBL_MAX)) return 1;
 337 #endif
 338 #endif
 339 return 0;
 340 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 341 case "${target}" in
 342   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 343   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 344   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 345   *) ac_cv_have_broken_isfinite=no ;;
 346 esac])
 347 ])
 348
 349 dnl the test does not seem to work on solaris 2.8
 350 dnl so lets fix this by hand
 351 case "${target}" in
 352   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 353   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 354 esac
 355
 356 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 357   AC_DEFINE(HAVE_ISFINITE)
 358 else
 359   AC_CHECK_FUNCS(finite,[],
 360       [AC_CHECK_FUNCS(isfinite,[],
 361          [AC_MSG_CHECKING(for isfinite with <math.h>)
 362           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 363 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 364                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 365 fi
 366
 367 AC_FULL_IEEE
 368
 369 CONFIGURE_PART(Resolve Portability Issues)
 370
 371 CHECK_FOR_WORKING_MS_ASYNC
 372
 373 dnl Do we need getopt_long
 374
 375 dnl even when including our own getopt implementation
 376 dnl we may want to make sure we use the external
 377 dnl defined by libc to not run into linker resolve trouble
 378
 379 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 380 [AC_TRY_LINK([#include <unistd.h>],
 381   [extern int opterr; opterr = 1;],
 382   [rd_cv_var_int_opterr=yes],
 383   [rd_cv_var_int_opterr=no])])
 384 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 385   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 386 fi
 387
 388 build_getopt=no
 389 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 390 AC_CHECK_FUNC(getopt_long,[],[
 391 RRD_GETOPT_LONG="getopt_long"
 392 build_getopt=yes
 393 ])
 394 AC_SUBST(RRD_GETOPT_LONG)
 395 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 396
 397 dnl what does realloc do if it gets called with a NULL pointer
 398
 399 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 400 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 401               int main(void){
 402               char *x = NULL;
 403               x = realloc (x,10);
 404               if (x==NULL) return 1;
 405               return 0;
 406              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 407
 408 if test x"$rd_cv_null_realloc" = xnope; then
 409 AC_DEFINE(NO_NULL_REALLOC)
 410 fi
 411
 412 AC_LANG_PUSH(C)
 413 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 414 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 415 AC_LINK_IFELSE(
 416     AC_LANG_PROGRAM(
 417            [[#include <time.h>]],
 418            [[ctime_r(NULL,NULL,0)]]
 419                    ),
 420     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 421       AC_LINK_IFELSE(
 422           AC_LANG_PROGRAM(
 423                 [[#include <time.h>]],
 424                 [[ctime_r(NULL,NULL)]]
 425                          ),
 426           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 427           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 428       )
 429     ],
 430     [ AC_LINK_IFELSE(
 431           AC_LANG_PROGRAM(
 432                 [[#include <time.h>]],
 433                 [[ctime_r(NULL,NULL)]]
 434                          ),
 435           [AC_MSG_RESULT(no)],
 436           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 437       )
 438     ]
 439 )
 440 AC_LANG_POP(C)
 441
 442 dnl Check for pthreads
 443 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 444
 445 AC_SUBST(MULTITHREAD_CFLAGS)
 446 AC_SUBST(MULTITHREAD_LDFLAGS)
 447
 448 if test $enable_pthread != no; then
 449  ACX_PTHREAD([
 450     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 451     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 452              ],
 453              [])
 454 fi
 455
 456 dnl since we use lots of *_r functions all over the code we better
 457 dnl make sure they are known
 458
 459 if test  "x$x_rflag" != "xno"; then
 460    CPPFLAGS="$CPPFLAGS $x_rflag"
 461 fi
 462
 463 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 464
 465 AC_LANG_PUSH(C)
 466 dnl see if we have to include malloc/malloc.h
 467 AC_MSG_CHECKING([do we need malloc/malloc.h])
 468 AC_LINK_IFELSE(
 469     AC_LANG_PROGRAM(
 470            [[#include <stdlib.h>]],
 471            [[malloc(1)]]
 472                    ),
 473     [ AC_MSG_RESULT([nope, works out of the box]) ],
 474     [ AC_LINK_IFELSE(
 475           AC_LANG_PROGRAM(
 476                 [[#include <stdlib.h>
 477                   #include <malloc/malloc.h>]],
 478                 [[malloc(1)]]
 479                          ),[
 480            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 481            AC_MSG_RESULT([yes we do])],
 482           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 483       )
 484     ]
 485 )
 486 AC_LANG_POP(C)
 487
 488 CONFIGURE_PART(Find 3rd-Party Libraries)
 489
 490 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
 491   XXX=$LIBS
 492   LIBS="$LIBS -ldbi -ldl"
 493   AC_MSG_CHECKING(for libdbi)
 494   AC_LINK_IFELSE(
 495     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 496                      [[dbi_initialize(NULL)]]
 497                     )
 498     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 499        AC_MSG_RESULT([yes])
 500        have_libdbi=yes
 501     ],[LIBS=$XXX
 502        AC_MSG_RESULT([no])
 503        have_libdbi=no
 504     ]
 505   )
 506 ])
 507 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 508
 509 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 510
 511
 512 CORE_LIBS="$LIBS"
 513
 514 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 515 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 516 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 517 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 518 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 519 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 520 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 521 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 522 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 523 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 524 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 525
 526 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 527   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 528 fi
 529
 530 ALL_LIBS="$LIBS"
 531 LIBS=
 532
 533 AC_SUBST(CORE_LIBS)
 534 AC_SUBST(ALL_LIBS)
 535
 536 CONFIGURE_PART(Prep for Building Language Bindings)
 537
 538 dnl Check for Perl and friends
 539 PATH=$PATH:/usr/perl5/bin
 540 export PATH
 541 AC_PATH_PROG(PERL, perl, no)
 542 AC_PATH_PROG(POD2MAN, pod2man, no)
 543 AC_PATH_PROG(POD2HTML, pod2html, no)
 544
 545
 546 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 547 [],[enable_perl=yes])
 548
 549
 550 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 551 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 552 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 553 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 554
 555 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 556         COMP_PERL=
 557 else
 558         COMP_PERL="perl_piped perl_shared"
 559         AC_MSG_CHECKING(for the perl version you are running)
 560         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 561         AC_MSG_RESULT($PERL_VERSION)
 562         if test -z "$PERLCC"; then
 563             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 564             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 565             AC_MSG_RESULT($perlcc)
 566             if test ! -x "$perlcc"; then
 567                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 568                 if test "$PERL_CC" = "no"; then
 569                     AC_MSG_WARN([
 570 I would not find the Compiler ($perlcc) that was originally used to compile
 571 your perl binary. You should either make sure that this compiler is
 572 available on your system, pick an other compiler and set PERLCC
 573 appropriately, or use a different perl setup that was compiled locally.
 574
 575 I will disable the compilation of the RRDs perl module for now.
 576 ])
 577                     COMP_PERL="perl_piped"
 578                 fi
 579             fi
 580         fi
 581 fi
 582
 583 AC_MSG_CHECKING(Perl Modules to build)
 584 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 585
 586 # Options to pass when configuring perl module
 587 langpref=$prefix
 588 test "$langpref" = "$(DESTDIR)NONE" && langpref='$(DESTDIR)'$ac_default_prefix
 589 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 590
 591 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 592
 593 dnl pass additional perl options when generating Makefile from Makefile.PL
 594 AC_ARG_ENABLE(perl-site-install,
 595 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 596 [PERL_MAKE_OPTIONS=],[])
 597
 598 if test ! -z "$PERLCC"; then
 599    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 600
 601    if test ! -z "$PERLCCFLAGS"; then
 602        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 603    fi
 604
 605    if test -z "$PERLLD"; then
 606        PERLLD=$PERLCC
 607    fi
 608    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 609
 610    if test ! -z "$PERLLDFLAGS"; then
 611        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 612    fi
 613 fi
 614
 615 AC_ARG_WITH(perl-options,
 616 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 617                           generating Makefile from Makefile.PL. If you set this
 618                           option, interesting things may happen unless you know
 619                           what you are doing!],
 620 [PERL_MAKE_OPTIONS=$withval])
 621
 622 AC_SUBST(PERL_MAKE_OPTIONS)
 623 AC_SUBST(PERL)
 624 AC_SUBST(COMP_PERL)
 625 AC_SUBST(PERL_VERSION)
 626
 627 dnl Check for Ruby.
 628 AC_PATH_PROG(RUBY, ruby, no)
 629
 630 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 631 [],[enable_ruby=yes])
 632
 633 AC_MSG_CHECKING(if ruby modules can be built)
 634
 635 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 636         COMP_RUBY=
 637         AC_MSG_RESULT(No .. Ruby not found or disabled)
 638 else
 639         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 640                 COMP_RUBY="ruby"
 641                 AC_MSG_RESULT(YES)
 642         else
 643                 COMP_RUBY=
 644                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 645         fi
 646 fi
 647
 648 dnl pass additional ruby options when generating Makefile from Makefile.PL
 649 AC_ARG_ENABLE(ruby-site-install,
 650 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 651 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 652
 653
 654 AC_ARG_WITH(ruby-options,
 655 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 656                           generating Makefile from extconf.rb. If you set this
 657                           option, interesting things may happen unless you know
 658                           what you are doing!],
 659 [RUBY_MAKE_OPTIONS=$withval])
 660
 661 AC_SUBST(RUBY_MAKE_OPTIONS)
 662 AC_SUBST(RUBY)
 663 AC_SUBST(COMP_RUBY)
 664
 665 dnl Check for Lua.
 666 AC_PATH_PROG(LUA, lua, no)
 667
 668 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 669 [],[enable_lua=yes])
 670
 671 COMP_LUA=
 672 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 673   enable_lua=no
 674 else
 675   AC_MSG_CHECKING(for lua >= 5.0)
 676   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 677     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 678 LUA_EOF
 679   if test 0$LUA_MAJOR -lt 5; then
 680     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 681   else
 682     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 683     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 684     lua_vndot=$LUA_MAJOR$LUA_MINOR
 685     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 686     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 687       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 688         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 689           [lua_headerdir=lua$lua_vndot],
 690           [])],
 691         [])],
 692       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 693         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 694           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 695             [lua_headerdir=lua$lua_vdot],
 696             [])],
 697           [])],
 698         [AC_CHECK_HEADERS(lua.h,
 699           [AC_CHECK_HEADERS(lualib.h,
 700             [AC_CHECK_HEADER(lauxlib.h,
 701               [lua_headerdir=""],
 702               [lua_headerdir="no"])],
 703             [])],
 704           [])])])
 705
 706     if test "$lua_headerdir" = "no"; then
 707       enable_lua=no
 708     else
 709       COMP_LUA=lua
 710     fi
 711
 712     if test "$COMP_LUA" != "lua"; then
 713       enable_lua=no
 714       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 715     else
 716       # OK, headers found, let's check the libraries (LIBS is not used)
 717       LIBS=
 718       lua_havelib=no
 719       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 720       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 721         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 722           [lua_havelib=LUA$lua_vndot],
 723           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 724             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 725              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 726             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 727               [lua_havelib=$lua_vndot],
 728               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 729         [COMP_LUA=], [-lm])
 730       lua_libs=$LIBS
 731       LIBS=
 732
 733       # Options to pass when configuring Lua module
 734       if test  "$lua_havelib" != "no"; then
 735         # OK, headers and libs found. Try to set lua flags
 736         # and modules installation dirs with pkg-config
 737         if test "$PKGCONFIG" != "no"; then
 738           if test "$lua_vndot" = "50"; then
 739             lua_pkg_prefix=lualib
 740           else
 741             lua_pkg_prefix=lua
 742           fi
 743           # try with dot, without dot and finally without version
 744           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 745             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 746             # same binaries?
 747             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 748                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 749                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 750                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 751                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 752                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 753                 break
 754             fi
 755           done
 756         fi
 757
 758         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 759         # if lua 5.0 can't find compat-5.1, force installation of
 760         # compat-5.1.lua together with RRDtool.
 761         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 762           lua_need_compat51=1
 763           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 764         fi
 765
 766         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 767         if test "$LUA_CFLAGS" = ""; then
 768           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 769           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 770           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 771           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 772         fi
 773
 774         dnl pass additional lua options
 775         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 776         dnl found and install together with RRDtool, under $langpref.
 777         AC_ARG_ENABLE(lua-site-install,
 778         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 779         [],
 780         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 781
 782         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 783         AC_SUBST(LUA)
 784         AC_SUBST(COMP_LUA)
 785         AC_SUBST(LUA_INSTALL_CMOD)
 786         AC_SUBST(LUA_INSTALL_LMOD)
 787         AC_SUBST(LUA_CFLAGS)
 788         AC_SUBST(LUA_LFLAGS)
 789         AC_SUBST(LUA_DEFINES)
 790       else
 791         enable_lua=no
 792         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 793       fi
 794     fi
 795   fi
 796 fi
 797 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 798 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 799 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 800       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 801 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 802 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 803 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 804 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 805
 806 enable_tcl_site=no
 807
 808 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 809 [],[enable_tcl=yes])
 810
 811 if test  "$enable_tcl" = "yes"; then
 812   dnl Check for Tcl.
 813   withval=""
 814   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 815   enable_tcl=no
 816   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 817     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 818     if test -f "$dir/tclConfig.sh" ; then
 819         tcl_config=$dir/tclConfig.sh
 820         enable_tcl=yes
 821         AC_MSG_RESULT(yes)
 822         break
 823     else
 824         AC_MSG_RESULT(no)
 825     fi
 826   done
 827
 828   if test "$enable_tcl" = "no"; then
 829         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 830   else
 831         . $tcl_config
 832         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 833         if test -n "$TCL_INC_DIR"; then
 834           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 835         fi
 836   fi
 837   AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 838   [],[enable_tcl_site=yes])
 839
 840 fi
 841
 842 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 843 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 844
 845
 846 AC_SUBST(TCL_PREFIX)
 847 AC_SUBST(TCL_SHLIB_CFLAGS)
 848 AC_SUBST(TCL_SHLIB_LD)
 849 AC_SUBST(TCL_SHLIB_SUFFIX)
 850 AC_SUBST(TCL_PACKAGE_PATH)
 851 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 852 AC_SUBST(TCL_STUB_LIB_SPEC)
 853 AC_SUBST(TCL_VERSION)
 854 AC_SUBST(TCL_PACKAGE_DIR)
 855 AC_SUBST(TCL_INCLUDE_SPEC)
 856
 857 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 858 [],[enable_python=yes])
 859
 860 if test  "$enable_python" = "yes"; then
 861 dnl Check for python
 862 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 863 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 864 fi
 865
 866 if test  x$enable_python = xno; then
 867         COMP_PYTHON=
 868 else
 869         COMP_PYTHON="python"
 870 fi
 871
 872 AC_SUBST(COMP_PYTHON)
 873
 874 dnl Check for nroff
 875 AC_PATH_PROGS(NROFF, gnroff nroff)
 876 AC_PATH_PROGS(TROFF, groff troff)
 877
 878 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 879 if test -z "$RRDDOCDIR"; then
 880    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 881
 882
 883 CONFIGURE_PART(Apply Configuration Information)
 884
 885 AC_CONFIG_FILES([examples/shared-demo.pl])
 886 AC_CONFIG_FILES([examples/piped-demo.pl])
 887 AC_CONFIG_FILES([examples/stripes.pl])
 888 AC_CONFIG_FILES([examples/bigtops.pl])
 889 AC_CONFIG_FILES([examples/minmax.pl])
 890 AC_CONFIG_FILES([examples/4charts.pl])
 891 AC_CONFIG_FILES([examples/perftest.pl])
 892 AC_CONFIG_FILES([examples/Makefile])
 893 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 894 AC_CONFIG_FILES([doc/Makefile])
 895 AC_CONFIG_FILES([po/Makefile.in])
 896 AC_CONFIG_FILES([src/Makefile])
 897 AC_CONFIG_FILES([src/librrd.sym.in])
 898 AC_CONFIG_FILES([src/librrd.pc])
 899 AC_CONFIG_FILES([bindings/Makefile])
 900 AC_CONFIG_FILES([bindings/tcl/Makefile])
 901 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 902 AC_CONFIG_FILES([Makefile])
 903 AC_CONFIG_FILES([bindings/lua/Makefile])
 904
 905 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 906 AC_OUTPUT
 907
 908 AC_MSG_CHECKING(in)
 909 AC_MSG_RESULT(and out again)
 910
 911 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 912 sleep 1
 913 echo $ECHO_N ".$ECHO_C" 1>&6
 914 sleep 1
 915 echo $ECHO_N ".$ECHO_C" 1>&6
 916 sleep 1
 917 echo $ECHO_N ".$ECHO_C" 1>&6
 918 sleep 1
 919 echo $ECHO_N ".$ECHO_C" 1>&6
 920 sleep 1
 921 AC_MSG_RESULT([ just kidding ;-)])
 922 echo
 923 echo "----------------------------------------------------------------"
 924 echo "Config is DONE!"
 925 echo
 926 echo "          With MMAP IO: $enable_mmap"
 927 echo "      Build rrd_getopt: $build_getopt"
 928 echo "       Static programs: $staticprogs"
 929 echo "          Perl Modules: $COMP_PERL"
 930 echo "           Perl Binary: $PERL"
 931 echo "          Perl Version: $PERL_VERSION"
 932 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 933 echo "          Ruby Modules: $COMP_RUBY"
 934 echo "           Ruby Binary: $RUBY"
 935 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 936 echo "    Build Lua Bindings: $enable_lua"
 937 if test "$enable_lua" = "yes"; then
 938 echo "            Lua Binary: $LUA"
 939 echo "           Lua Version: $lua_version"
 940 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 941 if test "$lua_need_compat51" = "1"; then
 942 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 943 fi
 944 fi
 945 echo "    Build Tcl Bindings: $enable_tcl"
 946 echo " Build Python Bindings: $enable_python"
 947 echo "          Build rrdcgi: $enable_rrdcgi"
 948 echo "       Build librrd MT: $enable_pthread"
 949 echo "     Link with libintl: $enable_libintl"
 950 echo "           With libDBI: $have_libdbi"
 951 echo
 952 echo "             Libraries: $ALL_LIBS"
 953 echo
 954 echo "Type 'make' to compile the software and use 'make install' to "
 955 echo "install everything to: $prefix."
 956 echo
 957 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 958 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 959 echo "place an order."
 960 echo
 961 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 962 echo "----------------------------------------------------------------"