configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 AC_INIT([rrdtool],[1.2.0])
  10 AC_CANONICAL_TARGET
  11 AM_INIT_AUTOMAKE
  12 AC_CONFIG_HEADERS([config.h])
  13
  14 dnl all our local stuff like install scripts and include files
  15 dnl is in there
  16
  17
  18 dnl determine the type of system we are running on
  19
  20
  21 AC_SUBST(VERSION)
  22
  23 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  24
  25 dnl Minimum Autoconf version required.
  26 AC_PREREQ(2.59)
  27
  28 dnl At the TOP of the HEADER
  29
  30 AH_TOP([
  31
  32 #ifndef CONFIG_H
  33 #define CONFIG_H
  34 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  35 #undef MUST_DISABLE_FPMASK
  36
  37 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  38
  39 #undef MUST_DISABLE_SIGFPE
  40
  41 /* realloc does not support NULL as argument */
  42 #undef NO_NULL_REALLOC
  43
  44  ])
  45
  46 AH_BOTTOM([
  47
  48 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  49    make sure you are NOT using bcopy, index or rindex in the code */
  50
  51 #if STDC_HEADERS
  52 # include <string.h>
  53 #else
  54 # ifndef HAVE_STRCHR
  55 #  define strchr index
  56 #  define strrchr rindex
  57 # endif
  58 char *strchr (), *strrchr ();
  59 # ifndef HAVE_MEMMOVE
  60 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  61 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  62 # endif
  63 #endif
  64
  65
  66 #if NO_NULL_REALLOC
  67 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  68 #else
  69 # define rrd_realloc(a,b) realloc((a), (b))
  70 #endif
  71
  72 #if HAVE_MATH_H
  73 #  include <math.h>
  74 #endif
  75
  76 #if HAVE_FLOAT_H
  77 #  include <float.h>
  78 #endif
  79
  80 #if HAVE_IEEEFP_H
  81 #  include <ieeefp.h>
  82 #endif
  83
  84 #if HAVE_FP_CLASS_H
  85 #  include <fp_class.h>
  86 #endif
  87
  88 /* for Solaris */
  89 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
  90 #  define HAVE_ISINF 1
  91 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
  92 #endif
  93
  94 /* for OSF1 Digital Unix */
  95 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
  96 #  define HAVE_ISINF 1
  97 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
  98 #endif
  99
 100 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 101 #  define HAVE_ISINF 1
 102 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 103 #endif
 104
 105 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 106 #  define HAVE_ISINF 1
 107 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 108 #endif
 109
 110 /* for AIX */
 111 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 112 #  define HAVE_ISINF 1
 113 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 114 #endif
 115
 116 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 117 #  define HAVE_FINITE 1
 118 #  define finite(a) isfinite(a)
 119 #endif
 120
 121 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 122 #  define HAVE_FINITE 1
 123 #  define finite(a) (! isnan(a) && ! isinf(a))
 124 #endif
 125
 126 #ifndef HAVE_FINITE
 127 #error "Can't compile without finite function"
 128 #endif
 129
 130 #ifndef HAVE_ISINF
 131 #error "Can't compile without isinf function"
 132 #endif
 133
 134 #endif /* CONFIG_H */
 135 ])
 136
 137
 138
 139 dnl Check for the compiler and static/shared library creation.
 140 AC_PROG_CC
 141 AC_PROG_CPP
 142 AC_PROG_LIBTOOL
 143
 144 dnl Check if we run on a system that has fonts
 145 AC_ARG_WITH(rrd-default-font,
 146 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 147 [RRD_DEFAULT_FONT=$withval],[
 148   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 149         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 150   else
 151         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 152   fi
 153 ])
 154
 155 AC_SUBST(RRD_DEFAULT_FONT)
 156
 157 dnl Checks for header files.
 158 AC_HEADER_STDC
 159 AC_HEADER_DIRENT
 160 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 161
 162 dnl Checks for typedefs, structures, and compiler characteristics.
 163 AC_C_CONST
 164 AC_HEADER_TIME
 165 AC_STRUCT_TM
 166
 167 dnl Checks for libraries.
 168 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 169
 170 dnl add pic flag in any case this makes sure all our code is relocatable
 171 eval `./libtool --config | grep pic_flag`
 172 CFLAGS="$CFLAGS $pic_flag"
 173
 174 dnl Checks for library functions.
 175 AC_FUNC_STRFTIME
 176 AC_FUNC_VPRINTF
 177
 178 AC_C_BIGENDIAN
 179
 180 dnl for each function found we get a definition in config.h
 181 dnl of the form HAVE_FUNCTION
 182
 183 AC_CHECK_FUNCS(tzset opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 184
 185 dnl Use mmap in rrd_update instead of seek+write
 186 AC_ARG_ENABLE([mmap],
 187 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 188 [],
 189 [enable_mmap=yes])
 190
 191 if test "x$enable_mmap" = xyes; then
 192   AC_FUNC_MMAP
 193 fi
 194
 195 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 196 dnl actual code to check if this works
 197 AC_CHECK_FUNCS(fpclassify, ,
 198   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 199     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
 200       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 201 AC_CHECK_FUNCS(finite, ,
 202   [AC_CHECK_FUNCS(isfinite, ,
 203     [AC_MSG_CHECKING(for isfinite with <math.h>)
 204     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
 205       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 206 AC_CHECK_FUNCS(isinf, ,
 207   [AC_MSG_CHECKING(for isinf with <math.h>)
 208     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
 209       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 210
 211 AC_FULL_IEEE
 212
 213 dnl How the vertical axis label is printed
 214 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 215  [Vertical label angle: 90.0 (default) or 270.0])
 216 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 217  [Vertical label angle: 90.0 (default) or 270.0])
 218
 219
 220 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 221 [],[enable_rrdcgi=yes])
 222 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 223
 224 if test $enable_rrdcgi != no; then
 225 EX_CHECK_ALL(cgi,        cgiInit,                   cgi.h,                  cgilib,      0.5,    http://www.infodrom.org/projects/cgilib, "")
 226 fi
 227 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 228 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.2,  http://www.gzip.org/zlib/, "")
 229 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 230 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 231
 232 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 233   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 234 fi
 235
 236 AC_LANG_PUSH(C)
 237 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 238 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 239 AC_LINK_IFELSE(
 240     AC_LANG_PROGRAM(
 241            [[#include <time.h>]],
 242            [[ctime_r(NULL,NULL,0)]]
 243                    ),
 244     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 245       AC_LINK_IFELSE(
 246           AC_LANG_PROGRAM(
 247                 [[#include <time.h>]],
 248                 [[ctime_r(NULL,NULL)]]
 249                          ),
 250           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 251           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 252       )
 253     ],
 254     [ AC_LINK_IFELSE(
 255           AC_LANG_PROGRAM(
 256                 [[#include <time.h>]],
 257                 [[ctime_r(NULL,NULL)]]
 258                          ),
 259           [AC_MSG_RESULT(yes)],
 260           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 261       )
 262     ]
 263 )
 264 AC_LANG_POP(C)
 265
 266 dnl Check for pthreads
 267 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 268
 269 AC_SUBST(MULTITHREAD_CFLAGS)
 270 AC_SUBST(MULTITHREAD_LDFLAGS)
 271
 272
 273 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 274 [],[enable_pthread=yes])
 275
 276
 277 if test $enable_pthread != no; then
 278  ACX_PTHREAD([
 279     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 280     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 281              ],
 282              [])
 283 fi
 284
 285 dnl since we use lots of *_r functions all over the code we better
 286 dnl make sure they are known
 287
 288 if test  "x$x_rflag" != "xno"; then
 289    CPPFLAGS="$CPPFLAGS $x_rflag"
 290 fi
 291
 292
 293 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 294
 295 dnl Check for Perl.
 296 AC_PATH_PROG(PERL, perl, no)
 297
 298 AC_ARG_ENABLE(perl,[  --disable-perl    do not build the perl modules],
 299 [],[enable_perl=yes])
 300
 301
 302 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 303         COMP_PERL=
 304 else
 305         COMP_PERL="perl_piped perl_shared"
 306         AC_MSG_CHECKING(for the perl version you are running)
 307         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 308         AC_MSG_RESULT($PERL_VERSION)
 309         AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 310         perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 311         AC_MSG_RESULT($perlcc)
 312         if test ! -x $perlcc; then
 313                AC_PATH_PROG(PERLCC, ${perlcc}, no)
 314                if test -x $"x$PERLCC" = "xno"; then
 315                   AC_MSG_WARN([
 316 I would not find the Compiler ($perlcc) that was originally used to compile your
 317 perl binary. You should either make sure that this compiler is available on your
 318 system, or use a different perl setup that was compiled with $CC.
 319
 320 I will disable the compilation of the RRDs perl module.
 321 ])
 322                   COMP_PERL="perl_piped"
 323                fi
 324         fi
 325 fi
 326 AC_MSG_CHECKING(Perl Modules to build)
 327 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 328
 329 # Options to pass when configuring perl module
 330 ppref=$prefix
 331 test "x$ppref" = xNONE && ppref=$ac_default_prefix
 332
 333 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 334
 335 dnl pass additional perl options when generating Makefile from Makefile.PL
 336 AC_ARG_ENABLE(perl-site-install,
 337 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 338                           together with rrdtool in $prefix/lib/perl. You have to
 339                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 340                           when you want to use them. When you set this option
 341                           the perl modules will get installed wherever
 342                           your perl setup thinks it is best.],
 343 [PERL_MAKE_OPTIONS=],[])
 344
 345 AC_ARG_WITH(perl-options,
 346 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 347                           generating Makefile from Makefile.PL. If you set this
 348                           option, interesting things may happen unless you know
 349                           what you are doing!],
 350 [PERL_MAKE_OPTIONS=$withval])
 351
 352 AC_SUBST(PERL_MAKE_OPTIONS)
 353 AC_SUBST(PERL)
 354 AC_SUBST(COMP_PERL)
 355 AC_SUBST(PERL_VERSION)
 356
 357
 358 dnl Check for Tcl.
 359 withval=""
 360 AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 361 found=0
 362 AC_MSG_CHECKING(for tclConfig.sh in $withval)
 363 if test -f "$withval/tclConfig.sh" ; then
 364         tcl_config=$withval/tclConfig.sh
 365         found=1
 366         AC_MSG_RESULT(yes)
 367         break
 368 else
 369         AC_MSG_RESULT(no)
 370 fi
 371
 372 if test $found -eq 0 ; then
 373         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 374 else
 375         . $tcl_config
 376 fi
 377
 378
 379 AM_CONDITIONAL(COMP_TCL, test x$found = x1 )
 380
 381 AC_SUBST(TCL_PREFIX)
 382 AC_SUBST(TCL_SHLIB_CFLAGS)
 383 AC_SUBST(TCL_SHLIB_LD)
 384 AC_SUBST(TCL_SHLIB_SUFFIX)
 385 AC_SUBST(TCL_PACKAGE_PATH)
 386 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 387
 388
 389
 390 dnl Check for nroff
 391 AC_PATH_PROGS(NROFF, gnroff nroff)
 392 AC_PATH_PROGS(TROFF, groff troff)
 393
 394 dnl Does the compiler like -Wall and -pedantic?
 395 if test "x$GCC" = "xyes"; then
 396   oCFLAGS=$CFLAGS
 397   CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 398   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 399                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 400                ]
 401         )
 402   if test $rd_cv_gcc_opt = no; then
 403          CFLAGS=$oCFLAGS
 404   fi
 405 fi
 406
 407 dnl what does realloc do if it gets called with a NULL pointer
 408
 409 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 410 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 411               int main(void){
 412               char *x = NULL;
 413               x = realloc (x,10);
 414               if (x==NULL) return 1;
 415               return 0;
 416              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 417
 418 if test x"$rd_cv_null_realloc" = xnope; then
 419 AC_DEFINE(NO_NULL_REALLOC)
 420 fi
 421
 422 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 423           examples/piped-demo.pl                        \
 424           examples/stripes.pl                           \
 425           examples/bigtops.pl                           \
 426           examples/minmax.pl                            \
 427           examples/cgi-demo.cgi                         \
 428           examples/4charts.pl                           \
 429           examples/Makefile                             \
 430           doc/Makefile                                  \
 431           src/Makefile                                  \
 432           bindings/Makefile                             \
 433           bindings/tcl/Makefile                         \
 434           Makefile])
 435 AC_CONFIG_COMMANDS([default],[[\
 436           chmod +x examples/*.cgi examples/*.pl]],[[]])
 437 AC_OUTPUT
 438
 439 AC_MSG_CHECKING(in)
 440 AC_MSG_RESULT(and out again)
 441
 442 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 443 sleep 1
 444 echo $ECHO_N ".$ECHO_C" 1>&6
 445 sleep 1
 446 echo $ECHO_N ".$ECHO_C" 1>&6
 447 sleep 1
 448 echo $ECHO_N ".$ECHO_C" 1>&6
 449 sleep 1
 450 echo $ECHO_N ".$ECHO_C" 1>&6
 451 sleep 1
 452 AC_MSG_RESULT([ just kidding ;-)])
 453 echo
 454 echo "----------------------------------------------------------------"
 455 echo "Config is DONE!"
 456 echo
 457 echo "    With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 458 echo "    Perl Modules: $COMP_PERL"
 459 echo "     Perl Binary: $PERL"
 460 echo "    Perl Version: $PERL_VERSION"
 461 echo "    Perl Options: $PERL_MAKE_OPTIONS"
 462 echo "      Tcl Config: $tcl_config"
 463 echo "    Build rrdcgi: $enable_rrdcgi"
 464 echo " Build librrd MT: $enable_pthread"
 465 echo
 466 echo
 467 echo "Type 'make' to compile the software and use 'make install' to "
 468 echo "install everything to: $prefix."
 469 echo
 470 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 471 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 472 echo "place an order."
 473 echo
 474 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 475 echo "----------------------------------------------------------------"