configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.3])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4003
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=5:3:1
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 AC_ARG_ENABLE(libwrap,
 106   AS_HELP_STRING([--disable-libwrap],
 107   [do not build in support for libwrap (tcp wrapper)]),
 108   [have_libwrap=no],[
 109     XXX=$LIBS
 110     LIBS="$LIBS -lwrap"
 111     AC_MSG_CHECKING(for libwrap)
 112     AC_LINK_IFELSE(
 113       [AC_LANG_PROGRAM([[#include "tcpd.h"]], [[hosts_access(NULL)]])
 114     ],[AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 115        AC_MSG_RESULT([yes])
 116        have_libwrap=yes
 117     ],[LIBS=$XXX
 118        AC_MSG_RESULT([no])
 119        have_libwrap=no
 120     ]
 121   )
 122 ])
 123 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
 124
 125 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 126
 127 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
 128 [enable_rrdcgi=no],[enable_rrd_graph=yes])
 129
 130 if test $enable_rrd_graph != no; then
 131  AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
 132 fi
 133
 134 dnl Check if we run on a system that has fonts
 135 AC_ARG_WITH(rrd-default-font,
 136 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 137 [RRD_DEFAULT_FONT=$withval],[
 138   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 139         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 140   else
 141         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 142   fi
 143 ])
 144
 145 dnl Use mmap in rrd_update instead of seek+write
 146 AC_ARG_ENABLE([mmap],
 147 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 148 [],
 149 [enable_mmap=yes])
 150
 151 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 152 [],[enable_pthread=yes])
 153
 154 AC_ARG_ENABLE(static-programs,
 155      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 156      [case "${enableval}" in
 157        yes) staticprogs=yes ;;
 158        no)  staticprogs=no ;;
 159        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 160      esac],[staticprogs=no])
 161 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 162
 163
 164 CONFIGURE_PART(Audit Compilation Environment)
 165
 166
 167 dnl Check for the compiler and static/shared library creation.
 168 AC_PROG_CPP
 169 AC_PROG_CC
 170 AM_PROG_CC_C_O
 171 AC_PROG_LIBTOOL
 172
 173 dnl Try to detect/use GNU features
 174 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 175
 176 dnl check for -Werror separatly
 177 dnl (quite a few autotool checks do not work with -Werror; also, the
 178 dnl check for -Werror fails after checking and adding the other flags)
 179 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 180   [AC_COMPILE_IFELSE(
 181     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 182     [rd_cv_gcc_flag__Werror="yes"],
 183     [rd_cv_gcc_flag__Werror="no"])])
 184 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 185   WERROR="-Werror"
 186 else
 187   WERROR=""
 188 fi
 189 AC_SUBST(WERROR)
 190
 191 dnl which flags does the compiler support?
 192 if test "x$GCC" = "xyes"; then
 193   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 194     oCFLAGS="$CFLAGS"
 195     CFLAGS="$CFLAGS $flag"
 196     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 197     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 198        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 199     if eval test \$$cachename = no; then
 200          CFLAGS="$oCFLAGS"
 201     fi
 202   done
 203 fi
 204
 205
 206
 207 AC_SUBST(RRD_DEFAULT_FONT)
 208
 209 CONFIGURE_PART(Checking for Header Files)
 210
 211 dnl Checks for header files.
 212 AC_HEADER_STDC
 213 AC_HEADER_DIRENT
 214 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 215
 216 dnl Checks for typedefs, structures, and compiler characteristics.
 217 AC_C_CONST
 218 AC_HEADER_TIME
 219 AC_STRUCT_TM
 220
 221 CONFIGURE_PART(Test Library Functions)
 222
 223 dnl Checks for libraries.
 224 AC_CHECK_FUNC(acos,  , AC_CHECK_LIB(m, acos))
 225 AC_CHECK_FUNC(round, , AC_CHECK_LIB(m, round))
 226
 227
 228 dnl add pic flag in any case this makes sure all our code is relocatable
 229 eval `./libtool --config | grep pic_flag`
 230 CFLAGS="$CFLAGS $pic_flag"
 231
 232
 233 dnl Checks for library functions.
 234 AC_FUNC_STRFTIME
 235 AC_FUNC_VPRINTF
 236
 237 AC_C_BIGENDIAN
 238
 239 dnl for each function found we get a definition in config.h
 240 dnl of the form HAVE_FUNCTION
 241
 242 AC_CHECK_FUNCS(nl_langinfo tzset fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 243
 244 AC_FUNC_STRERROR_R
 245
 246 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 247
 248 dnl Could use these to know if we need to provide a prototype
 249 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 250
 251 dnl check for fdatasync. Solaris has fdatasync in the librt
 252
 253 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 254 dnl if there is no fdatasync we may get lucky with fsync
 255 AC_CHECK_FUNCS(fsync)
 256
 257 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 258
 259 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 260 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 261
 262
 263
 264 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 265 if test "x$enable_mmap" = "xyes"; then
 266   case "$host" in
 267   *cygwin*)
 268     # the normal mmap test does not work in cygwin
 269     AC_CHECK_FUNCS(mmap)
 270     if test "x$ac_cv_func_mmap" = "xyes"; then
 271       ac_cv_func_mmap_fixed_mapped=yes
 272     fi
 273   ;;
 274   *)
 275     AC_CHECK_HEADERS(sys/mman.h)
 276     AC_FUNC_MMAP
 277     AC_CHECK_FUNCS(mmap munmap msync)
 278     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 279                                      # include <sys/mman.h>
 280                                      #endif])
 281     if test "x$ac_cv_have_decl_madvise" = "xyes";
 282     then
 283       AC_CHECK_FUNCS(madvise)
 284     else
 285       AC_CHECK_FUNCS(posix_madvise)
 286       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 287         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 288       fi
 289     fi
 290   ;;
 291   esac
 292   if test "x$ac_cv_func_mmap" != "xyes";
 293   then
 294     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 295 dnl enable_mmap="no"
 296   fi
 297 fi
 298
 299 dnl can we use posix_fadvise
 300 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 301 #include <fcntl.h>])
 302 AC_CHECK_FUNCS(posix_fadvise)
 303
 304 CONFIGURE_PART(Libintl Processing)
 305
 306 AM_GNU_GETTEXT_VERSION(0.18)
 307 AM_GNU_GETTEXT(external)
 308
 309 CONFIGURE_PART(IEEE Math Checks)
 310
 311
 312 dnl actual code to check if this works
 313 AC_CHECK_FUNCS(fpclassify, ,
 314   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 315     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 316 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 317       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 318
 319 AC_CHECK_FUNCS(isinf, ,
 320   [AC_MSG_CHECKING(for isinf with <math.h>)
 321     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 322 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 323       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 324
 325 dnl finite is BSD, isfinite is C99, so prefer the latter
 326 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 327 AC_TRY_RUN([
 328 #ifdef HAVE_MATH_H
 329 #include <math.h>
 330 #endif
 331 #ifdef HAVE_FLOAT_H
 332 #include <float.h>
 333 #endif
 334 int main ()
 335 {
 336 #ifdef isfinite
 337 #ifdef LDBL_MAX
 338   if (!isfinite(LDBL_MAX)) return 1;
 339 #endif
 340 #ifdef DBL_MAX
 341   if (!isfinite(DBL_MAX)) return 1;
 342 #endif
 343 #endif
 344 return 0;
 345 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 346 case "${target}" in
 347   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 348   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 349   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 350   *) ac_cv_have_broken_isfinite=no ;;
 351 esac])
 352 ])
 353
 354 dnl the test does not seem to work on solaris 2.8
 355 dnl so lets fix this by hand
 356 case "${target}" in
 357   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 358   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 359 esac
 360
 361 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 362   AC_DEFINE(HAVE_ISFINITE)
 363 else
 364   AC_CHECK_FUNCS(finite,[],
 365       [AC_CHECK_FUNCS(isfinite,[],
 366          [AC_MSG_CHECKING(for isfinite with <math.h>)
 367           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 368 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 369                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 370 fi
 371
 372 AC_FULL_IEEE
 373
 374 CONFIGURE_PART(Resolve Portability Issues)
 375
 376 CHECK_FOR_WORKING_MS_ASYNC
 377
 378 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
 379 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
 380   [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
 381     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
 382       AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
 383
 384 dnl Do we need getopt_long
 385
 386 dnl even when including our own getopt implementation
 387 dnl we may want to make sure we use the external
 388 dnl defined by libc to not run into linker resolve trouble
 389
 390 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 391 [AC_TRY_LINK([#include <unistd.h>],
 392   [extern int opterr; opterr = 1;],
 393   [rd_cv_var_int_opterr=yes],
 394   [rd_cv_var_int_opterr=no])])
 395 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 396   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 397 fi
 398
 399 build_getopt=no
 400 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 401 AC_CHECK_FUNC(getopt_long,[],[
 402 RRD_GETOPT_LONG="getopt_long"
 403 build_getopt=yes
 404 ])
 405 AC_SUBST(RRD_GETOPT_LONG)
 406 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 407
 408 dnl what does realloc do if it gets called with a NULL pointer
 409
 410 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 411 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 412               int main(void){
 413               char *x = NULL;
 414               x = realloc (x,10);
 415               if (x==NULL) return 1;
 416               return 0;
 417              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 418
 419 if test x"$rd_cv_null_realloc" = xnope; then
 420 AC_DEFINE(NO_NULL_REALLOC)
 421 fi
 422
 423 AC_LANG_PUSH(C)
 424 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 425 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 426 AC_LINK_IFELSE(
 427     AC_LANG_PROGRAM(
 428            [[#include <time.h>]],
 429            [[ctime_r(NULL,NULL,0)]]
 430                    ),
 431     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 432       AC_LINK_IFELSE(
 433           AC_LANG_PROGRAM(
 434                 [[#include <time.h>]],
 435                 [[ctime_r(NULL,NULL)]]
 436                          ),
 437           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 438           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 439       )
 440     ],
 441     [ AC_LINK_IFELSE(
 442           AC_LANG_PROGRAM(
 443                 [[#include <time.h>]],
 444                 [[ctime_r(NULL,NULL)]]
 445                          ),
 446           [AC_MSG_RESULT(no)],
 447           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 448       )
 449     ]
 450 )
 451 AC_LANG_POP(C)
 452
 453 dnl Check for pthreads
 454 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 455
 456 AC_SUBST(MULTITHREAD_CFLAGS)
 457 AC_SUBST(MULTITHREAD_LDFLAGS)
 458
 459 if test $enable_pthread != no; then
 460  ACX_PTHREAD([
 461     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 462     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 463              ],
 464              [])
 465 fi
 466
 467 dnl since we use lots of *_r functions all over the code we better
 468 dnl make sure they are known
 469
 470 if test  "x$x_rflag" != "xno"; then
 471    CPPFLAGS="$CPPFLAGS $x_rflag"
 472 fi
 473
 474 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 475
 476 AC_LANG_PUSH(C)
 477 dnl see if we have to include malloc/malloc.h
 478 AC_MSG_CHECKING([do we need malloc/malloc.h])
 479 AC_LINK_IFELSE(
 480     AC_LANG_PROGRAM(
 481            [[#include <stdlib.h>]],
 482            [[malloc(1)]]
 483                    ),
 484     [ AC_MSG_RESULT([nope, works out of the box]) ],
 485     [ AC_LINK_IFELSE(
 486           AC_LANG_PROGRAM(
 487                 [[#include <stdlib.h>
 488                   #include <malloc/malloc.h>]],
 489                 [[malloc(1)]]
 490                          ),[
 491            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 492            AC_MSG_RESULT([yes we do])],
 493           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 494       )
 495     ]
 496 )
 497
 498 dnl is time_t 32 of 64 bit ?
 499 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
 500 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
 501 AC_MSG_CHECKING([the type of time_t])
 502 AC_RUN_IFELSE(
 503     AC_LANG_PROGRAM(
 504         [[#include <time.h>]],
 505         [[if (sizeof(time_t) != 4) return 1; ]]
 506         ),
 507     [ AC_MSG_RESULT([time_t is 32 bit])
 508       AC_DEFINE([TIME_T_IS_32BIT])
 509     ],
 510     [ AC_RUN_IFELSE(
 511         AC_LANG_PROGRAM(
 512         [[#include <time.h>]],
 513         [[if (sizeof(time_t) != 8) return 1; ]]
 514         ),
 515         [
 516           AC_MSG_RESULT([time_t is 64 bit])
 517           AC_DEFINE([TIME_T_IS_64BIT])
 518         ],
 519         [AC_MSG_ERROR([can not figure type of time_t])]
 520       )
 521     ]
 522 )
 523
 524 AC_LANG_POP(C)
 525
 526 CONFIGURE_PART(Find 3rd-Party Libraries)
 527
 528 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
 529   XXX=$LIBS
 530   LIBS="$LIBS -ldbi -ldl"
 531   AC_MSG_CHECKING(for libdbi)
 532   AC_LINK_IFELSE(
 533     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 534                      [[dbi_initialize(NULL)]]
 535                     )
 536     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 537        AC_MSG_RESULT([yes])
 538        have_libdbi=yes
 539     ],[LIBS=$XXX
 540        AC_MSG_RESULT([no])
 541        have_libdbi=no
 542     ]
 543   )
 544 ])
 545 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 546
 547
 548 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
 549
 550
 551 CORE_LIBS="$LIBS"
 552
 553 if test $enable_rrd_graph != no; then
 554 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 555 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 556 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 557 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 558 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 559 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 560 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 561 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 562 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 563 EX_CHECK_ALL(pangocairo-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 564
 565 fi
 566
 567 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 568
 569 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 570   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 571 fi
 572
 573 ALL_LIBS="$LIBS"
 574 LIBS=
 575
 576 AC_SUBST(CORE_LIBS)
 577 AC_SUBST(ALL_LIBS)
 578
 579 CONFIGURE_PART(Prep for Building Language Bindings)
 580
 581 dnl Check for Perl and friends
 582 PATH=$PATH:/usr/perl5/bin
 583 export PATH
 584 AC_PATH_PROG(PERL, perl, no)
 585 AC_PATH_PROG(POD2MAN, pod2man, no)
 586 AC_PATH_PROG(POD2HTML, pod2html, no)
 587
 588
 589 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 590 [],[enable_perl=yes])
 591
 592
 593 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 594 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 595 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 596 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 597
 598 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 599         COMP_PERL=
 600 else
 601         COMP_PERL="perl_piped perl_shared"
 602         AC_MSG_CHECKING(for the perl version you are running)
 603         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 604         AC_MSG_RESULT($PERL_VERSION)
 605         if test -z "$PERLCC"; then
 606             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 607             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 608             AC_MSG_RESULT($perlcc)
 609             if test ! -x "$perlcc"; then
 610                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 611                 if test "$PERL_CC" = "no"; then
 612                     AC_MSG_WARN([
 613 I would not find the Compiler ($perlcc) that was originally used to compile
 614 your perl binary. You should either make sure that this compiler is
 615 available on your system, pick an other compiler and set PERLCC
 616 appropriately, or use a different perl setup that was compiled locally.
 617
 618 I will disable the compilation of the RRDs perl module for now.
 619 ])
 620                     COMP_PERL="perl_piped"
 621                 fi
 622             fi
 623         fi
 624 fi
 625
 626 AC_MSG_CHECKING(Perl Modules to build)
 627 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 628
 629 # Options to pass when configuring perl module
 630 langpref=$prefix
 631 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 632 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 633
 634 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 635
 636 dnl pass additional perl options when generating Makefile from Makefile.PL
 637 AC_ARG_ENABLE(perl-site-install,
 638 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 639 [PERL_MAKE_OPTIONS=],[])
 640
 641 if test ! -z "$PERLCC"; then
 642    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 643
 644    if test ! -z "$PERLCCFLAGS"; then
 645        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 646    fi
 647
 648    if test -z "$PERLLD"; then
 649        PERLLD=$PERLCC
 650    fi
 651    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 652
 653    if test ! -z "$PERLLDFLAGS"; then
 654        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 655    fi
 656 fi
 657
 658 AC_ARG_WITH(perl-options,
 659 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 660                           generating Makefile from Makefile.PL. If you set this
 661                           option, interesting things may happen unless you know
 662                           what you are doing!],
 663 [PERL_MAKE_OPTIONS=$withval])
 664
 665 AC_SUBST(PERL_MAKE_OPTIONS)
 666 AC_SUBST(PERL)
 667 AC_SUBST(COMP_PERL)
 668 AC_SUBST(PERL_VERSION)
 669
 670 dnl Check for Ruby.
 671 AC_PATH_PROG(RUBY, ruby, no)
 672
 673 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 674 [],[enable_ruby=yes])
 675
 676 AC_MSG_CHECKING(if ruby modules can be built)
 677
 678 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 679         COMP_RUBY=
 680         AC_MSG_RESULT(No .. Ruby not found or disabled)
 681 else
 682         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 683                 COMP_RUBY="ruby"
 684                 AC_MSG_RESULT(YES)
 685         else
 686                 COMP_RUBY=
 687                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 688         fi
 689 fi
 690
 691 dnl pass additional ruby options when generating Makefile from Makefile.PL
 692 AC_ARG_ENABLE(ruby-site-install,
 693 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 694 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 695
 696
 697 AC_ARG_WITH(ruby-options,
 698 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 699                           generating Makefile from extconf.rb. If you set this
 700                           option, interesting things may happen unless you know
 701                           what you are doing!],
 702 [RUBY_MAKE_OPTIONS=$withval])
 703
 704 AC_SUBST(RUBY_MAKE_OPTIONS)
 705 AC_SUBST(RUBY)
 706 AC_SUBST(COMP_RUBY)
 707
 708 dnl Check for Lua.
 709 AC_PATH_PROG(LUA, lua, no)
 710
 711 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 712 [],[enable_lua=yes])
 713
 714 COMP_LUA=
 715 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 716   enable_lua=no
 717 else
 718   AC_MSG_CHECKING(for lua >= 5.0)
 719   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 720     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 721 LUA_EOF
 722   if test 0$LUA_MAJOR -lt 5; then
 723     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 724   else
 725     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 726     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 727     lua_vndot=$LUA_MAJOR$LUA_MINOR
 728     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 729     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 730       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 731         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 732           [lua_headerdir=lua$lua_vndot],
 733           [])],
 734         [])],
 735       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 736         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 737           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 738             [lua_headerdir=lua$lua_vdot],
 739             [])],
 740           [])],
 741         [AC_CHECK_HEADERS(lua.h,
 742           [AC_CHECK_HEADERS(lualib.h,
 743             [AC_CHECK_HEADER(lauxlib.h,
 744               [lua_headerdir=""],
 745               [lua_headerdir="no"])],
 746             [])],
 747           [])])])
 748
 749     if test "$lua_headerdir" = "no"; then
 750       enable_lua=no
 751     else
 752       COMP_LUA=lua
 753     fi
 754
 755     if test "$COMP_LUA" != "lua"; then
 756       enable_lua=no
 757       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 758     else
 759       # OK, headers found, let's check the libraries (LIBS is not used)
 760       LIBS=
 761       lua_havelib=no
 762       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 763       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 764         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 765           [lua_havelib=LUA$lua_vndot],
 766           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 767             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 768              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 769             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 770               [lua_havelib=$lua_vndot],
 771               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 772         [COMP_LUA=], [-lm])
 773       lua_libs=$LIBS
 774       LIBS=
 775
 776       # Options to pass when configuring Lua module
 777       if test  "$lua_havelib" != "no"; then
 778         # OK, headers and libs found. Try to set lua flags
 779         # and modules installation dirs with pkg-config
 780         if test "$PKGCONFIG" != "no"; then
 781           if test "$lua_vndot" = "50"; then
 782             lua_pkg_prefix=lualib
 783           else
 784             lua_pkg_prefix=lua
 785           fi
 786           # try with dot, without dot and finally without version
 787           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 788             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 789             # same binaries?
 790             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 791                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 792                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 793                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 794                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 795                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 796                 break
 797             fi
 798           done
 799         fi
 800
 801         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 802         # if lua 5.0 can't find compat-5.1, force installation of
 803         # compat-5.1.lua together with RRDtool.
 804         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 805           lua_need_compat51=1
 806           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 807         fi
 808
 809         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 810         if test "$LUA_CFLAGS" = ""; then
 811           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 812           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 813           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 814           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 815         fi
 816
 817         dnl pass additional lua options
 818         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 819         dnl found and install together with RRDtool, under $langpref.
 820         AC_ARG_ENABLE(lua-site-install,
 821         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 822         [],
 823         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 824
 825         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 826         AC_SUBST(LUA)
 827         AC_SUBST(COMP_LUA)
 828         AC_SUBST(LUA_INSTALL_CMOD)
 829         AC_SUBST(LUA_INSTALL_LMOD)
 830         AC_SUBST(LUA_CFLAGS)
 831         AC_SUBST(LUA_LFLAGS)
 832         AC_SUBST(LUA_DEFINES)
 833       else
 834         enable_lua=no
 835         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 836       fi
 837     fi
 838   fi
 839 fi
 840 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 841 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 842 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 843       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 844 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 845 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 846 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 847 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 848
 849 enable_tcl_site=no
 850
 851 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 852 [],[enable_tcl=yes])
 853
 854 if test  "$enable_tcl" = "yes"; then
 855   dnl Check for Tcl.
 856   withval=""
 857   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 858   enable_tcl=no
 859   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 860     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 861     if test -f "$dir/tclConfig.sh" ; then
 862         tcl_config=$dir/tclConfig.sh
 863         enable_tcl=yes
 864         AC_MSG_RESULT(yes)
 865         break
 866     else
 867         AC_MSG_RESULT(no)
 868     fi
 869   done
 870
 871   if test "$enable_tcl" = "no"; then
 872         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 873   else
 874         . $tcl_config
 875         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 876         if test -n "$TCL_INC_DIR"; then
 877           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 878         fi
 879   fi
 880   AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 881   [],[enable_tcl_site=yes])
 882
 883 fi
 884
 885 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 886 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 887
 888
 889 AC_SUBST(TCL_PREFIX)
 890 AC_SUBST(TCL_SHLIB_CFLAGS)
 891 AC_SUBST(TCL_SHLIB_LD)
 892 AC_SUBST(TCL_SHLIB_SUFFIX)
 893 AC_SUBST(TCL_PACKAGE_PATH)
 894 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 895 AC_SUBST(TCL_STUB_LIB_SPEC)
 896 AC_SUBST(TCL_VERSION)
 897 AC_SUBST(TCL_PACKAGE_DIR)
 898 AC_SUBST(TCL_INCLUDE_SPEC)
 899
 900 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 901 [],[enable_python=yes])
 902
 903 if test  "$enable_python" = "yes"; then
 904 dnl Check for python
 905 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 906 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 907 fi
 908
 909 if test  x$enable_python = xno; then
 910         COMP_PYTHON=
 911 else
 912         COMP_PYTHON="python"
 913 fi
 914
 915 AC_SUBST(COMP_PYTHON)
 916
 917 dnl Check for nroff
 918 AC_PATH_PROGS(NROFF, gnroff nroff)
 919 AC_PATH_PROGS(TROFF, groff troff)
 920
 921 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 922 if test -z "$RRDDOCDIR"; then
 923    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 924
 925
 926 CONFIGURE_PART(Apply Configuration Information)
 927
 928 AC_CONFIG_FILES([examples/shared-demo.pl])
 929 AC_CONFIG_FILES([examples/piped-demo.pl])
 930 AC_CONFIG_FILES([examples/stripes.pl])
 931 AC_CONFIG_FILES([examples/bigtops.pl])
 932 AC_CONFIG_FILES([examples/minmax.pl])
 933 AC_CONFIG_FILES([examples/4charts.pl])
 934 AC_CONFIG_FILES([examples/perftest.pl])
 935 AC_CONFIG_FILES([examples/Makefile])
 936 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 937 AC_CONFIG_FILES([doc/Makefile])
 938 AC_CONFIG_FILES([po/Makefile.in])
 939 AC_CONFIG_FILES([src/Makefile])
 940 AC_CONFIG_FILES([src/librrd.sym.in])
 941 AC_CONFIG_FILES([src/librrd.pc])
 942 AC_CONFIG_FILES([bindings/Makefile])
 943 AC_CONFIG_FILES([bindings/tcl/Makefile])
 944 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 945 AC_CONFIG_FILES([Makefile])
 946 AC_CONFIG_FILES([bindings/lua/Makefile])
 947
 948 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 949
 950 dnl intl requires our config to be called config.h. indulge it.
 951 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 952
 953 AC_OUTPUT
 954
 955 AC_MSG_CHECKING(in)
 956 AC_MSG_RESULT(and out again)
 957
 958 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 959 sleep 1
 960 echo $ECHO_N ".$ECHO_C" 1>&6
 961 sleep 1
 962 echo $ECHO_N ".$ECHO_C" 1>&6
 963 sleep 1
 964 echo $ECHO_N ".$ECHO_C" 1>&6
 965 sleep 1
 966 echo $ECHO_N ".$ECHO_C" 1>&6
 967 sleep 1
 968 AC_MSG_RESULT([ just kidding ;-)])
 969 echo
 970 echo "----------------------------------------------------------------"
 971 echo "Config is DONE!"
 972 echo
 973 echo "          With MMAP IO: $enable_mmap"
 974 echo "      Build rrd_getopt: $build_getopt"
 975 echo "       Build rrd_graph: $enable_rrd_graph"
 976 echo "       Static programs: $staticprogs"
 977 echo "          Perl Modules: $COMP_PERL"
 978 echo "           Perl Binary: $PERL"
 979 echo "          Perl Version: $PERL_VERSION"
 980 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 981 echo "          Ruby Modules: $COMP_RUBY"
 982 echo "           Ruby Binary: $RUBY"
 983 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 984 echo "    Build Lua Bindings: $enable_lua"
 985 if test "$enable_lua" = "yes"; then
 986 echo "            Lua Binary: $LUA"
 987 echo "           Lua Version: $lua_version"
 988 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 989 if test "$lua_need_compat51" = "1"; then
 990 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 991 fi
 992 fi
 993 echo "    Build Tcl Bindings: $enable_tcl"
 994 echo " Build Python Bindings: $enable_python"
 995 echo "          Build rrdcgi: $enable_rrdcgi"
 996 echo "       Build librrd MT: $enable_pthread"
 997 echo "           Use gettext: $USE_NLS"
 998 echo "           With libDBI: $have_libdbi"
 999 echo "          With libwrap: $have_libwrap"
1000 echo
1001 echo "             Libraries: $ALL_LIBS"
1002 echo
1003 echo "Type 'make' to compile the software and use 'make install' to "
1004 echo "install everything to: $prefix."
1005 echo
1006 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
1007 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
1008 echo "place an order."
1009 echo
1010 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
1011 echo "----------------------------------------------------------------"