configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.999])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4999
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=6:255:2
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 106
 107 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
 108 [enable_rrdcgi=no],[enable_rrd_graph=yes])
 109
 110 if test $enable_rrd_graph != no; then
 111  AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
 112 fi
 113
 114 dnl Check if we run on a system that has fonts
 115 AC_ARG_WITH(rrd-default-font,
 116 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 117 [RRD_DEFAULT_FONT=$withval],[
 118   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 119         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 120   else
 121         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 122   fi
 123 ])
 124
 125 dnl Use mmap in rrd_update instead of seek+write
 126 AC_ARG_ENABLE([mmap],
 127 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 128 [],
 129 [enable_mmap=yes])
 130
 131 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 132 [],[enable_pthread=yes])
 133
 134 AC_ARG_ENABLE(static-programs,
 135      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 136      [case "${enableval}" in
 137        yes) staticprogs=yes ;;
 138        no)  staticprogs=no ;;
 139        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 140      esac],[staticprogs=no])
 141 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 142
 143
 144 CONFIGURE_PART(Audit Compilation Environment)
 145
 146
 147 dnl Check for the compiler and static/shared library creation.
 148 AC_PROG_CPP
 149 AC_PROG_CC
 150 AM_PROG_CC_C_O
 151 AC_PROG_LIBTOOL
 152
 153 dnl Try to detect/use GNU features
 154 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 155
 156 dnl check for -Werror separatly
 157 dnl (quite a few autotool checks do not work with -Werror; also, the
 158 dnl check for -Werror fails after checking and adding the other flags)
 159 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 160   [AC_COMPILE_IFELSE(
 161     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 162     [rd_cv_gcc_flag__Werror="yes"],
 163     [rd_cv_gcc_flag__Werror="no"])])
 164 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 165   WERROR="-Werror"
 166 else
 167   WERROR=""
 168 fi
 169 AC_SUBST(WERROR)
 170
 171 dnl which flags does the compiler support?
 172 if test "x$GCC" = "xyes"; then
 173   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 174     oCFLAGS="$CFLAGS"
 175     CFLAGS="$CFLAGS $flag"
 176     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 177     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 178        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 179     if eval test \$$cachename = no; then
 180          CFLAGS="$oCFLAGS"
 181     fi
 182   done
 183 fi
 184
 185
 186
 187 AC_SUBST(RRD_DEFAULT_FONT)
 188
 189 CONFIGURE_PART(Checking for Header Files)
 190
 191 dnl Checks for header files.
 192 AC_HEADER_STDC
 193 AC_HEADER_DIRENT
 194 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 195
 196 dnl Checks for typedefs, structures, and compiler characteristics.
 197 AC_C_CONST
 198 AC_HEADER_TIME
 199 AC_STRUCT_TM
 200
 201 CONFIGURE_PART(Test Library Functions)
 202
 203 dnl Checks for libraries.
 204 AC_CHECK_FUNC(acos,  , AC_CHECK_LIB(m, acos))
 205 AC_CHECK_FUNC(round, , AC_CHECK_LIB(m, round))
 206
 207
 208 dnl add pic flag in any case this makes sure all our code is relocatable
 209 eval `./libtool --config | grep pic_flag=`
 210 CFLAGS="$CFLAGS $pic_flag"
 211
 212
 213 dnl Checks for library functions.
 214 AC_FUNC_STRFTIME
 215 AC_FUNC_VPRINTF
 216
 217 AC_C_BIGENDIAN
 218
 219 dnl for each function found we get a definition in config.h
 220 dnl of the form HAVE_FUNCTION
 221
 222 AC_CHECK_FUNCS(nl_langinfo tzset fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 223
 224 AC_FUNC_STRERROR_R
 225
 226 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 227
 228 dnl Could use these to know if we need to provide a prototype
 229 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 230
 231 dnl check for fdatasync. Solaris has fdatasync in the librt
 232
 233 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 234 dnl if there is no fdatasync we may get lucky with fsync
 235 AC_CHECK_FUNCS(fsync)
 236
 237 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 238
 239 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 240 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 241
 242
 243
 244 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 245 if test "x$enable_mmap" = "xyes"; then
 246   case "$host" in
 247   *cygwin*)
 248     # the normal mmap test does not work in cygwin
 249     AC_CHECK_FUNCS(mmap)
 250     if test "x$ac_cv_func_mmap" = "xyes"; then
 251       ac_cv_func_mmap_fixed_mapped=yes
 252     fi
 253   ;;
 254   *)
 255     AC_CHECK_HEADERS(sys/mman.h)
 256     AC_FUNC_MMAP
 257     AC_CHECK_FUNCS(mmap munmap msync)
 258     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 259                                      # include <sys/mman.h>
 260                                      #endif])
 261     if test "x$ac_cv_have_decl_madvise" = "xyes";
 262     then
 263       AC_CHECK_FUNCS(madvise)
 264     else
 265       AC_CHECK_FUNCS(posix_madvise)
 266       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 267         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 268       fi
 269     fi
 270   ;;
 271   esac
 272   if test "x$ac_cv_func_mmap" != "xyes";
 273   then
 274     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 275 dnl enable_mmap="no"
 276   fi
 277 fi
 278
 279 dnl can we use posix_fadvise
 280 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 281 #include <fcntl.h>])
 282 AC_CHECK_FUNCS(posix_fadvise)
 283
 284 dnl can we use posix_fallocate
 285 AC_CHECK_FUNCS(posix_fallocate)
 286
 287 CONFIGURE_PART(Libintl Processing)
 288
 289 AM_GNU_GETTEXT_VERSION(0.17)
 290 AM_GNU_GETTEXT(external)
 291
 292 CONFIGURE_PART(IEEE Math Checks)
 293
 294
 295 dnl actual code to check if this works
 296 AC_CHECK_FUNCS(fpclassify, ,
 297   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 299 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 300       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 301
 302 AC_CHECK_FUNCS(isinf, ,
 303   [AC_MSG_CHECKING(for isinf with <math.h>)
 304     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 305 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 306       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 307
 308 dnl finite is BSD, isfinite is C99, so prefer the latter
 309 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 310 AC_TRY_RUN([
 311 #ifdef HAVE_MATH_H
 312 #include <math.h>
 313 #endif
 314 #ifdef HAVE_FLOAT_H
 315 #include <float.h>
 316 #endif
 317 int main ()
 318 {
 319 #ifdef isfinite
 320 #ifdef LDBL_MAX
 321   if (!isfinite(LDBL_MAX)) return 1;
 322 #endif
 323 #ifdef DBL_MAX
 324   if (!isfinite(DBL_MAX)) return 1;
 325 #endif
 326 #endif
 327 return 0;
 328 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 329 case "${target}" in
 330   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 331   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 332   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 333   *) ac_cv_have_broken_isfinite=no ;;
 334 esac])
 335 ])
 336
 337 dnl the test does not seem to work on solaris 2.8
 338 dnl so lets fix this by hand
 339 case "${target}" in
 340   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 341   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 342 esac
 343
 344 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 345   AC_DEFINE(HAVE_ISFINITE)
 346 else
 347   AC_CHECK_FUNCS(finite,[],
 348       [AC_CHECK_FUNCS(isfinite,[],
 349          [AC_MSG_CHECKING(for isfinite with <math.h>)
 350           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 351 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 352                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 353 fi
 354
 355 AC_FULL_IEEE
 356
 357 CONFIGURE_PART(Resolve Portability Issues)
 358
 359 GC_TIMEZONE()
 360
 361 CHECK_FOR_WORKING_MS_ASYNC
 362
 363 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
 364 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
 365   [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
 366     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
 367       AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
 368
 369 dnl Do we need getopt_long
 370
 371 dnl even when including our own getopt implementation
 372 dnl we may want to make sure we use the external
 373 dnl defined by libc to not run into linker resolve trouble
 374
 375 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 376 [AC_TRY_LINK([#include <unistd.h>],
 377   [extern int opterr; opterr = 1;],
 378   [rd_cv_var_int_opterr=yes],
 379   [rd_cv_var_int_opterr=no])])
 380 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 381   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 382 fi
 383
 384 build_getopt=no
 385 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 386 AC_CHECK_FUNC(getopt_long,[],[
 387 RRD_GETOPT_LONG="getopt_long"
 388 build_getopt=yes
 389 ])
 390 AC_SUBST(RRD_GETOPT_LONG)
 391 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 392
 393 dnl what does realloc do if it gets called with a NULL pointer
 394
 395 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 396 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 397               int main(void){
 398               char *x = NULL;
 399               x = realloc (x,10);
 400               if (x==NULL) return 1;
 401               return 0;
 402              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 403
 404 if test x"$rd_cv_null_realloc" = xnope; then
 405 AC_DEFINE(NO_NULL_REALLOC)
 406 fi
 407
 408 AC_LANG_PUSH(C)
 409 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 410 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 411 AC_LINK_IFELSE(
 412     AC_LANG_PROGRAM(
 413            [[#include <time.h>]],
 414            [[ctime_r(NULL,NULL,0)]]
 415                    ),
 416     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 417       AC_LINK_IFELSE(
 418           AC_LANG_PROGRAM(
 419                 [[#include <time.h>]],
 420                 [[ctime_r(NULL,NULL)]]
 421                          ),
 422           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 423           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 424       )
 425     ],
 426     [ AC_LINK_IFELSE(
 427           AC_LANG_PROGRAM(
 428                 [[#include <time.h>]],
 429                 [[ctime_r(NULL,NULL)]]
 430                          ),
 431           [AC_MSG_RESULT(no)],
 432           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 433       )
 434     ]
 435 )
 436 AC_LANG_POP(C)
 437
 438 dnl Check for pthreads
 439 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 440
 441 AC_SUBST(MULTITHREAD_CFLAGS)
 442 AC_SUBST(MULTITHREAD_LDFLAGS)
 443
 444 if test $enable_pthread != no; then
 445  ACX_PTHREAD([
 446     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 447     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 448              ],
 449              [])
 450 fi
 451
 452 dnl since we use lots of *_r functions all over the code we better
 453 dnl make sure they are known
 454
 455 if test  "x$x_rflag" != "xno"; then
 456    CPPFLAGS="$CPPFLAGS $x_rflag"
 457 fi
 458
 459 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 460
 461 AC_LANG_PUSH(C)
 462 dnl see if we have to include malloc/malloc.h
 463 AC_MSG_CHECKING([do we need malloc/malloc.h])
 464 AC_LINK_IFELSE(
 465     AC_LANG_PROGRAM(
 466            [[#include <stdlib.h>]],
 467            [[malloc(1)]]
 468                    ),
 469     [ AC_MSG_RESULT([nope, works out of the box]) ],
 470     [ AC_LINK_IFELSE(
 471           AC_LANG_PROGRAM(
 472                 [[#include <stdlib.h>
 473                   #include <malloc/malloc.h>]],
 474                 [[malloc(1)]]
 475                          ),[
 476            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 477            AC_MSG_RESULT([yes we do])],
 478           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 479       )
 480     ]
 481 )
 482
 483 dnl is time_t 32 of 64 bit ?
 484 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
 485 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
 486 AC_MSG_CHECKING([the type of time_t])
 487 AC_CHECK_SIZEOF([time_t])
 488 if test "x$ac_cv_sizeof_time_t" = "x4"; then
 489   AC_MSG_RESULT([time_t is 32 bit])
 490   AC_DEFINE([TIME_T_IS_32BIT])
 491 elif test "x$ac_cv_sizeof_time_t" = "x8"; then
 492   AC_MSG_RESULT([time_t is 64 bit])
 493   AC_DEFINE([TIME_T_IS_64BIT])
 494 else
 495   AC_MSG_ERROR([can not figure type of time_t])
 496 fi
 497
 498 AC_LANG_POP(C)
 499
 500 CONFIGURE_PART(Find 3rd-Party Libraries)
 501
 502 have_libdbi=no
 503
 504 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[],[
 505     AC_CHECK_HEADER(dbi/dbi.h, [
 506        AC_CHECK_LIB(dbi, dbi_initialize, [
 507            AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 508            LIBS="${LIBS} -ldbi -ldl"
 509            have_libdbi=yes
 510        ])
 511     ])
 512 ])
 513
 514 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 515
 516 have_libwrap=no
 517
 518 AC_ARG_ENABLE(libwrap, AS_HELP_STRING([--disable-libwrap], [do not build in support for libwrap (tcp wrapper)]),[],[
 519     AC_CHECK_HEADER(tcpd.h,[
 520         AC_CHECK_FUNCS(hosts_access, [
 521             AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 522             have_libwrap=yes
 523         ],
 524         [
 525             AC_CHECK_LIB(wrap, hosts_access, [
 526                AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 527                LIBS="${LIBS} -lwrap"
 528                have_libwrap=yes
 529             ])
 530         ])
 531     ])
 532 ])
 533
 534
 535 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
 536
 537 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
 538
 539
 540 CORE_LIBS="$LIBS"
 541
 542 if test $enable_rrd_graph != no; then
 543 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.5,  http://zlib.net/, "")
 544 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.4.8,  ftp://ftp.simplesystems.org/pub/libpng/png/src/, "")
 545 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.4.6,  http://download.savannah.gnu.org/releases/freetype/, /usr/include/freetype2)
 546 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.8.0,  http://www.freedesktop.org/software/fontconfig/release/, /usr/include)
 547 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.10.2,  http://cairographics.org/releases/, "")
 548 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.10.2,  http://cairographics.org/releases/, "")
 549 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.10.2,  http://cairographics.org/releases/, "")
 550 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.10.2,  http://cairographics.org/releases/, "")
 551 EX_CHECK_ALL(pangocairo-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.28.4,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.28, "")
 552
 553 fi
 554 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.28.7, ftp://ftp.gtk.org/pub/glib/2.28/, "")
 555 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.7.8,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 556
 557 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 558   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 559 fi
 560
 561 ALL_LIBS="$LIBS"
 562 LIBS=
 563
 564 AC_SUBST(CORE_LIBS)
 565 AC_SUBST(ALL_LIBS)
 566
 567 CONFIGURE_PART(Prep for Building Language Bindings)
 568
 569 dnl Check for Perl and friends
 570 PATH=$PATH:/usr/perl5/bin
 571 export PATH
 572 AC_PATH_PROG(PERL, perl, no)
 573 AC_PATH_PROG(POD2MAN, pod2man, no)
 574 AC_PATH_PROG(POD2HTML, pod2html, no)
 575
 576
 577 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 578 [],[enable_perl=yes])
 579
 580
 581 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 582 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 583 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 584 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 585
 586 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 587         COMP_PERL=
 588 else
 589         COMP_PERL="perl_piped perl_shared"
 590         AC_MSG_CHECKING(for the perl version you are running)
 591         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 592         AC_MSG_RESULT($PERL_VERSION)
 593         if test -z "$PERLCC"; then
 594             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 595             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 596             AC_MSG_RESULT($perlcc)
 597             if test ! -x "$perlcc"; then
 598                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 599                 if test "$PERL_CC" = "no"; then
 600                     AC_MSG_WARN([
 601 I would not find the Compiler ($perlcc) that was originally used to compile
 602 your perl binary. You should either make sure that this compiler is
 603 available on your system, pick an other compiler and set PERLCC
 604 appropriately, or use a different perl setup that was compiled locally.
 605
 606 I will disable the compilation of the RRDs perl module for now.
 607 ])
 608                     COMP_PERL="perl_piped"
 609                 fi
 610             fi
 611         fi
 612 fi
 613
 614 AC_MSG_CHECKING(Perl Modules to build)
 615 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 616
 617 # Options to pass when configuring perl module
 618 langpref=$prefix
 619 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 620 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 621
 622 PERL_MAKE_OPTIONS="PREFIX=$langpref INSTALL_BASE= LIB=$langpref/lib/perl/$PERL_VERSION"
 623
 624 dnl pass additional perl options when generating Makefile from Makefile.PL
 625 AC_ARG_ENABLE(perl-site-install,
 626 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 627 [PERL_MAKE_OPTIONS=],[])
 628
 629 if test ! -z "$PERLCC"; then
 630    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 631
 632    if test ! -z "$PERLCCFLAGS"; then
 633        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 634    fi
 635
 636    if test -z "$PERLLD"; then
 637        PERLLD=$PERLCC
 638    fi
 639    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 640
 641    if test ! -z "$PERLLDFLAGS"; then
 642        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 643    fi
 644 fi
 645
 646 AC_ARG_WITH(perl-options,
 647 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 648                           generating Makefile from Makefile.PL. If you set this
 649                           option, interesting things may happen unless you know
 650                           what you are doing!],
 651 [PERL_MAKE_OPTIONS=$withval])
 652
 653 AC_SUBST(PERL_MAKE_OPTIONS)
 654 AC_SUBST(PERL)
 655 AC_SUBST(COMP_PERL)
 656 AC_SUBST(PERL_VERSION)
 657
 658 dnl Check for Ruby.
 659 AC_PATH_PROG(RUBY, ruby, no)
 660
 661 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 662 [],[enable_ruby=yes])
 663
 664 AC_MSG_CHECKING(if ruby modules can be built)
 665
 666 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 667         COMP_RUBY=
 668         AC_MSG_RESULT(No .. Ruby not found or disabled)
 669 else
 670         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 671                 COMP_RUBY="ruby"
 672                 AC_MSG_RESULT(YES)
 673         else
 674                 COMP_RUBY=
 675                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 676         fi
 677 fi
 678
 679 dnl pass additional ruby options when generating Makefile from Makefile.PL
 680 AC_ARG_ENABLE(ruby-site-install,
 681 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 682 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 683
 684
 685 AC_ARG_WITH(ruby-options,
 686 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 687                           generating Makefile from extconf.rb. If you set this
 688                           option, interesting things may happen unless you know
 689                           what you are doing!],
 690 [RUBY_MAKE_OPTIONS=$withval])
 691
 692 AC_SUBST(RUBY_MAKE_OPTIONS)
 693 AC_SUBST(RUBY)
 694 AC_SUBST(COMP_RUBY)
 695
 696 dnl Check for Lua.
 697 AC_PATH_PROG(LUA, lua, no)
 698
 699 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 700 [],[enable_lua=yes])
 701
 702 COMP_LUA=
 703 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 704   enable_lua=no
 705 else
 706   AC_MSG_CHECKING(for lua >= 5.0)
 707   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 708     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 709 LUA_EOF
 710   if test 0$LUA_MAJOR -lt 5; then
 711     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 712   else
 713     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 714     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 715     lua_vndot=$LUA_MAJOR$LUA_MINOR
 716     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 717     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 718       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 719         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 720           [lua_headerdir=lua$lua_vndot],
 721           [])],
 722         [])],
 723       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 724         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 725           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 726             [lua_headerdir=lua$lua_vdot],
 727             [])],
 728           [])],
 729         [AC_CHECK_HEADERS(lua.h,
 730           [AC_CHECK_HEADERS(lualib.h,
 731             [AC_CHECK_HEADER(lauxlib.h,
 732               [lua_headerdir=""],
 733               [lua_headerdir="no"])],
 734             [])],
 735           [])])])
 736
 737     if test "$lua_headerdir" = "no"; then
 738       enable_lua=no
 739     else
 740       COMP_LUA=lua
 741     fi
 742
 743     if test "$COMP_LUA" != "lua"; then
 744       enable_lua=no
 745       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 746     else
 747       # OK, headers found, let's check the libraries (LIBS is not used)
 748       LIBS=
 749       lua_havelib=no
 750       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 751       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 752         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 753           [lua_havelib=LUA$lua_vndot],
 754           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 755             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 756              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 757             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 758               [lua_havelib=$lua_vndot],
 759               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 760         [COMP_LUA=], [-lm])
 761       lua_libs=$LIBS
 762       LIBS=
 763
 764       # Options to pass when configuring Lua module
 765       if test  "$lua_havelib" != "no"; then
 766         # OK, headers and libs found. Try to set lua flags
 767         # and modules installation dirs with pkg-config
 768         if test "$PKGCONFIG" != "no"; then
 769           if test "$lua_vndot" = "50"; then
 770             lua_pkg_prefix=lualib
 771           else
 772             lua_pkg_prefix=lua
 773           fi
 774           # try with dot, without dot and finally without version
 775           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 776             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 777             # same binaries?
 778             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 779                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 780                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 781                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 782                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 783                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 784                 break
 785             fi
 786           done
 787         fi
 788
 789         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 790         # if lua 5.0 can't find compat-5.1, force installation of
 791         # compat-5.1.lua together with RRDtool.
 792         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 793           lua_need_compat51=1
 794           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 795         fi
 796
 797         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 798         if test "$LUA_CFLAGS" = ""; then
 799           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 800           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 801           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 802           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 803         fi
 804
 805         dnl pass additional lua options
 806         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 807         dnl found and install together with RRDtool, under $langpref.
 808         AC_ARG_ENABLE(lua-site-install,
 809         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 810         [],
 811         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 812
 813         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 814         AC_SUBST(LUA)
 815         AC_SUBST(COMP_LUA)
 816         AC_SUBST(LUA_INSTALL_CMOD)
 817         AC_SUBST(LUA_INSTALL_LMOD)
 818         AC_SUBST(LUA_CFLAGS)
 819         AC_SUBST(LUA_LFLAGS)
 820         AC_SUBST(LUA_DEFINES)
 821       else
 822         enable_lua=no
 823         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 824       fi
 825     fi
 826   fi
 827 fi
 828 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 829 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 830 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 831       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 832 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 833 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 834 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 835 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 836
 837 enable_tcl_site=no
 838
 839 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 840 [],[enable_tcl=yes])
 841
 842 if test  "$enable_tcl" = "yes"; then
 843   dnl Check for Tcl.
 844   withval=""
 845   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 846   enable_tcl=no
 847   for dir in $withval /usr/lib /usr/lib64 /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 848     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 849     if test -f "$dir/tclConfig.sh" ; then
 850         tcl_config=$dir/tclConfig.sh
 851         enable_tcl=yes
 852         AC_MSG_RESULT(yes)
 853         break
 854     else
 855         AC_MSG_RESULT(no)
 856     fi
 857   done
 858
 859   if test "$enable_tcl" = "no"; then
 860         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 861   else
 862         . $tcl_config
 863         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 864         if test -n "$TCL_INC_DIR"; then
 865           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 866         fi
 867   fi
 868   AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 869   [],[enable_tcl_site=yes])
 870
 871 fi
 872
 873 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 874 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 875
 876
 877 AC_SUBST(TCL_PREFIX)
 878 AC_SUBST(TCL_SHLIB_CFLAGS)
 879 AC_SUBST(TCL_SHLIB_LD)
 880 AC_SUBST(TCL_SHLIB_SUFFIX)
 881 AC_SUBST(TCL_PACKAGE_PATH)
 882 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 883 AC_SUBST(TCL_STUB_LIB_SPEC)
 884 AC_SUBST(TCL_VERSION)
 885 AC_SUBST(TCL_PACKAGE_DIR)
 886 AC_SUBST(TCL_INCLUDE_SPEC)
 887
 888 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 889 [],[enable_python=yes])
 890
 891 if test  "$enable_python" = "yes"; then
 892 dnl Check for python
 893 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 894 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 895 fi
 896
 897 if test  x$enable_python = xno; then
 898         COMP_PYTHON=
 899 else
 900         COMP_PYTHON="python"
 901 fi
 902
 903 AC_SUBST(COMP_PYTHON)
 904
 905 dnl Check for nroff
 906 AC_ARG_VAR(NROFF, [path to the local nroff version])
 907 AC_PATH_PROGS(NROFF, [gnroff nroff])
 908 if test x$NROFF = x; then
 909   AC_MSG_ERROR([I need a copy of *nroff to format the documentation])
 910 fi
 911 AC_ARG_VAR(TROFF, [path to the local troff version])
 912 AC_PATH_PROGS(TROFF, [groff troff])
 913 if test x$TROFF = x; then
 914   AC_MSG_ERROR([I need a copy of *troff to format the documentation])
 915 fi
 916
 917 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 918 if test -z "$RRDDOCDIR"; then
 919    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 920
 921 # systemd check
 922 PKG_PROG_PKG_CONFIG
 923 AC_ARG_WITH([systemdsystemunitdir],
 924         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 925         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 926 if test "x$with_systemdsystemunitdir" != xno; then
 927         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
 928         AC_OUTPUT([etc/rrdcached.socket etc/rrdcached.service])
 929 fi
 930 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
 931
 932
 933 CONFIGURE_PART(Apply Configuration Information)
 934
 935 AC_CONFIG_FILES([examples/shared-demo.pl])
 936 AC_CONFIG_FILES([examples/piped-demo.pl])
 937 AC_CONFIG_FILES([examples/stripes.pl])
 938 AC_CONFIG_FILES([examples/bigtops.pl])
 939 AC_CONFIG_FILES([examples/minmax.pl])
 940 AC_CONFIG_FILES([examples/4charts.pl])
 941 AC_CONFIG_FILES([examples/perftest.pl])
 942 AC_CONFIG_FILES([examples/Makefile])
 943 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 944 AC_CONFIG_FILES([doc/Makefile])
 945 AC_CONFIG_FILES([po/Makefile.in])
 946 AC_CONFIG_FILES([src/Makefile])
 947 AC_CONFIG_FILES([src/librrd.sym.in])
 948 AC_CONFIG_FILES([src/librrd.pc])
 949 AC_CONFIG_FILES([bindings/Makefile])
 950 AC_CONFIG_FILES([bindings/tcl/Makefile])
 951 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 952 AC_CONFIG_FILES([Makefile])
 953 AC_CONFIG_FILES([bindings/lua/Makefile])
 954
 955 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 956
 957 dnl intl requires our config to be called config.h. indulge it.
 958 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 959
 960 AC_OUTPUT
 961
 962 AC_MSG_CHECKING(in)
 963 AC_MSG_RESULT(and out again)
 964
 965 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 966 sleep 1
 967 echo $ECHO_N ".$ECHO_C" 1>&6
 968 sleep 1
 969 echo $ECHO_N ".$ECHO_C" 1>&6
 970 sleep 1
 971 echo $ECHO_N ".$ECHO_C" 1>&6
 972 sleep 1
 973 echo $ECHO_N ".$ECHO_C" 1>&6
 974 sleep 1
 975 AC_MSG_RESULT([ just kidding ;-)])
 976 echo
 977 echo "----------------------------------------------------------------"
 978 echo "Config is DONE!"
 979 echo
 980 echo "          With MMAP IO: $enable_mmap"
 981 echo "      Build rrd_getopt: $build_getopt"
 982 echo "       Build rrd_graph: $enable_rrd_graph"
 983 echo "       Static programs: $staticprogs"
 984 echo "          Perl Modules: $COMP_PERL"
 985 echo "           Perl Binary: $PERL"
 986 echo "          Perl Version: $PERL_VERSION"
 987 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 988 echo "          Ruby Modules: $COMP_RUBY"
 989 echo "           Ruby Binary: $RUBY"
 990 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 991 echo "    Build Lua Bindings: $enable_lua"
 992 if test "$enable_lua" = "yes"; then
 993 echo "            Lua Binary: $LUA"
 994 echo "           Lua Version: $lua_version"
 995 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 996 if test "$lua_need_compat51" = "1"; then
 997 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 998 fi
 999 fi
1000 echo "    Build Tcl Bindings: $enable_tcl"
1001 echo " Build Python Bindings: $enable_python"
1002 echo "          Build rrdcgi: $enable_rrdcgi"
1003 echo "       Build librrd MT: $enable_pthread"
1004 echo "           Use gettext: $USE_NLS"
1005 echo "           With libDBI: $have_libdbi"
1006 echo "          With libwrap: $have_libwrap"
1007 echo "      With systemd dir: $with_systemdsystemunitdir"
1008 echo
1009 echo "             Libraries: $ALL_LIBS"
1010 echo
1011 echo "Type 'make' to compile the software and use 'make install' to "
1012 echo "install everything to: $prefix."
1013 echo
1014 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
1015 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
1016 echo "place an order."
1017 echo
1018 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
1019 echo "----------------------------------------------------------------"