configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.999])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4999
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=6:999:2
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 106
 107 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
 108 [enable_rrdcgi=no],[enable_rrd_graph=yes])
 109
 110 if test $enable_rrd_graph != no; then
 111  AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
 112 fi
 113
 114 dnl Check if we run on a system that has fonts
 115 AC_ARG_WITH(rrd-default-font,
 116 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 117 [RRD_DEFAULT_FONT=$withval],[
 118   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 119         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 120   else
 121         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 122   fi
 123 ])
 124
 125 dnl Use mmap in rrd_update instead of seek+write
 126 AC_ARG_ENABLE([mmap],
 127 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 128 [],
 129 [enable_mmap=yes])
 130
 131 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 132 [],[enable_pthread=yes])
 133
 134 AC_ARG_ENABLE(static-programs,
 135      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 136      [case "${enableval}" in
 137        yes) staticprogs=yes ;;
 138        no)  staticprogs=no ;;
 139        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 140      esac],[staticprogs=no])
 141 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 142
 143
 144 CONFIGURE_PART(Audit Compilation Environment)
 145
 146
 147 dnl Check for the compiler and static/shared library creation.
 148 AC_PROG_CPP
 149 AC_PROG_CC
 150 AM_PROG_CC_C_O
 151 AC_PROG_LIBTOOL
 152
 153 dnl Try to detect/use GNU features
 154 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 155
 156 dnl check for -Werror separatly
 157 dnl (quite a few autotool checks do not work with -Werror; also, the
 158 dnl check for -Werror fails after checking and adding the other flags)
 159 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 160   [AC_COMPILE_IFELSE(
 161     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 162     [rd_cv_gcc_flag__Werror="yes"],
 163     [rd_cv_gcc_flag__Werror="no"])])
 164 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 165   WERROR="-Werror"
 166 else
 167   WERROR=""
 168 fi
 169 AC_SUBST(WERROR)
 170
 171 dnl which flags does the compiler support?
 172 if test "x$GCC" = "xyes"; then
 173   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 174     oCFLAGS="$CFLAGS"
 175     CFLAGS="$CFLAGS $flag"
 176     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 177     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 178        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 179     if eval test \$$cachename = no; then
 180          CFLAGS="$oCFLAGS"
 181     fi
 182   done
 183 fi
 184
 185
 186
 187 AC_SUBST(RRD_DEFAULT_FONT)
 188
 189 CONFIGURE_PART(Checking for Header Files)
 190
 191 dnl Checks for header files.
 192 AC_HEADER_STDC
 193 AC_HEADER_DIRENT
 194 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 195
 196 dnl Checks for typedefs, structures, and compiler characteristics.
 197 AC_C_CONST
 198 AC_HEADER_TIME
 199 AC_STRUCT_TM
 200
 201 CONFIGURE_PART(Test Library Functions)
 202
 203 dnl Checks for libraries.
 204 AC_CHECK_FUNC(acos,  , AC_CHECK_LIB(m, acos))
 205 AC_CHECK_FUNC(round, , AC_CHECK_LIB(m, round))
 206
 207
 208 dnl add pic flag in any case this makes sure all our code is relocatable
 209 eval `./libtool --config | grep pic_flag=`
 210 CFLAGS="$CFLAGS $pic_flag"
 211
 212
 213 dnl Checks for library functions.
 214 AC_FUNC_STRFTIME
 215 AC_FUNC_VPRINTF
 216
 217 AC_C_BIGENDIAN
 218
 219 dnl for each function found we get a definition in config.h
 220 dnl of the form HAVE_FUNCTION
 221
 222 AC_CHECK_FUNCS(nl_langinfo tzset fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 223
 224 AC_FUNC_STRERROR_R
 225
 226 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 227
 228 dnl Could use these to know if we need to provide a prototype
 229 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 230
 231 dnl check for fdatasync. Solaris has fdatasync in the librt
 232
 233 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 234 dnl if there is no fdatasync we may get lucky with fsync
 235 AC_CHECK_FUNCS(fsync)
 236
 237 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 238
 239 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 240 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 241
 242
 243
 244 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 245 if test "x$enable_mmap" = "xyes"; then
 246   case "$host" in
 247   *cygwin*)
 248     # the normal mmap test does not work in cygwin
 249     AC_CHECK_FUNCS(mmap)
 250     if test "x$ac_cv_func_mmap" = "xyes"; then
 251       ac_cv_func_mmap_fixed_mapped=yes
 252     fi
 253   ;;
 254   *)
 255     AC_CHECK_HEADERS(sys/mman.h)
 256     AC_FUNC_MMAP
 257     AC_CHECK_FUNCS(mmap munmap msync)
 258     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 259                                      # include <sys/mman.h>
 260                                      #endif])
 261     if test "x$ac_cv_have_decl_madvise" = "xyes";
 262     then
 263       AC_CHECK_FUNCS(madvise)
 264     else
 265       AC_CHECK_FUNCS(posix_madvise)
 266       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 267         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 268       fi
 269     fi
 270   ;;
 271   esac
 272   if test "x$ac_cv_func_mmap" != "xyes";
 273   then
 274     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 275 dnl enable_mmap="no"
 276   fi
 277 fi
 278
 279 dnl can we use posix_fadvise
 280 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 281 #include <fcntl.h>])
 282 AC_CHECK_FUNCS(posix_fadvise)
 283
 284 CONFIGURE_PART(Libintl Processing)
 285
 286 AM_GNU_GETTEXT_VERSION(0.17)
 287 AM_GNU_GETTEXT(external)
 288
 289 CONFIGURE_PART(IEEE Math Checks)
 290
 291
 292 dnl actual code to check if this works
 293 AC_CHECK_FUNCS(fpclassify, ,
 294   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 295     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 296 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 297       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 298
 299 AC_CHECK_FUNCS(isinf, ,
 300   [AC_MSG_CHECKING(for isinf with <math.h>)
 301     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 302 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 303       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 304
 305 dnl finite is BSD, isfinite is C99, so prefer the latter
 306 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 307 AC_TRY_RUN([
 308 #ifdef HAVE_MATH_H
 309 #include <math.h>
 310 #endif
 311 #ifdef HAVE_FLOAT_H
 312 #include <float.h>
 313 #endif
 314 int main ()
 315 {
 316 #ifdef isfinite
 317 #ifdef LDBL_MAX
 318   if (!isfinite(LDBL_MAX)) return 1;
 319 #endif
 320 #ifdef DBL_MAX
 321   if (!isfinite(DBL_MAX)) return 1;
 322 #endif
 323 #endif
 324 return 0;
 325 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 326 case "${target}" in
 327   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 328   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 329   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 330   *) ac_cv_have_broken_isfinite=no ;;
 331 esac])
 332 ])
 333
 334 dnl the test does not seem to work on solaris 2.8
 335 dnl so lets fix this by hand
 336 case "${target}" in
 337   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 338   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 339 esac
 340
 341 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 342   AC_DEFINE(HAVE_ISFINITE)
 343 else
 344   AC_CHECK_FUNCS(finite,[],
 345       [AC_CHECK_FUNCS(isfinite,[],
 346          [AC_MSG_CHECKING(for isfinite with <math.h>)
 347           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 348 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 349                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 350 fi
 351
 352 AC_FULL_IEEE
 353
 354 CONFIGURE_PART(Resolve Portability Issues)
 355
 356 GC_TIMEZONE()
 357
 358 CHECK_FOR_WORKING_MS_ASYNC
 359
 360 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
 361 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
 362   [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
 363     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
 364       AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
 365
 366 dnl Do we need getopt_long
 367
 368 dnl even when including our own getopt implementation
 369 dnl we may want to make sure we use the external
 370 dnl defined by libc to not run into linker resolve trouble
 371
 372 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 373 [AC_TRY_LINK([#include <unistd.h>],
 374   [extern int opterr; opterr = 1;],
 375   [rd_cv_var_int_opterr=yes],
 376   [rd_cv_var_int_opterr=no])])
 377 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 378   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 379 fi
 380
 381 build_getopt=no
 382 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 383 AC_CHECK_FUNC(getopt_long,[],[
 384 RRD_GETOPT_LONG="getopt_long"
 385 build_getopt=yes
 386 ])
 387 AC_SUBST(RRD_GETOPT_LONG)
 388 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 389
 390 dnl what does realloc do if it gets called with a NULL pointer
 391
 392 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 393 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 394               int main(void){
 395               char *x = NULL;
 396               x = realloc (x,10);
 397               if (x==NULL) return 1;
 398               return 0;
 399              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 400
 401 if test x"$rd_cv_null_realloc" = xnope; then
 402 AC_DEFINE(NO_NULL_REALLOC)
 403 fi
 404
 405 AC_LANG_PUSH(C)
 406 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 407 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 408 AC_LINK_IFELSE(
 409     AC_LANG_PROGRAM(
 410            [[#include <time.h>]],
 411            [[ctime_r(NULL,NULL,0)]]
 412                    ),
 413     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 414       AC_LINK_IFELSE(
 415           AC_LANG_PROGRAM(
 416                 [[#include <time.h>]],
 417                 [[ctime_r(NULL,NULL)]]
 418                          ),
 419           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 420           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 421       )
 422     ],
 423     [ AC_LINK_IFELSE(
 424           AC_LANG_PROGRAM(
 425                 [[#include <time.h>]],
 426                 [[ctime_r(NULL,NULL)]]
 427                          ),
 428           [AC_MSG_RESULT(no)],
 429           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 430       )
 431     ]
 432 )
 433 AC_LANG_POP(C)
 434
 435 dnl Check for pthreads
 436 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 437
 438 AC_SUBST(MULTITHREAD_CFLAGS)
 439 AC_SUBST(MULTITHREAD_LDFLAGS)
 440
 441 if test $enable_pthread != no; then
 442  ACX_PTHREAD([
 443     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 444     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 445              ],
 446              [])
 447 fi
 448
 449 dnl since we use lots of *_r functions all over the code we better
 450 dnl make sure they are known
 451
 452 if test  "x$x_rflag" != "xno"; then
 453    CPPFLAGS="$CPPFLAGS $x_rflag"
 454 fi
 455
 456 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 457
 458 AC_LANG_PUSH(C)
 459 dnl see if we have to include malloc/malloc.h
 460 AC_MSG_CHECKING([do we need malloc/malloc.h])
 461 AC_LINK_IFELSE(
 462     AC_LANG_PROGRAM(
 463            [[#include <stdlib.h>]],
 464            [[malloc(1)]]
 465                    ),
 466     [ AC_MSG_RESULT([nope, works out of the box]) ],
 467     [ AC_LINK_IFELSE(
 468           AC_LANG_PROGRAM(
 469                 [[#include <stdlib.h>
 470                   #include <malloc/malloc.h>]],
 471                 [[malloc(1)]]
 472                          ),[
 473            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 474            AC_MSG_RESULT([yes we do])],
 475           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 476       )
 477     ]
 478 )
 479
 480 dnl is time_t 32 of 64 bit ?
 481 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
 482 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
 483 AC_MSG_CHECKING([the type of time_t])
 484 AC_CHECK_SIZEOF([time_t])
 485 if test "x$ac_cv_sizeof_time_t" = "x4"; then
 486   AC_MSG_RESULT([time_t is 32 bit])
 487   AC_DEFINE([TIME_T_IS_32BIT])
 488 elif test "x$ac_cv_sizeof_time_t" = "x8"; then
 489   AC_MSG_RESULT([time_t is 64 bit])
 490   AC_DEFINE([TIME_T_IS_64BIT])
 491 else
 492   AC_MSG_ERROR([can not figure type of time_t])
 493 fi
 494
 495 AC_LANG_POP(C)
 496
 497 CONFIGURE_PART(Find 3rd-Party Libraries)
 498
 499 have_libdbi=no
 500
 501 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[],[
 502     AC_CHECK_HEADER(dbi/dbi.h, [
 503        AC_CHECK_LIB(dbi, dbi_initialize, [
 504            AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 505            LIBS="${LIBS} -ldbi -ldl"
 506            have_libdbi=yes
 507        ])
 508     ])
 509 ])
 510
 511 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 512
 513 have_libwrap=no
 514
 515 AC_ARG_ENABLE(libwrap, AS_HELP_STRING([--disable-libwrap], [do not build in support for libwrap (tcp wrapper)]),[],[
 516     AC_CHECK_HEADER(tcpd.h,[
 517         AC_CHECK_FUNCS(hosts_access, [
 518             AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 519             have_libwrap=yes
 520         ],
 521         [
 522             AC_CHECK_LIB(wrap, hosts_access, [
 523                AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 524                LIBS="${LIBS} -lwrap"
 525                have_libwrap=yes
 526             ])
 527         ])
 528     ])
 529 ])
 530
 531
 532 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
 533
 534 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
 535
 536
 537 CORE_LIBS="$LIBS"
 538
 539 if test $enable_rrd_graph != no; then
 540 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.5,  http://zlib.net/, "")
 541 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.4.8,  ftp://ftp.simplesystems.org/pub/libpng/png/src/, "")
 542 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.4.6,  http://download.savannah.gnu.org/releases/freetype/, /usr/include/freetype2)
 543 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.8.0,  http://www.freedesktop.org/software/fontconfig/release/, /usr/include)
 544 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.10.2,  http://cairographics.org/releases/, "")
 545 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.10.2,  http://cairographics.org/releases/, "")
 546 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.10.2,  http://cairographics.org/releases/, "")
 547 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.10.2,  http://cairographics.org/releases/, "")
 548 EX_CHECK_ALL(pangocairo-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.28.4,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.28, "")
 549
 550 fi
 551 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.28.7, ftp://ftp.gtk.org/pub/glib/2.28/, "")
 552 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.7.8,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 553
 554 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 555   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 556 fi
 557
 558 ALL_LIBS="$LIBS"
 559 LIBS=
 560
 561 AC_SUBST(CORE_LIBS)
 562 AC_SUBST(ALL_LIBS)
 563
 564 CONFIGURE_PART(Prep for Building Language Bindings)
 565
 566 dnl Check for Perl and friends
 567 PATH=$PATH:/usr/perl5/bin
 568 export PATH
 569 AC_PATH_PROG(PERL, perl, no)
 570 AC_PATH_PROG(POD2MAN, pod2man, no)
 571 AC_PATH_PROG(POD2HTML, pod2html, no)
 572
 573
 574 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 575 [],[enable_perl=yes])
 576
 577
 578 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 579 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 580 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 581 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 582
 583 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 584         COMP_PERL=
 585 else
 586         COMP_PERL="perl_piped perl_shared"
 587         AC_MSG_CHECKING(for the perl version you are running)
 588         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 589         AC_MSG_RESULT($PERL_VERSION)
 590         if test -z "$PERLCC"; then
 591             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 592             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 593             AC_MSG_RESULT($perlcc)
 594             if test ! -x "$perlcc"; then
 595                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 596                 if test "$PERL_CC" = "no"; then
 597                     AC_MSG_WARN([
 598 I would not find the Compiler ($perlcc) that was originally used to compile
 599 your perl binary. You should either make sure that this compiler is
 600 available on your system, pick an other compiler and set PERLCC
 601 appropriately, or use a different perl setup that was compiled locally.
 602
 603 I will disable the compilation of the RRDs perl module for now.
 604 ])
 605                     COMP_PERL="perl_piped"
 606                 fi
 607             fi
 608         fi
 609 fi
 610
 611 AC_MSG_CHECKING(Perl Modules to build)
 612 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 613
 614 # Options to pass when configuring perl module
 615 langpref=$prefix
 616 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 617 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 618
 619 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 620
 621 dnl pass additional perl options when generating Makefile from Makefile.PL
 622 AC_ARG_ENABLE(perl-site-install,
 623 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 624 [PERL_MAKE_OPTIONS=],[])
 625
 626 if test ! -z "$PERLCC"; then
 627    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 628
 629    if test ! -z "$PERLCCFLAGS"; then
 630        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 631    fi
 632
 633    if test -z "$PERLLD"; then
 634        PERLLD=$PERLCC
 635    fi
 636    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 637
 638    if test ! -z "$PERLLDFLAGS"; then
 639        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 640    fi
 641 fi
 642
 643 AC_ARG_WITH(perl-options,
 644 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 645                           generating Makefile from Makefile.PL. If you set this
 646                           option, interesting things may happen unless you know
 647                           what you are doing!],
 648 [PERL_MAKE_OPTIONS=$withval])
 649
 650 AC_SUBST(PERL_MAKE_OPTIONS)
 651 AC_SUBST(PERL)
 652 AC_SUBST(COMP_PERL)
 653 AC_SUBST(PERL_VERSION)
 654
 655 dnl Check for Ruby.
 656 AC_PATH_PROG(RUBY, ruby, no)
 657
 658 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 659 [],[enable_ruby=yes])
 660
 661 AC_MSG_CHECKING(if ruby modules can be built)
 662
 663 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 664         COMP_RUBY=
 665         AC_MSG_RESULT(No .. Ruby not found or disabled)
 666 else
 667         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 668                 COMP_RUBY="ruby"
 669                 AC_MSG_RESULT(YES)
 670         else
 671                 COMP_RUBY=
 672                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 673         fi
 674 fi
 675
 676 dnl pass additional ruby options when generating Makefile from Makefile.PL
 677 AC_ARG_ENABLE(ruby-site-install,
 678 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 679 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 680
 681
 682 AC_ARG_WITH(ruby-options,
 683 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 684                           generating Makefile from extconf.rb. If you set this
 685                           option, interesting things may happen unless you know
 686                           what you are doing!],
 687 [RUBY_MAKE_OPTIONS=$withval])
 688
 689 AC_SUBST(RUBY_MAKE_OPTIONS)
 690 AC_SUBST(RUBY)
 691 AC_SUBST(COMP_RUBY)
 692
 693 dnl Check for Lua.
 694 AC_PATH_PROG(LUA, lua, no)
 695
 696 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 697 [],[enable_lua=yes])
 698
 699 COMP_LUA=
 700 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 701   enable_lua=no
 702 else
 703   AC_MSG_CHECKING(for lua >= 5.0)
 704   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 705     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 706 LUA_EOF
 707   if test 0$LUA_MAJOR -lt 5; then
 708     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 709   else
 710     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 711     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 712     lua_vndot=$LUA_MAJOR$LUA_MINOR
 713     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 714     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 715       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 716         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 717           [lua_headerdir=lua$lua_vndot],
 718           [])],
 719         [])],
 720       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 721         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 722           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 723             [lua_headerdir=lua$lua_vdot],
 724             [])],
 725           [])],
 726         [AC_CHECK_HEADERS(lua.h,
 727           [AC_CHECK_HEADERS(lualib.h,
 728             [AC_CHECK_HEADER(lauxlib.h,
 729               [lua_headerdir=""],
 730               [lua_headerdir="no"])],
 731             [])],
 732           [])])])
 733
 734     if test "$lua_headerdir" = "no"; then
 735       enable_lua=no
 736     else
 737       COMP_LUA=lua
 738     fi
 739
 740     if test "$COMP_LUA" != "lua"; then
 741       enable_lua=no
 742       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 743     else
 744       # OK, headers found, let's check the libraries (LIBS is not used)
 745       LIBS=
 746       lua_havelib=no
 747       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 748       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 749         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 750           [lua_havelib=LUA$lua_vndot],
 751           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 752             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 753              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 754             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 755               [lua_havelib=$lua_vndot],
 756               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 757         [COMP_LUA=], [-lm])
 758       lua_libs=$LIBS
 759       LIBS=
 760
 761       # Options to pass when configuring Lua module
 762       if test  "$lua_havelib" != "no"; then
 763         # OK, headers and libs found. Try to set lua flags
 764         # and modules installation dirs with pkg-config
 765         if test "$PKGCONFIG" != "no"; then
 766           if test "$lua_vndot" = "50"; then
 767             lua_pkg_prefix=lualib
 768           else
 769             lua_pkg_prefix=lua
 770           fi
 771           # try with dot, without dot and finally without version
 772           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 773             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 774             # same binaries?
 775             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 776                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 777                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 778                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 779                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 780                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 781                 break
 782             fi
 783           done
 784         fi
 785
 786         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 787         # if lua 5.0 can't find compat-5.1, force installation of
 788         # compat-5.1.lua together with RRDtool.
 789         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 790           lua_need_compat51=1
 791           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 792         fi
 793
 794         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 795         if test "$LUA_CFLAGS" = ""; then
 796           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 797           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 798           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 799           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 800         fi
 801
 802         dnl pass additional lua options
 803         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 804         dnl found and install together with RRDtool, under $langpref.
 805         AC_ARG_ENABLE(lua-site-install,
 806         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 807         [],
 808         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 809
 810         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 811         AC_SUBST(LUA)
 812         AC_SUBST(COMP_LUA)
 813         AC_SUBST(LUA_INSTALL_CMOD)
 814         AC_SUBST(LUA_INSTALL_LMOD)
 815         AC_SUBST(LUA_CFLAGS)
 816         AC_SUBST(LUA_LFLAGS)
 817         AC_SUBST(LUA_DEFINES)
 818       else
 819         enable_lua=no
 820         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 821       fi
 822     fi
 823   fi
 824 fi
 825 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 826 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 827 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 828       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 829 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 830 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 831 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 832 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 833
 834 enable_tcl_site=no
 835
 836 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 837 [],[enable_tcl=yes])
 838
 839 if test  "$enable_tcl" = "yes"; then
 840   dnl Check for Tcl.
 841   withval=""
 842   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 843   enable_tcl=no
 844   for dir in $withval /usr/lib /usr/lib64 /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 845     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 846     if test -f "$dir/tclConfig.sh" ; then
 847         tcl_config=$dir/tclConfig.sh
 848         enable_tcl=yes
 849         AC_MSG_RESULT(yes)
 850         break
 851     else
 852         AC_MSG_RESULT(no)
 853     fi
 854   done
 855
 856   if test "$enable_tcl" = "no"; then
 857         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 858   else
 859         . $tcl_config
 860         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 861         if test -n "$TCL_INC_DIR"; then
 862           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 863         fi
 864   fi
 865   AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 866   [],[enable_tcl_site=yes])
 867
 868 fi
 869
 870 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 871 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 872
 873
 874 AC_SUBST(TCL_PREFIX)
 875 AC_SUBST(TCL_SHLIB_CFLAGS)
 876 AC_SUBST(TCL_SHLIB_LD)
 877 AC_SUBST(TCL_SHLIB_SUFFIX)
 878 AC_SUBST(TCL_PACKAGE_PATH)
 879 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 880 AC_SUBST(TCL_STUB_LIB_SPEC)
 881 AC_SUBST(TCL_VERSION)
 882 AC_SUBST(TCL_PACKAGE_DIR)
 883 AC_SUBST(TCL_INCLUDE_SPEC)
 884
 885 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 886 [],[enable_python=yes])
 887
 888 if test  "$enable_python" = "yes"; then
 889 dnl Check for python
 890 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 891 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 892 fi
 893
 894 if test  x$enable_python = xno; then
 895         COMP_PYTHON=
 896 else
 897         COMP_PYTHON="python"
 898 fi
 899
 900 AC_SUBST(COMP_PYTHON)
 901
 902 dnl Check for nroff
 903 AC_ARG_VAR(NROFF, [path to the local nroff version])
 904 AC_PATH_PROGS(NROFF, [gnroff nroff])
 905 if test x$NROFF = x; then
 906   AC_MSG_ERROR([I need a copy of *nroff to format the documentation])
 907 fi
 908 AC_ARG_VAR(TROFF, [path to the local troff version])
 909 AC_PATH_PROGS(TROFF, [groff troff])
 910 if test x$TROFF = x; then
 911   AC_MSG_ERROR([I need a copy of *troff to format the documentation])
 912 fi
 913
 914 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 915 if test -z "$RRDDOCDIR"; then
 916    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 917
 918
 919 CONFIGURE_PART(Apply Configuration Information)
 920
 921 AC_CONFIG_FILES([examples/shared-demo.pl])
 922 AC_CONFIG_FILES([examples/piped-demo.pl])
 923 AC_CONFIG_FILES([examples/stripes.pl])
 924 AC_CONFIG_FILES([examples/bigtops.pl])
 925 AC_CONFIG_FILES([examples/minmax.pl])
 926 AC_CONFIG_FILES([examples/4charts.pl])
 927 AC_CONFIG_FILES([examples/perftest.pl])
 928 AC_CONFIG_FILES([examples/Makefile])
 929 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 930 AC_CONFIG_FILES([doc/Makefile])
 931 AC_CONFIG_FILES([po/Makefile.in])
 932 AC_CONFIG_FILES([src/Makefile])
 933 AC_CONFIG_FILES([src/librrd.sym.in])
 934 AC_CONFIG_FILES([src/librrd.pc])
 935 AC_CONFIG_FILES([bindings/Makefile])
 936 AC_CONFIG_FILES([bindings/tcl/Makefile])
 937 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 938 AC_CONFIG_FILES([Makefile])
 939 AC_CONFIG_FILES([bindings/lua/Makefile])
 940
 941 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 942
 943 dnl intl requires our config to be called config.h. indulge it.
 944 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 945
 946 AC_OUTPUT
 947
 948 AC_MSG_CHECKING(in)
 949 AC_MSG_RESULT(and out again)
 950
 951 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 952 sleep 1
 953 echo $ECHO_N ".$ECHO_C" 1>&6
 954 sleep 1
 955 echo $ECHO_N ".$ECHO_C" 1>&6
 956 sleep 1
 957 echo $ECHO_N ".$ECHO_C" 1>&6
 958 sleep 1
 959 echo $ECHO_N ".$ECHO_C" 1>&6
 960 sleep 1
 961 AC_MSG_RESULT([ just kidding ;-)])
 962 echo
 963 echo "----------------------------------------------------------------"
 964 echo "Config is DONE!"
 965 echo
 966 echo "          With MMAP IO: $enable_mmap"
 967 echo "      Build rrd_getopt: $build_getopt"
 968 echo "       Build rrd_graph: $enable_rrd_graph"
 969 echo "       Static programs: $staticprogs"
 970 echo "          Perl Modules: $COMP_PERL"
 971 echo "           Perl Binary: $PERL"
 972 echo "          Perl Version: $PERL_VERSION"
 973 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 974 echo "          Ruby Modules: $COMP_RUBY"
 975 echo "           Ruby Binary: $RUBY"
 976 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 977 echo "    Build Lua Bindings: $enable_lua"
 978 if test "$enable_lua" = "yes"; then
 979 echo "            Lua Binary: $LUA"
 980 echo "           Lua Version: $lua_version"
 981 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 982 if test "$lua_need_compat51" = "1"; then
 983 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 984 fi
 985 fi
 986 echo "    Build Tcl Bindings: $enable_tcl"
 987 echo " Build Python Bindings: $enable_python"
 988 echo "          Build rrdcgi: $enable_rrdcgi"
 989 echo "       Build librrd MT: $enable_pthread"
 990 echo "           Use gettext: $USE_NLS"
 991 echo "           With libDBI: $have_libdbi"
 992 echo "          With libwrap: $have_libwrap"
 993 echo
 994 echo "             Libraries: $ALL_LIBS"
 995 echo
 996 echo "Type 'make' to compile the software and use 'make install' to "
 997 echo "install everything to: $prefix."
 998 echo
 999 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
1000 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
1001 echo "place an order."
1002 echo
1003 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
1004 echo "----------------------------------------------------------------"