configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.99907052400])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devel versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.299907061100
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52  ])
  53
  54 AH_BOTTOM([
  55 /* make sure that we pickup the correct stuff from all headers */
  56 #define _XOPEN_SOURCE 600
  57 #ifdef HAVE_FEATURES_H
  58 # include <features.h>
  59 #endif
  60
  61 #ifdef HAVE_SYS_TYPES_H
  62 # include <sys/types.h>
  63 #endif
  64
  65 #ifdef HAVE_SYS_PARAM_H
  66 # include <sys/param.h>
  67 #endif
  68 #ifndef MAXPATH
  69 # ifdef PATH_MAX
  70 #  define MAXPATH PATH_MAX
  71 # endif
  72 #endif
  73 #ifndef MAXPATH
  74 /* else try the BSD variant */
  75 # ifdef MAXPATHLEN
  76 #  define MAXPATH MAXPATHLEN
  77 # endif
  78 #endif
  79
  80 #ifdef HAVE_ERRNO_H
  81 # include <errno.h>
  82 #endif
  83
  84 #ifdef HAVE_SYS_MMAN_H
  85 # include <sys/mman.h>
  86 #endif
  87 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
  88 /* use posix_madvise family */
  89 # define madvise posix_madvise
  90 # define MADV_NORMAL POSIX_MADV_NORMAL
  91 # define MADV_RANDOM POSIX_MADV_RANDOM
  92 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
  93 # define MADV_WILLNEED POSIX_MADV_WILLNEED
  94 # define MADV_DONTNEED POSIX_MADV_DONTNEED
  95 #endif
  96 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
  97 # define USE_MADVISE 1
  98 #endif
  99
 100 #ifdef HAVE_SYS_STAT_H
 101 # include <sys/stat.h>
 102 #endif
 103
 104 #ifdef HAVE_FCNTL_H
 105 #include <fcntl.h>
 106 #endif
 107
 108 #ifdef HAVE_UNISTD_H
 109 # include <unistd.h>
 110 #endif
 111
 112 #ifdef TIME_WITH_SYS_TIME
 113 # include <sys/time.h>
 114 # include <time.h>
 115 #else
 116 # ifdef HAVE_SYS_TIME_H
 117 #  include <sys/time.h>
 118 # else
 119 #  include <time.h>
 120 # endif
 121 #endif
 122
 123 #ifdef HAVE_SYS_TIMES_H
 124 # include <sys/times.h>
 125 #endif
 126
 127 #ifdef HAVE_SYS_RESOURCE_H
 128 # include <sys/resource.h>
 129 #if (defined(__svr4__) && defined(__sun__))
 130 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
 131    Use this instead. */
 132 extern int getrusage(int, struct rusage *);
 133 #endif /* __svr4__ && __sun__ */
 134 #endif
 135
 136
 137 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 138    make sure you are NOT using bcopy, index or rindex in the code */
 139
 140 #ifdef STDC_HEADERS
 141 # include <string.h>
 142 #else
 143 # ifndef HAVE_STRCHR
 144 #  define strchr index
 145 #  define strrchr rindex
 146 # endif
 147 char *strchr (), *strrchr ();
 148 # ifndef HAVE_MEMMOVE
 149 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 150 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 151 # endif
 152 #endif
 153
 154 #ifdef NO_NULL_REALLOC
 155 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 156 #else
 157 # define rrd_realloc(a,b) realloc((a), (b))
 158 #endif
 159
 160 #ifdef NEED_MALLOC_MALLOC_H
 161 #  include <malloc/malloc.h>
 162 #endif
 163
 164 #ifdef HAVE_STDIO_H
 165 # include <stdio.h>
 166 #endif
 167
 168 #ifdef HAVE_STDLIB_H
 169 # include <stdlib.h>
 170 #endif
 171
 172 #ifdef HAVE_CTYPE_H
 173 # include <ctype.h>
 174 #endif
 175
 176 #ifdef HAVE_DIRENT_H
 177 # include <dirent.h>
 178 # define NAMLEN(dirent) strlen((dirent)->d_name)
 179 #else
 180 # define dirent direct
 181 # define NAMLEN(dirent) (dirent)->d_namlen
 182 # ifdef HAVE_SYS_NDIR_H
 183 #  include <sys/ndir.h>
 184 # endif
 185 # ifdef HAVE_SYS_DIR_H
 186 #  include <sys/dir.h>
 187 # endif
 188 # ifdef HAVE_NDIR_H
 189 #  include <ndir.h>
 190 # endif
 191 #endif
 192
 193 #ifdef MUST_DISABLE_SIGFPE
 194 # include <signal.h>
 195 #endif
 196
 197 #ifdef MUST_DISABLE_FPMASK
 198 # include <floatingpoint.h>
 199 #endif
 200
 201
 202 #ifdef HAVE_MATH_H
 203 # include <math.h>
 204 #endif
 205
 206 #ifdef HAVE_FLOAT_H
 207 # include <float.h>
 208 #endif
 209
 210 #ifdef HAVE_IEEEFP_H
 211 # include <ieeefp.h>
 212 #endif
 213
 214 #ifdef HAVE_FP_CLASS_H
 215 # include <fp_class.h>
 216 #endif
 217
 218 /* for Solaris */
 219 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 220 #  define HAVE_ISINF 1
 221 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 222 #endif
 223
 224 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 225 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 226 #  undef isnan
 227 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 228 #endif
 229
 230 /* for OSF1 Digital Unix */
 231 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 232 #  define HAVE_ISINF 1
 233 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 234 #endif
 235
 236 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 237 #  define HAVE_ISINF 1
 238 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 239 #endif
 240
 241 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 242 #  define HAVE_ISINF 1
 243 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 244 #endif
 245
 246 /* for AIX */
 247 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 248 #  define HAVE_ISINF 1
 249 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 250 #endif
 251
 252 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 253 #  define HAVE_FINITE 1
 254 #  define finite(a) isfinite(a)
 255 #endif
 256
 257 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 258 #  define HAVE_FINITE 1
 259 #  define finite(a) (! isnan(a) && ! isinf(a))
 260 #endif
 261
 262 #ifndef HAVE_FINITE
 263 #error "Can't compile without finite function"
 264 #endif
 265
 266 #ifndef HAVE_ISINF
 267 #error "Can't compile without isinf function"
 268 #endif
 269
 270 #endif /* RRD_CONFIG_H */
 271 ])
 272
 273 dnl Process Special Options
 274 dnl -----------------------------------
 275
 276 dnl How the vertical axis label is printed
 277 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 278  [Vertical label angle: -90.0 (default) or 90.0])
 279 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 280  [Vertical label angle: -90.0 (default) or 90.0])
 281
 282 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 283 [],[enable_rrdcgi=yes])
 284
 285 dnl Check if we run on a system that has fonts
 286 AC_ARG_WITH(rrd-default-font,
 287 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 288 [RRD_DEFAULT_FONT=$withval],[
 289   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 290         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 291   else
 292         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,Mono"'
 293   fi
 294 ])
 295
 296 dnl Use mmap in rrd_update instead of seek+write
 297 AC_ARG_ENABLE([mmap],
 298 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 299 [],
 300 [enable_mmap=yes])
 301
 302 dnl will most likely not work on compressed filesystems, i think.. *shrug*
 303 AC_ARG_ENABLE([direct-io],
 304 [  --enable-direct-io      enable O_DIRECT if available],
 305 [enable_direct_io=yes],
 306 [])
 307
 308 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 309 [],[enable_pthread=yes])
 310
 311 AC_ARG_ENABLE(static-programs,
 312      [  --enable-static-programs  Build static programs],
 313      [case "${enableval}" in
 314        yes) staticprogs=yes ;;
 315        no)  staticprogs=no ;;
 316        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 317      esac],[staticprogs=no])
 318 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 319
 320
 321 CONFIGURE_PART(Audit Compilation Environment)
 322
 323
 324 dnl Check for the compiler and static/shared library creation.
 325 AC_PROG_CC
 326 AC_PROG_CPP
 327 AC_PROG_LIBTOOL
 328
 329 dnl Try to detect/use GNU features
 330 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 331
 332 dnl which flags does the compiler support?
 333 if test "x$GCC" = "xyes"; then
 334   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W; do
 335     oCFLAGS="$CFLAGS"
 336     CFLAGS="$CFLAGS $flag"
 337     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 338     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 339        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 340     if eval test \$$cachename = no; then
 341          CFLAGS="$oCFLAGS"
 342     fi
 343   done
 344 fi
 345
 346
 347
 348 AC_SUBST(RRD_DEFAULT_FONT)
 349
 350 CONFIGURE_PART(Checking for Header Files)
 351
 352 dnl Checks for header files.
 353 AC_HEADER_STDC
 354 AC_HEADER_DIRENT
 355 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 356
 357 if test "x$enable_direct_io" = "xyes"; then
 358 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],rrd_cv_HAVE_OPEN_O_DIRECT,[
 359 AC_TRY_COMPILE([
 360 #ifdef HAVE_UNISTD_H
 361 #include <unistd.h>
 362 #endif
 363 #ifdef HAVE_FCNTL_H
 364 #include <fcntl.h>
 365 #endif],
 366 [int fd = open("/dev/null", O_DIRECT);],
 367 rrd_cv_HAVE_OPEN_O_DIRECT=yes,rrd_cv_HAVE_OPEN_O_DIRECT=no)])
 368   if test "x$rrd_cv_HAVE_OPEN_O_DIRECT" = "xyes"; then
 369     AC_DEFINE(USE_DIRECT_IO,1,[Whether the open(2) accepts O_DIRECT])
 370   else
 371     enable_direct_io="no"
 372   fi
 373 else
 374   enable_direct_io="no"
 375 fi
 376
 377 dnl Checks for typedefs, structures, and compiler characteristics.
 378 AC_C_CONST
 379 AC_HEADER_TIME
 380 AC_STRUCT_TM
 381
 382 dnl Checks for libraries.
 383 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 384
 385 dnl add pic flag in any case this makes sure all our code is relocatable
 386 eval `./libtool --config | grep pic_flag`
 387 CFLAGS="$CFLAGS $pic_flag"
 388
 389 CONFIGURE_PART(Test Library Functions)
 390
 391 dnl Checks for library functions.
 392 AC_FUNC_STRFTIME
 393 AC_FUNC_VPRINTF
 394
 395 AC_C_BIGENDIAN
 396
 397 dnl for each function found we get a definition in config.h
 398 dnl of the form HAVE_FUNCTION
 399
 400 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 401
 402 dnl Could use these to know if we need to provide a prototype
 403 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 404
 405 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 406 if test "x$enable_mmap" = "xyes"; then
 407   case "$host" in
 408   *cygwin*)
 409     # the normal mmap test does not work in cygwin
 410     AC_CHECK_FUNCS(mmap)
 411     if test "x$ac_cv_func_mmap" = "xyes"; then
 412       ac_cv_func_mmap_fixed_mapped=yes
 413     fi
 414   ;;
 415   *)
 416     AC_CHECK_HEADERS(sys/mman.h)
 417     AC_FUNC_MMAP
 418     AC_CHECK_FUNCS(mmap munmap)
 419     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 420                                      # include <sys/mman.h>
 421                                      #endif])
 422     if test "x$ac_cv_have_decl_madvise" = "xyes";
 423     then
 424       AC_CHECK_FUNCS(madvise)
 425     else
 426       AC_CHECK_FUNCS(posix_madvise)
 427       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 428         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 429       fi
 430     fi
 431   ;;
 432   esac
 433   if test "x$ac_cv_func_mmap" != "xyes";
 434   then
 435     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 436 dnl enable_mmap="no"
 437   fi
 438 fi
 439
 440 dnl use FD based I/O ?
 441 if test "x$enable_mmap" = "xno";then
 442     AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 443 #include <fcntl.h>])
 444     AC_CHECK_FUNCS(posix_fadvise)
 445 fi
 446
 447
 448 CONFIGURE_PART(IEEE Math Checks)
 449
 450
 451 dnl actual code to check if this works
 452 AC_CHECK_FUNCS(fpclassify, ,
 453   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 454     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 455 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 456       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 457
 458 AC_CHECK_FUNCS(isinf, ,
 459   [AC_MSG_CHECKING(for isinf with <math.h>)
 460     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 461 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 462       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 463
 464 dnl finite is BSD, isfinite is C99, so prefer the latter
 465 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 466 AC_TRY_RUN([
 467 #ifdef HAVE_MATH_H
 468 #include <math.h>
 469 #endif
 470 #ifdef HAVE_FLOAT_H
 471 #include <float.h>
 472 #endif
 473 int main ()
 474 {
 475 #ifdef isfinite
 476 #ifdef LDBL_MAX
 477   if (!isfinite(LDBL_MAX)) return 1;
 478 #endif
 479 #ifdef DBL_MAX
 480   if (!isfinite(DBL_MAX)) return 1;
 481 #endif
 482 #endif
 483 return 0;
 484 }],[
 485 have_broken_isfinite=no],have_broken_isfinite=yes,[
 486 case "${target}" in
 487   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 488   *) have_broken_isfinite=no ;;
 489 esac])
 490 ])
 491 if test "x$have_broken_isfinite" = "xno"; then
 492   AC_DEFINE(HAVE_ISFINITE)
 493 else
 494 AC_CHECK_FUNCS(finite,[],
 495   [AC_CHECK_FUNCS(isfinite,[],
 496       [AC_MSG_CHECKING(for isfinite with <math.h>)
 497        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 498 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 499                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 500 fi
 501
 502 AC_FULL_IEEE
 503
 504 CONFIGURE_PART(Resolve Portability Issues)
 505
 506 dnl what does realloc do if it gets called with a NULL pointer
 507
 508 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 509 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 510               int main(void){
 511               char *x = NULL;
 512               x = realloc (x,10);
 513               if (x==NULL) return 1;
 514               return 0;
 515              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 516
 517 if test x"$rd_cv_null_realloc" = xnope; then
 518 AC_DEFINE(NO_NULL_REALLOC)
 519 fi
 520
 521 AC_LANG_PUSH(C)
 522 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 523 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 524 AC_LINK_IFELSE(
 525     AC_LANG_PROGRAM(
 526            [[#include <time.h>]],
 527            [[ctime_r(NULL,NULL,0)]]
 528                    ),
 529     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 530       AC_LINK_IFELSE(
 531           AC_LANG_PROGRAM(
 532                 [[#include <time.h>]],
 533                 [[ctime_r(NULL,NULL)]]
 534                          ),
 535           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 536           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 537       )
 538     ],
 539     [ AC_LINK_IFELSE(
 540           AC_LANG_PROGRAM(
 541                 [[#include <time.h>]],
 542                 [[ctime_r(NULL,NULL)]]
 543                          ),
 544           [AC_MSG_RESULT(no)],
 545           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 546       )
 547     ]
 548 )
 549 AC_LANG_POP(C)
 550
 551 dnl Check for pthreads
 552 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 553
 554 AC_SUBST(MULTITHREAD_CFLAGS)
 555 AC_SUBST(MULTITHREAD_LDFLAGS)
 556
 557 if test $enable_pthread != no; then
 558  ACX_PTHREAD([
 559     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 560     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 561              ],
 562              [])
 563 fi
 564
 565 dnl since we use lots of *_r functions all over the code we better
 566 dnl make sure they are known
 567
 568 if test  "x$x_rflag" != "xno"; then
 569    CPPFLAGS="$CPPFLAGS $x_rflag"
 570 fi
 571
 572 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 573
 574 AC_LANG_PUSH(C)
 575 dnl see if we have to include malloc/malloc.h
 576 AC_MSG_CHECKING([do we need malloc/malloc.h])
 577 AC_LINK_IFELSE(
 578     AC_LANG_PROGRAM(
 579            [[#include <stdlib.h>]],
 580            [[malloc(1)]]
 581                    ),
 582     [ AC_MSG_RESULT([nope, works out of the box]) ],
 583     [ AC_LINK_IFELSE(
 584           AC_LANG_PROGRAM(
 585                 [[#include <stdlib.h>
 586                   #include <malloc/malloc.h>]],
 587                 [[malloc(1)]]
 588                          ),
 589           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 590            AC_MSG_RESULT([yes we do])],
 591           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 592       )
 593     ]
 594 )
 595 AC_LANG_POP(C)
 596
 597 CONFIGURE_PART(Find 3rd-Party Libraries)
 598
 599
 600 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 601
 602 CORE_LIBS="$LIBS"
 603
 604 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 605 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 606 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,                     freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 607 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,               fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 608 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 609 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 610 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 611
 612 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 613   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 614 fi
 615
 616 ALL_LIBS="$LIBS"
 617 LIBS=
 618
 619 AC_SUBST(CORE_LIBS)
 620 AC_SUBST(ALL_LIBS)
 621
 622 CONFIGURE_PART(Prep for Building Language Bindings)
 623
 624 dnl Check for Perl.
 625 AC_PATH_PROG(PERL, perl, no)
 626
 627 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 628 [],[enable_perl=yes])
 629
 630
 631 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 632 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 633 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 634 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 635
 636 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 637         COMP_PERL=
 638 else
 639         COMP_PERL="perl_piped perl_shared"
 640         AC_MSG_CHECKING(for the perl version you are running)
 641         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 642         AC_MSG_RESULT($PERL_VERSION)
 643         if test -z "$PERLCC"; then
 644             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 645             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 646             AC_MSG_RESULT($perlcc)
 647             if test ! -x "$perlcc"; then
 648                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 649                 if test "$PERL_CC" = "no"; then
 650                     AC_MSG_WARN([
 651 I would not find the Compiler ($perlcc) that was originally used to compile
 652 your perl binary. You should either make sure that this compiler is
 653 available on your system, pick an other compiler and set PERLCC
 654 appropriately, or use a different perl setup that was compiled locally.
 655
 656 I will disable the compilation of the RRDs perl module for now.
 657 ])
 658                     COMP_PERL="perl_piped"
 659                 fi
 660             fi
 661         fi
 662 fi
 663
 664 AC_MSG_CHECKING(Perl Modules to build)
 665 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 666
 667 # Options to pass when configuring perl module
 668 ppref=$prefix
 669 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 670
 671 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 672
 673 dnl pass additional perl options when generating Makefile from Makefile.PL
 674 AC_ARG_ENABLE(perl-site-install,
 675 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 676                           together with rrdtool in $prefix/lib/perl. You have to
 677                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 678                           when you want to use them. When you set this option
 679                           the perl modules will get installed wherever
 680                           your perl setup thinks it is best.],
 681 [PERL_MAKE_OPTIONS=],[])
 682
 683 if test ! -z "$PERLCC"; then
 684    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 685
 686    if test ! -z "$PERLCCFLAGS"; then
 687        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 688    fi
 689
 690    if test -z "$PERLLD"; then
 691        PERLLD=$PERLCC
 692    fi
 693    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 694
 695    if test ! -z "$PERLLDFLAGS"; then
 696        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 697    fi
 698 fi
 699
 700 AC_ARG_WITH(perl-options,
 701 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 702                           generating Makefile from Makefile.PL. If you set this
 703                           option, interesting things may happen unless you know
 704                           what you are doing!],
 705 [PERL_MAKE_OPTIONS=$withval])
 706
 707 AC_SUBST(PERL_MAKE_OPTIONS)
 708 AC_SUBST(PERL)
 709 AC_SUBST(COMP_PERL)
 710 AC_SUBST(PERL_VERSION)
 711
 712 dnl Check for Ruby.
 713 AC_PATH_PROG(RUBY, ruby, no)
 714
 715 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 716 [],[enable_ruby=yes])
 717
 718 AC_MSG_CHECKING(if ruby modules can be built)
 719
 720 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 721         COMP_RUBY=
 722         AC_MSG_RESULT(No .. Ruby not found or disabled)
 723 else
 724         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 725                 COMP_RUBY="ruby"
 726                 AC_MSG_RESULT(YES)
 727         else
 728                 COMP_RUBY=
 729                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 730         fi
 731 fi
 732
 733
 734 dnl pass additional ruby options when generating Makefile from Makefile.PL
 735 AC_ARG_ENABLE(ruby-site-install,
 736 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 737                           together with rrdtool in $prefix/lib/ruby. You have to
 738                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 739                           for ruby to find the RRD.so file.],
 740 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 741
 742
 743 AC_ARG_WITH(ruby-options,
 744 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 745                           generating Makefile from extconf.rb. If you set this
 746                           option, interesting things may happen unless you know
 747                           what you are doing!],
 748 [RUBY_MAKE_OPTIONS=$withval])
 749
 750 AC_SUBST(RUBY_MAKE_OPTIONS)
 751 AC_SUBST(RUBY)
 752 AC_SUBST(COMP_RUBY)
 753
 754
 755 enable_tcl_site=no
 756
 757 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 758 [],[enable_tcl=yes])
 759
 760 if test  "$enable_tcl" = "yes"; then
 761   dnl Check for Tcl.
 762   withval=""
 763   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 764   enable_tcl=no
 765   for dir in $withval /usr/lib /usr/local/lib; do
 766     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 767     if test -f "$dir/tclConfig.sh" ; then
 768         tcl_config=$dir/tclConfig.sh
 769         enable_tcl=yes
 770         AC_MSG_RESULT(yes)
 771         break
 772     else
 773         AC_MSG_RESULT(no)
 774     fi
 775   done
 776
 777   if test "$enable_tcl" = "no"; then
 778         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 779   else
 780         . $tcl_config
 781         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 782   fi
 783   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 784   [],[enable_tcl_site=yes])
 785
 786 fi
 787
 788 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 789 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 790
 791 AC_SUBST(TCL_PREFIX)
 792 AC_SUBST(TCL_SHLIB_CFLAGS)
 793 AC_SUBST(TCL_SHLIB_LD)
 794 AC_SUBST(TCL_SHLIB_SUFFIX)
 795 AC_SUBST(TCL_PACKAGE_PATH)
 796 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 797 AC_SUBST(TCL_STUB_LIB_SPEC)
 798 AC_SUBST(TCL_VERSION)
 799 AC_SUBST(TCL_PACKAGE_DIR)
 800
 801 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 802 [],[enable_python=yes])
 803
 804 if test  "$enable_python" = "yes"; then
 805 dnl Check for python
 806 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 807 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 808 fi
 809
 810 if test  x$enable_python = xno; then
 811         COMP_PYTHON=
 812 else
 813         COMP_PYTHON="python"
 814 fi
 815
 816 AC_SUBST(COMP_PYTHON)
 817
 818 dnl Check for nroff
 819 AC_PATH_PROGS(NROFF, gnroff nroff)
 820 AC_PATH_PROGS(TROFF, groff troff)
 821
 822 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 823 if test -z "$RRDDOCDIR"; then
 824    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 825
 826
 827 CONFIGURE_PART(Apply Configuration Information)
 828
 829 AC_CONFIG_FILES([examples/shared-demo.pl])
 830 AC_CONFIG_FILES([examples/piped-demo.pl])
 831 AC_CONFIG_FILES([examples/stripes.pl])
 832 AC_CONFIG_FILES([examples/bigtops.pl])
 833 AC_CONFIG_FILES([examples/minmax.pl])
 834 AC_CONFIG_FILES([examples/4charts.pl])
 835 AC_CONFIG_FILES([examples/perftest.pl])
 836 AC_CONFIG_FILES([examples/Makefile])
 837 AC_CONFIG_FILES([doc/Makefile])
 838 AC_CONFIG_FILES([src/Makefile])
 839 AC_CONFIG_FILES([bindings/Makefile])
 840 AC_CONFIG_FILES([bindings/tcl/Makefile])
 841 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 842 AC_CONFIG_FILES([Makefile])
 843
 844 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 845 AC_OUTPUT
 846
 847 AC_MSG_CHECKING(in)
 848 AC_MSG_RESULT(and out again)
 849
 850 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 851 sleep 1
 852 echo $ECHO_N ".$ECHO_C" 1>&6
 853 sleep 1
 854 echo $ECHO_N ".$ECHO_C" 1>&6
 855 sleep 1
 856 echo $ECHO_N ".$ECHO_C" 1>&6
 857 sleep 1
 858 echo $ECHO_N ".$ECHO_C" 1>&6
 859 sleep 1
 860 AC_MSG_RESULT([ just kidding ;-)])
 861 echo
 862 echo "----------------------------------------------------------------"
 863 echo "Config is DONE!"
 864 echo
 865 echo "          With MMAP IO: $enable_mmap"
 866 echo "          Use O_DIRECT: $enable_direct_io"
 867 echo "       Static programs: $staticprogs"
 868 echo "          Perl Modules: $COMP_PERL"
 869 echo "           Perl Binary: $PERL"
 870 echo "          Perl Version: $PERL_VERSION"
 871 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 872 echo "          Ruby Modules: $COMP_RUBY"
 873 echo "           Ruby Binary: $RUBY"
 874 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 875 echo "    Build Tcl Bindings: $enable_tcl"
 876 echo " Build Python Bindings: $enable_python"
 877 echo "          Build rrdcgi: $enable_rrdcgi"
 878 echo "       Build librrd MT: $enable_pthread"
 879 echo
 880 echo
 881 echo "Type 'make' to compile the software and use 'make install' to "
 882 echo "install everything to: $prefix."
 883 echo
 884 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 885 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 886 echo "place an order."
 887 echo
 888 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 889 echo "----------------------------------------------------------------"