configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.3.999])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.3999
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=5:0:1
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include <rrd_config_bottom.h>
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 dnl Check if we run on a system that has fonts
 106 AC_ARG_WITH(rrd-default-font,
 107 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 108 [RRD_DEFAULT_FONT=$withval],[
 109   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 110         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 111   else
 112         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 113   fi
 114 ])
 115
 116 dnl Use mmap in rrd_update instead of seek+write
 117 AC_ARG_ENABLE([mmap],
 118 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 119 [],
 120 [enable_mmap=yes])
 121
 122 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 123 [],[enable_pthread=yes])
 124
 125 AC_ARG_ENABLE(static-programs,
 126      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 127      [case "${enableval}" in
 128        yes) staticprogs=yes ;;
 129        no)  staticprogs=no ;;
 130        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 131      esac],[staticprogs=no])
 132 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 133
 134
 135 CONFIGURE_PART(Audit Compilation Environment)
 136
 137
 138 dnl Check for the compiler and static/shared library creation.
 139 AC_PROG_CPP
 140 AC_PROG_CC
 141 AM_PROG_CC_C_O
 142 AC_PROG_LIBTOOL
 143
 144 dnl Try to detect/use GNU features
 145 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 146
 147 dnl check for -Werror separatly
 148 dnl (quite a few autotool checks do not work with -Werror; also, the
 149 dnl check for -Werror fails after checking and adding the other flags)
 150 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 151   [AC_COMPILE_IFELSE(
 152     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 153     [rd_cv_gcc_flag__Werror="yes"],
 154     [rd_cv_gcc_flag__Werror="no"])])
 155 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 156   WERROR="-Werror"
 157 else
 158   WERROR=""
 159 fi
 160 AC_SUBST(WERROR)
 161
 162 dnl which flags does the compiler support?
 163 if test "x$GCC" = "xyes"; then
 164   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 165     oCFLAGS="$CFLAGS"
 166     CFLAGS="$CFLAGS $flag"
 167     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 168     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 169        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 170     if eval test \$$cachename = no; then
 171          CFLAGS="$oCFLAGS"
 172     fi
 173   done
 174 fi
 175
 176
 177
 178 AC_SUBST(RRD_DEFAULT_FONT)
 179
 180 CONFIGURE_PART(Checking for Header Files)
 181
 182 dnl Checks for header files.
 183 AC_HEADER_STDC
 184 AC_HEADER_DIRENT
 185 AC_CHECK_HEADERS(stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 186
 187 dnl Checks for typedefs, structures, and compiler characteristics.
 188 AC_C_CONST
 189 AC_HEADER_TIME
 190 AC_STRUCT_TM
 191
 192 CONFIGURE_PART(Test Library Functions)
 193
 194 dnl Checks for libraries.
 195 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 196
 197
 198 dnl add pic flag in any case this makes sure all our code is relocatable
 199 eval `./libtool --config | grep pic_flag`
 200 CFLAGS="$CFLAGS $pic_flag"
 201
 202
 203 dnl Checks for library functions.
 204 AC_FUNC_STRFTIME
 205 AC_FUNC_VPRINTF
 206
 207 AC_C_BIGENDIAN
 208
 209 dnl for each function found we get a definition in config.h
 210 dnl of the form HAVE_FUNCTION
 211
 212 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 213
 214 AC_FUNC_STRERROR_R
 215
 216 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 217
 218 dnl Could use these to know if we need to provide a prototype
 219 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 220
 221 dnl check for fdatasync. Solaris has fdatasync in the librt
 222
 223 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 224 dnl if there is no fdatasync we may get lucky with fsync
 225 AC_CHECK_FUNCS(fsync)
 226
 227
 228 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 229 if test "x$enable_mmap" = "xyes"; then
 230   case "$host" in
 231   *cygwin*)
 232     # the normal mmap test does not work in cygwin
 233     AC_CHECK_FUNCS(mmap)
 234     if test "x$ac_cv_func_mmap" = "xyes"; then
 235       ac_cv_func_mmap_fixed_mapped=yes
 236     fi
 237   ;;
 238   *)
 239     AC_CHECK_HEADERS(sys/mman.h)
 240     AC_FUNC_MMAP
 241     AC_CHECK_FUNCS(mmap munmap msync)
 242     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 243                                      # include <sys/mman.h>
 244                                      #endif])
 245     if test "x$ac_cv_have_decl_madvise" = "xyes";
 246     then
 247       AC_CHECK_FUNCS(madvise)
 248     else
 249       AC_CHECK_FUNCS(posix_madvise)
 250       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 251         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 252       fi
 253     fi
 254   ;;
 255   esac
 256   if test "x$ac_cv_func_mmap" != "xyes";
 257   then
 258     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 259 dnl enable_mmap="no"
 260   fi
 261 fi
 262
 263 dnl can we use posix_fadvise
 264 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 265 #include <fcntl.h>])
 266 AC_CHECK_FUNCS(posix_fadvise)
 267
 268 CONFIGURE_PART(Libintl Processing)
 269
 270 AM_GNU_GETTEXT_VERSION(0.14.4)
 271 AM_GNU_GETTEXT()
 272
 273 CONFIGURE_PART(IEEE Math Checks)
 274
 275
 276 dnl actual code to check if this works
 277 AC_CHECK_FUNCS(fpclassify, ,
 278   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 279     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 280 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 281       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 282
 283 AC_CHECK_FUNCS(isinf, ,
 284   [AC_MSG_CHECKING(for isinf with <math.h>)
 285     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 286 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 287       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 288
 289 dnl finite is BSD, isfinite is C99, so prefer the latter
 290 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 291 AC_TRY_RUN([
 292 #ifdef HAVE_MATH_H
 293 #include <math.h>
 294 #endif
 295 #ifdef HAVE_FLOAT_H
 296 #include <float.h>
 297 #endif
 298 int main ()
 299 {
 300 #ifdef isfinite
 301 #ifdef LDBL_MAX
 302   if (!isfinite(LDBL_MAX)) return 1;
 303 #endif
 304 #ifdef DBL_MAX
 305   if (!isfinite(DBL_MAX)) return 1;
 306 #endif
 307 #endif
 308 return 0;
 309 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 310 case "${target}" in
 311   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 312   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 313   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 314   *) ac_cv_have_broken_isfinite=no ;;
 315 esac])
 316 ])
 317
 318 dnl the test does not seem to work on solaris 2.8
 319 dnl so lets fix this by hand
 320 case "${target}" in
 321   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 322   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 323 esac
 324
 325 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 326   AC_DEFINE(HAVE_ISFINITE)
 327 else
 328   AC_CHECK_FUNCS(finite,[],
 329       [AC_CHECK_FUNCS(isfinite,[],
 330          [AC_MSG_CHECKING(for isfinite with <math.h>)
 331           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 332 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 333                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 334 fi
 335
 336 AC_FULL_IEEE
 337
 338 CONFIGURE_PART(Resolve Portability Issues)
 339
 340 CHECK_FOR_WORKING_MS_ASYNC
 341
 342 dnl Do we need getopt_long
 343
 344 dnl even when including our own getopt implementation
 345 dnl we may want to make sure we use the external
 346 dnl defined by libc to not run into linker resolve trouble
 347
 348 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 349 [AC_TRY_LINK([#include <unistd.h>],
 350   [extern int opterr; opterr = 1;],
 351   [rd_cv_var_int_opterr=yes],
 352   [rd_cv_var_int_opterr=no])])
 353 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 354   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 355 fi
 356
 357 build_getopt=no
 358 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 359 AC_CHECK_FUNC(getopt_long,[],[
 360 RRD_GETOPT_LONG="getopt_long"
 361 build_getopt=yes
 362 ])
 363 AC_SUBST(RRD_GETOPT_LONG)
 364 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 365
 366 dnl what does realloc do if it gets called with a NULL pointer
 367
 368 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 369 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 370               int main(void){
 371               char *x = NULL;
 372               x = realloc (x,10);
 373               if (x==NULL) return 1;
 374               return 0;
 375              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 376
 377 if test x"$rd_cv_null_realloc" = xnope; then
 378 AC_DEFINE(NO_NULL_REALLOC)
 379 fi
 380
 381 AC_LANG_PUSH(C)
 382 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 383 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 384 AC_LINK_IFELSE(
 385     AC_LANG_PROGRAM(
 386            [[#include <time.h>]],
 387            [[ctime_r(NULL,NULL,0)]]
 388                    ),
 389     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 390       AC_LINK_IFELSE(
 391           AC_LANG_PROGRAM(
 392                 [[#include <time.h>]],
 393                 [[ctime_r(NULL,NULL)]]
 394                          ),
 395           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 396           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 397       )
 398     ],
 399     [ AC_LINK_IFELSE(
 400           AC_LANG_PROGRAM(
 401                 [[#include <time.h>]],
 402                 [[ctime_r(NULL,NULL)]]
 403                          ),
 404           [AC_MSG_RESULT(no)],
 405           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 406       )
 407     ]
 408 )
 409 AC_LANG_POP(C)
 410
 411 dnl Check for pthreads
 412 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 413
 414 AC_SUBST(MULTITHREAD_CFLAGS)
 415 AC_SUBST(MULTITHREAD_LDFLAGS)
 416
 417 if test $enable_pthread != no; then
 418  ACX_PTHREAD([
 419     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 420     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 421              ],
 422              [])
 423 fi
 424
 425 dnl since we use lots of *_r functions all over the code we better
 426 dnl make sure they are known
 427
 428 if test  "x$x_rflag" != "xno"; then
 429    CPPFLAGS="$CPPFLAGS $x_rflag"
 430 fi
 431
 432 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 433
 434 AC_LANG_PUSH(C)
 435 dnl see if we have to include malloc/malloc.h
 436 AC_MSG_CHECKING([do we need malloc/malloc.h])
 437 AC_LINK_IFELSE(
 438     AC_LANG_PROGRAM(
 439            [[#include <stdlib.h>]],
 440            [[malloc(1)]]
 441                    ),
 442     [ AC_MSG_RESULT([nope, works out of the box]) ],
 443     [ AC_LINK_IFELSE(
 444           AC_LANG_PROGRAM(
 445                 [[#include <stdlib.h>
 446                   #include <malloc/malloc.h>]],
 447                 [[malloc(1)]]
 448                          ),[
 449            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 450            AC_MSG_RESULT([yes we do])],
 451           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 452       )
 453     ]
 454 )
 455
 456 dnl is time_t long or long long ?
 457 AC_DEFINE([TIME_T_IS_LONG], [], [time_t is long])
 458 AC_DEFINE([TIME_T_IS_LONG_LONG], [], [time_t is long long])
 459 AC_MSG_CHECKING([the type of time_t])
 460 AC_RUN_IFELSE(
 461     AC_LANG_PROGRAM(
 462         [[#include <time.h>]],
 463         [[if (sizeof(long) != sizeof(time_t)) return 1; ]]
 464         ),
 465     [ AC_MSG_RESULT([time_t is long])
 466       AC_DEFINE([TIME_T_IS_LONG])
 467     ],
 468     [ AC_RUN_IFELSE(
 469         AC_LANG_PROGRAM(
 470         [[#include <time.h>]],
 471         [[if (sizeof(long long) != sizeof(time_t)) return 1; ]]
 472         ),
 473         [
 474           AC_MSG_RESULT([time_t is long long])
 475           AC_DEFINE([TIME_T_IS_LONG_LONG])
 476         ],
 477         [AC_MSG_ERROR([can not figure type of time_t])]
 478       )
 479     ]
 480 )
 481
 482 AC_LANG_POP(C)
 483
 484 CONFIGURE_PART(Find 3rd-Party Libraries)
 485
 486 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
 487   XXX=$LIBS
 488   LIBS="$LIBS -ldbi -ldl"
 489   AC_MSG_CHECKING(for libdbi)
 490   AC_LINK_IFELSE(
 491     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 492                      [[dbi_initialize(NULL)]]
 493                     )
 494     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 495        AC_MSG_RESULT([yes])
 496        have_libdbi=yes
 497     ],[LIBS=$XXX
 498        AC_MSG_RESULT([no])
 499        have_libdbi=no
 500     ]
 501   )
 502 ])
 503 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 504
 505 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 506
 507
 508 CORE_LIBS="$LIBS"
 509
 510 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 511 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 512 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 513 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 514 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 515 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 516 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 517 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 518 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 519 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 520 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 521
 522 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 523   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 524 fi
 525
 526 ALL_LIBS="$LIBS"
 527 LIBS=
 528
 529 AC_SUBST(CORE_LIBS)
 530 AC_SUBST(ALL_LIBS)
 531
 532 CONFIGURE_PART(Prep for Building Language Bindings)
 533
 534 dnl Check for Perl and friends
 535 PATH=$PATH:/usr/perl5/bin
 536 export PATH
 537 AC_PATH_PROG(PERL, perl, no)
 538 AC_PATH_PROG(POD2MAN, pod2man, no)
 539 AC_PATH_PROG(POD2HTML, pod2html, no)
 540
 541
 542 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 543 [],[enable_perl=yes])
 544
 545
 546 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 547 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 548 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 549 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 550
 551 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 552         COMP_PERL=
 553 else
 554         COMP_PERL="perl_piped perl_shared"
 555         AC_MSG_CHECKING(for the perl version you are running)
 556         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 557         AC_MSG_RESULT($PERL_VERSION)
 558         if test -z "$PERLCC"; then
 559             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 560             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 561             AC_MSG_RESULT($perlcc)
 562             if test ! -x "$perlcc"; then
 563                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 564                 if test "$PERL_CC" = "no"; then
 565                     AC_MSG_WARN([
 566 I would not find the Compiler ($perlcc) that was originally used to compile
 567 your perl binary. You should either make sure that this compiler is
 568 available on your system, pick an other compiler and set PERLCC
 569 appropriately, or use a different perl setup that was compiled locally.
 570
 571 I will disable the compilation of the RRDs perl module for now.
 572 ])
 573                     COMP_PERL="perl_piped"
 574                 fi
 575             fi
 576         fi
 577 fi
 578
 579 AC_MSG_CHECKING(Perl Modules to build)
 580 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 581
 582 # Options to pass when configuring perl module
 583 langpref=$prefix
 584 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 585 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 586
 587 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 588
 589 dnl pass additional perl options when generating Makefile from Makefile.PL
 590 AC_ARG_ENABLE(perl-site-install,
 591 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 592 [PERL_MAKE_OPTIONS=],[])
 593
 594 if test ! -z "$PERLCC"; then
 595    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 596
 597    if test ! -z "$PERLCCFLAGS"; then
 598        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 599    fi
 600
 601    if test -z "$PERLLD"; then
 602        PERLLD=$PERLCC
 603    fi
 604    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 605
 606    if test ! -z "$PERLLDFLAGS"; then
 607        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 608    fi
 609 fi
 610
 611 AC_ARG_WITH(perl-options,
 612 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 613                           generating Makefile from Makefile.PL. If you set this
 614                           option, interesting things may happen unless you know
 615                           what you are doing!],
 616 [PERL_MAKE_OPTIONS=$withval])
 617
 618 AC_SUBST(PERL_MAKE_OPTIONS)
 619 AC_SUBST(PERL)
 620 AC_SUBST(COMP_PERL)
 621 AC_SUBST(PERL_VERSION)
 622
 623 dnl Check for Ruby.
 624 AC_PATH_PROG(RUBY, ruby, no)
 625
 626 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 627 [],[enable_ruby=yes])
 628
 629 AC_MSG_CHECKING(if ruby modules can be built)
 630
 631 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 632         COMP_RUBY=
 633         AC_MSG_RESULT(No .. Ruby not found or disabled)
 634 else
 635         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 636                 COMP_RUBY="ruby"
 637                 AC_MSG_RESULT(YES)
 638         else
 639                 COMP_RUBY=
 640                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 641         fi
 642 fi
 643
 644 dnl pass additional ruby options when generating Makefile from Makefile.PL
 645 AC_ARG_ENABLE(ruby-site-install,
 646 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 647 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 648
 649
 650 AC_ARG_WITH(ruby-options,
 651 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 652                           generating Makefile from extconf.rb. If you set this
 653                           option, interesting things may happen unless you know
 654                           what you are doing!],
 655 [RUBY_MAKE_OPTIONS=$withval])
 656
 657 AC_SUBST(RUBY_MAKE_OPTIONS)
 658 AC_SUBST(RUBY)
 659 AC_SUBST(COMP_RUBY)
 660
 661 dnl Check for Lua.
 662 AC_PATH_PROG(LUA, lua, no)
 663
 664 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 665 [],[enable_lua=yes])
 666
 667 COMP_LUA=
 668 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 669   enable_lua=no
 670 else
 671   AC_MSG_CHECKING(for lua >= 5.0)
 672   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 673     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 674 LUA_EOF
 675   if test 0$LUA_MAJOR -lt 5; then
 676     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 677   else
 678     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 679     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 680     lua_vndot=$LUA_MAJOR$LUA_MINOR
 681     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 682     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 683       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 684         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 685           [lua_headerdir=lua$lua_vndot],
 686           [])],
 687         [])],
 688       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 689         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 690           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 691             [lua_headerdir=lua$lua_vdot],
 692             [])],
 693           [])],
 694         [AC_CHECK_HEADERS(lua.h,
 695           [AC_CHECK_HEADERS(lualib.h,
 696             [AC_CHECK_HEADER(lauxlib.h,
 697               [lua_headerdir=""],
 698               [lua_headerdir="no"])],
 699             [])],
 700           [])])])
 701
 702     if test "$lua_headerdir" = "no"; then
 703       enable_lua=no
 704     else
 705       COMP_LUA=lua
 706     fi
 707
 708     if test "$COMP_LUA" != "lua"; then
 709       enable_lua=no
 710       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 711     else
 712       # OK, headers found, let's check the libraries (LIBS is not used)
 713       LIBS=
 714       lua_havelib=no
 715       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 716       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 717         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 718           [lua_havelib=LUA$lua_vndot],
 719           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 720             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 721              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 722             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 723               [lua_havelib=$lua_vndot],
 724               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 725         [COMP_LUA=], [-lm])
 726       lua_libs=$LIBS
 727       LIBS=
 728
 729       # Options to pass when configuring Lua module
 730       if test  "$lua_havelib" != "no"; then
 731         # OK, headers and libs found. Try to set lua flags
 732         # and modules installation dirs with pkg-config
 733         if test "$PKGCONFIG" != "no"; then
 734           if test "$lua_vndot" = "50"; then
 735             lua_pkg_prefix=lualib
 736           else
 737             lua_pkg_prefix=lua
 738           fi
 739           # try with dot, without dot and finally without version
 740           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 741             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 742             # same binaries?
 743             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 744                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 745                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 746                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 747                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 748                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 749                 break
 750             fi
 751           done
 752         fi
 753
 754         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 755         # if lua 5.0 can't find compat-5.1, force installation of
 756         # compat-5.1.lua together with RRDtool.
 757         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 758           lua_need_compat51=1
 759           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 760         fi
 761
 762         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 763         if test "$LUA_CFLAGS" = ""; then
 764           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 765           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 766           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 767           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 768         fi
 769
 770         dnl pass additional lua options
 771         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 772         dnl found and install together with RRDtool, under $langpref.
 773         AC_ARG_ENABLE(lua-site-install,
 774         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 775         [],
 776         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 777
 778         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 779         AC_SUBST(LUA)
 780         AC_SUBST(COMP_LUA)
 781         AC_SUBST(LUA_INSTALL_CMOD)
 782         AC_SUBST(LUA_INSTALL_LMOD)
 783         AC_SUBST(LUA_CFLAGS)
 784         AC_SUBST(LUA_LFLAGS)
 785         AC_SUBST(LUA_DEFINES)
 786       else
 787         enable_lua=no
 788         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 789       fi
 790     fi
 791   fi
 792 fi
 793 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 794 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 795 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 796       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 797 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 798 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 799 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 800 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 801
 802 enable_tcl_site=no
 803
 804 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 805 [],[enable_tcl=yes])
 806
 807 if test  "$enable_tcl" = "yes"; then
 808   dnl Check for Tcl.
 809   withval=""
 810   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 811   enable_tcl=no
 812   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 813     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 814     if test -f "$dir/tclConfig.sh" ; then
 815         tcl_config=$dir/tclConfig.sh
 816         enable_tcl=yes
 817         AC_MSG_RESULT(yes)
 818         break
 819     else
 820         AC_MSG_RESULT(no)
 821     fi
 822   done
 823
 824   if test "$enable_tcl" = "no"; then
 825         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 826   else
 827         . $tcl_config
 828         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 829         if test -n "$TCL_INC_DIR"; then
 830           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 831         fi
 832   fi
 833   AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 834   [],[enable_tcl_site=yes])
 835
 836 fi
 837
 838 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 839 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 840
 841
 842 AC_SUBST(TCL_PREFIX)
 843 AC_SUBST(TCL_SHLIB_CFLAGS)
 844 AC_SUBST(TCL_SHLIB_LD)
 845 AC_SUBST(TCL_SHLIB_SUFFIX)
 846 AC_SUBST(TCL_PACKAGE_PATH)
 847 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 848 AC_SUBST(TCL_STUB_LIB_SPEC)
 849 AC_SUBST(TCL_VERSION)
 850 AC_SUBST(TCL_PACKAGE_DIR)
 851 AC_SUBST(TCL_INCLUDE_SPEC)
 852
 853 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 854 [],[enable_python=yes])
 855
 856 if test  "$enable_python" = "yes"; then
 857 dnl Check for python
 858 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 859 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 860 fi
 861
 862 if test  x$enable_python = xno; then
 863         COMP_PYTHON=
 864 else
 865         COMP_PYTHON="python"
 866 fi
 867
 868 AC_SUBST(COMP_PYTHON)
 869
 870 dnl Check for nroff
 871 AC_PATH_PROGS(NROFF, gnroff nroff)
 872 AC_PATH_PROGS(TROFF, groff troff)
 873
 874 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 875 if test -z "$RRDDOCDIR"; then
 876    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 877
 878
 879 CONFIGURE_PART(Apply Configuration Information)
 880
 881 AC_CONFIG_FILES([examples/shared-demo.pl])
 882 AC_CONFIG_FILES([examples/piped-demo.pl])
 883 AC_CONFIG_FILES([examples/stripes.pl])
 884 AC_CONFIG_FILES([examples/bigtops.pl])
 885 AC_CONFIG_FILES([examples/minmax.pl])
 886 AC_CONFIG_FILES([examples/4charts.pl])
 887 AC_CONFIG_FILES([examples/perftest.pl])
 888 AC_CONFIG_FILES([examples/Makefile])
 889 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 890 AC_CONFIG_FILES([doc/Makefile])
 891 AC_CONFIG_FILES([po/Makefile.in])
 892 AC_CONFIG_FILES([intl/Makefile])
 893 AC_CONFIG_FILES([src/Makefile])
 894 AC_CONFIG_FILES([src/librrd.sym.in])
 895 AC_CONFIG_FILES([src/librrd.pc])
 896 AC_CONFIG_FILES([bindings/Makefile])
 897 AC_CONFIG_FILES([bindings/tcl/Makefile])
 898 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 899 AC_CONFIG_FILES([Makefile])
 900 AC_CONFIG_FILES([bindings/lua/Makefile])
 901
 902 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 903
 904 dnl intl requires our config to be called config.h. indulge it.
 905 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 906
 907 AC_OUTPUT
 908
 909 AC_MSG_CHECKING(in)
 910 AC_MSG_RESULT(and out again)
 911
 912 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 913 sleep 1
 914 echo $ECHO_N ".$ECHO_C" 1>&6
 915 sleep 1
 916 echo $ECHO_N ".$ECHO_C" 1>&6
 917 sleep 1
 918 echo $ECHO_N ".$ECHO_C" 1>&6
 919 sleep 1
 920 echo $ECHO_N ".$ECHO_C" 1>&6
 921 sleep 1
 922 AC_MSG_RESULT([ just kidding ;-)])
 923 echo
 924 echo "----------------------------------------------------------------"
 925 echo "Config is DONE!"
 926 echo
 927 echo "          With MMAP IO: $enable_mmap"
 928 echo "      Build rrd_getopt: $build_getopt"
 929 echo "       Static programs: $staticprogs"
 930 echo "          Perl Modules: $COMP_PERL"
 931 echo "           Perl Binary: $PERL"
 932 echo "          Perl Version: $PERL_VERSION"
 933 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 934 echo "          Ruby Modules: $COMP_RUBY"
 935 echo "           Ruby Binary: $RUBY"
 936 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 937 echo "    Build Lua Bindings: $enable_lua"
 938 if test "$enable_lua" = "yes"; then
 939 echo "            Lua Binary: $LUA"
 940 echo "           Lua Version: $lua_version"
 941 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 942 if test "$lua_need_compat51" = "1"; then
 943 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 944 fi
 945 fi
 946 echo "    Build Tcl Bindings: $enable_tcl"
 947 echo " Build Python Bindings: $enable_python"
 948 echo "          Build rrdcgi: $enable_rrdcgi"
 949 echo "       Build librrd MT: $enable_pthread"
 950 echo "           Use gettext: $USE_NLS"
 951 echo "           With libDBI: $have_libdbi"
 952 echo
 953 echo "             Libraries: $ALL_LIBS"
 954 echo
 955 echo "Type 'make' to compile the software and use 'make install' to "
 956 echo "install everything to: $prefix."
 957 echo
 958 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 959 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 960 echo "place an order."
 961 echo
 962 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 963 echo "----------------------------------------------------------------"