configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.3.999])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.3999
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=5:0:1
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE(m4_version_prereq(2.63, [silent-rules], [[]]))
  40 AM_MAINTAINER_MODE
  41 m4_version_prereq(2.63, [AM_SILENT_RULES([yes])], [#])
  42 AC_CONFIG_HEADERS([rrd_config.h])
  43 AC_CONFIG_MACRO_DIR([m4])
  44
  45 dnl all our local stuff like install scripts and include files
  46 dnl is in there
  47
  48
  49 dnl determine the type of system we are running on
  50
  51 AC_SUBST(VERSION)
  52
  53 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  54
  55 dnl At the TOP of the HEADER
  56
  57 AH_TOP([
  58 #ifndef RRD_CONFIG_H
  59 #define RRD_CONFIG_H
  60
  61 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  62 #undef MUST_DISABLE_FPMASK
  63
  64 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  65 #undef MUST_DISABLE_SIGFPE
  66
  67 /* realloc does not support NULL as argument */
  68 #undef NO_NULL_REALLOC
  69
  70 /* lets enable madvise defines in NetBSD */
  71 #if defined(__NetBSD__)
  72 # if !defined(_NETBSD_SOURCE)
  73 #  define _NETBSD_SOURCE
  74 # endif
  75 #endif
  76
  77 ])
  78
  79 AH_BOTTOM([
  80
  81 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  82 #  include <malloc/malloc.h>
  83 #endif
  84
  85 #include <rrd_config_bottom.h>
  86
  87 #endif
  88 ])
  89
  90 dnl Process Special Options
  91 dnl -----------------------------------
  92
  93 dnl How the vertical axis label is printed
  94 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  95  [Vertical label angle: -90.0 (default) or 90.0])
  96 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
  97  [Vertical label angle: -90.0 (default) or 90.0])
  98
  99 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 100 [],[enable_rrdcgi=yes])
 101
 102 dnl Check if we run on a system that has fonts
 103 AC_ARG_WITH(rrd-default-font,
 104 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 105 [RRD_DEFAULT_FONT=$withval],[
 106   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 107         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 108   else
 109         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 110   fi
 111 ])
 112
 113 dnl Use mmap in rrd_update instead of seek+write
 114 AC_ARG_ENABLE([mmap],
 115 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 116 [],
 117 [enable_mmap=yes])
 118
 119 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 120 [],[enable_pthread=yes])
 121
 122 AC_ARG_ENABLE(static-programs,
 123      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 124      [case "${enableval}" in
 125        yes) staticprogs=yes ;;
 126        no)  staticprogs=no ;;
 127        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 128      esac],[staticprogs=no])
 129 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 130
 131
 132 CONFIGURE_PART(Audit Compilation Environment)
 133
 134
 135 dnl Check for the compiler and static/shared library creation.
 136 AC_PROG_CPP
 137 AC_PROG_CC
 138 AM_PROG_CC_C_O
 139 AC_PROG_LIBTOOL
 140
 141 dnl Try to detect/use GNU features
 142 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 143
 144 dnl check for -Werror separatly
 145 dnl (quite a few autotool checks do not work with -Werror; also, the
 146 dnl check for -Werror fails after checking and adding the other flags)
 147 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 148   [AC_COMPILE_IFELSE(
 149     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 150     [rd_cv_gcc_flag__Werror="yes"],
 151     [rd_cv_gcc_flag__Werror="no"])])
 152 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 153   WERROR="-Werror"
 154 else
 155   WERROR=""
 156 fi
 157 AC_SUBST(WERROR)
 158
 159 dnl which flags does the compiler support?
 160 if test "x$GCC" = "xyes"; then
 161   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 162     oCFLAGS="$CFLAGS"
 163     CFLAGS="$CFLAGS $flag"
 164     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 165     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 166        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 167     if eval test \$$cachename = no; then
 168          CFLAGS="$oCFLAGS"
 169     fi
 170   done
 171 fi
 172
 173
 174
 175 AC_SUBST(RRD_DEFAULT_FONT)
 176
 177 CONFIGURE_PART(Checking for Header Files)
 178
 179 dnl Checks for header files.
 180 AC_HEADER_STDC
 181 AC_HEADER_DIRENT
 182 AC_CHECK_HEADERS(libgen.h features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 183
 184 dnl Checks for typedefs, structures, and compiler characteristics.
 185 AC_C_CONST
 186 AC_HEADER_TIME
 187 AC_STRUCT_TM
 188
 189 CONFIGURE_PART(Test Library Functions)
 190
 191 dnl Checks for libraries.
 192 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 193
 194
 195 dnl add pic flag in any case this makes sure all our code is relocatable
 196 eval `./libtool --config | grep pic_flag`
 197 CFLAGS="$CFLAGS $pic_flag"
 198
 199
 200 dnl Checks for library functions.
 201 AC_FUNC_STRFTIME
 202 AC_FUNC_VPRINTF
 203
 204 AC_C_BIGENDIAN
 205
 206 dnl for each function found we get a definition in config.h
 207 dnl of the form HAVE_FUNCTION
 208
 209 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 210
 211 AC_FUNC_STRERROR_R
 212
 213 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 214
 215 dnl Could use these to know if we need to provide a prototype
 216 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 217
 218 dnl check for fdatasync. Solaris has fdatasync in the librt
 219
 220 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 221 dnl if there is no fdatasync we may get lucky with fsync
 222 AC_CHECK_FUNCS(fsync)
 223
 224
 225 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 226 if test "x$enable_mmap" = "xyes"; then
 227   case "$host" in
 228   *cygwin*)
 229     # the normal mmap test does not work in cygwin
 230     AC_CHECK_FUNCS(mmap)
 231     if test "x$ac_cv_func_mmap" = "xyes"; then
 232       ac_cv_func_mmap_fixed_mapped=yes
 233     fi
 234   ;;
 235   *)
 236     AC_CHECK_HEADERS(sys/mman.h)
 237     AC_FUNC_MMAP
 238     AC_CHECK_FUNCS(mmap munmap msync)
 239     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 240                                      # include <sys/mman.h>
 241                                      #endif])
 242     if test "x$ac_cv_have_decl_madvise" = "xyes";
 243     then
 244       AC_CHECK_FUNCS(madvise)
 245     else
 246       AC_CHECK_FUNCS(posix_madvise)
 247       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 248         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 249       fi
 250     fi
 251   ;;
 252   esac
 253   if test "x$ac_cv_func_mmap" != "xyes";
 254   then
 255     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 256 dnl enable_mmap="no"
 257   fi
 258 fi
 259
 260 dnl can we use posix_fadvise
 261 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 262 #include <fcntl.h>])
 263 AC_CHECK_FUNCS(posix_fadvise)
 264
 265 CONFIGURE_PART(Libintl Processing)
 266
 267 AM_GNU_GETTEXT_VERSION(0.14.4)
 268 AM_GNU_GETTEXT()
 269
 270 CONFIGURE_PART(IEEE Math Checks)
 271
 272
 273 dnl actual code to check if this works
 274 AC_CHECK_FUNCS(fpclassify, ,
 275   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 276     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 277 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 278       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 279
 280 AC_CHECK_FUNCS(isinf, ,
 281   [AC_MSG_CHECKING(for isinf with <math.h>)
 282     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 283 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 284       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 285
 286 dnl finite is BSD, isfinite is C99, so prefer the latter
 287 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 288 AC_TRY_RUN([
 289 #ifdef HAVE_MATH_H
 290 #include <math.h>
 291 #endif
 292 #ifdef HAVE_FLOAT_H
 293 #include <float.h>
 294 #endif
 295 int main ()
 296 {
 297 #ifdef isfinite
 298 #ifdef LDBL_MAX
 299   if (!isfinite(LDBL_MAX)) return 1;
 300 #endif
 301 #ifdef DBL_MAX
 302   if (!isfinite(DBL_MAX)) return 1;
 303 #endif
 304 #endif
 305 return 0;
 306 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 307 case "${target}" in
 308   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 309   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 310   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 311   *) ac_cv_have_broken_isfinite=no ;;
 312 esac])
 313 ])
 314
 315 dnl the test does not seem to work on solaris 2.8
 316 dnl so lets fix this by hand
 317 case "${target}" in
 318   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 319   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 320 esac
 321
 322 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 323   AC_DEFINE(HAVE_ISFINITE)
 324 else
 325   AC_CHECK_FUNCS(finite,[],
 326       [AC_CHECK_FUNCS(isfinite,[],
 327          [AC_MSG_CHECKING(for isfinite with <math.h>)
 328           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 329 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 330                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 331 fi
 332
 333 AC_FULL_IEEE
 334
 335 CONFIGURE_PART(Resolve Portability Issues)
 336
 337 CHECK_FOR_WORKING_MS_ASYNC
 338
 339 dnl Do we need getopt_long
 340
 341 dnl even when including our own getopt implementation
 342 dnl we may want to make sure we use the external
 343 dnl defined by libc to not run into linker resolve trouble
 344
 345 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 346 [AC_TRY_LINK([#include <unistd.h>],
 347   [extern int opterr; opterr = 1;],
 348   [rd_cv_var_int_opterr=yes],
 349   [rd_cv_var_int_opterr=no])])
 350 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 351   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 352 fi
 353
 354 build_getopt=no
 355 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 356 AC_CHECK_FUNC(getopt_long,[],[
 357 RRD_GETOPT_LONG="getopt_long"
 358 build_getopt=yes
 359 ])
 360 AC_SUBST(RRD_GETOPT_LONG)
 361 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 362
 363 dnl what does realloc do if it gets called with a NULL pointer
 364
 365 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 366 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 367               int main(void){
 368               char *x = NULL;
 369               x = realloc (x,10);
 370               if (x==NULL) return 1;
 371               return 0;
 372              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 373
 374 if test x"$rd_cv_null_realloc" = xnope; then
 375 AC_DEFINE(NO_NULL_REALLOC)
 376 fi
 377
 378 AC_LANG_PUSH(C)
 379 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 380 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 381 AC_LINK_IFELSE(
 382     AC_LANG_PROGRAM(
 383            [[#include <time.h>]],
 384            [[ctime_r(NULL,NULL,0)]]
 385                    ),
 386     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 387       AC_LINK_IFELSE(
 388           AC_LANG_PROGRAM(
 389                 [[#include <time.h>]],
 390                 [[ctime_r(NULL,NULL)]]
 391                          ),
 392           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 393           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 394       )
 395     ],
 396     [ AC_LINK_IFELSE(
 397           AC_LANG_PROGRAM(
 398                 [[#include <time.h>]],
 399                 [[ctime_r(NULL,NULL)]]
 400                          ),
 401           [AC_MSG_RESULT(no)],
 402           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 403       )
 404     ]
 405 )
 406 AC_LANG_POP(C)
 407
 408 dnl Check for pthreads
 409 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 410
 411 AC_SUBST(MULTITHREAD_CFLAGS)
 412 AC_SUBST(MULTITHREAD_LDFLAGS)
 413
 414 if test $enable_pthread != no; then
 415  ACX_PTHREAD([
 416     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 417     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 418              ],
 419              [])
 420 fi
 421
 422 dnl since we use lots of *_r functions all over the code we better
 423 dnl make sure they are known
 424
 425 if test  "x$x_rflag" != "xno"; then
 426    CPPFLAGS="$CPPFLAGS $x_rflag"
 427 fi
 428
 429 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 430
 431 AC_LANG_PUSH(C)
 432 dnl see if we have to include malloc/malloc.h
 433 AC_MSG_CHECKING([do we need malloc/malloc.h])
 434 AC_LINK_IFELSE(
 435     AC_LANG_PROGRAM(
 436            [[#include <stdlib.h>]],
 437            [[malloc(1)]]
 438                    ),
 439     [ AC_MSG_RESULT([nope, works out of the box]) ],
 440     [ AC_LINK_IFELSE(
 441           AC_LANG_PROGRAM(
 442                 [[#include <stdlib.h>
 443                   #include <malloc/malloc.h>]],
 444                 [[malloc(1)]]
 445                          ),[
 446            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 447            AC_MSG_RESULT([yes we do])],
 448           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 449       )
 450     ]
 451 )
 452
 453 dnl is time_t long or long long ?
 454 AC_DEFINE([TIME_T_IS_LONG], [], [time_t is long])
 455 AC_DEFINE([TIME_T_IS_LONG_LONG], [], [time_t is long long])
 456 AC_MSG_CHECKING([the type of time_t])
 457 AC_RUN_IFELSE(
 458     AC_LANG_PROGRAM(
 459         [[#include <time.h>]],
 460         [[if (sizeof(long) != sizeof(time_t)) return 1; ]]
 461         ),
 462     [ AC_MSG_RESULT([time_t is long])
 463       AC_DEFINE([TIME_T_IS_LONG])
 464     ],
 465     [ AC_RUN_IFELSE(
 466         AC_LANG_PROGRAM(
 467         [[#include <time.h>]],
 468         [[if (sizeof(long long) != sizeof(time_t)) return 1; ]]
 469         ),
 470         [
 471           AC_MSG_RESULT([time_t is long long])
 472           AC_DEFINE([TIME_T_IS_LONG_LONG])
 473         ],
 474         [AC_MSG_ERROR([can not figure type of time_t])]
 475       )
 476     ]
 477 )
 478
 479 AC_LANG_POP(C)
 480
 481 CONFIGURE_PART(Find 3rd-Party Libraries)
 482
 483 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[have_libdbi=no],[
 484   XXX=$LIBS
 485   LIBS="$LIBS -ldbi -ldl"
 486   AC_MSG_CHECKING(for libdbi)
 487   AC_LINK_IFELSE(
 488     [AC_LANG_PROGRAM([[#include <dbi/dbi.h>]],
 489                      [[dbi_initialize(NULL)]]
 490                     )
 491     ],[AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 492        AC_MSG_RESULT([yes])
 493        have_libdbi=yes
 494     ],[LIBS=$XXX
 495        AC_MSG_RESULT([no])
 496        have_libdbi=no
 497     ]
 498   )
 499 ])
 500 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 501
 502 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 503
 504
 505 CORE_LIBS="$LIBS"
 506
 507 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 508 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 509 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 510 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 511 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 512 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 513 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 514 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 515 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 516 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 517 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 518
 519 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 520   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 521 fi
 522
 523 ALL_LIBS="$LIBS"
 524 LIBS=
 525
 526 AC_SUBST(CORE_LIBS)
 527 AC_SUBST(ALL_LIBS)
 528
 529 CONFIGURE_PART(Prep for Building Language Bindings)
 530
 531 dnl Check for Perl and friends
 532 PATH=$PATH:/usr/perl5/bin
 533 export PATH
 534 AC_PATH_PROG(PERL, perl, no)
 535 AC_PATH_PROG(POD2MAN, pod2man, no)
 536 AC_PATH_PROG(POD2HTML, pod2html, no)
 537
 538
 539 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 540 [],[enable_perl=yes])
 541
 542
 543 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 544 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 545 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 546 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 547
 548 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 549         COMP_PERL=
 550 else
 551         COMP_PERL="perl_piped perl_shared"
 552         AC_MSG_CHECKING(for the perl version you are running)
 553         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 554         AC_MSG_RESULT($PERL_VERSION)
 555         if test -z "$PERLCC"; then
 556             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 557             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 558             AC_MSG_RESULT($perlcc)
 559             if test ! -x "$perlcc"; then
 560                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 561                 if test "$PERL_CC" = "no"; then
 562                     AC_MSG_WARN([
 563 I would not find the Compiler ($perlcc) that was originally used to compile
 564 your perl binary. You should either make sure that this compiler is
 565 available on your system, pick an other compiler and set PERLCC
 566 appropriately, or use a different perl setup that was compiled locally.
 567
 568 I will disable the compilation of the RRDs perl module for now.
 569 ])
 570                     COMP_PERL="perl_piped"
 571                 fi
 572             fi
 573         fi
 574 fi
 575
 576 AC_MSG_CHECKING(Perl Modules to build)
 577 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 578
 579 # Options to pass when configuring perl module
 580 langpref=$prefix
 581 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 582 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 583
 584 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 585
 586 dnl pass additional perl options when generating Makefile from Makefile.PL
 587 AC_ARG_ENABLE(perl-site-install,
 588 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 589 [PERL_MAKE_OPTIONS=],[])
 590
 591 if test ! -z "$PERLCC"; then
 592    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 593
 594    if test ! -z "$PERLCCFLAGS"; then
 595        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 596    fi
 597
 598    if test -z "$PERLLD"; then
 599        PERLLD=$PERLCC
 600    fi
 601    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 602
 603    if test ! -z "$PERLLDFLAGS"; then
 604        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 605    fi
 606 fi
 607
 608 AC_ARG_WITH(perl-options,
 609 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 610                           generating Makefile from Makefile.PL. If you set this
 611                           option, interesting things may happen unless you know
 612                           what you are doing!],
 613 [PERL_MAKE_OPTIONS=$withval])
 614
 615 AC_SUBST(PERL_MAKE_OPTIONS)
 616 AC_SUBST(PERL)
 617 AC_SUBST(COMP_PERL)
 618 AC_SUBST(PERL_VERSION)
 619
 620 dnl Check for Ruby.
 621 AC_PATH_PROG(RUBY, ruby, no)
 622
 623 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 624 [],[enable_ruby=yes])
 625
 626 AC_MSG_CHECKING(if ruby modules can be built)
 627
 628 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 629         COMP_RUBY=
 630         AC_MSG_RESULT(No .. Ruby not found or disabled)
 631 else
 632         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 633                 COMP_RUBY="ruby"
 634                 AC_MSG_RESULT(YES)
 635         else
 636                 COMP_RUBY=
 637                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 638         fi
 639 fi
 640
 641 dnl pass additional ruby options when generating Makefile from Makefile.PL
 642 AC_ARG_ENABLE(ruby-site-install,
 643 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 644 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 645
 646
 647 AC_ARG_WITH(ruby-options,
 648 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 649                           generating Makefile from extconf.rb. If you set this
 650                           option, interesting things may happen unless you know
 651                           what you are doing!],
 652 [RUBY_MAKE_OPTIONS=$withval])
 653
 654 AC_SUBST(RUBY_MAKE_OPTIONS)
 655 AC_SUBST(RUBY)
 656 AC_SUBST(COMP_RUBY)
 657
 658 dnl Check for Lua.
 659 AC_PATH_PROG(LUA, lua, no)
 660
 661 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 662 [],[enable_lua=yes])
 663
 664 COMP_LUA=
 665 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 666   enable_lua=no
 667 else
 668   AC_MSG_CHECKING(for lua >= 5.0)
 669   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 670     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 671 LUA_EOF
 672   if test 0$LUA_MAJOR -lt 5; then
 673     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 674   else
 675     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 676     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 677     lua_vndot=$LUA_MAJOR$LUA_MINOR
 678     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 679     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 680       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 681         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 682           [lua_headerdir=lua$lua_vndot],
 683           [])],
 684         [])],
 685       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 686         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 687           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 688             [lua_headerdir=lua$lua_vdot],
 689             [])],
 690           [])],
 691         [AC_CHECK_HEADERS(lua.h,
 692           [AC_CHECK_HEADERS(lualib.h,
 693             [AC_CHECK_HEADER(lauxlib.h,
 694               [lua_headerdir=""],
 695               [lua_headerdir="no"])],
 696             [])],
 697           [])])])
 698
 699     if test "$lua_headerdir" = "no"; then
 700       enable_lua=no
 701     else
 702       COMP_LUA=lua
 703     fi
 704
 705     if test "$COMP_LUA" != "lua"; then
 706       enable_lua=no
 707       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 708     else
 709       # OK, headers found, let's check the libraries (LIBS is not used)
 710       LIBS=
 711       lua_havelib=no
 712       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 713       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 714         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 715           [lua_havelib=LUA$lua_vndot],
 716           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 717             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 718              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 719             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 720               [lua_havelib=$lua_vndot],
 721               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 722         [COMP_LUA=], [-lm])
 723       lua_libs=$LIBS
 724       LIBS=
 725
 726       # Options to pass when configuring Lua module
 727       if test  "$lua_havelib" != "no"; then
 728         # OK, headers and libs found. Try to set lua flags
 729         # and modules installation dirs with pkg-config
 730         if test "$PKGCONFIG" != "no"; then
 731           if test "$lua_vndot" = "50"; then
 732             lua_pkg_prefix=lualib
 733           else
 734             lua_pkg_prefix=lua
 735           fi
 736           # try with dot, without dot and finally without version
 737           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 738             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 739             # same binaries?
 740             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 741                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 742                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 743                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 744                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 745                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 746                 break
 747             fi
 748           done
 749         fi
 750
 751         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 752         # if lua 5.0 can't find compat-5.1, force installation of
 753         # compat-5.1.lua together with RRDtool.
 754         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 755           lua_need_compat51=1
 756           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 757         fi
 758
 759         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 760         if test "$LUA_CFLAGS" = ""; then
 761           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 762           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 763           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 764           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 765         fi
 766
 767         dnl pass additional lua options
 768         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 769         dnl found and install together with RRDtool, under $langpref.
 770         AC_ARG_ENABLE(lua-site-install,
 771         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 772         [],
 773         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 774
 775         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 776         AC_SUBST(LUA)
 777         AC_SUBST(COMP_LUA)
 778         AC_SUBST(LUA_INSTALL_CMOD)
 779         AC_SUBST(LUA_INSTALL_LMOD)
 780         AC_SUBST(LUA_CFLAGS)
 781         AC_SUBST(LUA_LFLAGS)
 782         AC_SUBST(LUA_DEFINES)
 783       else
 784         enable_lua=no
 785         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 786       fi
 787     fi
 788   fi
 789 fi
 790 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 791 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 792 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 793       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 794 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 795 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 796 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 797 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 798
 799 enable_tcl_site=no
 800
 801 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 802 [],[enable_tcl=yes])
 803
 804 if test  "$enable_tcl" = "yes"; then
 805   dnl Check for Tcl.
 806   withval=""
 807   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 808   enable_tcl=no
 809   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 810     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 811     if test -f "$dir/tclConfig.sh" ; then
 812         tcl_config=$dir/tclConfig.sh
 813         enable_tcl=yes
 814         AC_MSG_RESULT(yes)
 815         break
 816     else
 817         AC_MSG_RESULT(no)
 818     fi
 819   done
 820
 821   if test "$enable_tcl" = "no"; then
 822         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 823   else
 824         . $tcl_config
 825         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 826         if test -n "$TCL_INC_DIR"; then
 827           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 828         fi
 829   fi
 830   AC_ARG_ENABLE(tcl,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 831   [],[enable_tcl_site=yes])
 832
 833 fi
 834
 835 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 836 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 837
 838
 839 AC_SUBST(TCL_PREFIX)
 840 AC_SUBST(TCL_SHLIB_CFLAGS)
 841 AC_SUBST(TCL_SHLIB_LD)
 842 AC_SUBST(TCL_SHLIB_SUFFIX)
 843 AC_SUBST(TCL_PACKAGE_PATH)
 844 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 845 AC_SUBST(TCL_STUB_LIB_SPEC)
 846 AC_SUBST(TCL_VERSION)
 847 AC_SUBST(TCL_PACKAGE_DIR)
 848 AC_SUBST(TCL_INCLUDE_SPEC)
 849
 850 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 851 [],[enable_python=yes])
 852
 853 if test  "$enable_python" = "yes"; then
 854 dnl Check for python
 855 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 856 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 857 fi
 858
 859 if test  x$enable_python = xno; then
 860         COMP_PYTHON=
 861 else
 862         COMP_PYTHON="python"
 863 fi
 864
 865 AC_SUBST(COMP_PYTHON)
 866
 867 dnl Check for nroff
 868 AC_PATH_PROGS(NROFF, gnroff nroff)
 869 AC_PATH_PROGS(TROFF, groff troff)
 870
 871 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 872 if test -z "$RRDDOCDIR"; then
 873    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 874
 875
 876 CONFIGURE_PART(Apply Configuration Information)
 877
 878 AC_CONFIG_FILES([examples/shared-demo.pl])
 879 AC_CONFIG_FILES([examples/piped-demo.pl])
 880 AC_CONFIG_FILES([examples/stripes.pl])
 881 AC_CONFIG_FILES([examples/bigtops.pl])
 882 AC_CONFIG_FILES([examples/minmax.pl])
 883 AC_CONFIG_FILES([examples/4charts.pl])
 884 AC_CONFIG_FILES([examples/perftest.pl])
 885 AC_CONFIG_FILES([examples/Makefile])
 886 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 887 AC_CONFIG_FILES([doc/Makefile])
 888 AC_CONFIG_FILES([po/Makefile.in])
 889 AC_CONFIG_FILES([intl/Makefile])
 890 AC_CONFIG_FILES([src/Makefile])
 891 AC_CONFIG_FILES([src/librrd.sym.in])
 892 AC_CONFIG_FILES([src/librrd.pc])
 893 AC_CONFIG_FILES([bindings/Makefile])
 894 AC_CONFIG_FILES([bindings/tcl/Makefile])
 895 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 896 AC_CONFIG_FILES([Makefile])
 897 AC_CONFIG_FILES([bindings/lua/Makefile])
 898
 899 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 900
 901 dnl intl requires our config to be called config.h. indulge it.
 902 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 903
 904 AC_OUTPUT
 905
 906 AC_MSG_CHECKING(in)
 907 AC_MSG_RESULT(and out again)
 908
 909 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 910 sleep 1
 911 echo $ECHO_N ".$ECHO_C" 1>&6
 912 sleep 1
 913 echo $ECHO_N ".$ECHO_C" 1>&6
 914 sleep 1
 915 echo $ECHO_N ".$ECHO_C" 1>&6
 916 sleep 1
 917 echo $ECHO_N ".$ECHO_C" 1>&6
 918 sleep 1
 919 AC_MSG_RESULT([ just kidding ;-)])
 920 echo
 921 echo "----------------------------------------------------------------"
 922 echo "Config is DONE!"
 923 echo
 924 echo "          With MMAP IO: $enable_mmap"
 925 echo "      Build rrd_getopt: $build_getopt"
 926 echo "       Static programs: $staticprogs"
 927 echo "          Perl Modules: $COMP_PERL"
 928 echo "           Perl Binary: $PERL"
 929 echo "          Perl Version: $PERL_VERSION"
 930 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 931 echo "          Ruby Modules: $COMP_RUBY"
 932 echo "           Ruby Binary: $RUBY"
 933 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 934 echo "    Build Lua Bindings: $enable_lua"
 935 if test "$enable_lua" = "yes"; then
 936 echo "            Lua Binary: $LUA"
 937 echo "           Lua Version: $lua_version"
 938 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 939 if test "$lua_need_compat51" = "1"; then
 940 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 941 fi
 942 fi
 943 echo "    Build Tcl Bindings: $enable_tcl"
 944 echo " Build Python Bindings: $enable_python"
 945 echo "          Build rrdcgi: $enable_rrdcgi"
 946 echo "       Build librrd MT: $enable_pthread"
 947 echo "           Use gettext: $USE_NLS"
 948 echo "           With libDBI: $have_libdbi"
 949 echo
 950 echo "             Libraries: $ALL_LIBS"
 951 echo
 952 echo "Type 'make' to compile the software and use 'make install' to "
 953 echo "install everything to: $prefix."
 954 echo
 955 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 956 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 957 echo "place an order."
 958 echo
 959 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 960 echo "----------------------------------------------------------------"