configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 AC_INIT([rrdtool],[1.2.6])
  10 AC_CANONICAL_TARGET
  11 AM_INIT_AUTOMAKE
  12 AC_CONFIG_HEADERS([config.h])
  13
  14 dnl all our local stuff like install scripts and include files
  15 dnl is in there
  16
  17
  18 dnl determine the type of system we are running on
  19
  20
  21 AC_SUBST(VERSION)
  22
  23 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  24
  25 dnl Minimum Autoconf version required.
  26 AC_PREREQ(2.59)
  27
  28 dnl At the TOP of the HEADER
  29
  30 AH_TOP([
  31
  32 #ifndef CONFIG_H
  33 #define CONFIG_H
  34 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  35 #undef MUST_DISABLE_FPMASK
  36
  37 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  38
  39 #undef MUST_DISABLE_SIGFPE
  40
  41 /* realloc does not support NULL as argument */
  42 #undef NO_NULL_REALLOC
  43
  44  ])
  45
  46 AH_BOTTOM([
  47
  48 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  49    make sure you are NOT using bcopy, index or rindex in the code */
  50
  51 #if STDC_HEADERS
  52 # include <string.h>
  53 #else
  54 # ifndef HAVE_STRCHR
  55 #  define strchr index
  56 #  define strrchr rindex
  57 # endif
  58 char *strchr (), *strrchr ();
  59 # ifndef HAVE_MEMMOVE
  60 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  61 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  62 # endif
  63 #endif
  64
  65
  66 #if NO_NULL_REALLOC
  67 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  68 #else
  69 # define rrd_realloc(a,b) realloc((a), (b))
  70 #endif
  71
  72 #if HAVE_MATH_H
  73 #  include <math.h>
  74 #endif
  75
  76 #if HAVE_FLOAT_H
  77 #  include <float.h>
  78 #endif
  79
  80 #if HAVE_IEEEFP_H
  81 #  include <ieeefp.h>
  82 #endif
  83
  84 #if HAVE_FP_CLASS_H
  85 #  include <fp_class.h>
  86 #endif
  87
  88 /* for Solaris */
  89 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
  90 #  define HAVE_ISINF 1
  91 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
  92 #endif
  93
  94 /* for OSF1 Digital Unix */
  95 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
  96 #  define HAVE_ISINF 1
  97 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
  98 #endif
  99
 100 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 101 #  define HAVE_ISINF 1
 102 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 103 #endif
 104
 105 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 106 #  define HAVE_ISINF 1
 107 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 108 #endif
 109
 110 /* for AIX */
 111 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 112 #  define HAVE_ISINF 1
 113 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 114 #endif
 115
 116 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 117 #  define HAVE_FINITE 1
 118 #  define finite(a) isfinite(a)
 119 #endif
 120
 121 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 122 #  define HAVE_FINITE 1
 123 #  define finite(a) (! isnan(a) && ! isinf(a))
 124 #endif
 125
 126 #ifndef HAVE_FINITE
 127 #error "Can't compile without finite function"
 128 #endif
 129
 130 #ifndef HAVE_ISINF
 131 #error "Can't compile without isinf function"
 132 #endif
 133
 134 #endif /* CONFIG_H */
 135 ])
 136
 137
 138
 139 dnl Check for the compiler and static/shared library creation.
 140 AC_PROG_CC
 141 AC_PROG_CPP
 142 AC_PROG_LIBTOOL
 143
 144 dnl Check if we run on a system that has fonts
 145 AC_ARG_WITH(rrd-default-font,
 146 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 147 [RRD_DEFAULT_FONT=$withval],[
 148   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 149         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 150   else
 151         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 152   fi
 153 ])
 154
 155 AC_SUBST(RRD_DEFAULT_FONT)
 156
 157 dnl Checks for header files.
 158 AC_HEADER_STDC
 159 AC_HEADER_DIRENT
 160 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 161
 162 dnl Checks for typedefs, structures, and compiler characteristics.
 163 AC_C_CONST
 164 AC_HEADER_TIME
 165 AC_STRUCT_TM
 166
 167 dnl Checks for libraries.
 168 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 169 dnl Use libiconv if we have one but fall back to libc otherwhise
 170 AC_CHECK_LIB(iconv, iconv_open, , [
 171          AC_CHECK_FUNC(iconv_open,,)
 172          ])
 173
 174 dnl add pic flag in any case this makes sure all our code is relocatable
 175 eval `./libtool --config | grep pic_flag`
 176 CFLAGS="$CFLAGS $pic_flag"
 177
 178 dnl Checks for library functions.
 179 AC_FUNC_STRFTIME
 180 AC_FUNC_VPRINTF
 181
 182 AC_C_BIGENDIAN
 183
 184 dnl for each function found we get a definition in config.h
 185 dnl of the form HAVE_FUNCTION
 186
 187 AC_CHECK_FUNCS(tzset opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 188
 189 dnl Use mmap in rrd_update instead of seek+write
 190 AC_ARG_ENABLE([mmap],
 191 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 192 [],
 193 [enable_mmap=yes])
 194
 195 if test "x$enable_mmap" = xyes; then
 196   AC_FUNC_MMAP
 197 fi
 198
 199 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 200 dnl actual code to check if this works
 201 AC_CHECK_FUNCS(fpclassify, ,
 202   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 203     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
 204       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 205 AC_CHECK_FUNCS(finite, ,
 206   [AC_CHECK_FUNCS(isfinite, ,
 207     [AC_MSG_CHECKING(for isfinite with <math.h>)
 208     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
 209       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 210 AC_CHECK_FUNCS(isinf, ,
 211   [AC_MSG_CHECKING(for isinf with <math.h>)
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
 213       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 214
 215 AC_FULL_IEEE
 216
 217 dnl How the vertical axis label is printed
 218 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 219  [Vertical label angle: 90.0 (default) or 270.0])
 220 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 221  [Vertical label angle: 90.0 (default) or 270.0])
 222
 223
 224 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 225 [],[enable_rrdcgi=yes])
 226 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 227
 228 if test $enable_rrdcgi != no; then
 229 EX_CHECK_ALL(cgi,        cgiInit,                   cgi.h,                  cgilib,      0.5,    http://www.infodrom.org/projects/cgilib, "")
 230 fi
 231 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 232 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.2,  http://www.gzip.org/zlib/, "")
 233 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 234 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 235
 236 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 237   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 238 fi
 239
 240 AC_LANG_PUSH(C)
 241 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 242 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 243 AC_LINK_IFELSE(
 244     AC_LANG_PROGRAM(
 245            [[#include <time.h>]],
 246            [[ctime_r(NULL,NULL,0)]]
 247                    ),
 248     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 249       AC_LINK_IFELSE(
 250           AC_LANG_PROGRAM(
 251                 [[#include <time.h>]],
 252                 [[ctime_r(NULL,NULL)]]
 253                          ),
 254           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 255           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 256       )
 257     ],
 258     [ AC_LINK_IFELSE(
 259           AC_LANG_PROGRAM(
 260                 [[#include <time.h>]],
 261                 [[ctime_r(NULL,NULL)]]
 262                          ),
 263           [AC_MSG_RESULT(yes)],
 264           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 265       )
 266     ]
 267 )
 268 AC_LANG_POP(C)
 269
 270 dnl Check for pthreads
 271 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 272
 273 AC_SUBST(MULTITHREAD_CFLAGS)
 274 AC_SUBST(MULTITHREAD_LDFLAGS)
 275
 276
 277 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 278 [],[enable_pthread=yes])
 279
 280
 281 if test $enable_pthread != no; then
 282  ACX_PTHREAD([
 283     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 284     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 285              ],
 286              [])
 287 fi
 288
 289 dnl since we use lots of *_r functions all over the code we better
 290 dnl make sure they are known
 291
 292 if test  "x$x_rflag" != "xno"; then
 293    CPPFLAGS="$CPPFLAGS $x_rflag"
 294 fi
 295
 296
 297 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 298
 299 dnl Check for Perl.
 300 AC_PATH_PROG(PERL, perl, no)
 301
 302 AC_ARG_ENABLE(perl,[  --disable-perl    do not build the perl modules],
 303 [],[enable_perl=yes])
 304
 305
 306 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 307         COMP_PERL=
 308 else
 309         COMP_PERL="perl_piped perl_shared"
 310         AC_MSG_CHECKING(for the perl version you are running)
 311         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 312         AC_MSG_RESULT($PERL_VERSION)
 313         AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 314         perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 315         AC_MSG_RESULT($perlcc)
 316         if test ! -x $perlcc; then
 317                AC_PATH_PROG(PERLCC, ${perlcc}, no)
 318                if test -x "x$PERLCC" = "xno"; then
 319                   AC_MSG_WARN([
 320 I would not find the Compiler ($perlcc) that was originally used to compile your
 321 perl binary. You should either make sure that this compiler is available on your
 322 system, or use a different perl setup that was compiled with $CC.
 323
 324 I will disable the compilation of the RRDs perl module.
 325 ])
 326                   COMP_PERL="perl_piped"
 327                fi
 328         fi
 329 fi
 330 AC_MSG_CHECKING(Perl Modules to build)
 331 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 332
 333 # Options to pass when configuring perl module
 334 ppref=$prefix
 335 test "x$ppref" = xNONE && ppref=$ac_default_prefix
 336
 337 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 338
 339 dnl pass additional perl options when generating Makefile from Makefile.PL
 340 AC_ARG_ENABLE(perl-site-install,
 341 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 342                           together with rrdtool in $prefix/lib/perl. You have to
 343                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 344                           when you want to use them. When you set this option
 345                           the perl modules will get installed wherever
 346                           your perl setup thinks it is best.],
 347 [PERL_MAKE_OPTIONS=],[])
 348
 349 AC_ARG_WITH(perl-options,
 350 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 351                           generating Makefile from Makefile.PL. If you set this
 352                           option, interesting things may happen unless you know
 353                           what you are doing!],
 354 [PERL_MAKE_OPTIONS=$withval])
 355
 356 AC_SUBST(PERL_MAKE_OPTIONS)
 357 AC_SUBST(PERL)
 358 AC_SUBST(COMP_PERL)
 359 AC_SUBST(PERL_VERSION)
 360
 361
 362 dnl Check for Tcl.
 363 withval=""
 364 AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 365 found=0
 366 AC_MSG_CHECKING(for tclConfig.sh in $withval)
 367 if test -f "$withval/tclConfig.sh" ; then
 368         tcl_config=$withval/tclConfig.sh
 369         found=1
 370         AC_MSG_RESULT(yes)
 371         break
 372 else
 373         AC_MSG_RESULT(no)
 374 fi
 375
 376 if test $found -eq 0 ; then
 377         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 378 else
 379         . $tcl_config
 380 fi
 381
 382
 383 AM_CONDITIONAL(COMP_TCL, test x$found = x1 )
 384
 385 AC_SUBST(TCL_PREFIX)
 386 AC_SUBST(TCL_SHLIB_CFLAGS)
 387 AC_SUBST(TCL_SHLIB_LD)
 388 AC_SUBST(TCL_SHLIB_SUFFIX)
 389 AC_SUBST(TCL_PACKAGE_PATH)
 390 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 391
 392 dnl Check for python
 393 AM_PATH_PYTHON(2.3)
 394 AM_CHECK_PYTHON_HEADERS(,[AC_MSG_ERROR(could not find Python headers)])
 395
 396
 397
 398 dnl Check for nroff
 399 AC_PATH_PROGS(NROFF, gnroff nroff)
 400 AC_PATH_PROGS(TROFF, groff troff)
 401
 402 dnl Does the compiler like -Wall and -pedantic?
 403 if test "x$GCC" = "xyes"; then
 404   oCFLAGS=$CFLAGS
 405   CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 406   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 407                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 408                ]
 409         )
 410   if test $rd_cv_gcc_opt = no; then
 411          CFLAGS=$oCFLAGS
 412   fi
 413 fi
 414
 415 dnl what does realloc do if it gets called with a NULL pointer
 416
 417 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 418 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 419               int main(void){
 420               char *x = NULL;
 421               x = realloc (x,10);
 422               if (x==NULL) return 1;
 423               return 0;
 424              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 425
 426 if test x"$rd_cv_null_realloc" = xnope; then
 427 AC_DEFINE(NO_NULL_REALLOC)
 428 fi
 429
 430 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 431           examples/piped-demo.pl                        \
 432           examples/stripes.pl                           \
 433           examples/bigtops.pl                           \
 434           examples/minmax.pl                            \
 435           examples/cgi-demo.cgi                         \
 436           examples/4charts.pl                           \
 437           examples/Makefile                             \
 438           doc/Makefile                                  \
 439           src/Makefile                                  \
 440           bindings/Makefile                             \
 441           bindings/tcl/Makefile                         \
 442           bindings/python/Makefile                      \
 443           Makefile])
 444 AC_CONFIG_COMMANDS([default],[[\
 445           chmod +x examples/*.cgi examples/*.pl]],[[]])
 446 AC_OUTPUT
 447
 448 AC_MSG_CHECKING(in)
 449 AC_MSG_RESULT(and out again)
 450
 451 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 452 sleep 1
 453 echo $ECHO_N ".$ECHO_C" 1>&6
 454 sleep 1
 455 echo $ECHO_N ".$ECHO_C" 1>&6
 456 sleep 1
 457 echo $ECHO_N ".$ECHO_C" 1>&6
 458 sleep 1
 459 echo $ECHO_N ".$ECHO_C" 1>&6
 460 sleep 1
 461 AC_MSG_RESULT([ just kidding ;-)])
 462 echo
 463 echo "----------------------------------------------------------------"
 464 echo "Config is DONE!"
 465 echo
 466 echo "    With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 467 echo "    Perl Modules: $COMP_PERL"
 468 echo "     Perl Binary: $PERL"
 469 echo "    Perl Version: $PERL_VERSION"
 470 echo "    Perl Options: $PERL_MAKE_OPTIONS"
 471 echo "      Tcl Config: $tcl_config"
 472 echo "  Python Version: $PYTHON_VERSION"
 473 echo "    Build rrdcgi: $enable_rrdcgi"
 474 echo " Build librrd MT: $enable_pthread"
 475 echo
 476 echo
 477 echo "Type 'make' to compile the software and use 'make install' to "
 478 echo "install everything to: $prefix."
 479 echo
 480 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 481 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 482 echo "place an order."
 483 echo
 484 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 485 echo "----------------------------------------------------------------"