configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 AC_INIT([rrdtool],[1.2rc1])
  10 AC_CANONICAL_TARGET
  11 AM_INIT_AUTOMAKE
  12 AC_CONFIG_HEADERS([config.h])
  13
  14 dnl all our local stuff like install scripts and include files
  15 dnl is in there
  16
  17
  18 dnl determine the type of system we are running on
  19
  20
  21 AC_SUBST(VERSION)
  22
  23 dnl where we install our stuff ...
  24 if [ -d /opt ]; then
  25    xxpreinst = /opt
  26 else
  27    xxpreinst = /usr/local
  28 fi
  29
  30 AC_PREFIX_DEFAULT( $xxpreinst/local/rrdtool-$PACKAGE_VERSION )
  31
  32 dnl Minimum Autoconf version required.
  33 AC_PREREQ(2.59)
  34
  35 dnl At the TOP of the HEADER
  36
  37 AH_TOP([
  38
  39 #ifndef CONFIG_H
  40 #define CONFIG_H
  41 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  42 #undef MUST_DISABLE_FPMASK
  43
  44 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  45
  46 #undef MUST_DISABLE_SIGFPE
  47
  48 /* realloc does not support NULL as argument */
  49 #undef NO_NULL_REALLOC
  50
  51  ])
  52
  53 AH_BOTTOM([
  54
  55 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  56    make sure you are NOT using bcopy, index or rindex in the code */
  57
  58 #if STDC_HEADERS
  59 # include <string.h>
  60 #else
  61 # ifndef HAVE_STRCHR
  62 #  define strchr index
  63 #  define strrchr rindex
  64 # endif
  65 char *strchr (), *strrchr ();
  66 # ifndef HAVE_MEMMOVE
  67 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  68 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  69 # endif
  70 #endif
  71
  72
  73 #if NO_NULL_REALLOC
  74 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  75 #else
  76 # define rrd_realloc(a,b) realloc((a), (b))
  77 #endif
  78
  79 #if HAVE_MATH_H
  80 #  include <math.h>
  81 #endif
  82
  83 #if HAVE_FLOAT_H
  84 #  include <float.h>
  85 #endif
  86
  87 #if HAVE_IEEEFP_H
  88 #  include <ieeefp.h>
  89 #endif
  90
  91 #if HAVE_FP_CLASS_H
  92 #  include <fp_class.h>
  93 #endif
  94
  95 /* for Solaris */
  96 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
  97 #  define HAVE_ISINF 1
  98 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
  99 #endif
 100
 101 /* for OSF1 Digital Unix */
 102 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 103 #  define HAVE_ISINF 1
 104 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 105 #endif
 106
 107 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 108 #  define HAVE_ISINF 1
 109 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 110 #endif
 111
 112 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 113 #  define HAVE_ISINF 1
 114 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 115 #endif
 116
 117 /* for AIX */
 118 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 119 #  define HAVE_ISINF 1
 120 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 121 #endif
 122
 123 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 124 #  define HAVE_FINITE 1
 125 #  define finite(a) isfinite(a)
 126 #endif
 127
 128 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 129 #  define HAVE_FINITE 1
 130 #  define finite(a) (! isnan(a) && ! isinf(a))
 131 #endif
 132
 133 #ifndef HAVE_FINITE
 134 #error "Can't compile without finite function"
 135 #endif
 136
 137 #ifndef HAVE_ISINF
 138 #error "Can't compile without isinf function"
 139 #endif
 140
 141 #endif /* CONFIG_H */
 142 ])
 143
 144
 145
 146 dnl Check for the compiler and static/shared library creation.
 147 AC_PROG_CC
 148 AC_PROG_CPP
 149 AC_PROG_LIBTOOL
 150
 151 dnl Checks for header files.
 152 AC_HEADER_STDC
 153 AC_HEADER_DIRENT
 154 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 155
 156 dnl Checks for typedefs, structures, and compiler characteristics.
 157 AC_C_CONST
 158 AC_HEADER_TIME
 159 AC_STRUCT_TM
 160
 161 dnl Checks for libraries.
 162 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 163
 164 dnl add pic flag in any case this makes sure all our code is relocatable
 165 eval `./libtool --config | grep pic_flag`
 166 CFLAGS="$CFLAGS $pic_flag"
 167
 168 dnl Checks for library functions.
 169 AC_FUNC_STRFTIME
 170 AC_FUNC_VPRINTF
 171
 172 AC_C_BIGENDIAN
 173
 174 dnl for each function found we get a definition in config.h
 175 dnl of the form HAVE_FUNCTION
 176
 177 AC_CHECK_FUNCS(tzset opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 178
 179 dnl Use mmap in rrd_update instead of seek+write
 180 AC_ARG_ENABLE([mmap],
 181 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 182 [],
 183 [enable_mmap=yes])
 184
 185 if test "x$enable_mmap" = xyes; then
 186   AC_FUNC_MMAP
 187 fi
 188
 189 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 190 dnl actual code to check if this works
 191 AC_CHECK_FUNCS(fpclassify, ,
 192   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 193     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
 194       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 195 AC_CHECK_FUNCS(finite, ,
 196   [AC_CHECK_FUNCS(isfinite, ,
 197     [AC_MSG_CHECKING(for isfinite with <math.h>)
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
 199       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 200 AC_CHECK_FUNCS(isinf, ,
 201   [AC_MSG_CHECKING(for isinf with <math.h>)
 202     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
 203       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 204
 205 AC_FULL_IEEE
 206
 207 dnl How the vertical axis label is printed
 208 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 209  [Vertical label angle: 90.0 (default) or 270.0])
 210 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 211  [Vertical label angle: 90.0 (default) or 270.0])
 212
 213
 214 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 215 [],[enable_rrdcgi=yes])
 216 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 217
 218 if test $enable_rrdcgi != no; then
 219 EX_CHECK_ALL(cgi,        cgiInit,                   cgi.h,                  cgilib,      0.5,    http://www.infodrom.org/projects/cgilib, "")
 220 fi
 221 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 222 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.1,  http://www.gzip.org/zlib/, "")
 223 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 224 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,              freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 225
 226 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 227   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 228 fi
 229
 230 AC_LANG_PUSH(C)
 231 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 232 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 233 AC_LINK_IFELSE(
 234     AC_LANG_PROGRAM(
 235            [[#include <time.h>]],
 236            [[ctime_r(NULL,NULL,0)]]
 237                    ),
 238     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 239       AC_LINK_IFELSE(
 240           AC_LANG_PROGRAM(
 241                 [[#include <time.h>]],
 242                 [[ctime_r(NULL,NULL)]]
 243                          ),
 244           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 245           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 246       )
 247     ],
 248     [ AC_LINK_IFELSE(
 249           AC_LANG_PROGRAM(
 250                 [[#include <time.h>]],
 251                 [[ctime_r(NULL,NULL)]]
 252                          ),
 253           [AC_MSG_RESULT(yes)],
 254           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 255       )
 256     ]
 257 )
 258 AC_LANG_POP(C)
 259
 260 dnl Check for pthreads
 261 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 262
 263 AC_SUBST(MULTITHREAD_CFLAGS)
 264 AC_SUBST(MULTITHREAD_LDFLAGS)
 265
 266
 267 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 268 [],[enable_pthread=yes])
 269
 270
 271 if test $enable_pthread != no; then
 272  ACX_PTHREAD([
 273     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 274     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 275              ],
 276              [])
 277 fi
 278
 279 dnl since we use lots of *_r functions all over the code we better
 280 dnl make sure they are known
 281
 282 if test  "x$x_rflag" != "xno"; then
 283    CPPFLAGS="$CPPFLAGS $x_rflag"
 284 fi
 285
 286
 287 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 288
 289 dnl Check for Perl.
 290 AC_PATH_PROG(PERL, perl, no)
 291 if test "x$PERL" = "xno"; then
 292         COMP_PERL=
 293 else
 294         COMP_PERL="perl_piped perl_shared"
 295         AC_MSG_CHECKING(for the perl version you are running)
 296         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 297         AC_MSG_RESULT($PERL_VERSION)
 298         AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 299         perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 300         AC_MSG_RESULT($perlcc)
 301         if test ! -x $perlcc; then
 302                AC_PATH_PROG(PERLCC, ${perlcc}, no)
 303                if test -x $"x$PERLCC" = "xno"; then
 304                   AC_MSG_WARN([
 305 I would not find the Compiler ($perlcc) that was originally used to compile your
 306 perl binary. You should either make sure that this compiler is available on your
 307 system, or use a different perl setup that was compiled with $CC.
 308
 309 I will disable the compilation of the RRDs perl module.
 310 ])
 311                   COMP_PERL="perl_piped"
 312                fi
 313         fi
 314 fi
 315 AC_MSG_CHECKING(Perl Modules to build)
 316 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 317
 318 # Options to pass when configuring perl module
 319 PERL_MAKE_OPTIONS="PREFIX=$prefix LIB=$prefix/lib/perl/$PERL_VERSION"
 320
 321 dnl pass additional perl options when generating Makefile from Makefile.PL
 322 AC_ARG_ENABLE(perl-site-install,
 323 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 324                           together with rrdtool in $prefix/lib/perl. You have to
 325                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 326                           when you want to use them. When you set this option
 327                           the perl modules will get installed wherever
 328                           your perl setup thinks it is best.],
 329 [PERL_MAKE_OPTIONS=],[])
 330
 331 AC_ARG_WITH(perl-options,
 332 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 333                           generating Makefile from Makefile.PL. If you set this
 334                           option, interesting things may happen unless you know
 335                           what you are doing!],
 336 [PERL_MAKE_OPTIONS=$withval])
 337
 338 AC_SUBST(PERL_MAKE_OPTIONS)
 339 AC_SUBST(PERL)
 340 AC_SUBST(COMP_PERL)
 341 AC_SUBST(PERL_VERSION)
 342
 343
 344 dnl Check for Tcl.
 345 withval=""
 346 AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 347 found=0
 348 AC_MSG_CHECKING(for tclConfig.sh in $withval)
 349 if test -f "$withval/tclConfig.sh" ; then
 350         tcl_config=$withval/tclConfig.sh
 351         found=1
 352         AC_MSG_RESULT(yes)
 353         break
 354 else
 355         AC_MSG_RESULT(no)
 356 fi
 357
 358 if test $found -eq 0 ; then
 359         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 360 else
 361         . $tcl_config
 362 fi
 363
 364
 365 AM_CONDITIONAL(COMP_TCL, test x$found = x1 )
 366
 367 AC_SUBST(TCL_PREFIX)
 368 AC_SUBST(TCL_SHLIB_CFLAGS)
 369 AC_SUBST(TCL_SHLIB_LD)
 370 AC_SUBST(TCL_SHLIB_SUFFIX)
 371 AC_SUBST(TCL_PACKAGE_PATH)
 372 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 373
 374
 375
 376 dnl Check for nroff
 377 AC_PATH_PROGS(NROFF, gnroff nroff)
 378 AC_PATH_PROGS(TROFF, groff troff)
 379
 380 dnl Does the compiler like -Wall and -pedantic?
 381 if test "x$GCC" = "xyes"; then
 382   oCFLAGS=$CFLAGS
 383   CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 384   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 385                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 386                ]
 387         )
 388   if test $rd_cv_gcc_opt = no; then
 389          CFLAGS=$oCFLAGS
 390   fi
 391 fi
 392
 393 dnl what does realloc do if it gets called with a NULL pointer
 394
 395 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 396 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 397               int main(void){
 398               char *x = NULL;
 399               x = realloc (x,10);
 400               if (x==NULL) return 1;
 401               return 0;
 402              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 403
 404 if test x"$rd_cv_null_realloc" = xnope; then
 405 AC_DEFINE(NO_NULL_REALLOC)
 406 fi
 407
 408 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 409           examples/piped-demo.pl                        \
 410           examples/stripes.pl                           \
 411           examples/bigtops.pl                           \
 412           examples/minmax.pl                            \
 413           examples/cgi-demo.cgi                         \
 414           examples/4charts.pl                           \
 415           examples/Makefile                             \
 416           doc/Makefile                                  \
 417           src/Makefile                                  \
 418           bindings/Makefile                             \
 419           bindings/tcl/Makefile                         \
 420           Makefile])
 421 AC_CONFIG_COMMANDS([default],[[\
 422           chmod +x examples/*.cgi examples/*.pl]],[[]])
 423 AC_OUTPUT
 424
 425 AC_MSG_CHECKING(in)
 426 AC_MSG_RESULT(and out again)
 427
 428 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 429 sleep 1
 430 echo $ECHO_N ".$ECHO_C" 1>&6
 431 sleep 1
 432 echo $ECHO_N ".$ECHO_C" 1>&6
 433 sleep 1
 434 echo $ECHO_N ".$ECHO_C" 1>&6
 435 sleep 1
 436 echo $ECHO_N ".$ECHO_C" 1>&6
 437 sleep 1
 438 AC_MSG_RESULT([ just kidding ;-)])
 439 echo
 440 echo "----------------------------------------------------------------"
 441 echo "Config is DONE!"
 442 echo
 443 echo "    With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 444 echo "    Perl Modules: $COMP_PERL"
 445 echo "     Perl Binary: $PERL"
 446 echo "    Perl Version: $PERL_VERSION"
 447 echo "    Perl Options: $PERL_MAKE_OPTIONS"
 448 echo "      Tcl Config: $tcl_config"
 449 echo "    Build rrdcgi: $enable_rrdcgi"
 450 echo " Build librrd MT: $enable_pthread"
 451 echo
 452 ech
 453 echo "Type 'make' to compile the software and use 'make install' to "
 454 echo "install everything to: $prefix."
 455 echo
 456 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 457 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 458 echo "place an order."
 459 echo
 460 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 461 echo "----------------------------------------------------------------"