configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.12])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devl versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.2012
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef CONFIG_H
  41 #define CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52  ])
  53
  54 AH_BOTTOM([
  55
  56 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  57    make sure you are NOT using bcopy, index or rindex in the code */
  58
  59 #if STDC_HEADERS
  60 # include <string.h>
  61 #else
  62 # ifndef HAVE_STRCHR
  63 #  define strchr index
  64 #  define strrchr rindex
  65 # endif
  66 char *strchr (), *strrchr ();
  67 # ifndef HAVE_MEMMOVE
  68 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  69 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  70 # endif
  71 #endif
  72
  73
  74 #if NO_NULL_REALLOC
  75 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  76 #else
  77 # define rrd_realloc(a,b) realloc((a), (b))
  78 #endif
  79
  80 #if NEED_MALLOC_MALLOC_H
  81 #  include <malloc/malloc.h>
  82 #endif
  83
  84 #if HAVE_MATH_H
  85 #  include <math.h>
  86 #endif
  87
  88 #if HAVE_FLOAT_H
  89 #  include <float.h>
  90 #endif
  91
  92 #if HAVE_IEEEFP_H
  93 #  include <ieeefp.h>
  94 #endif
  95
  96 #if HAVE_FP_CLASS_H
  97 #  include <fp_class.h>
  98 #endif
  99
 100 /* for Solaris */
 101 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 102 #  define HAVE_ISINF 1
 103 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 104 #endif
 105
 106 /* for OSF1 Digital Unix */
 107 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 108 #  define HAVE_ISINF 1
 109 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 110 #endif
 111
 112 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 113 #  define HAVE_ISINF 1
 114 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 115 #endif
 116
 117 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 118 #  define HAVE_ISINF 1
 119 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 120 #endif
 121
 122 /* for AIX */
 123 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 124 #  define HAVE_ISINF 1
 125 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 126 #endif
 127
 128 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 129 #  define HAVE_FINITE 1
 130 #  define finite(a) isfinite(a)
 131 #endif
 132
 133 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 134 #  define HAVE_FINITE 1
 135 #  define finite(a) (! isnan(a) && ! isinf(a))
 136 #endif
 137
 138 #ifndef HAVE_FINITE
 139 #error "Can't compile without finite function"
 140 #endif
 141
 142 #ifndef HAVE_ISINF
 143 #error "Can't compile without isinf function"
 144 #endif
 145
 146 #endif /* CONFIG_H */
 147 ])
 148
 149 dnl Process Special Options
 150 dnl -----------------------------------
 151
 152 dnl How the vertical axis label is printed
 153 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 154  [Vertical label angle: 90.0 (default) or 270.0])
 155 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 156  [Vertical label angle: 90.0 (default) or 270.0])
 157
 158 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 159 [],[enable_rrdcgi=yes])
 160
 161 dnl Check if we run on a system that has fonts
 162 AC_ARG_WITH(rrd-default-font,
 163 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 164 [RRD_DEFAULT_FONT=$withval],[
 165   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 166         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 167   else
 168         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 169   fi
 170 ])
 171
 172 dnl Use mmap in rrd_update instead of seek+write
 173 AC_ARG_ENABLE([mmap],
 174 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 175 [],
 176 [enable_mmap=yes])
 177
 178
 179  AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 180 [],[enable_pthread=yes])
 181
 182
 183
 184 CONFIGURE_PART(Audit Compilation Environment)
 185
 186
 187 dnl Check for the compiler and static/shared library creation.
 188 AC_PROG_CC
 189 AC_PROG_CPP
 190 AC_PROG_LIBTOOL
 191
 192
 193 AC_SUBST(RRD_DEFAULT_FONT)
 194
 195 CONFIGURE_PART(Checking for Header Files)
 196
 197 dnl Checks for header files.
 198 AC_HEADER_STDC
 199 AC_HEADER_DIRENT
 200 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 201
 202 dnl Checks for typedefs, structures, and compiler characteristics.
 203 AC_C_CONST
 204 AC_HEADER_TIME
 205 AC_STRUCT_TM
 206
 207 dnl Checks for libraries.
 208 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 209
 210 dnl add pic flag in any case this makes sure all our code is relocatable
 211 eval `./libtool --config | grep pic_flag`
 212 CFLAGS="$CFLAGS $pic_flag"
 213
 214 CONFIGURE_PART(Test Library Functions)
 215
 216 dnl Checks for library functions.
 217 AC_FUNC_STRFTIME
 218 AC_FUNC_VPRINTF
 219
 220 AC_C_BIGENDIAN
 221
 222 dnl for each function found we get a definition in config.h
 223 dnl of the form HAVE_FUNCTION
 224
 225 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 226
 227
 228 if test "x$enable_mmap" = xyes; then
 229   case "$host" in
 230     *cygwin*)
 231        # the normal mmap test does not work in cygwin
 232        AC_CHECK_FUNCS(mmap)
 233        if [ "x${ac_cv_func_mmap}" = xyes ]; then
 234          ac_cv_func_mmap_fixed_mapped=yes
 235        fi
 236     ;;
 237     *)
 238        AC_FUNC_MMAP
 239     ;;
 240   esac
 241 fi
 242
 243
 244 CONFIGURE_PART(IEEE Math Checks)
 245
 246 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 247 dnl actual code to check if this works
 248 AC_CHECK_FUNCS(fpclassify, ,
 249   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 250     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 251 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 252       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 253 AC_CHECK_FUNCS(finite, ,
 254   [AC_CHECK_FUNCS(isfinite, ,
 255     [AC_MSG_CHECKING(for isfinite with <math.h>)
 256     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 257 volatile int x;volatile float f;  ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 258       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 259 AC_CHECK_FUNCS(isinf, ,
 260   [AC_MSG_CHECKING(for isinf with <math.h>)
 261     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 262 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 263       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 264
 265 AC_FULL_IEEE
 266
 267 CONFIGURE_PART(Resolve Portability Issues)
 268
 269 dnl what does realloc do if it gets called with a NULL pointer
 270
 271 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 272 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 273               int main(void){
 274               char *x = NULL;
 275               x = realloc (x,10);
 276               if (x==NULL) return 1;
 277               return 0;
 278              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 279
 280 if test x"$rd_cv_null_realloc" = xnope; then
 281 AC_DEFINE(NO_NULL_REALLOC)
 282 fi
 283
 284 AC_LANG_PUSH(C)
 285 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 286 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 287 AC_LINK_IFELSE(
 288     AC_LANG_PROGRAM(
 289            [[#include <time.h>]],
 290            [[ctime_r(NULL,NULL,0)]]
 291                    ),
 292     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 293       AC_LINK_IFELSE(
 294           AC_LANG_PROGRAM(
 295                 [[#include <time.h>]],
 296                 [[ctime_r(NULL,NULL)]]
 297                          ),
 298           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 299           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 300       )
 301     ],
 302     [ AC_LINK_IFELSE(
 303           AC_LANG_PROGRAM(
 304                 [[#include <time.h>]],
 305                 [[ctime_r(NULL,NULL)]]
 306                          ),
 307           [AC_MSG_RESULT(no)],
 308           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 309       )
 310     ]
 311 )
 312 AC_LANG_POP(C)
 313
 314 dnl Check for pthreads
 315 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 316
 317 AC_SUBST(MULTITHREAD_CFLAGS)
 318 AC_SUBST(MULTITHREAD_LDFLAGS)
 319
 320 if test $enable_pthread != no; then
 321  ACX_PTHREAD([
 322     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 323     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 324              ],
 325              [])
 326 fi
 327
 328 dnl since we use lots of *_r functions all over the code we better
 329 dnl make sure they are known
 330
 331 if test  "x$x_rflag" != "xno"; then
 332    CPPFLAGS="$CPPFLAGS $x_rflag"
 333 fi
 334
 335 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 336
 337 AC_LANG_PUSH(C)
 338 dnl see if we have to include malloc/malloc.h
 339 AC_MSG_CHECKING([do we need malloc/malloc.h])
 340 AC_LINK_IFELSE(
 341     AC_LANG_PROGRAM(
 342            [[#include <stdlib.h>]],
 343            [[malloc(1)]]
 344                    ),
 345     [ AC_MSG_RESULT([nope, works out of the box]) ],
 346     [ AC_LINK_IFELSE(
 347           AC_LANG_PROGRAM(
 348                 [[#include <stdlib.h>
 349                   #include <malloc/malloc.h>]],
 350                 [[malloc(1)]]
 351                          ),
 352           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 353            AC_MSG_RESULT([yes we do])],
 354           [AC_MSG_ERROR([Can't figure how to compile malloc])]
 355       )
 356     ]
 357 )
 358 AC_LANG_POP(C)
 359
 360 CONFIGURE_PART(Findr 3rd-Party Libraries)
 361
 362
 363 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 364
 365 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 366 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 367 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 368 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 369
 370 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 371   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 372 fi
 373
 374
 375 CONFIGURE_PART(Prep for Building Language Bindings)
 376
 377 dnl Check for Perl.
 378 AC_PATH_PROG(PERL, perl, no)
 379
 380 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 381 [],[enable_perl=yes])
 382
 383
 384 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 385 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 386 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 387 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 388
 389 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 390         COMP_PERL=
 391 else
 392         COMP_PERL="perl_piped perl_shared"
 393         AC_MSG_CHECKING(for the perl version you are running)
 394         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 395         AC_MSG_RESULT($PERL_VERSION)
 396         if test -z "$PERLCC"; then
 397             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 398             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 399             AC_MSG_RESULT($perlcc)
 400             if test ! -x "$perlcc"; then
 401                 AC_PATH_PROG(PERL_CC, "${perlcc}", no)
 402                 if test "$PERL_CC" = "no"; then
 403                     AC_MSG_WARN([
 404 I would not find the Compiler ($perlcc) that was originally used to compile
 405 your perl binary. You should either make sure that this compiler is
 406 available on your system, pick an other compiler and set PERLCC
 407 appropriately, or use a different perl setup that was compiled locally.
 408
 409 I will disable the compilation of the RRDs perl module for now.
 410 ])
 411                     COMP_PERL="perl_piped"
 412                 fi
 413             fi
 414         fi
 415 fi
 416
 417 AC_MSG_CHECKING(Perl Modules to build)
 418 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 419
 420 # Options to pass when configuring perl module
 421 ppref=$prefix
 422 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 423
 424 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 425
 426 dnl pass additional perl options when generating Makefile from Makefile.PL
 427 AC_ARG_ENABLE(perl-site-install,
 428 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 429                           together with rrdtool in $prefix/lib/perl. You have to
 430                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 431                           when you want to use them. When you set this option
 432                           the perl modules will get installed wherever
 433                           your perl setup thinks it is best.],
 434 [PERL_MAKE_OPTIONS=],[])
 435
 436 if test ! -z "$PERLCC"; then
 437    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 438
 439    if test ! -z "$PERLCCFLAGS"; then
 440        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 441    fi
 442
 443    if test -z "$PERLLD"; then
 444        PERLLD=$PERLCC
 445    fi
 446    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 447
 448    if test ! -z "$PERLLDFLAGS"; then
 449        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 450    fi
 451 fi
 452
 453 AC_ARG_WITH(perl-options,
 454 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 455                           generating Makefile from Makefile.PL. If you set this
 456                           option, interesting things may happen unless you know
 457                           what you are doing!],
 458 [PERL_MAKE_OPTIONS=$withval])
 459
 460 AC_SUBST(PERL_MAKE_OPTIONS)
 461 AC_SUBST(PERL)
 462 AC_SUBST(COMP_PERL)
 463 AC_SUBST(PERL_VERSION)
 464
 465 enable_tcl_site=no
 466
 467 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 468 [],[enable_tcl=yes])
 469
 470 if test  "$enable_tcl" = "yes"; then
 471   dnl Check for Tcl.
 472   withval=""
 473   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 474   enable_tcl=no
 475   for dir in $withval /usr/lib /usr/local/lib; do
 476     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 477     if test -f "$dir/tclConfig.sh" ; then
 478         tcl_config=$dir/tclConfig.sh
 479         enable_tcl=yes
 480         AC_MSG_RESULT(yes)
 481         break
 482     else
 483         AC_MSG_RESULT(no)
 484     fi
 485   done
 486
 487   if test "$enable_tcl" = "no"; then
 488         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 489   else
 490         . $tcl_config
 491         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 492   fi
 493   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 494   [],[enable_tcl_site=yes])
 495
 496 fi
 497
 498 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 499 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 500
 501 AC_SUBST(TCL_PREFIX)
 502 AC_SUBST(TCL_SHLIB_CFLAGS)
 503 AC_SUBST(TCL_SHLIB_LD)
 504 AC_SUBST(TCL_SHLIB_SUFFIX)
 505 AC_SUBST(TCL_PACKAGE_PATH)
 506 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 507 AC_SUBST(TCL_STUB_LIB_SPEC)
 508 AC_SUBST(TCL_VERSION)
 509 AC_SUBST(TCL_PACKAGE_DIR)
 510
 511 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 512 [],[enable_python=yes])
 513
 514 if test  "$enable_python" = "yes"; then
 515 dnl Check for python
 516 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 517 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 518 fi
 519
 520 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
 521
 522 dnl Check for nroff
 523 AC_PATH_PROGS(NROFF, gnroff nroff)
 524 AC_PATH_PROGS(TROFF, groff troff)
 525
 526 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 527 if test -z "$RRDDOCDIR"; then
 528    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 529
 530 dnl Does the compiler like -Wall and -pedantic?
 531 if test "$GCC" = "yes"; then
 532   oCFLAGS=$CFLAGS
 533   CFLAGS="$CFLAGS -fno-strict-aliasing -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 534   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 535                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 536                ]
 537         )
 538   if test $rd_cv_gcc_opt = no; then
 539          CFLAGS=$oCFLAGS
 540   fi
 541 fi
 542
 543
 544 CONFIGURE_PART(Apply Configuration Information)
 545
 546 AC_CONFIG_FILES([examples/shared-demo.pl])
 547 AC_CONFIG_FILES([examples/piped-demo.pl])
 548 AC_CONFIG_FILES([examples/stripes.pl])
 549 AC_CONFIG_FILES([examples/bigtops.pl])
 550 AC_CONFIG_FILES([examples/minmax.pl])
 551 AC_CONFIG_FILES([examples/cgi-demo.cgi])
 552 AC_CONFIG_FILES([examples/4charts.pl])
 553 AC_CONFIG_FILES([examples/Makefile])
 554 AC_CONFIG_FILES([doc/Makefile])
 555 AC_CONFIG_FILES([src/Makefile])
 556 AC_CONFIG_FILES([bindings/Makefile])
 557 AC_CONFIG_FILES([bindings/tcl/Makefile])
 558 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 559 AC_CONFIG_FILES([bindings/python/Makefile])
 560 AC_CONFIG_FILES([Makefile])
 561
 562 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.cgi examples/*.pl]],[[]])
 563 AC_OUTPUT
 564
 565 AC_MSG_CHECKING(in)
 566 AC_MSG_RESULT(and out again)
 567
 568 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/oetiker/wish $ECHO_C" 1>&6
 569 sleep 1
 570 echo $ECHO_N ".$ECHO_C" 1>&6
 571 sleep 1
 572 echo $ECHO_N ".$ECHO_C" 1>&6
 573 sleep 1
 574 echo $ECHO_N ".$ECHO_C" 1>&6
 575 sleep 1
 576 echo $ECHO_N ".$ECHO_C" 1>&6
 577 sleep 1
 578 AC_MSG_RESULT([ just kidding ;-)])
 579 echo
 580 echo "----------------------------------------------------------------"
 581 echo "Config is DONE!"
 582 echo
 583 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 584 echo "          Perl Modules: $COMP_PERL"
 585 echo "           Perl Binary: $PERL"
 586 echo "          Perl Version: $PERL_VERSION"
 587 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 588 echo "    Build Tcl Bindings: $enable_tcl"
 589 echo " Build Python Bindings: $enable_python"
 590 echo "          Build rrdcgi: $enable_rrdcgi"
 591 echo "       Build librrd MT: $enable_pthread"
 592 echo
 593 echo
 594 echo "Type 'make' to compile the software and use 'make install' to "
 595 echo "install everything to: $prefix."
 596 echo
 597 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 598 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 599 echo "place an order."
 600 echo
 601 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 602 echo "----------------------------------------------------------------"