configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 AC_INIT([rrdtool],[1.2rc1])
  10 AC_CANONICAL_TARGET
  11 AM_INIT_AUTOMAKE
  12 AC_CONFIG_HEADERS([config.h])
  13
  14 dnl all our local stuff like install scripts and include files
  15 dnl is in there
  16
  17
  18 dnl determine the type of system we are running on
  19
  20
  21 AC_SUBST(VERSION)
  22
  23 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  24
  25 dnl Minimum Autoconf version required.
  26 AC_PREREQ(2.59)
  27
  28 dnl At the TOP of the HEADER
  29
  30 AH_TOP([
  31
  32 #ifndef CONFIG_H
  33 #define CONFIG_H
  34 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  35 #undef MUST_DISABLE_FPMASK
  36
  37 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  38
  39 #undef MUST_DISABLE_SIGFPE
  40
  41 /* realloc does not support NULL as argument */
  42 #undef NO_NULL_REALLOC
  43
  44  ])
  45
  46 AH_BOTTOM([
  47
  48 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  49    make sure you are NOT using bcopy, index or rindex in the code */
  50
  51 #if STDC_HEADERS
  52 # include <string.h>
  53 #else
  54 # ifndef HAVE_STRCHR
  55 #  define strchr index
  56 #  define strrchr rindex
  57 # endif
  58 char *strchr (), *strrchr ();
  59 # ifndef HAVE_MEMMOVE
  60 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  61 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  62 # endif
  63 #endif
  64
  65
  66 #if NO_NULL_REALLOC
  67 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  68 #else
  69 # define rrd_realloc(a,b) realloc((a), (b))
  70 #endif
  71
  72 #if HAVE_MATH_H
  73 #  include <math.h>
  74 #endif
  75
  76 #if HAVE_FLOAT_H
  77 #  include <float.h>
  78 #endif
  79
  80 #if HAVE_IEEEFP_H
  81 #  include <ieeefp.h>
  82 #endif
  83
  84 #if HAVE_FP_CLASS_H
  85 #  include <fp_class.h>
  86 #endif
  87
  88 /* for Solaris */
  89 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
  90 #  define HAVE_ISINF 1
  91 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
  92 #endif
  93
  94 /* for OSF1 Digital Unix */
  95 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
  96 #  define HAVE_ISINF 1
  97 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
  98 #endif
  99
 100 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 101 #  define HAVE_ISINF 1
 102 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 103 #endif
 104
 105 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 106 #  define HAVE_ISINF 1
 107 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 108 #endif
 109
 110 /* for AIX */
 111 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 112 #  define HAVE_ISINF 1
 113 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 114 #endif
 115
 116 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 117 #  define HAVE_FINITE 1
 118 #  define finite(a) isfinite(a)
 119 #endif
 120
 121 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 122 #  define HAVE_FINITE 1
 123 #  define finite(a) (! isnan(a) && ! isinf(a))
 124 #endif
 125
 126 #ifndef HAVE_FINITE
 127 #error "Can't compile without finite function"
 128 #endif
 129
 130 #ifndef HAVE_ISINF
 131 #error "Can't compile without isinf function"
 132 #endif
 133
 134 #endif /* CONFIG_H */
 135 ])
 136
 137
 138
 139 dnl Check for the compiler and static/shared library creation.
 140 AC_PROG_CC
 141 AC_PROG_CPP
 142 AC_PROG_LIBTOOL
 143
 144 dnl Checks for header files.
 145 AC_HEADER_STDC
 146 AC_HEADER_DIRENT
 147 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 148
 149 dnl Checks for typedefs, structures, and compiler characteristics.
 150 AC_C_CONST
 151 AC_HEADER_TIME
 152 AC_STRUCT_TM
 153
 154 dnl Checks for libraries.
 155 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 156
 157 dnl add pic flag in any case this makes sure all our code is relocatable
 158 eval `./libtool --config | grep pic_flag`
 159 CFLAGS="$CFLAGS $pic_flag"
 160
 161 dnl Checks for library functions.
 162 AC_FUNC_STRFTIME
 163 AC_FUNC_VPRINTF
 164
 165 AC_C_BIGENDIAN
 166
 167 dnl for each function found we get a definition in config.h
 168 dnl of the form HAVE_FUNCTION
 169
 170 AC_CHECK_FUNCS(tzset opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 171
 172 dnl Use mmap in rrd_update instead of seek+write
 173 AC_ARG_ENABLE([mmap],
 174 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 175 [],
 176 [enable_mmap=yes])
 177
 178 if test "x$enable_mmap" = xyes; then
 179   AC_FUNC_MMAP
 180 fi
 181
 182 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 183 dnl actual code to check if this works
 184 AC_CHECK_FUNCS(fpclassify, ,
 185   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
 187       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 188 AC_CHECK_FUNCS(finite, ,
 189   [AC_CHECK_FUNCS(isfinite, ,
 190     [AC_MSG_CHECKING(for isfinite with <math.h>)
 191     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
 192       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 193 AC_CHECK_FUNCS(isinf, ,
 194   [AC_MSG_CHECKING(for isinf with <math.h>)
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
 196       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 197
 198 AC_FULL_IEEE
 199
 200 dnl How the vertical axis label is printed
 201 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 202  [Vertical label angle: 90.0 (default) or 270.0])
 203 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 204  [Vertical label angle: 90.0 (default) or 270.0])
 205
 206
 207 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 208 [],[enable_rrdcgi=yes])
 209 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 210
 211 if test $enable_rrdcgi != no; then
 212 EX_CHECK_ALL(cgi,        cgiInit,                   cgi.h,                  cgilib,      0.5,    http://www.infodrom.org/projects/cgilib, "")
 213 fi
 214 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 215 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.1,  http://www.gzip.org/zlib/, "")
 216 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 217 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,              freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 218
 219 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 220   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 221 fi
 222
 223 AC_LANG_PUSH(C)
 224 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 225 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 226 AC_LINK_IFELSE(
 227     AC_LANG_PROGRAM(
 228            [[#include <time.h>]],
 229            [[ctime_r(NULL,NULL,0)]]
 230                    ),
 231     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 232       AC_LINK_IFELSE(
 233           AC_LANG_PROGRAM(
 234                 [[#include <time.h>]],
 235                 [[ctime_r(NULL,NULL)]]
 236                          ),
 237           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 238           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 239       )
 240     ],
 241     [ AC_LINK_IFELSE(
 242           AC_LANG_PROGRAM(
 243                 [[#include <time.h>]],
 244                 [[ctime_r(NULL,NULL)]]
 245                          ),
 246           [AC_MSG_RESULT(yes)],
 247           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 248       )
 249     ]
 250 )
 251 AC_LANG_POP(C)
 252
 253 dnl Check for pthreads
 254 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 255
 256 AC_SUBST(MULTITHREAD_CFLAGS)
 257 AC_SUBST(MULTITHREAD_LDFLAGS)
 258
 259
 260 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 261 [],[enable_pthread=yes])
 262
 263
 264 if test $enable_pthread != no; then
 265  ACX_PTHREAD([
 266     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 267     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 268              ],
 269              [])
 270 fi
 271
 272 dnl since we use lots of *_r functions all over the code we better
 273 dnl make sure they are known
 274
 275 if test  "x$x_rflag" != "xno"; then
 276    CPPFLAGS="$CPPFLAGS $x_rflag"
 277 fi
 278
 279
 280 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 281
 282 dnl Check for Perl.
 283 AC_PATH_PROG(PERL, perl, no)
 284 if test "x$PERL" = "xno"; then
 285         COMP_PERL=
 286 else
 287         COMP_PERL="perl_piped perl_shared"
 288         AC_MSG_CHECKING(for the perl version you are running)
 289         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 290         AC_MSG_RESULT($PERL_VERSION)
 291         AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 292         perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 293         AC_MSG_RESULT($perlcc)
 294         if test ! -x $perlcc; then
 295                AC_PATH_PROG(PERLCC, ${perlcc}, no)
 296                if test -x $"x$PERLCC" = "xno"; then
 297                   AC_MSG_WARN([
 298 I would not find the Compiler ($perlcc) that was originally used to compile your
 299 perl binary. You should either make sure that this compiler is available on your
 300 system, or use a different perl setup that was compiled with $CC.
 301
 302 I will disable the compilation of the RRDs perl module.
 303 ])
 304                   COMP_PERL="perl_piped"
 305                fi
 306         fi
 307 fi
 308 AC_MSG_CHECKING(Perl Modules to build)
 309 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 310
 311 # Options to pass when configuring perl module
 312 PERL_MAKE_OPTIONS="PREFIX=$prefix LIB=$prefix/lib/perl/$PERL_VERSION"
 313
 314 dnl pass additional perl options when generating Makefile from Makefile.PL
 315 AC_ARG_ENABLE(perl-site-install,
 316 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 317                           together with rrdtool in $prefix/lib/perl. You have to
 318                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 319                           when you want to use them. When you set this option
 320                           the perl modules will get installed wherever
 321                           your perl setup thinks it is best.],
 322 [PERL_MAKE_OPTIONS=],[])
 323
 324 AC_ARG_WITH(perl-options,
 325 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 326                           generating Makefile from Makefile.PL. If you set this
 327                           option, interesting things may happen unless you know
 328                           what you are doing!],
 329 [PERL_MAKE_OPTIONS=$withval])
 330
 331 AC_SUBST(PERL_MAKE_OPTIONS)
 332 AC_SUBST(PERL)
 333 AC_SUBST(COMP_PERL)
 334 AC_SUBST(PERL_VERSION)
 335
 336
 337 dnl Check for Tcl.
 338 withval=""
 339 AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 340 found=0
 341 AC_MSG_CHECKING(for tclConfig.sh in $withval)
 342 if test -f "$withval/tclConfig.sh" ; then
 343         tcl_config=$withval/tclConfig.sh
 344         found=1
 345         AC_MSG_RESULT(yes)
 346         break
 347 else
 348         AC_MSG_RESULT(no)
 349 fi
 350
 351 if test $found -eq 0 ; then
 352         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 353 else
 354         . $tcl_config
 355 fi
 356
 357
 358 AM_CONDITIONAL(COMP_TCL, test x$found = x1 )
 359
 360 AC_SUBST(TCL_PREFIX)
 361 AC_SUBST(TCL_SHLIB_CFLAGS)
 362 AC_SUBST(TCL_SHLIB_LD)
 363 AC_SUBST(TCL_SHLIB_SUFFIX)
 364 AC_SUBST(TCL_PACKAGE_PATH)
 365 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 366
 367
 368
 369 dnl Check for nroff
 370 AC_PATH_PROGS(NROFF, gnroff nroff)
 371 AC_PATH_PROGS(TROFF, groff troff)
 372
 373 dnl Does the compiler like -Wall and -pedantic?
 374 if test "x$GCC" = "xyes"; then
 375   oCFLAGS=$CFLAGS
 376   CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 377   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 378                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 379                ]
 380         )
 381   if test $rd_cv_gcc_opt = no; then
 382          CFLAGS=$oCFLAGS
 383   fi
 384 fi
 385
 386 dnl what does realloc do if it gets called with a NULL pointer
 387
 388 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 389 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 390               int main(void){
 391               char *x = NULL;
 392               x = realloc (x,10);
 393               if (x==NULL) return 1;
 394               return 0;
 395              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 396
 397 if test x"$rd_cv_null_realloc" = xnope; then
 398 AC_DEFINE(NO_NULL_REALLOC)
 399 fi
 400
 401 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 402           examples/piped-demo.pl                        \
 403           examples/stripes.pl                           \
 404           examples/bigtops.pl                           \
 405           examples/minmax.pl                            \
 406           examples/cgi-demo.cgi                         \
 407           examples/4charts.pl                           \
 408           examples/Makefile                             \
 409           doc/Makefile                                  \
 410           src/Makefile                                  \
 411           bindings/Makefile                             \
 412           bindings/tcl/Makefile                         \
 413           Makefile])
 414 AC_CONFIG_COMMANDS([default],[[\
 415           chmod +x examples/*.cgi examples/*.pl]],[[]])
 416 AC_OUTPUT
 417
 418 AC_MSG_CHECKING(in)
 419 AC_MSG_RESULT(and out again)
 420
 421 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 422 sleep 1
 423 echo $ECHO_N ".$ECHO_C" 1>&6
 424 sleep 1
 425 echo $ECHO_N ".$ECHO_C" 1>&6
 426 sleep 1
 427 echo $ECHO_N ".$ECHO_C" 1>&6
 428 sleep 1
 429 echo $ECHO_N ".$ECHO_C" 1>&6
 430 sleep 1
 431 AC_MSG_RESULT([ just kidding ;-)])
 432 echo
 433 echo "----------------------------------------------------------------"
 434 echo "Config is DONE!"
 435 echo
 436 echo "    With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 437 echo "    Perl Modules: $COMP_PERL"
 438 echo "     Perl Binary: $PERL"
 439 echo "    Perl Version: $PERL_VERSION"
 440 echo "    Perl Options: $PERL_MAKE_OPTIONS"
 441 echo "      Tcl Config: $tcl_config"
 442 echo "    Build rrdcgi: $enable_rrdcgi"
 443 echo " Build librrd MT: $enable_pthread"
 444 echo
 445 echo
 446 echo "Type 'make' to compile the software and use 'make install' to "
 447 echo "install everything to: $prefix."
 448 echo
 449 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 450 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 451 echo "place an order."
 452 echo
 453 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 454 echo "----------------------------------------------------------------"