configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.99907080300])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devel versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.299907080300
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52 /* lets enable madvise defines in NetBSD */
  53 #if defined(__NetBSD__)
  54 # if !defined(_NETBSD_SOURCE)
  55 #  define _NETBSD_SOURCE
  56 # endif
  57 #endif
  58
  59  ])
  60
  61 AH_BOTTOM([
  62 /* make sure that we pickup the correct stuff from all headers */
  63 #ifdef HAVE_FEATURES_H
  64 #undef _XOPEN_SOURCE /* keep unmodified */
  65 #undef _BSD_SOURCE /* keep unmodified */
  66 #define _XOPEN_SOURCE 600
  67 #define _BSD_SOURCE 1
  68 # include <features.h>
  69 #endif
  70
  71 #ifdef HAVE_SYS_TYPES_H
  72 # include <sys/types.h>
  73 #endif
  74
  75 #ifdef HAVE_SYS_PARAM_H
  76 # include <sys/param.h>
  77 #endif
  78 #ifndef MAXPATH
  79 # ifdef PATH_MAX
  80 #  define MAXPATH PATH_MAX
  81 # endif
  82 #endif
  83 #ifndef MAXPATH
  84 /* else try the BSD variant */
  85 # ifdef MAXPATHLEN
  86 #  define MAXPATH MAXPATHLEN
  87 # endif
  88 #endif
  89
  90 #ifdef HAVE_ERRNO_H
  91 # include <errno.h>
  92 #endif
  93
  94 #ifdef HAVE_SYS_MMAN_H
  95 # include <sys/mman.h>
  96 #endif
  97
  98 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
  99 /* use posix_madvise family */
 100 # define madvise posix_madvise
 101 # define MADV_NORMAL POSIX_MADV_NORMAL
 102 # define MADV_RANDOM POSIX_MADV_RANDOM
 103 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
 104 # define MADV_WILLNEED POSIX_MADV_WILLNEED
 105 # define MADV_DONTNEED POSIX_MADV_DONTNEED
 106 #endif
 107 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
 108 # define USE_MADVISE 1
 109 #endif
 110
 111 #ifdef HAVE_SYS_STAT_H
 112 # include <sys/stat.h>
 113 #endif
 114
 115 #ifdef HAVE_FCNTL_H
 116 #include <fcntl.h>
 117 #endif
 118
 119 #ifdef HAVE_UNISTD_H
 120 # include <unistd.h>
 121 #endif
 122
 123 #ifdef TIME_WITH_SYS_TIME
 124 # include <sys/time.h>
 125 # include <time.h>
 126 #else
 127 # ifdef HAVE_SYS_TIME_H
 128 #  include <sys/time.h>
 129 # else
 130 #  include <time.h>
 131 # endif
 132 #endif
 133
 134 #ifdef HAVE_SYS_TIMES_H
 135 # include <sys/times.h>
 136 #endif
 137
 138 #ifdef HAVE_SYS_RESOURCE_H
 139 # include <sys/resource.h>
 140 #if (defined(__svr4__) && defined(__sun__))
 141 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
 142    Use this instead. */
 143 extern int getrusage(int, struct rusage *);
 144 #endif /* __svr4__ && __sun__ */
 145 #endif
 146
 147
 148 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 149    make sure you are NOT using bcopy, index or rindex in the code */
 150
 151 #ifdef STDC_HEADERS
 152 # include <string.h>
 153 #else
 154 # ifndef HAVE_STRCHR
 155 #  define strchr index
 156 #  define strrchr rindex
 157 # endif
 158 char *strchr (), *strrchr ();
 159 # ifndef HAVE_MEMMOVE
 160 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 161 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 162 # endif
 163 #endif
 164
 165 #ifdef NO_NULL_REALLOC
 166 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 167 #else
 168 # define rrd_realloc(a,b) realloc((a), (b))
 169 #endif
 170
 171 #ifdef NEED_MALLOC_MALLOC_H
 172 #  include <malloc/malloc.h>
 173 #endif
 174
 175 #ifdef HAVE_STDIO_H
 176 # include <stdio.h>
 177 #endif
 178
 179 #ifdef HAVE_STDLIB_H
 180 # include <stdlib.h>
 181 #endif
 182
 183 #ifdef HAVE_CTYPE_H
 184 # include <ctype.h>
 185 #endif
 186
 187 #ifdef HAVE_DIRENT_H
 188 # include <dirent.h>
 189 # define NAMLEN(dirent) strlen((dirent)->d_name)
 190 #else
 191 # define dirent direct
 192 # define NAMLEN(dirent) (dirent)->d_namlen
 193 # ifdef HAVE_SYS_NDIR_H
 194 #  include <sys/ndir.h>
 195 # endif
 196 # ifdef HAVE_SYS_DIR_H
 197 #  include <sys/dir.h>
 198 # endif
 199 # ifdef HAVE_NDIR_H
 200 #  include <ndir.h>
 201 # endif
 202 #endif
 203
 204 #ifdef MUST_DISABLE_SIGFPE
 205 # include <signal.h>
 206 #endif
 207
 208 #ifdef MUST_DISABLE_FPMASK
 209 # include <floatingpoint.h>
 210 #endif
 211
 212
 213 #ifdef HAVE_MATH_H
 214 # include <math.h>
 215 #endif
 216
 217 #ifdef HAVE_FLOAT_H
 218 # include <float.h>
 219 #endif
 220
 221 #ifdef HAVE_IEEEFP_H
 222 # include <ieeefp.h>
 223 #endif
 224
 225 #ifdef HAVE_FP_CLASS_H
 226 # include <fp_class.h>
 227 #endif
 228
 229 /* for Solaris */
 230 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 231 #  define HAVE_ISINF 1
 232 #  ifdef isinf
 233 #  undef isinf /* confuse autoconf */
 234 #  endif
 235 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 236 #endif
 237
 238 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 239 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 240 #  undef isnan /* confuse autoconf to NOT remove this */
 241 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 242 #endif
 243
 244 /* for OSF1 Digital Unix */
 245 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 246 #  define HAVE_ISINF 1
 247 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 248 #endif
 249
 250 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 251 #  define HAVE_ISINF 1
 252 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 253 #endif
 254
 255 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 256 #  define HAVE_ISINF 1
 257 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 258 #endif
 259
 260 /* for AIX */
 261 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 262 #  define HAVE_ISINF 1
 263 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 264 #endif
 265
 266 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 267 #  define HAVE_FINITE 1
 268 #  define finite(a) isfinite(a)
 269 #endif
 270
 271 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 272 #  define HAVE_FINITE 1
 273 #  define finite(a) (! isnan(a) && ! isinf(a))
 274 #endif
 275
 276 #ifndef HAVE_FINITE
 277 #error "Can't compile without finite function"
 278 #endif
 279
 280 #ifndef HAVE_ISINF
 281 #error "Can't compile without isinf function"
 282 #endif
 283
 284 #endif /* RRD_CONFIG_H */
 285 ])
 286
 287 dnl Process Special Options
 288 dnl -----------------------------------
 289
 290 dnl How the vertical axis label is printed
 291 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 292  [Vertical label angle: -90.0 (default) or 90.0])
 293 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 294  [Vertical label angle: -90.0 (default) or 90.0])
 295
 296 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 297 [],[enable_rrdcgi=yes])
 298
 299 dnl Check if we run on a system that has fonts
 300 AC_ARG_WITH(rrd-default-font,
 301 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 302 [RRD_DEFAULT_FONT=$withval],[
 303   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 304         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 305   else
 306         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 307   fi
 308 ])
 309
 310 dnl Use mmap in rrd_update instead of seek+write
 311 AC_ARG_ENABLE([mmap],
 312 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 313 [],
 314 [enable_mmap=yes])
 315
 316 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 317 [],[enable_pthread=yes])
 318
 319 AC_ARG_ENABLE(static-programs,
 320      [  --enable-static-programs  Build static programs],
 321      [case "${enableval}" in
 322        yes) staticprogs=yes ;;
 323        no)  staticprogs=no ;;
 324        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 325      esac],[staticprogs=no])
 326 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 327
 328
 329 CONFIGURE_PART(Audit Compilation Environment)
 330
 331
 332 dnl Check for the compiler and static/shared library creation.
 333 AC_PROG_CC
 334 AC_PROG_CPP
 335 AC_PROG_LIBTOOL
 336
 337 dnl Try to detect/use GNU features
 338 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 339
 340 dnl which flags does the compiler support?
 341 if test "x$GCC" = "xyes"; then
 342   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wc++-compat -Wold-style-definition -W; do
 343     oCFLAGS="$CFLAGS"
 344     CFLAGS="$CFLAGS $flag"
 345     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 346     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 347        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 348     if eval test \$$cachename = no; then
 349          CFLAGS="$oCFLAGS"
 350     fi
 351   done
 352 fi
 353
 354
 355
 356 AC_SUBST(RRD_DEFAULT_FONT)
 357
 358 CONFIGURE_PART(Checking for Header Files)
 359
 360 dnl Checks for header files.
 361 AC_HEADER_STDC
 362 AC_HEADER_DIRENT
 363 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 364
 365 dnl Checks for typedefs, structures, and compiler characteristics.
 366 AC_C_CONST
 367 AC_HEADER_TIME
 368 AC_STRUCT_TM
 369
 370 dnl Checks for libraries.
 371 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 372
 373
 374 dnl add pic flag in any case this makes sure all our code is relocatable
 375 eval `./libtool --config | grep pic_flag`
 376 CFLAGS="$CFLAGS $pic_flag"
 377
 378 CONFIGURE_PART(Test Library Functions)
 379
 380 dnl Checks for library functions.
 381 AC_FUNC_STRFTIME
 382 AC_FUNC_VPRINTF
 383
 384 AC_C_BIGENDIAN
 385
 386 dnl for each function found we get a definition in config.h
 387 dnl of the form HAVE_FUNCTION
 388
 389 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 390
 391
 392 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 393 if test "x$enable_mmap" = "xyes"; then
 394   case "$host" in
 395   *cygwin*)
 396     # the normal mmap test does not work in cygwin
 397     AC_CHECK_FUNCS(mmap)
 398     if test "x$ac_cv_func_mmap" = "xyes"; then
 399       ac_cv_func_mmap_fixed_mapped=yes
 400     fi
 401   ;;
 402   *)
 403     AC_CHECK_HEADERS(sys/mman.h)
 404     AC_FUNC_MMAP
 405     AC_CHECK_FUNCS(mmap munmap msync)
 406     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 407                                      # include <sys/mman.h>
 408                                      #endif])
 409     if test "x$ac_cv_have_decl_madvise" = "xyes";
 410     then
 411       AC_CHECK_FUNCS(madvise)
 412     else
 413       AC_CHECK_FUNCS(posix_madvise)
 414       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 415         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 416       fi
 417     fi
 418   ;;
 419   esac
 420   if test "x$ac_cv_func_mmap" != "xyes";
 421   then
 422     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 423 dnl enable_mmap="no"
 424   fi
 425 fi
 426
 427 dnl can we use posix_fadvise
 428 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 429 #include <fcntl.h>])
 430 AC_CHECK_FUNCS(posix_fadvise)
 431
 432
 433
 434 CONFIGURE_PART(IEEE Math Checks)
 435
 436
 437 dnl actual code to check if this works
 438 AC_CHECK_FUNCS(fpclassify, ,
 439   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 440     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 441 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 442       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 443
 444 AC_CHECK_FUNCS(isinf, ,
 445   [AC_MSG_CHECKING(for isinf with <math.h>)
 446     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 447 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 448       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 449
 450 dnl finite is BSD, isfinite is C99, so prefer the latter
 451 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 452 AC_TRY_RUN([
 453 #ifdef HAVE_MATH_H
 454 #include <math.h>
 455 #endif
 456 #ifdef HAVE_FLOAT_H
 457 #include <float.h>
 458 #endif
 459 int main ()
 460 {
 461 #ifdef isfinite
 462 #ifdef LDBL_MAX
 463   if (!isfinite(LDBL_MAX)) return 1;
 464 #endif
 465 #ifdef DBL_MAX
 466   if (!isfinite(DBL_MAX)) return 1;
 467 #endif
 468 #endif
 469 return 0;
 470 }],[
 471 have_broken_isfinite=no],have_broken_isfinite=yes,[
 472 case "${target}" in
 473   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 474   *) have_broken_isfinite=no ;;
 475 esac])
 476 ])
 477 if test "x$have_broken_isfinite" = "xno"; then
 478   AC_DEFINE(HAVE_ISFINITE)
 479 else
 480 AC_CHECK_FUNCS(finite,[],
 481   [AC_CHECK_FUNCS(isfinite,[],
 482       [AC_MSG_CHECKING(for isfinite with <math.h>)
 483        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 484 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 485                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 486 fi
 487
 488 AC_FULL_IEEE
 489
 490 CONFIGURE_PART(Resolve Portability Issues)
 491
 492 dnl what does realloc do if it gets called with a NULL pointer
 493
 494 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 495 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 496               int main(void){
 497               char *x = NULL;
 498               x = realloc (x,10);
 499               if (x==NULL) return 1;
 500               return 0;
 501              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 502
 503 if test x"$rd_cv_null_realloc" = xnope; then
 504 AC_DEFINE(NO_NULL_REALLOC)
 505 fi
 506
 507 AC_LANG_PUSH(C)
 508 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 509 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 510 AC_LINK_IFELSE(
 511     AC_LANG_PROGRAM(
 512            [[#include <time.h>]],
 513            [[ctime_r(NULL,NULL,0)]]
 514                    ),
 515     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 516       AC_LINK_IFELSE(
 517           AC_LANG_PROGRAM(
 518                 [[#include <time.h>]],
 519                 [[ctime_r(NULL,NULL)]]
 520                          ),
 521           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 522           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 523       )
 524     ],
 525     [ AC_LINK_IFELSE(
 526           AC_LANG_PROGRAM(
 527                 [[#include <time.h>]],
 528                 [[ctime_r(NULL,NULL)]]
 529                          ),
 530           [AC_MSG_RESULT(no)],
 531           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 532       )
 533     ]
 534 )
 535 AC_LANG_POP(C)
 536
 537 dnl Check for pthreads
 538 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 539
 540 AC_SUBST(MULTITHREAD_CFLAGS)
 541 AC_SUBST(MULTITHREAD_LDFLAGS)
 542
 543 if test $enable_pthread != no; then
 544  ACX_PTHREAD([
 545     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 546     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 547              ],
 548              [])
 549 fi
 550
 551 dnl since we use lots of *_r functions all over the code we better
 552 dnl make sure they are known
 553
 554 if test  "x$x_rflag" != "xno"; then
 555    CPPFLAGS="$CPPFLAGS $x_rflag"
 556 fi
 557
 558 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 559
 560 AC_LANG_PUSH(C)
 561 dnl see if we have to include malloc/malloc.h
 562 AC_MSG_CHECKING([do we need malloc/malloc.h])
 563 AC_LINK_IFELSE(
 564     AC_LANG_PROGRAM(
 565            [[#include <stdlib.h>]],
 566            [[malloc(1)]]
 567                    ),
 568     [ AC_MSG_RESULT([nope, works out of the box]) ],
 569     [ AC_LINK_IFELSE(
 570           AC_LANG_PROGRAM(
 571                 [[#include <stdlib.h>
 572                   #include <malloc/malloc.h>]],
 573                 [[malloc(1)]]
 574                          ),
 575           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 576            AC_MSG_RESULT([yes we do])],
 577           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 578       )
 579     ]
 580 )
 581 AC_LANG_POP(C)
 582
 583 dnl Could use these to know if we need to provide a prototype
 584 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 585
 586 dnl solaris has fdatasync in the librt
 587
 588 AC_CHECK_FUNC(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"],[]))
 589
 590
 591 CONFIGURE_PART(Find 3rd-Party Libraries)
 592
 593
 594 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 595
 596 CORE_LIBS="$LIBS"
 597
 598 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 599 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 600 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,                     freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 601 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,               fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 602 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 603 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 604 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 605
 606 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 607   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 608 fi
 609
 610 ALL_LIBS="$LIBS"
 611 LIBS=
 612
 613 AC_SUBST(CORE_LIBS)
 614 AC_SUBST(ALL_LIBS)
 615
 616 CONFIGURE_PART(Prep for Building Language Bindings)
 617
 618 dnl Check for Perl.
 619 AC_PATH_PROG(PERL, perl, no)
 620
 621 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 622 [],[enable_perl=yes])
 623
 624
 625 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 626 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 627 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 628 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 629
 630 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 631         COMP_PERL=
 632 else
 633         COMP_PERL="perl_piped perl_shared"
 634         AC_MSG_CHECKING(for the perl version you are running)
 635         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 636         AC_MSG_RESULT($PERL_VERSION)
 637         if test -z "$PERLCC"; then
 638             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 639             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 640             AC_MSG_RESULT($perlcc)
 641             if test ! -x "$perlcc"; then
 642                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 643                 if test "$PERL_CC" = "no"; then
 644                     AC_MSG_WARN([
 645 I would not find the Compiler ($perlcc) that was originally used to compile
 646 your perl binary. You should either make sure that this compiler is
 647 available on your system, pick an other compiler and set PERLCC
 648 appropriately, or use a different perl setup that was compiled locally.
 649
 650 I will disable the compilation of the RRDs perl module for now.
 651 ])
 652                     COMP_PERL="perl_piped"
 653                 fi
 654             fi
 655         fi
 656 fi
 657
 658 AC_MSG_CHECKING(Perl Modules to build)
 659 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 660
 661 # Options to pass when configuring perl module
 662 ppref=$prefix
 663 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 664
 665 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 666
 667 dnl pass additional perl options when generating Makefile from Makefile.PL
 668 AC_ARG_ENABLE(perl-site-install,
 669 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 670                           together with rrdtool in $prefix/lib/perl. You have to
 671                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 672                           when you want to use them. When you set this option
 673                           the perl modules will get installed wherever
 674                           your perl setup thinks it is best.],
 675 [PERL_MAKE_OPTIONS=],[])
 676
 677 if test ! -z "$PERLCC"; then
 678    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 679
 680    if test ! -z "$PERLCCFLAGS"; then
 681        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 682    fi
 683
 684    if test -z "$PERLLD"; then
 685        PERLLD=$PERLCC
 686    fi
 687    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 688
 689    if test ! -z "$PERLLDFLAGS"; then
 690        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 691    fi
 692 fi
 693
 694 AC_ARG_WITH(perl-options,
 695 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 696                           generating Makefile from Makefile.PL. If you set this
 697                           option, interesting things may happen unless you know
 698                           what you are doing!],
 699 [PERL_MAKE_OPTIONS=$withval])
 700
 701 AC_SUBST(PERL_MAKE_OPTIONS)
 702 AC_SUBST(PERL)
 703 AC_SUBST(COMP_PERL)
 704 AC_SUBST(PERL_VERSION)
 705
 706 dnl Check for Ruby.
 707 AC_PATH_PROG(RUBY, ruby, no)
 708
 709 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 710 [],[enable_ruby=yes])
 711
 712 AC_MSG_CHECKING(if ruby modules can be built)
 713
 714 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 715         COMP_RUBY=
 716         AC_MSG_RESULT(No .. Ruby not found or disabled)
 717 else
 718         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 719                 COMP_RUBY="ruby"
 720                 AC_MSG_RESULT(YES)
 721         else
 722                 COMP_RUBY=
 723                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 724         fi
 725 fi
 726
 727
 728 dnl pass additional ruby options when generating Makefile from Makefile.PL
 729 AC_ARG_ENABLE(ruby-site-install,
 730 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 731                           together with rrdtool in $prefix/lib/ruby. You have to
 732                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 733                           for ruby to find the RRD.so file.],
 734 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 735
 736
 737 AC_ARG_WITH(ruby-options,
 738 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 739                           generating Makefile from extconf.rb. If you set this
 740                           option, interesting things may happen unless you know
 741                           what you are doing!],
 742 [RUBY_MAKE_OPTIONS=$withval])
 743
 744 AC_SUBST(RUBY_MAKE_OPTIONS)
 745 AC_SUBST(RUBY)
 746 AC_SUBST(COMP_RUBY)
 747
 748
 749 enable_tcl_site=no
 750
 751 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 752 [],[enable_tcl=yes])
 753
 754 if test  "$enable_tcl" = "yes"; then
 755   dnl Check for Tcl.
 756   withval=""
 757   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 758   enable_tcl=no
 759   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 760     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 761     if test -f "$dir/tclConfig.sh" ; then
 762         tcl_config=$dir/tclConfig.sh
 763         enable_tcl=yes
 764         AC_MSG_RESULT(yes)
 765         break
 766     else
 767         AC_MSG_RESULT(no)
 768     fi
 769   done
 770
 771   if test "$enable_tcl" = "no"; then
 772         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 773   else
 774         . $tcl_config
 775         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 776   fi
 777   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 778   [],[enable_tcl_site=yes])
 779
 780 fi
 781
 782 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 783 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 784
 785 AC_SUBST(TCL_PREFIX)
 786 AC_SUBST(TCL_SHLIB_CFLAGS)
 787 AC_SUBST(TCL_SHLIB_LD)
 788 AC_SUBST(TCL_SHLIB_SUFFIX)
 789 AC_SUBST(TCL_PACKAGE_PATH)
 790 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 791 AC_SUBST(TCL_STUB_LIB_SPEC)
 792 AC_SUBST(TCL_VERSION)
 793 AC_SUBST(TCL_PACKAGE_DIR)
 794 AC_SUBST(TCL_INC_DIR)
 795
 796 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 797 [],[enable_python=yes])
 798
 799 if test  "$enable_python" = "yes"; then
 800 dnl Check for python
 801 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 802 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 803 fi
 804
 805 if test  x$enable_python = xno; then
 806         COMP_PYTHON=
 807 else
 808         COMP_PYTHON="python"
 809 fi
 810
 811 AC_SUBST(COMP_PYTHON)
 812
 813 dnl Check for nroff
 814 AC_PATH_PROGS(NROFF, gnroff nroff)
 815 AC_PATH_PROGS(TROFF, groff troff)
 816
 817 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 818 if test -z "$RRDDOCDIR"; then
 819    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 820
 821
 822 CONFIGURE_PART(Apply Configuration Information)
 823
 824 AC_CONFIG_FILES([examples/shared-demo.pl])
 825 AC_CONFIG_FILES([examples/piped-demo.pl])
 826 AC_CONFIG_FILES([examples/stripes.pl])
 827 AC_CONFIG_FILES([examples/bigtops.pl])
 828 AC_CONFIG_FILES([examples/minmax.pl])
 829 AC_CONFIG_FILES([examples/4charts.pl])
 830 AC_CONFIG_FILES([examples/perftest.pl])
 831 AC_CONFIG_FILES([examples/Makefile])
 832 AC_CONFIG_FILES([doc/Makefile])
 833 AC_CONFIG_FILES([src/Makefile])
 834 AC_CONFIG_FILES([bindings/Makefile])
 835 AC_CONFIG_FILES([bindings/tcl/Makefile])
 836 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 837 AC_CONFIG_FILES([Makefile])
 838
 839 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 840 AC_OUTPUT
 841
 842 AC_MSG_CHECKING(in)
 843 AC_MSG_RESULT(and out again)
 844
 845 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 846 sleep 1
 847 echo $ECHO_N ".$ECHO_C" 1>&6
 848 sleep 1
 849 echo $ECHO_N ".$ECHO_C" 1>&6
 850 sleep 1
 851 echo $ECHO_N ".$ECHO_C" 1>&6
 852 sleep 1
 853 echo $ECHO_N ".$ECHO_C" 1>&6
 854 sleep 1
 855 AC_MSG_RESULT([ just kidding ;-)])
 856 echo
 857 echo "----------------------------------------------------------------"
 858 echo "Config is DONE!"
 859 echo
 860 echo "          With MMAP IO: $enable_mmap"
 861 echo "       Static programs: $staticprogs"
 862 echo "          Perl Modules: $COMP_PERL"
 863 echo "           Perl Binary: $PERL"
 864 echo "          Perl Version: $PERL_VERSION"
 865 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 866 echo "          Ruby Modules: $COMP_RUBY"
 867 echo "           Ruby Binary: $RUBY"
 868 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 869 echo "    Build Tcl Bindings: $enable_tcl"
 870 echo " Build Python Bindings: $enable_python"
 871 echo "          Build rrdcgi: $enable_rrdcgi"
 872 echo "       Build librrd MT: $enable_pthread"
 873 echo
 874 echo
 875 echo "Type 'make' to compile the software and use 'make install' to "
 876 echo "install everything to: $prefix."
 877 echo
 878 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 879 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 880 echo "place an order."
 881 echo
 882 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 883 echo "----------------------------------------------------------------"