configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.11])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devl versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.2011
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29
  30 AC_SUBST(VERSION)
  31
  32 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  33
  34 dnl Minimum Autoconf version required.
  35 AC_PREREQ(2.59)
  36
  37 dnl At the TOP of the HEADER
  38
  39 AH_TOP([
  40
  41 #ifndef CONFIG_H
  42 #define CONFIG_H
  43 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  44 #undef MUST_DISABLE_FPMASK
  45
  46 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  47
  48 #undef MUST_DISABLE_SIGFPE
  49
  50 /* realloc does not support NULL as argument */
  51 #undef NO_NULL_REALLOC
  52
  53  ])
  54
  55 AH_BOTTOM([
  56
  57 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  58    make sure you are NOT using bcopy, index or rindex in the code */
  59
  60 #if STDC_HEADERS
  61 # include <string.h>
  62 #else
  63 # ifndef HAVE_STRCHR
  64 #  define strchr index
  65 #  define strrchr rindex
  66 # endif
  67 char *strchr (), *strrchr ();
  68 # ifndef HAVE_MEMMOVE
  69 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  70 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  71 # endif
  72 #endif
  73
  74
  75 #if NO_NULL_REALLOC
  76 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  77 #else
  78 # define rrd_realloc(a,b) realloc((a), (b))
  79 #endif
  80
  81 #if NEED_MALLOC_MALLOC_H
  82 #  include <malloc/malloc.h>
  83 #endif
  84
  85 #if HAVE_MATH_H
  86 #  include <math.h>
  87 #endif
  88
  89 #if HAVE_FLOAT_H
  90 #  include <float.h>
  91 #endif
  92
  93 #if HAVE_IEEEFP_H
  94 #  include <ieeefp.h>
  95 #endif
  96
  97 #if HAVE_FP_CLASS_H
  98 #  include <fp_class.h>
  99 #endif
 100
 101 /* for Solaris */
 102 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 103 #  define HAVE_ISINF 1
 104 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 105 #endif
 106
 107 /* for OSF1 Digital Unix */
 108 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 109 #  define HAVE_ISINF 1
 110 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 111 #endif
 112
 113 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 114 #  define HAVE_ISINF 1
 115 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 116 #endif
 117
 118 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 119 #  define HAVE_ISINF 1
 120 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 121 #endif
 122
 123 /* for AIX */
 124 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 125 #  define HAVE_ISINF 1
 126 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 127 #endif
 128
 129 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 130 #  define HAVE_FINITE 1
 131 #  define finite(a) isfinite(a)
 132 #endif
 133
 134 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 135 #  define HAVE_FINITE 1
 136 #  define finite(a) (! isnan(a) && ! isinf(a))
 137 #endif
 138
 139 #ifndef HAVE_FINITE
 140 #error "Can't compile without finite function"
 141 #endif
 142
 143 #ifndef HAVE_ISINF
 144 #error "Can't compile without isinf function"
 145 #endif
 146
 147 #endif /* CONFIG_H */
 148 ])
 149
 150 dnl Process Special Options
 151 dnl -----------------------------------
 152
 153 dnl How the vertical axis label is printed
 154 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 155  [Vertical label angle: 90.0 (default) or 270.0])
 156 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 157  [Vertical label angle: 90.0 (default) or 270.0])
 158
 159 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 160 [],[enable_rrdcgi=yes])
 161
 162 dnl Check if we run on a system that has fonts
 163 AC_ARG_WITH(rrd-default-font,
 164 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 165 [RRD_DEFAULT_FONT=$withval],[
 166   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 167         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 168   else
 169         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 170   fi
 171 ])
 172
 173 dnl Use mmap in rrd_update instead of seek+write
 174 AC_ARG_ENABLE([mmap],
 175 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 176 [],
 177 [enable_mmap=yes])
 178
 179
 180  AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 181 [],[enable_pthread=yes])
 182
 183
 184
 185 CONFIGURE_PART(Audit Compilation Environment)
 186
 187
 188 dnl Check for the compiler and static/shared library creation.
 189 AC_PROG_CC
 190 AC_PROG_CPP
 191 AC_PROG_LIBTOOL
 192
 193
 194 AC_SUBST(RRD_DEFAULT_FONT)
 195
 196 CONFIGURE_PART(Checking for Header Files)
 197
 198 dnl Checks for header files.
 199 AC_HEADER_STDC
 200 AC_HEADER_DIRENT
 201 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 202
 203 dnl Checks for typedefs, structures, and compiler characteristics.
 204 AC_C_CONST
 205 AC_HEADER_TIME
 206 AC_STRUCT_TM
 207
 208 dnl Checks for libraries.
 209 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 210
 211 dnl add pic flag in any case this makes sure all our code is relocatable
 212 eval `./libtool --config | grep pic_flag`
 213 CFLAGS="$CFLAGS $pic_flag"
 214
 215 CONFIGURE_PART(Test Library Functions)
 216
 217 dnl Checks for library functions.
 218 AC_FUNC_STRFTIME
 219 AC_FUNC_VPRINTF
 220
 221 AC_C_BIGENDIAN
 222
 223 dnl for each function found we get a definition in config.h
 224 dnl of the form HAVE_FUNCTION
 225
 226 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 227
 228
 229 if test "x$enable_mmap" = xyes; then
 230   case "$host" in
 231     *cygwin*)
 232        # the normal mmap test does not work in cygwin
 233        AC_CHECK_FUNCS(mmap)
 234        if [ "x${ac_cv_func_mmap}" = xyes ]; then
 235          ac_cv_func_mmap_fixed_mapped=yes
 236        fi
 237     ;;
 238     *)
 239        AC_FUNC_MMAP
 240     ;;
 241   esac
 242 fi
 243
 244
 245 CONFIGURE_PART(IEEE Math Checks)
 246
 247 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 248 dnl actual code to check if this works
 249 AC_CHECK_FUNCS(fpclassify, ,
 250   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 251     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 252 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 253       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 254 AC_CHECK_FUNCS(finite, ,
 255   [AC_CHECK_FUNCS(isfinite, ,
 256     [AC_MSG_CHECKING(for isfinite with <math.h>)
 257     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 258 volatile int x;volatile float f;  ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 259       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 260 AC_CHECK_FUNCS(isinf, ,
 261   [AC_MSG_CHECKING(for isinf with <math.h>)
 262     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 263 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 264       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 265
 266 AC_FULL_IEEE
 267
 268 CONFIGURE_PART(Resolve Portability Issues)
 269
 270 dnl what does realloc do if it gets called with a NULL pointer
 271
 272 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 273 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 274               int main(void){
 275               char *x = NULL;
 276               x = realloc (x,10);
 277               if (x==NULL) return 1;
 278               return 0;
 279              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 280
 281 if test x"$rd_cv_null_realloc" = xnope; then
 282 AC_DEFINE(NO_NULL_REALLOC)
 283 fi
 284
 285 AC_LANG_PUSH(C)
 286 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 287 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 288 AC_LINK_IFELSE(
 289     AC_LANG_PROGRAM(
 290            [[#include <time.h>]],
 291            [[ctime_r(NULL,NULL,0)]]
 292                    ),
 293     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 294       AC_LINK_IFELSE(
 295           AC_LANG_PROGRAM(
 296                 [[#include <time.h>]],
 297                 [[ctime_r(NULL,NULL)]]
 298                          ),
 299           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 300           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 301       )
 302     ],
 303     [ AC_LINK_IFELSE(
 304           AC_LANG_PROGRAM(
 305                 [[#include <time.h>]],
 306                 [[ctime_r(NULL,NULL)]]
 307                          ),
 308           [AC_MSG_RESULT(no)],
 309           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 310       )
 311     ]
 312 )
 313 AC_LANG_POP(C)
 314
 315 dnl Check for pthreads
 316 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 317
 318 AC_SUBST(MULTITHREAD_CFLAGS)
 319 AC_SUBST(MULTITHREAD_LDFLAGS)
 320
 321 if test $enable_pthread != no; then
 322  ACX_PTHREAD([
 323     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 324     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 325              ],
 326              [])
 327 fi
 328
 329 dnl since we use lots of *_r functions all over the code we better
 330 dnl make sure they are known
 331
 332 if test  "x$x_rflag" != "xno"; then
 333    CPPFLAGS="$CPPFLAGS $x_rflag"
 334 fi
 335
 336 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 337
 338 AC_LANG_PUSH(C)
 339 dnl see if we have to include malloc/malloc.h
 340 AC_MSG_CHECKING([do we need malloc/malloc.h])
 341 AC_LINK_IFELSE(
 342     AC_LANG_PROGRAM(
 343            [[#include <stdlib.h>]],
 344            [[malloc(1)]]
 345                    ),
 346     [ AC_MSG_RESULT([nope, works out of the box]) ],
 347     [ AC_LINK_IFELSE(
 348           AC_LANG_PROGRAM(
 349                 [[#include <stdlib.h>
 350                   #include <malloc/malloc.h>]],
 351                 [[malloc(1)]]
 352                          ),
 353           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 354            AC_MSG_RESULT([yes we do])],
 355           [AC_MSG_ERROR([Can't figure how to compile malloc])]
 356       )
 357     ]
 358 )
 359 AC_LANG_POP(C)
 360
 361 CONFIGURE_PART(Findr 3rd-Party Libraries)
 362
 363
 364 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 365
 366 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 367 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.2,  http://www.gzip.org/zlib/, "")
 368 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 369 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 370
 371 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 372   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 373 fi
 374
 375
 376 CONFIGURE_PART(Prep for Building Language Bindings)
 377
 378 dnl Check for Perl.
 379 AC_PATH_PROG(PERL, perl, no)
 380
 381 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 382 [],[enable_perl=yes])
 383
 384
 385 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 386 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 387 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 388 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 389
 390 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 391         COMP_PERL=
 392 else
 393         COMP_PERL="perl_piped perl_shared"
 394         AC_MSG_CHECKING(for the perl version you are running)
 395         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 396         AC_MSG_RESULT($PERL_VERSION)
 397         if test -z "$PERLCC"; then
 398             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 399             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 400             AC_MSG_RESULT($perlcc)
 401             if test ! -x "$perlcc"; then
 402                 AC_PATH_PROG(PERL_CC, "${perlcc}", no)
 403                 if test "$PERL_CC" = "no"; then
 404                     AC_MSG_WARN([
 405 I would not find the Compiler ($perlcc) that was originally used to compile
 406 your perl binary. You should either make sure that this compiler is
 407 available on your system, pick an other compiler and set PERLCC
 408 appropriately, or use a different perl setup that was compiled locally.
 409
 410 I will disable the compilation of the RRDs perl module for now.
 411 ])
 412                     COMP_PERL="perl_piped"
 413                 fi
 414             fi
 415         fi
 416 fi
 417
 418 AC_MSG_CHECKING(Perl Modules to build)
 419 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 420
 421 # Options to pass when configuring perl module
 422 ppref=$prefix
 423 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 424
 425 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 426
 427 dnl pass additional perl options when generating Makefile from Makefile.PL
 428 AC_ARG_ENABLE(perl-site-install,
 429 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 430                           together with rrdtool in $prefix/lib/perl. You have to
 431                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 432                           when you want to use them. When you set this option
 433                           the perl modules will get installed wherever
 434                           your perl setup thinks it is best.],
 435 [PERL_MAKE_OPTIONS=],[])
 436
 437 if test ! -z "$PERLCC"; then
 438    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 439
 440    if test ! -z "$PERLCCFLAGS"; then
 441        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 442    fi
 443
 444    if test -z "$PERLLD"; then
 445        PERLLD=$PERLCC
 446    fi
 447    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 448
 449    if test ! -z "$PERLLDFLAGS"; then
 450        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 451    fi
 452 fi
 453
 454 AC_ARG_WITH(perl-options,
 455 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 456                           generating Makefile from Makefile.PL. If you set this
 457                           option, interesting things may happen unless you know
 458                           what you are doing!],
 459 [PERL_MAKE_OPTIONS=$withval])
 460
 461 AC_SUBST(PERL_MAKE_OPTIONS)
 462 AC_SUBST(PERL)
 463 AC_SUBST(COMP_PERL)
 464 AC_SUBST(PERL_VERSION)
 465
 466 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 467 [],[enable_tcl=yes])
 468
 469 if test  "$enable_tcl" = "yes"; then
 470   dnl Check for Tcl.
 471   withval=""
 472   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 473   enable_tcl=no
 474   for dir in $withval /usr/lib /usr/local/lib; do
 475     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 476     if test -f "$dir/tclConfig.sh" ; then
 477         tcl_config=$dir/tclConfig.sh
 478         enable_tcl=yes
 479         AC_MSG_RESULT(yes)
 480         break
 481     else
 482         AC_MSG_RESULT(no)
 483     fi
 484   done
 485
 486   if test "$enable_tcl" = "no"; then
 487         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 488   else
 489         . $tcl_config
 490         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 491   fi
 492 fi
 493
 494 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 495
 496 AC_SUBST(TCL_PREFIX)
 497 AC_SUBST(TCL_SHLIB_CFLAGS)
 498 AC_SUBST(TCL_SHLIB_LD)
 499 AC_SUBST(TCL_SHLIB_SUFFIX)
 500 AC_SUBST(TCL_PACKAGE_PATH)
 501 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 502 AC_SUBST(TCL_STUB_LIB_SPEC)
 503 AC_SUBST(TCL_VERSION)
 504 AC_SUBST(TCL_PACKAGE_DIR)
 505
 506 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 507 [],[enable_python=yes])
 508
 509 if test  "$enable_python" = "yes"; then
 510 dnl Check for python
 511 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 512 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 513 fi
 514
 515 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
 516
 517 dnl Check for nroff
 518 AC_PATH_PROGS(NROFF, gnroff nroff)
 519 AC_PATH_PROGS(TROFF, groff troff)
 520
 521 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 522 if test -z "$RRDDOCDIR"; then
 523    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 524
 525 dnl Does the compiler like -Wall and -pedantic?
 526 if test "$GCC" = "yes"; then
 527   oCFLAGS=$CFLAGS
 528   CFLAGS="$CFLAGS -fno-strict-aliasing -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 529   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 530                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 531                ]
 532         )
 533   if test $rd_cv_gcc_opt = no; then
 534          CFLAGS=$oCFLAGS
 535   fi
 536 fi
 537
 538
 539 CONFIGURE_PART(Apply Configuration Information)
 540
 541 AC_CONFIG_FILES([examples/shared-demo.pl])
 542 AC_CONFIG_FILES([examples/piped-demo.pl])
 543 AC_CONFIG_FILES([examples/stripes.pl])
 544 AC_CONFIG_FILES([examples/bigtops.pl])
 545 AC_CONFIG_FILES([examples/minmax.pl])
 546 AC_CONFIG_FILES([examples/cgi-demo.cgi])
 547 AC_CONFIG_FILES([examples/4charts.pl])
 548 AC_CONFIG_FILES([examples/Makefile])
 549 AC_CONFIG_FILES([doc/Makefile])
 550 AC_CONFIG_FILES([src/Makefile])
 551 AC_CONFIG_FILES([bindings/Makefile])
 552 AC_CONFIG_FILES([bindings/tcl/Makefile])
 553 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 554 AC_CONFIG_FILES([bindings/python/Makefile])
 555 AC_CONFIG_FILES([Makefile])
 556
 557 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.cgi examples/*.pl]],[[]])
 558 AC_OUTPUT
 559
 560 AC_MSG_CHECKING(in)
 561 AC_MSG_RESULT(and out again)
 562
 563 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 564 sleep 1
 565 echo $ECHO_N ".$ECHO_C" 1>&6
 566 sleep 1
 567 echo $ECHO_N ".$ECHO_C" 1>&6
 568 sleep 1
 569 echo $ECHO_N ".$ECHO_C" 1>&6
 570 sleep 1
 571 echo $ECHO_N ".$ECHO_C" 1>&6
 572 sleep 1
 573 AC_MSG_RESULT([ just kidding ;-)])
 574 echo
 575 echo "----------------------------------------------------------------"
 576 echo "Config is DONE!"
 577 echo
 578 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 579 echo "          Perl Modules: $COMP_PERL"
 580 echo "           Perl Binary: $PERL"
 581 echo "          Perl Version: $PERL_VERSION"
 582 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 583 echo "    Build Tcl Bindings: $enable_tcl"
 584 echo " Build Python Bindings: $enable_python"
 585 echo "          Build rrdcgi: $enable_rrdcgi"
 586 echo "       Build librrd MT: $enable_pthread"
 587 echo
 588 echo
 589 echo "Type 'make' to compile the software and use 'make install' to "
 590 echo "install everything to: $prefix."
 591 echo
 592 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 593 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 594 echo "place an order."
 595 echo
 596 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 597 echo "----------------------------------------------------------------"