configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.10])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devl versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.2010
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29
  30 AC_SUBST(VERSION)
  31
  32 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  33
  34 dnl Minimum Autoconf version required.
  35 AC_PREREQ(2.59)
  36
  37 dnl At the TOP of the HEADER
  38
  39 AH_TOP([
  40
  41 #ifndef CONFIG_H
  42 #define CONFIG_H
  43 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  44 #undef MUST_DISABLE_FPMASK
  45
  46 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  47
  48 #undef MUST_DISABLE_SIGFPE
  49
  50 /* realloc does not support NULL as argument */
  51 #undef NO_NULL_REALLOC
  52
  53  ])
  54
  55 AH_BOTTOM([
  56
  57 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  58    make sure you are NOT using bcopy, index or rindex in the code */
  59
  60 #if STDC_HEADERS
  61 # include <string.h>
  62 #else
  63 # ifndef HAVE_STRCHR
  64 #  define strchr index
  65 #  define strrchr rindex
  66 # endif
  67 char *strchr (), *strrchr ();
  68 # ifndef HAVE_MEMMOVE
  69 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  70 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  71 # endif
  72 #endif
  73
  74
  75 #if NO_NULL_REALLOC
  76 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  77 #else
  78 # define rrd_realloc(a,b) realloc((a), (b))
  79 #endif
  80
  81 #if HAVE_MATH_H
  82 #  include <math.h>
  83 #endif
  84
  85 #if HAVE_FLOAT_H
  86 #  include <float.h>
  87 #endif
  88
  89 #if HAVE_IEEEFP_H
  90 #  include <ieeefp.h>
  91 #endif
  92
  93 #if HAVE_FP_CLASS_H
  94 #  include <fp_class.h>
  95 #endif
  96
  97 /* for Solaris */
  98 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
  99 #  define HAVE_ISINF 1
 100 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 101 #endif
 102
 103 /* for OSF1 Digital Unix */
 104 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 105 #  define HAVE_ISINF 1
 106 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 107 #endif
 108
 109 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 110 #  define HAVE_ISINF 1
 111 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 112 #endif
 113
 114 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 115 #  define HAVE_ISINF 1
 116 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 117 #endif
 118
 119 /* for AIX */
 120 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 121 #  define HAVE_ISINF 1
 122 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 123 #endif
 124
 125 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 126 #  define HAVE_FINITE 1
 127 #  define finite(a) isfinite(a)
 128 #endif
 129
 130 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 131 #  define HAVE_FINITE 1
 132 #  define finite(a) (! isnan(a) && ! isinf(a))
 133 #endif
 134
 135 #ifndef HAVE_FINITE
 136 #error "Can't compile without finite function"
 137 #endif
 138
 139 #ifndef HAVE_ISINF
 140 #error "Can't compile without isinf function"
 141 #endif
 142
 143 #endif /* CONFIG_H */
 144 ])
 145
 146
 147
 148 dnl Check for the compiler and static/shared library creation.
 149 AC_PROG_CC
 150 AC_PROG_CPP
 151 AC_PROG_LIBTOOL
 152
 153 dnl Check if we run on a system that has fonts
 154 AC_ARG_WITH(rrd-default-font,
 155 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 156 [RRD_DEFAULT_FONT=$withval],[
 157   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 158         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 159   else
 160         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 161   fi
 162 ])
 163
 164 AC_SUBST(RRD_DEFAULT_FONT)
 165
 166 dnl Checks for header files.
 167 AC_HEADER_STDC
 168 AC_HEADER_DIRENT
 169 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 170
 171 dnl Checks for typedefs, structures, and compiler characteristics.
 172 AC_C_CONST
 173 AC_HEADER_TIME
 174 AC_STRUCT_TM
 175
 176 dnl Checks for libraries.
 177 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 178
 179 dnl add pic flag in any case this makes sure all our code is relocatable
 180 eval `./libtool --config | grep pic_flag`
 181 CFLAGS="$CFLAGS $pic_flag"
 182
 183 dnl Checks for library functions.
 184 AC_FUNC_STRFTIME
 185 AC_FUNC_VPRINTF
 186
 187 AC_C_BIGENDIAN
 188
 189 dnl for each function found we get a definition in config.h
 190 dnl of the form HAVE_FUNCTION
 191
 192 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 193
 194 dnl Use mmap in rrd_update instead of seek+write
 195 AC_ARG_ENABLE([mmap],
 196 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 197 [],
 198 [enable_mmap=yes])
 199
 200 if test "x$enable_mmap" = xyes; then
 201   AC_FUNC_MMAP
 202 fi
 203
 204 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 205 dnl actual code to check if this works
 206 AC_CHECK_FUNCS(fpclassify, ,
 207   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 208     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
 209       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 210 AC_CHECK_FUNCS(finite, ,
 211   [AC_CHECK_FUNCS(isfinite, ,
 212     [AC_MSG_CHECKING(for isfinite with <math.h>)
 213     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
 214       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 215 AC_CHECK_FUNCS(isinf, ,
 216   [AC_MSG_CHECKING(for isinf with <math.h>)
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
 218       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 219
 220 AC_FULL_IEEE
 221
 222 dnl How the vertical axis label is printed
 223 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 224  [Vertical label angle: 90.0 (default) or 270.0])
 225 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 226  [Vertical label angle: 90.0 (default) or 270.0])
 227
 228
 229 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 230 [],[enable_rrdcgi=yes])
 231 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 232
 233 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 234 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.2,  http://www.gzip.org/zlib/, "")
 235 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 236 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 237
 238 save_LIBS=${LIBS}
 239 save_CPPFLAGS=${CPPFLAGS}
 240 save_LDFLAGS=${LDFLAGS}
 241
 242 if test $enable_rrdcgi != no; then
 243 EX_CHECK_ALL(cgi,        cgiInit,                   cgi.h,                  cgilib,      0.5,    http://www.infodrom.org/projects/cgilib, "")
 244 fi
 245
 246 CGI_LIBS=${LIBS}
 247 CGI_CPPFLAGS=${CPPFLAGS}
 248 CGI_LDFLAGS=${LDFLAGS}
 249
 250 AC_SUBST(CGI_LIBS)
 251 AC_SUBST(CGI_CPPFLAGS)
 252 AC_SUBST(CGI_LDFLAGS)
 253
 254 LIBS=${save_LIBS}
 255 CPPFLAGS=${save_CPPFLAGS}
 256 LDFLAGS=${save_LDFLAGS}
 257
 258 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 259   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 260 fi
 261
 262 AC_LANG_PUSH(C)
 263 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 264 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 265 AC_LINK_IFELSE(
 266     AC_LANG_PROGRAM(
 267            [[#include <time.h>]],
 268            [[ctime_r(NULL,NULL,0)]]
 269                    ),
 270     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 271       AC_LINK_IFELSE(
 272           AC_LANG_PROGRAM(
 273                 [[#include <time.h>]],
 274                 [[ctime_r(NULL,NULL)]]
 275                          ),
 276           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 277           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 278       )
 279     ],
 280     [ AC_LINK_IFELSE(
 281           AC_LANG_PROGRAM(
 282                 [[#include <time.h>]],
 283                 [[ctime_r(NULL,NULL)]]
 284                          ),
 285           [AC_MSG_RESULT(no)],
 286           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 287       )
 288     ]
 289 )
 290 AC_LANG_POP(C)
 291
 292 dnl Check for pthreads
 293 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 294
 295 AC_SUBST(MULTITHREAD_CFLAGS)
 296 AC_SUBST(MULTITHREAD_LDFLAGS)
 297
 298
 299 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 300 [],[enable_pthread=yes])
 301
 302
 303 if test $enable_pthread != no; then
 304  ACX_PTHREAD([
 305     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 306     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 307              ],
 308              [])
 309 fi
 310
 311 dnl since we use lots of *_r functions all over the code we better
 312 dnl make sure they are known
 313
 314 if test  "x$x_rflag" != "xno"; then
 315    CPPFLAGS="$CPPFLAGS $x_rflag"
 316 fi
 317
 318
 319 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 320
 321 dnl Check for Perl.
 322 AC_PATH_PROG(PERL, perl, no)
 323
 324 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 325 [],[enable_perl=yes])
 326
 327
 328 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 329         COMP_PERL=
 330 else
 331         COMP_PERL="perl_piped perl_shared"
 332         AC_MSG_CHECKING(for the perl version you are running)
 333         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 334         AC_MSG_RESULT($PERL_VERSION)
 335         AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 336         perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 337         AC_MSG_RESULT($perlcc)
 338         if test ! -x "$perlcc"; then
 339                AC_PATH_PROG(PERLCC, "${perlcc}", no)
 340                if test "$PERLCC" = "no"; then
 341                   AC_MSG_WARN([
 342 I would not find the Compiler ($perlcc) that was originally used to compile your
 343 perl binary. You should either make sure that this compiler is available on your
 344 system, or use a different perl setup that was compiled with $CC.
 345
 346 I will disable the compilation of the RRDs perl module.
 347 ])
 348                   COMP_PERL="perl_piped"
 349                fi
 350         fi
 351 fi
 352 AC_MSG_CHECKING(Perl Modules to build)
 353 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 354
 355 # Options to pass when configuring perl module
 356 ppref=$prefix
 357 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 358
 359 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 360
 361 dnl pass additional perl options when generating Makefile from Makefile.PL
 362 AC_ARG_ENABLE(perl-site-install,
 363 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 364                           together with rrdtool in $prefix/lib/perl. You have to
 365                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 366                           when you want to use them. When you set this option
 367                           the perl modules will get installed wherever
 368                           your perl setup thinks it is best.],
 369 [PERL_MAKE_OPTIONS=],[])
 370
 371 AC_ARG_WITH(perl-options,
 372 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 373                           generating Makefile from Makefile.PL. If you set this
 374                           option, interesting things may happen unless you know
 375                           what you are doing!],
 376 [PERL_MAKE_OPTIONS=$withval])
 377
 378 AC_SUBST(PERL_MAKE_OPTIONS)
 379 AC_SUBST(PERL)
 380 AC_SUBST(COMP_PERL)
 381 AC_SUBST(PERL_VERSION)
 382
 383 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 384 [],[enable_tcl=yes])
 385
 386 if test  "$enable_tcl" = "yes"; then
 387   dnl Check for Tcl.
 388   withval=""
 389   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 390   enable_tcl=no
 391   for dir in $withval /usr/lib /usr/local/lib; do
 392     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 393     if test -f "$dir/tclConfig.sh" ; then
 394         tcl_config=$dir/tclConfig.sh
 395         enable_tcl=yes
 396         AC_MSG_RESULT(yes)
 397         break
 398     else
 399         AC_MSG_RESULT(no)
 400     fi
 401   done
 402
 403   if test "$enable_tcl" = "no"; then
 404         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 405   else
 406         . $tcl_config
 407         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 408   fi
 409 fi
 410
 411 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 412
 413 AC_SUBST(TCL_PREFIX)
 414 AC_SUBST(TCL_SHLIB_CFLAGS)
 415 AC_SUBST(TCL_SHLIB_LD)
 416 AC_SUBST(TCL_SHLIB_SUFFIX)
 417 AC_SUBST(TCL_PACKAGE_PATH)
 418 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 419 AC_SUBST(TCL_VERSION)
 420 AC_SUBST(TCL_PACKAGE_DIR)
 421
 422 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 423 [],[enable_python=yes])
 424
 425 if test  "$enable_python" = "yes"; then
 426 dnl Check for python
 427 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 428 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 429 fi
 430
 431 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
 432
 433 dnl Check for nroff
 434 AC_PATH_PROGS(NROFF, gnroff nroff)
 435 AC_PATH_PROGS(TROFF, groff troff)
 436
 437 dnl Does the compiler like -Wall and -pedantic?
 438 if test "$GCC" = "yes"; then
 439   oCFLAGS=$CFLAGS
 440   CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 441   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 442                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 443                ]
 444         )
 445   if test $rd_cv_gcc_opt = no; then
 446          CFLAGS=$oCFLAGS
 447   fi
 448 fi
 449
 450 dnl what does realloc do if it gets called with a NULL pointer
 451
 452 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 453 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 454               int main(void){
 455               char *x = NULL;
 456               x = realloc (x,10);
 457               if (x==NULL) return 1;
 458               return 0;
 459              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 460
 461 if test x"$rd_cv_null_realloc" = xnope; then
 462 AC_DEFINE(NO_NULL_REALLOC)
 463 fi
 464
 465 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 466           examples/piped-demo.pl                        \
 467           examples/stripes.pl                           \
 468           examples/bigtops.pl                           \
 469           examples/minmax.pl                            \
 470           examples/cgi-demo.cgi                         \
 471           examples/4charts.pl                           \
 472           examples/Makefile                             \
 473           doc/Makefile                                  \
 474           src/Makefile                                  \
 475           bindings/Makefile                             \
 476           bindings/tcl/Makefile                         \
 477           bindings/tcl/ifOctets.tcl                     \
 478           bindings/python/Makefile                      \
 479           Makefile])
 480 AC_CONFIG_COMMANDS([default],[[\
 481           chmod +x examples/*.cgi examples/*.pl]],[[]])
 482 AC_OUTPUT
 483
 484 AC_MSG_CHECKING(in)
 485 AC_MSG_RESULT(and out again)
 486
 487 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 488 sleep 1
 489 echo $ECHO_N ".$ECHO_C" 1>&6
 490 sleep 1
 491 echo $ECHO_N ".$ECHO_C" 1>&6
 492 sleep 1
 493 echo $ECHO_N ".$ECHO_C" 1>&6
 494 sleep 1
 495 echo $ECHO_N ".$ECHO_C" 1>&6
 496 sleep 1
 497 AC_MSG_RESULT([ just kidding ;-)])
 498 echo
 499 echo "----------------------------------------------------------------"
 500 echo "Config is DONE!"
 501 echo
 502 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 503 echo "          Perl Modules: $COMP_PERL"
 504 echo "           Perl Binary: $PERL"
 505 echo "          Perl Version: $PERL_VERSION"
 506 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 507 echo "    Build Tcl Bindings: $enable_tcl"
 508 echo " Build Python Bindings: $enable_python"
 509 echo "          Build rrdcgi: $enable_rrdcgi"
 510 echo "       Build librrd MT: $enable_pthread"
 511 echo
 512 echo
 513 echo "Type 'make' to compile the software and use 'make install' to "
 514 echo "install everything to: $prefix."
 515 echo
 516 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 517 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 518 echo "place an order."
 519 echo
 520 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 521 echo "----------------------------------------------------------------"