configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.99907080300])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devel versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.299907080300
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52 /* lets enable madvise defines in netbsd */
  53 #if defined(__NetBSD__)
  54 # if !defined(_NETBSD_SOURCE)
  55 #  define _NETBSD_SOURCE
  56 # endif
  57 #endif
  58
  59  ])
  60
  61 AH_BOTTOM([
  62 /* make sure that we pickup the correct stuff from all headers */
  63 #define _XOPEN_SOURCE 600
  64 #ifdef HAVE_FEATURES_H
  65 # include <features.h>
  66 #endif
  67
  68 #ifdef HAVE_SYS_TYPES_H
  69 # include <sys/types.h>
  70 #endif
  71
  72 #ifdef HAVE_SYS_PARAM_H
  73 # include <sys/param.h>
  74 #endif
  75 #ifndef MAXPATH
  76 # ifdef PATH_MAX
  77 #  define MAXPATH PATH_MAX
  78 # endif
  79 #endif
  80 #ifndef MAXPATH
  81 /* else try the BSD variant */
  82 # ifdef MAXPATHLEN
  83 #  define MAXPATH MAXPATHLEN
  84 # endif
  85 #endif
  86
  87 #ifdef HAVE_ERRNO_H
  88 # include <errno.h>
  89 #endif
  90
  91 #ifdef HAVE_SYS_MMAN_H
  92 # include <sys/mman.h>
  93 #endif
  94
  95 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
  96 /* use posix_madvise family */
  97 # define madvise posix_madvise
  98 # define MADV_NORMAL POSIX_MADV_NORMAL
  99 # define MADV_RANDOM POSIX_MADV_RANDOM
 100 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
 101 # define MADV_WILLNEED POSIX_MADV_WILLNEED
 102 # define MADV_DONTNEED POSIX_MADV_DONTNEED
 103 #endif
 104 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
 105 # define USE_MADVISE 1
 106 #endif
 107
 108 #ifdef HAVE_SYS_STAT_H
 109 # include <sys/stat.h>
 110 #endif
 111
 112 #ifdef HAVE_FCNTL_H
 113 #include <fcntl.h>
 114 #endif
 115
 116 #ifdef HAVE_UNISTD_H
 117 # include <unistd.h>
 118 #endif
 119
 120 #ifdef TIME_WITH_SYS_TIME
 121 # include <sys/time.h>
 122 # include <time.h>
 123 #else
 124 # ifdef HAVE_SYS_TIME_H
 125 #  include <sys/time.h>
 126 # else
 127 #  include <time.h>
 128 # endif
 129 #endif
 130
 131 #ifdef HAVE_SYS_TIMES_H
 132 # include <sys/times.h>
 133 #endif
 134
 135 #ifdef HAVE_SYS_RESOURCE_H
 136 # include <sys/resource.h>
 137 #if (defined(__svr4__) && defined(__sun__))
 138 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
 139    Use this instead. */
 140 extern int getrusage(int, struct rusage *);
 141 #endif /* __svr4__ && __sun__ */
 142 #endif
 143
 144
 145 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 146    make sure you are NOT using bcopy, index or rindex in the code */
 147
 148 #ifdef STDC_HEADERS
 149 # include <string.h>
 150 #else
 151 # ifndef HAVE_STRCHR
 152 #  define strchr index
 153 #  define strrchr rindex
 154 # endif
 155 char *strchr (), *strrchr ();
 156 # ifndef HAVE_MEMMOVE
 157 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 158 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 159 # endif
 160 #endif
 161
 162 #ifdef NO_NULL_REALLOC
 163 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 164 #else
 165 # define rrd_realloc(a,b) realloc((a), (b))
 166 #endif
 167
 168 #ifdef NEED_MALLOC_MALLOC_H
 169 #  include <malloc/malloc.h>
 170 #endif
 171
 172 #ifdef HAVE_STDIO_H
 173 # include <stdio.h>
 174 #endif
 175
 176 #ifdef HAVE_STDLIB_H
 177 # include <stdlib.h>
 178 #endif
 179
 180 #ifdef HAVE_CTYPE_H
 181 # include <ctype.h>
 182 #endif
 183
 184 #ifdef HAVE_DIRENT_H
 185 # include <dirent.h>
 186 # define NAMLEN(dirent) strlen((dirent)->d_name)
 187 #else
 188 # define dirent direct
 189 # define NAMLEN(dirent) (dirent)->d_namlen
 190 # ifdef HAVE_SYS_NDIR_H
 191 #  include <sys/ndir.h>
 192 # endif
 193 # ifdef HAVE_SYS_DIR_H
 194 #  include <sys/dir.h>
 195 # endif
 196 # ifdef HAVE_NDIR_H
 197 #  include <ndir.h>
 198 # endif
 199 #endif
 200
 201 #ifdef MUST_DISABLE_SIGFPE
 202 # include <signal.h>
 203 #endif
 204
 205 #ifdef MUST_DISABLE_FPMASK
 206 # include <floatingpoint.h>
 207 #endif
 208
 209
 210 #ifdef HAVE_MATH_H
 211 # include <math.h>
 212 #endif
 213
 214 #ifdef HAVE_FLOAT_H
 215 # include <float.h>
 216 #endif
 217
 218 #ifdef HAVE_IEEEFP_H
 219 # include <ieeefp.h>
 220 #endif
 221
 222 #ifdef HAVE_FP_CLASS_H
 223 # include <fp_class.h>
 224 #endif
 225
 226 /* for Solaris */
 227 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 228 #  define HAVE_ISINF 1
 229 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 230 #endif
 231
 232 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 233 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 234 #  undef isnan
 235 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 236 #endif
 237
 238 /* for OSF1 Digital Unix */
 239 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 240 #  define HAVE_ISINF 1
 241 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 242 #endif
 243
 244 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 245 #  define HAVE_ISINF 1
 246 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 247 #endif
 248
 249 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 250 #  define HAVE_ISINF 1
 251 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 252 #endif
 253
 254 /* for AIX */
 255 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 256 #  define HAVE_ISINF 1
 257 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 258 #endif
 259
 260 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 261 #  define HAVE_FINITE 1
 262 #  define finite(a) isfinite(a)
 263 #endif
 264
 265 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 266 #  define HAVE_FINITE 1
 267 #  define finite(a) (! isnan(a) && ! isinf(a))
 268 #endif
 269
 270 #ifndef HAVE_FINITE
 271 #error "Can't compile without finite function"
 272 #endif
 273
 274 #ifndef HAVE_ISINF
 275 #error "Can't compile without isinf function"
 276 #endif
 277
 278 #endif /* RRD_CONFIG_H */
 279 ])
 280
 281 dnl Process Special Options
 282 dnl -----------------------------------
 283
 284 dnl How the vertical axis label is printed
 285 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 286  [Vertical label angle: -90.0 (default) or 90.0])
 287 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 288  [Vertical label angle: -90.0 (default) or 90.0])
 289
 290 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 291 [],[enable_rrdcgi=yes])
 292
 293 dnl Check if we run on a system that has fonts
 294 AC_ARG_WITH(rrd-default-font,
 295 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 296 [RRD_DEFAULT_FONT=$withval],[
 297   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 298         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 299   else
 300         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 301   fi
 302 ])
 303
 304 dnl Use mmap in rrd_update instead of seek+write
 305 AC_ARG_ENABLE([mmap],
 306 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 307 [],
 308 [enable_mmap=yes])
 309
 310 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 311 [],[enable_pthread=yes])
 312
 313 AC_ARG_ENABLE(static-programs,
 314      [  --enable-static-programs  Build static programs],
 315      [case "${enableval}" in
 316        yes) staticprogs=yes ;;
 317        no)  staticprogs=no ;;
 318        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 319      esac],[staticprogs=no])
 320 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 321
 322
 323 CONFIGURE_PART(Audit Compilation Environment)
 324
 325
 326 dnl Check for the compiler and static/shared library creation.
 327 AC_PROG_CC
 328 AC_PROG_CPP
 329 AC_PROG_LIBTOOL
 330
 331 dnl Try to detect/use GNU features
 332 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 333
 334 dnl which flags does the compiler support?
 335 if test "x$GCC" = "xyes"; then
 336   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wc++-compat -Wold-style-definition -W; do
 337     oCFLAGS="$CFLAGS"
 338     CFLAGS="$CFLAGS $flag"
 339     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 340     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 341        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 342     if eval test \$$cachename = no; then
 343          CFLAGS="$oCFLAGS"
 344     fi
 345   done
 346 fi
 347
 348
 349
 350 AC_SUBST(RRD_DEFAULT_FONT)
 351
 352 CONFIGURE_PART(Checking for Header Files)
 353
 354 dnl Checks for header files.
 355 AC_HEADER_STDC
 356 AC_HEADER_DIRENT
 357 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 358
 359 dnl Checks for typedefs, structures, and compiler characteristics.
 360 AC_C_CONST
 361 AC_HEADER_TIME
 362 AC_STRUCT_TM
 363
 364 dnl Checks for libraries.
 365 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 366
 367 dnl add pic flag in any case this makes sure all our code is relocatable
 368 eval `./libtool --config | grep pic_flag`
 369 CFLAGS="$CFLAGS $pic_flag"
 370
 371 CONFIGURE_PART(Test Library Functions)
 372
 373 dnl Checks for library functions.
 374 AC_FUNC_STRFTIME
 375 AC_FUNC_VPRINTF
 376
 377 AC_C_BIGENDIAN
 378
 379 dnl for each function found we get a definition in config.h
 380 dnl of the form HAVE_FUNCTION
 381
 382 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 383
 384 dnl Could use these to know if we need to provide a prototype
 385 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 386
 387 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 388 if test "x$enable_mmap" = "xyes"; then
 389   case "$host" in
 390   *cygwin*)
 391     # the normal mmap test does not work in cygwin
 392     AC_CHECK_FUNCS(mmap)
 393     if test "x$ac_cv_func_mmap" = "xyes"; then
 394       ac_cv_func_mmap_fixed_mapped=yes
 395     fi
 396   ;;
 397   *)
 398     AC_CHECK_HEADERS(sys/mman.h)
 399     AC_FUNC_MMAP
 400     AC_CHECK_FUNCS(mmap munmap msync)
 401     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 402                                      # include <sys/mman.h>
 403                                      #endif])
 404     if test "x$ac_cv_have_decl_madvise" = "xyes";
 405     then
 406       AC_CHECK_FUNCS(madvise)
 407     else
 408       AC_CHECK_FUNCS(posix_madvise)
 409       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 410         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 411       fi
 412     fi
 413   ;;
 414   esac
 415   if test "x$ac_cv_func_mmap" != "xyes";
 416   then
 417     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 418 dnl enable_mmap="no"
 419   fi
 420 fi
 421
 422 dnl can we use posix_fadvise
 423 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 424 #include <fcntl.h>])
 425 AC_CHECK_FUNCS(posix_fadvise)
 426
 427
 428
 429 CONFIGURE_PART(IEEE Math Checks)
 430
 431
 432 dnl actual code to check if this works
 433 AC_CHECK_FUNCS(fpclassify, ,
 434   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 435     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 436 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 437       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 438
 439 AC_CHECK_FUNCS(isinf, ,
 440   [AC_MSG_CHECKING(for isinf with <math.h>)
 441     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 442 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 443       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 444
 445 dnl finite is BSD, isfinite is C99, so prefer the latter
 446 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 447 AC_TRY_RUN([
 448 #ifdef HAVE_MATH_H
 449 #include <math.h>
 450 #endif
 451 #ifdef HAVE_FLOAT_H
 452 #include <float.h>
 453 #endif
 454 int main ()
 455 {
 456 #ifdef isfinite
 457 #ifdef LDBL_MAX
 458   if (!isfinite(LDBL_MAX)) return 1;
 459 #endif
 460 #ifdef DBL_MAX
 461   if (!isfinite(DBL_MAX)) return 1;
 462 #endif
 463 #endif
 464 return 0;
 465 }],[
 466 have_broken_isfinite=no],have_broken_isfinite=yes,[
 467 case "${target}" in
 468   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 469   *) have_broken_isfinite=no ;;
 470 esac])
 471 ])
 472 if test "x$have_broken_isfinite" = "xno"; then
 473   AC_DEFINE(HAVE_ISFINITE)
 474 else
 475 AC_CHECK_FUNCS(finite,[],
 476   [AC_CHECK_FUNCS(isfinite,[],
 477       [AC_MSG_CHECKING(for isfinite with <math.h>)
 478        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 479 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 480                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 481 fi
 482
 483 AC_FULL_IEEE
 484
 485 CONFIGURE_PART(Resolve Portability Issues)
 486
 487 dnl what does realloc do if it gets called with a NULL pointer
 488
 489 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 490 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 491               int main(void){
 492               char *x = NULL;
 493               x = realloc (x,10);
 494               if (x==NULL) return 1;
 495               return 0;
 496              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 497
 498 if test x"$rd_cv_null_realloc" = xnope; then
 499 AC_DEFINE(NO_NULL_REALLOC)
 500 fi
 501
 502 AC_LANG_PUSH(C)
 503 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 504 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 505 AC_LINK_IFELSE(
 506     AC_LANG_PROGRAM(
 507            [[#include <time.h>]],
 508            [[ctime_r(NULL,NULL,0)]]
 509                    ),
 510     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 511       AC_LINK_IFELSE(
 512           AC_LANG_PROGRAM(
 513                 [[#include <time.h>]],
 514                 [[ctime_r(NULL,NULL)]]
 515                          ),
 516           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 517           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 518       )
 519     ],
 520     [ AC_LINK_IFELSE(
 521           AC_LANG_PROGRAM(
 522                 [[#include <time.h>]],
 523                 [[ctime_r(NULL,NULL)]]
 524                          ),
 525           [AC_MSG_RESULT(no)],
 526           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 527       )
 528     ]
 529 )
 530 AC_LANG_POP(C)
 531
 532 dnl Check for pthreads
 533 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 534
 535 AC_SUBST(MULTITHREAD_CFLAGS)
 536 AC_SUBST(MULTITHREAD_LDFLAGS)
 537
 538 if test $enable_pthread != no; then
 539  ACX_PTHREAD([
 540     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 541     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 542              ],
 543              [])
 544 fi
 545
 546 dnl since we use lots of *_r functions all over the code we better
 547 dnl make sure they are known
 548
 549 if test  "x$x_rflag" != "xno"; then
 550    CPPFLAGS="$CPPFLAGS $x_rflag"
 551 fi
 552
 553 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 554
 555 AC_LANG_PUSH(C)
 556 dnl see if we have to include malloc/malloc.h
 557 AC_MSG_CHECKING([do we need malloc/malloc.h])
 558 AC_LINK_IFELSE(
 559     AC_LANG_PROGRAM(
 560            [[#include <stdlib.h>]],
 561            [[malloc(1)]]
 562                    ),
 563     [ AC_MSG_RESULT([nope, works out of the box]) ],
 564     [ AC_LINK_IFELSE(
 565           AC_LANG_PROGRAM(
 566                 [[#include <stdlib.h>
 567                   #include <malloc/malloc.h>]],
 568                 [[malloc(1)]]
 569                          ),
 570           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 571            AC_MSG_RESULT([yes we do])],
 572           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 573       )
 574     ]
 575 )
 576 AC_LANG_POP(C)
 577
 578 CONFIGURE_PART(Find 3rd-Party Libraries)
 579
 580
 581 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 582
 583 CORE_LIBS="$LIBS"
 584
 585 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 586 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 587 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,                     freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 588 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,               fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 589 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 590 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 591 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 592
 593 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 594   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 595 fi
 596
 597 ALL_LIBS="$LIBS"
 598 LIBS=
 599
 600 AC_SUBST(CORE_LIBS)
 601 AC_SUBST(ALL_LIBS)
 602
 603 CONFIGURE_PART(Prep for Building Language Bindings)
 604
 605 dnl Check for Perl.
 606 AC_PATH_PROG(PERL, perl, no)
 607
 608 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 609 [],[enable_perl=yes])
 610
 611
 612 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 613 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 614 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 615 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 616
 617 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 618         COMP_PERL=
 619 else
 620         COMP_PERL="perl_piped perl_shared"
 621         AC_MSG_CHECKING(for the perl version you are running)
 622         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 623         AC_MSG_RESULT($PERL_VERSION)
 624         if test -z "$PERLCC"; then
 625             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 626             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 627             AC_MSG_RESULT($perlcc)
 628             if test ! -x "$perlcc"; then
 629                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 630                 if test "$PERL_CC" = "no"; then
 631                     AC_MSG_WARN([
 632 I would not find the Compiler ($perlcc) that was originally used to compile
 633 your perl binary. You should either make sure that this compiler is
 634 available on your system, pick an other compiler and set PERLCC
 635 appropriately, or use a different perl setup that was compiled locally.
 636
 637 I will disable the compilation of the RRDs perl module for now.
 638 ])
 639                     COMP_PERL="perl_piped"
 640                 fi
 641             fi
 642         fi
 643 fi
 644
 645 AC_MSG_CHECKING(Perl Modules to build)
 646 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 647
 648 # Options to pass when configuring perl module
 649 ppref=$prefix
 650 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 651
 652 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 653
 654 dnl pass additional perl options when generating Makefile from Makefile.PL
 655 AC_ARG_ENABLE(perl-site-install,
 656 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 657                           together with rrdtool in $prefix/lib/perl. You have to
 658                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 659                           when you want to use them. When you set this option
 660                           the perl modules will get installed wherever
 661                           your perl setup thinks it is best.],
 662 [PERL_MAKE_OPTIONS=],[])
 663
 664 if test ! -z "$PERLCC"; then
 665    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 666
 667    if test ! -z "$PERLCCFLAGS"; then
 668        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 669    fi
 670
 671    if test -z "$PERLLD"; then
 672        PERLLD=$PERLCC
 673    fi
 674    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 675
 676    if test ! -z "$PERLLDFLAGS"; then
 677        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 678    fi
 679 fi
 680
 681 AC_ARG_WITH(perl-options,
 682 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 683                           generating Makefile from Makefile.PL. If you set this
 684                           option, interesting things may happen unless you know
 685                           what you are doing!],
 686 [PERL_MAKE_OPTIONS=$withval])
 687
 688 AC_SUBST(PERL_MAKE_OPTIONS)
 689 AC_SUBST(PERL)
 690 AC_SUBST(COMP_PERL)
 691 AC_SUBST(PERL_VERSION)
 692
 693 dnl Check for Ruby.
 694 AC_PATH_PROG(RUBY, ruby, no)
 695
 696 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 697 [],[enable_ruby=yes])
 698
 699 AC_MSG_CHECKING(if ruby modules can be built)
 700
 701 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 702         COMP_RUBY=
 703         AC_MSG_RESULT(No .. Ruby not found or disabled)
 704 else
 705         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 706                 COMP_RUBY="ruby"
 707                 AC_MSG_RESULT(YES)
 708         else
 709                 COMP_RUBY=
 710                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 711         fi
 712 fi
 713
 714
 715 dnl pass additional ruby options when generating Makefile from Makefile.PL
 716 AC_ARG_ENABLE(ruby-site-install,
 717 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 718                           together with rrdtool in $prefix/lib/ruby. You have to
 719                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 720                           for ruby to find the RRD.so file.],
 721 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 722
 723
 724 AC_ARG_WITH(ruby-options,
 725 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 726                           generating Makefile from extconf.rb. If you set this
 727                           option, interesting things may happen unless you know
 728                           what you are doing!],
 729 [RUBY_MAKE_OPTIONS=$withval])
 730
 731 AC_SUBST(RUBY_MAKE_OPTIONS)
 732 AC_SUBST(RUBY)
 733 AC_SUBST(COMP_RUBY)
 734
 735
 736 enable_tcl_site=no
 737
 738 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 739 [],[enable_tcl=yes])
 740
 741 if test  "$enable_tcl" = "yes"; then
 742   dnl Check for Tcl.
 743   withval=""
 744   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 745   enable_tcl=no
 746   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 747     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 748     if test -f "$dir/tclConfig.sh" ; then
 749         tcl_config=$dir/tclConfig.sh
 750         enable_tcl=yes
 751         AC_MSG_RESULT(yes)
 752         break
 753     else
 754         AC_MSG_RESULT(no)
 755     fi
 756   done
 757
 758   if test "$enable_tcl" = "no"; then
 759         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 760   else
 761         . $tcl_config
 762         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 763   fi
 764   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 765   [],[enable_tcl_site=yes])
 766
 767 fi
 768
 769 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 770 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 771
 772 AC_SUBST(TCL_PREFIX)
 773 AC_SUBST(TCL_SHLIB_CFLAGS)
 774 AC_SUBST(TCL_SHLIB_LD)
 775 AC_SUBST(TCL_SHLIB_SUFFIX)
 776 AC_SUBST(TCL_PACKAGE_PATH)
 777 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 778 AC_SUBST(TCL_STUB_LIB_SPEC)
 779 AC_SUBST(TCL_VERSION)
 780 AC_SUBST(TCL_PACKAGE_DIR)
 781 AC_SUBST(TCL_INC_DIR)
 782
 783 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 784 [],[enable_python=yes])
 785
 786 if test  "$enable_python" = "yes"; then
 787 dnl Check for python
 788 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 789 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 790 fi
 791
 792 if test  x$enable_python = xno; then
 793         COMP_PYTHON=
 794 else
 795         COMP_PYTHON="python"
 796 fi
 797
 798 AC_SUBST(COMP_PYTHON)
 799
 800 dnl Check for nroff
 801 AC_PATH_PROGS(NROFF, gnroff nroff)
 802 AC_PATH_PROGS(TROFF, groff troff)
 803
 804 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 805 if test -z "$RRDDOCDIR"; then
 806    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 807
 808
 809 CONFIGURE_PART(Apply Configuration Information)
 810
 811 AC_CONFIG_FILES([examples/shared-demo.pl])
 812 AC_CONFIG_FILES([examples/piped-demo.pl])
 813 AC_CONFIG_FILES([examples/stripes.pl])
 814 AC_CONFIG_FILES([examples/bigtops.pl])
 815 AC_CONFIG_FILES([examples/minmax.pl])
 816 AC_CONFIG_FILES([examples/4charts.pl])
 817 AC_CONFIG_FILES([examples/perftest.pl])
 818 AC_CONFIG_FILES([examples/Makefile])
 819 AC_CONFIG_FILES([doc/Makefile])
 820 AC_CONFIG_FILES([src/Makefile])
 821 AC_CONFIG_FILES([bindings/Makefile])
 822 AC_CONFIG_FILES([bindings/tcl/Makefile])
 823 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 824 AC_CONFIG_FILES([Makefile])
 825
 826 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 827 AC_OUTPUT
 828
 829 AC_MSG_CHECKING(in)
 830 AC_MSG_RESULT(and out again)
 831
 832 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 833 sleep 1
 834 echo $ECHO_N ".$ECHO_C" 1>&6
 835 sleep 1
 836 echo $ECHO_N ".$ECHO_C" 1>&6
 837 sleep 1
 838 echo $ECHO_N ".$ECHO_C" 1>&6
 839 sleep 1
 840 echo $ECHO_N ".$ECHO_C" 1>&6
 841 sleep 1
 842 AC_MSG_RESULT([ just kidding ;-)])
 843 echo
 844 echo "----------------------------------------------------------------"
 845 echo "Config is DONE!"
 846 echo
 847 echo "          With MMAP IO: $enable_mmap"
 848 echo "       Static programs: $staticprogs"
 849 echo "          Perl Modules: $COMP_PERL"
 850 echo "           Perl Binary: $PERL"
 851 echo "          Perl Version: $PERL_VERSION"
 852 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 853 echo "          Ruby Modules: $COMP_RUBY"
 854 echo "           Ruby Binary: $RUBY"
 855 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 856 echo "    Build Tcl Bindings: $enable_tcl"
 857 echo " Build Python Bindings: $enable_python"
 858 echo "          Build rrdcgi: $enable_rrdcgi"
 859 echo "       Build librrd MT: $enable_pthread"
 860 echo
 861 echo
 862 echo "Type 'make' to compile the software and use 'make install' to "
 863 echo "install everything to: $prefix."
 864 echo
 865 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 866 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 867 echo "place an order."
 868 echo
 869 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 870 echo "----------------------------------------------------------------"