configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.11])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devl versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.2011
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29
  30 AC_SUBST(VERSION)
  31
  32 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  33
  34 dnl Minimum Autoconf version required.
  35 AC_PREREQ(2.59)
  36
  37 dnl At the TOP of the HEADER
  38
  39 AH_TOP([
  40
  41 #ifndef CONFIG_H
  42 #define CONFIG_H
  43 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  44 #undef MUST_DISABLE_FPMASK
  45
  46 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  47
  48 #undef MUST_DISABLE_SIGFPE
  49
  50 /* realloc does not support NULL as argument */
  51 #undef NO_NULL_REALLOC
  52
  53  ])
  54
  55 AH_BOTTOM([
  56
  57 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  58    make sure you are NOT using bcopy, index or rindex in the code */
  59
  60 #if STDC_HEADERS
  61 # include <string.h>
  62 #else
  63 # ifndef HAVE_STRCHR
  64 #  define strchr index
  65 #  define strrchr rindex
  66 # endif
  67 char *strchr (), *strrchr ();
  68 # ifndef HAVE_MEMMOVE
  69 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  70 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  71 # endif
  72 #endif
  73
  74
  75 #if NO_NULL_REALLOC
  76 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  77 #else
  78 # define rrd_realloc(a,b) realloc((a), (b))
  79 #endif
  80
  81 #if NEED_MALLOC_MALLOC_H
  82 #  include <malloc/malloc.h>
  83 #endif
  84
  85 #if HAVE_MATH_H
  86 #  include <math.h>
  87 #endif
  88
  89 #if HAVE_FLOAT_H
  90 #  include <float.h>
  91 #endif
  92
  93 #if HAVE_IEEEFP_H
  94 #  include <ieeefp.h>
  95 #endif
  96
  97 #if HAVE_FP_CLASS_H
  98 #  include <fp_class.h>
  99 #endif
 100
 101 /* for Solaris */
 102 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 103 #  define HAVE_ISINF 1
 104 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 105 #endif
 106
 107 /* for OSF1 Digital Unix */
 108 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 109 #  define HAVE_ISINF 1
 110 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 111 #endif
 112
 113 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 114 #  define HAVE_ISINF 1
 115 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 116 #endif
 117
 118 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 119 #  define HAVE_ISINF 1
 120 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 121 #endif
 122
 123 /* for AIX */
 124 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 125 #  define HAVE_ISINF 1
 126 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 127 #endif
 128
 129 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 130 #  define HAVE_FINITE 1
 131 #  define finite(a) isfinite(a)
 132 #endif
 133
 134 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 135 #  define HAVE_FINITE 1
 136 #  define finite(a) (! isnan(a) && ! isinf(a))
 137 #endif
 138
 139 #ifndef HAVE_FINITE
 140 #error "Can't compile without finite function"
 141 #endif
 142
 143 #ifndef HAVE_ISINF
 144 #error "Can't compile without isinf function"
 145 #endif
 146
 147 #endif /* CONFIG_H */
 148 ])
 149
 150
 151
 152 dnl Check for the compiler and static/shared library creation.
 153 AC_PROG_CC
 154 AC_PROG_CPP
 155 AC_PROG_LIBTOOL
 156
 157 dnl Check if we run on a system that has fonts
 158 AC_ARG_WITH(rrd-default-font,
 159 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 160 [RRD_DEFAULT_FONT=$withval],[
 161   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 162         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 163   else
 164         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 165   fi
 166 ])
 167
 168 AC_SUBST(RRD_DEFAULT_FONT)
 169
 170 dnl Checks for header files.
 171 AC_HEADER_STDC
 172 AC_HEADER_DIRENT
 173 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 174
 175 dnl Checks for typedefs, structures, and compiler characteristics.
 176 AC_C_CONST
 177 AC_HEADER_TIME
 178 AC_STRUCT_TM
 179
 180 dnl Checks for libraries.
 181 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 182
 183 dnl add pic flag in any case this makes sure all our code is relocatable
 184 eval `./libtool --config | grep pic_flag`
 185 CFLAGS="$CFLAGS $pic_flag"
 186
 187 dnl Checks for library functions.
 188 AC_FUNC_STRFTIME
 189 AC_FUNC_VPRINTF
 190
 191 AC_C_BIGENDIAN
 192
 193 dnl for each function found we get a definition in config.h
 194 dnl of the form HAVE_FUNCTION
 195
 196 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 197
 198 dnl Use mmap in rrd_update instead of seek+write
 199 AC_ARG_ENABLE([mmap],
 200 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 201 [],
 202 [enable_mmap=yes])
 203
 204 if test "x$enable_mmap" = xyes; then
 205   AC_FUNC_MMAP
 206 fi
 207
 208 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 209 dnl actual code to check if this works
 210 AC_CHECK_FUNCS(fpclassify, ,
 211   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 213 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 214       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 215 AC_CHECK_FUNCS(finite, ,
 216   [AC_CHECK_FUNCS(isfinite, ,
 217     [AC_MSG_CHECKING(for isfinite with <math.h>)
 218     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 219 volatile int x;volatile float f;  ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 220       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 221 AC_CHECK_FUNCS(isinf, ,
 222   [AC_MSG_CHECKING(for isinf with <math.h>)
 223     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 224 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 225       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 226
 227 AC_FULL_IEEE
 228
 229 AC_LANG_PUSH(C)
 230 dnl see if we have to include malloc/malloc.h
 231 AC_MSG_CHECKING([do we need malloc/malloc.h])
 232 AC_LINK_IFELSE(
 233     AC_LANG_PROGRAM(
 234            [[#include <stdlib.h>]],
 235            [[malloc(1)]]
 236                    ),
 237     [ AC_MSG_RESULT([nope, works out of the box]) ],
 238     [ AC_LINK_IFELSE(
 239           AC_LANG_PROGRAM(
 240                 [[#include <stdlib.h>
 241                   #include <malloc/malloc.h>]],
 242                 [[malloc(1)]]
 243                          ),
 244           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 245            AC_MSG_RESULT([yes we do])],
 246           [AC_MSG_ERROR([Can't figure how to compile malloc])]
 247       )
 248     ]
 249 )
 250 AC_LANG_POP(C)
 251
 252 dnl How the vertical axis label is printed
 253 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 254  [Vertical label angle: 90.0 (default) or 270.0])
 255 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 256  [Vertical label angle: 90.0 (default) or 270.0])
 257
 258
 259 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 260 [],[enable_rrdcgi=yes])
 261 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 262
 263 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 264 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.2,  http://www.gzip.org/zlib/, "")
 265 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 266 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 267
 268 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 269   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 270 fi
 271
 272 AC_LANG_PUSH(C)
 273 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 274 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 275 AC_LINK_IFELSE(
 276     AC_LANG_PROGRAM(
 277            [[#include <time.h>]],
 278            [[ctime_r(NULL,NULL,0)]]
 279                    ),
 280     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 281       AC_LINK_IFELSE(
 282           AC_LANG_PROGRAM(
 283                 [[#include <time.h>]],
 284                 [[ctime_r(NULL,NULL)]]
 285                          ),
 286           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 287           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 288       )
 289     ],
 290     [ AC_LINK_IFELSE(
 291           AC_LANG_PROGRAM(
 292                 [[#include <time.h>]],
 293                 [[ctime_r(NULL,NULL)]]
 294                          ),
 295           [AC_MSG_RESULT(no)],
 296           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 297       )
 298     ]
 299 )
 300 AC_LANG_POP(C)
 301
 302 dnl Check for pthreads
 303 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 304
 305 AC_SUBST(MULTITHREAD_CFLAGS)
 306 AC_SUBST(MULTITHREAD_LDFLAGS)
 307
 308
 309 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 310 [],[enable_pthread=yes])
 311
 312
 313 if test $enable_pthread != no; then
 314  ACX_PTHREAD([
 315     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 316     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 317              ],
 318              [])
 319 fi
 320
 321 dnl since we use lots of *_r functions all over the code we better
 322 dnl make sure they are known
 323
 324 if test  "x$x_rflag" != "xno"; then
 325    CPPFLAGS="$CPPFLAGS $x_rflag"
 326 fi
 327
 328
 329 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 330
 331 dnl Check for Perl.
 332 AC_PATH_PROG(PERL, perl, no)
 333
 334 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 335 [],[enable_perl=yes])
 336
 337
 338 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 339 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 340 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 341 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 342
 343 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 344         COMP_PERL=
 345 else
 346         COMP_PERL="perl_piped perl_shared"
 347         AC_MSG_CHECKING(for the perl version you are running)
 348         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 349         AC_MSG_RESULT($PERL_VERSION)
 350         if test -z "$PERLCC"; then
 351             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 352             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 353             AC_MSG_RESULT($perlcc)
 354             if test ! -x "$perlcc"; then
 355                 AC_PATH_PROG(PERL_CC, "${perlcc}", no)
 356                 if test "$PERL_CC" = "no"; then
 357                     AC_MSG_WARN([
 358 I would not find the Compiler ($perlcc) that was originally used to compile
 359 your perl binary. You should either make sure that this compiler is
 360 available on your system, pick an other compiler and set PERLCC
 361 appropriately, or use a different perl setup that was compiled locally.
 362
 363 I will disable the compilation of the RRDs perl module for now.
 364 ])
 365                     COMP_PERL="perl_piped"
 366                 fi
 367             fi
 368         fi
 369 fi
 370 AC_MSG_CHECKING(Perl Modules to build)
 371 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 372
 373 # Options to pass when configuring perl module
 374 ppref=$prefix
 375 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 376
 377 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 378
 379 dnl pass additional perl options when generating Makefile from Makefile.PL
 380 AC_ARG_ENABLE(perl-site-install,
 381 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 382                           together with rrdtool in $prefix/lib/perl. You have to
 383                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 384                           when you want to use them. When you set this option
 385                           the perl modules will get installed wherever
 386                           your perl setup thinks it is best.],
 387 [PERL_MAKE_OPTIONS=],[])
 388
 389 if test ! -z "$PERLCC"; then
 390    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 391
 392    if test ! -z "$PERLCCFLAGS"; then
 393        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 394    fi
 395
 396    if test -z "$PERLLD"; then
 397        PERLLD=$PERLCC
 398    fi
 399    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 400
 401    if test ! -z "$PERLLDFLAGS"; then
 402        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 403    fi
 404 fi
 405
 406 AC_ARG_WITH(perl-options,
 407 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 408                           generating Makefile from Makefile.PL. If you set this
 409                           option, interesting things may happen unless you know
 410                           what you are doing!],
 411 [PERL_MAKE_OPTIONS=$withval])
 412
 413 AC_SUBST(PERL_MAKE_OPTIONS)
 414 AC_SUBST(PERL)
 415 AC_SUBST(COMP_PERL)
 416 AC_SUBST(PERL_VERSION)
 417
 418 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 419 [],[enable_tcl=yes])
 420
 421 if test  "$enable_tcl" = "yes"; then
 422   dnl Check for Tcl.
 423   withval=""
 424   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 425   enable_tcl=no
 426   for dir in $withval /usr/lib /usr/local/lib; do
 427     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 428     if test -f "$dir/tclConfig.sh" ; then
 429         tcl_config=$dir/tclConfig.sh
 430         enable_tcl=yes
 431         AC_MSG_RESULT(yes)
 432         break
 433     else
 434         AC_MSG_RESULT(no)
 435     fi
 436   done
 437
 438   if test "$enable_tcl" = "no"; then
 439         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 440   else
 441         . $tcl_config
 442         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 443   fi
 444 fi
 445
 446 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 447
 448 AC_SUBST(TCL_PREFIX)
 449 AC_SUBST(TCL_SHLIB_CFLAGS)
 450 AC_SUBST(TCL_SHLIB_LD)
 451 AC_SUBST(TCL_SHLIB_SUFFIX)
 452 AC_SUBST(TCL_PACKAGE_PATH)
 453 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 454 AC_SUBST(TCL_STUB_LIB_SPEC)
 455 AC_SUBST(TCL_VERSION)
 456 AC_SUBST(TCL_PACKAGE_DIR)
 457
 458 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 459 [],[enable_python=yes])
 460
 461 if test  "$enable_python" = "yes"; then
 462 dnl Check for python
 463 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 464 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 465 fi
 466
 467 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
 468
 469 dnl Check for nroff
 470 AC_PATH_PROGS(NROFF, gnroff nroff)
 471 AC_PATH_PROGS(TROFF, groff troff)
 472
 473 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 474 if test -z "$RRDDOCDIR"; then
 475    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 476
 477 dnl Does the compiler like -Wall and -pedantic?
 478 if test "$GCC" = "yes"; then
 479   oCFLAGS=$CFLAGS
 480   CFLAGS="$CFLAGS -fno-strict-aliasing -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 481   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 482                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 483                ]
 484         )
 485   if test $rd_cv_gcc_opt = no; then
 486          CFLAGS=$oCFLAGS
 487   fi
 488 fi
 489
 490 dnl what does realloc do if it gets called with a NULL pointer
 491
 492 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 493 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 494               int main(void){
 495               char *x = NULL;
 496               x = realloc (x,10);
 497               if (x==NULL) return 1;
 498               return 0;
 499              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 500
 501 if test x"$rd_cv_null_realloc" = xnope; then
 502 AC_DEFINE(NO_NULL_REALLOC)
 503 fi
 504
 505 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 506           examples/piped-demo.pl                        \
 507           examples/stripes.pl                           \
 508           examples/bigtops.pl                           \
 509           examples/minmax.pl                            \
 510           examples/cgi-demo.cgi                         \
 511           examples/4charts.pl                           \
 512           examples/Makefile                             \
 513           doc/Makefile                                  \
 514           src/Makefile                                  \
 515           bindings/Makefile                             \
 516           bindings/tcl/Makefile                         \
 517           bindings/tcl/ifOctets.tcl                     \
 518           bindings/python/Makefile                      \
 519           Makefile])
 520 AC_CONFIG_COMMANDS([default],[[\
 521           chmod +x examples/*.cgi examples/*.pl]],[[]])
 522 AC_OUTPUT
 523
 524 AC_MSG_CHECKING(in)
 525 AC_MSG_RESULT(and out again)
 526
 527 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 528 sleep 1
 529 echo $ECHO_N ".$ECHO_C" 1>&6
 530 sleep 1
 531 echo $ECHO_N ".$ECHO_C" 1>&6
 532 sleep 1
 533 echo $ECHO_N ".$ECHO_C" 1>&6
 534 sleep 1
 535 echo $ECHO_N ".$ECHO_C" 1>&6
 536 sleep 1
 537 AC_MSG_RESULT([ just kidding ;-)])
 538 echo
 539 echo "----------------------------------------------------------------"
 540 echo "Config is DONE!"
 541 echo
 542 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 543 echo "          Perl Modules: $COMP_PERL"
 544 echo "           Perl Binary: $PERL"
 545 echo "          Perl Version: $PERL_VERSION"
 546 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 547 echo "    Build Tcl Bindings: $enable_tcl"
 548 echo " Build Python Bindings: $enable_python"
 549 echo "          Build rrdcgi: $enable_rrdcgi"
 550 echo "       Build librrd MT: $enable_pthread"
 551 echo
 552 echo
 553 echo "Type 'make' to compile the software and use 'make install' to "
 554 echo "install everything to: $prefix."
 555 echo
 556 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 557 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 558 echo "place an order."
 559 echo
 560 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 561 echo "----------------------------------------------------------------"