configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.99907080300])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devel versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.299907080300
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52 /* lets enable madvise defines in netbsd */
  53 #if defined(__NetBSD__)
  54 # if !defined(_NETBSD_SOURCE)
  55 #  define _NETBSD_SOURCE
  56 # endif
  57 #endif
  58
  59  ])
  60
  61 AH_BOTTOM([
  62 /* make sure that we pickup the correct stuff from all headers */
  63 #define _XOPEN_SOURCE 600
  64 #ifdef HAVE_FEATURES_H
  65 # include <features.h>
  66 #endif
  67
  68 #ifdef HAVE_SYS_TYPES_H
  69 # include <sys/types.h>
  70 #endif
  71
  72 #ifdef HAVE_SYS_PARAM_H
  73 # include <sys/param.h>
  74 #endif
  75 #ifndef MAXPATH
  76 # ifdef PATH_MAX
  77 #  define MAXPATH PATH_MAX
  78 # endif
  79 #endif
  80 #ifndef MAXPATH
  81 /* else try the BSD variant */
  82 # ifdef MAXPATHLEN
  83 #  define MAXPATH MAXPATHLEN
  84 # endif
  85 #endif
  86
  87 #ifdef HAVE_ERRNO_H
  88 # include <errno.h>
  89 #endif
  90
  91 #ifdef HAVE_SYS_MMAN_H
  92 # include <sys/mman.h>
  93 #endif
  94 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
  95 /* use posix_madvise family */
  96 # define madvise posix_madvise
  97 # define MADV_NORMAL POSIX_MADV_NORMAL
  98 # define MADV_RANDOM POSIX_MADV_RANDOM
  99 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
 100 # define MADV_WILLNEED POSIX_MADV_WILLNEED
 101 # define MADV_DONTNEED POSIX_MADV_DONTNEED
 102 #endif
 103 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
 104 # define USE_MADVISE 1
 105 #endif
 106
 107 #ifdef HAVE_SYS_STAT_H
 108 # include <sys/stat.h>
 109 #endif
 110
 111 #ifdef HAVE_FCNTL_H
 112 #include <fcntl.h>
 113 #endif
 114
 115 #ifdef HAVE_UNISTD_H
 116 # include <unistd.h>
 117 #endif
 118
 119 #ifdef TIME_WITH_SYS_TIME
 120 # include <sys/time.h>
 121 # include <time.h>
 122 #else
 123 # ifdef HAVE_SYS_TIME_H
 124 #  include <sys/time.h>
 125 # else
 126 #  include <time.h>
 127 # endif
 128 #endif
 129
 130 #ifdef HAVE_SYS_TIMES_H
 131 # include <sys/times.h>
 132 #endif
 133
 134 #ifdef HAVE_SYS_RESOURCE_H
 135 # include <sys/resource.h>
 136 #if (defined(__svr4__) && defined(__sun__))
 137 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
 138    Use this instead. */
 139 extern int getrusage(int, struct rusage *);
 140 #endif /* __svr4__ && __sun__ */
 141 #endif
 142
 143
 144 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 145    make sure you are NOT using bcopy, index or rindex in the code */
 146
 147 #ifdef STDC_HEADERS
 148 # include <string.h>
 149 #else
 150 # ifndef HAVE_STRCHR
 151 #  define strchr index
 152 #  define strrchr rindex
 153 # endif
 154 char *strchr (), *strrchr ();
 155 # ifndef HAVE_MEMMOVE
 156 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 157 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 158 # endif
 159 #endif
 160
 161 #ifdef NO_NULL_REALLOC
 162 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 163 #else
 164 # define rrd_realloc(a,b) realloc((a), (b))
 165 #endif
 166
 167 #ifdef NEED_MALLOC_MALLOC_H
 168 #  include <malloc/malloc.h>
 169 #endif
 170
 171 #ifdef HAVE_STDIO_H
 172 # include <stdio.h>
 173 #endif
 174
 175 #ifdef HAVE_STDLIB_H
 176 # include <stdlib.h>
 177 #endif
 178
 179 #ifdef HAVE_CTYPE_H
 180 # include <ctype.h>
 181 #endif
 182
 183 #ifdef HAVE_DIRENT_H
 184 # include <dirent.h>
 185 # define NAMLEN(dirent) strlen((dirent)->d_name)
 186 #else
 187 # define dirent direct
 188 # define NAMLEN(dirent) (dirent)->d_namlen
 189 # ifdef HAVE_SYS_NDIR_H
 190 #  include <sys/ndir.h>
 191 # endif
 192 # ifdef HAVE_SYS_DIR_H
 193 #  include <sys/dir.h>
 194 # endif
 195 # ifdef HAVE_NDIR_H
 196 #  include <ndir.h>
 197 # endif
 198 #endif
 199
 200 #ifdef MUST_DISABLE_SIGFPE
 201 # include <signal.h>
 202 #endif
 203
 204 #ifdef MUST_DISABLE_FPMASK
 205 # include <floatingpoint.h>
 206 #endif
 207
 208
 209 #ifdef HAVE_MATH_H
 210 # include <math.h>
 211 #endif
 212
 213 #ifdef HAVE_FLOAT_H
 214 # include <float.h>
 215 #endif
 216
 217 #ifdef HAVE_IEEEFP_H
 218 # include <ieeefp.h>
 219 #endif
 220
 221 #ifdef HAVE_FP_CLASS_H
 222 # include <fp_class.h>
 223 #endif
 224
 225 /* for Solaris */
 226 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 227 #  define HAVE_ISINF 1
 228 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 229 #endif
 230
 231 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 232 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 233 #  undef isnan
 234 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 235 #endif
 236
 237 /* for OSF1 Digital Unix */
 238 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 239 #  define HAVE_ISINF 1
 240 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 241 #endif
 242
 243 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 244 #  define HAVE_ISINF 1
 245 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 246 #endif
 247
 248 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 249 #  define HAVE_ISINF 1
 250 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 251 #endif
 252
 253 /* for AIX */
 254 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 255 #  define HAVE_ISINF 1
 256 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 257 #endif
 258
 259 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 260 #  define HAVE_FINITE 1
 261 #  define finite(a) isfinite(a)
 262 #endif
 263
 264 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 265 #  define HAVE_FINITE 1
 266 #  define finite(a) (! isnan(a) && ! isinf(a))
 267 #endif
 268
 269 #ifndef HAVE_FINITE
 270 #error "Can't compile without finite function"
 271 #endif
 272
 273 #ifndef HAVE_ISINF
 274 #error "Can't compile without isinf function"
 275 #endif
 276
 277 #endif /* RRD_CONFIG_H */
 278 ])
 279
 280 dnl Process Special Options
 281 dnl -----------------------------------
 282
 283 dnl How the vertical axis label is printed
 284 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 285  [Vertical label angle: -90.0 (default) or 90.0])
 286 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 287  [Vertical label angle: -90.0 (default) or 90.0])
 288
 289 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 290 [],[enable_rrdcgi=yes])
 291
 292 dnl Check if we run on a system that has fonts
 293 AC_ARG_WITH(rrd-default-font,
 294 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 295 [RRD_DEFAULT_FONT=$withval],[
 296   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 297         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 298   else
 299         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 300   fi
 301 ])
 302
 303 dnl Use mmap in rrd_update instead of seek+write
 304 AC_ARG_ENABLE([mmap],
 305 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 306 [],
 307 [enable_mmap=yes])
 308
 309 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 310 [],[enable_pthread=yes])
 311
 312 AC_ARG_ENABLE(static-programs,
 313      [  --enable-static-programs  Build static programs],
 314      [case "${enableval}" in
 315        yes) staticprogs=yes ;;
 316        no)  staticprogs=no ;;
 317        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 318      esac],[staticprogs=no])
 319 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 320
 321
 322 CONFIGURE_PART(Audit Compilation Environment)
 323
 324
 325 dnl Check for the compiler and static/shared library creation.
 326 AC_PROG_CC
 327 AC_PROG_CPP
 328 AC_PROG_LIBTOOL
 329
 330 dnl Try to detect/use GNU features
 331 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 332
 333 dnl which flags does the compiler support?
 334 if test "x$GCC" = "xyes"; then
 335   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wc++-compat -Wold-style-definition -W; do
 336     oCFLAGS="$CFLAGS"
 337     CFLAGS="$CFLAGS $flag"
 338     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 339     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 340        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 341     if eval test \$$cachename = no; then
 342          CFLAGS="$oCFLAGS"
 343     fi
 344   done
 345 fi
 346
 347
 348
 349 AC_SUBST(RRD_DEFAULT_FONT)
 350
 351 CONFIGURE_PART(Checking for Header Files)
 352
 353 dnl Checks for header files.
 354 AC_HEADER_STDC
 355 AC_HEADER_DIRENT
 356 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 357
 358 dnl Checks for typedefs, structures, and compiler characteristics.
 359 AC_C_CONST
 360 AC_HEADER_TIME
 361 AC_STRUCT_TM
 362
 363 dnl Checks for libraries.
 364 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 365
 366 dnl add pic flag in any case this makes sure all our code is relocatable
 367 eval `./libtool --config | grep pic_flag`
 368 CFLAGS="$CFLAGS $pic_flag"
 369
 370 CONFIGURE_PART(Test Library Functions)
 371
 372 dnl Checks for library functions.
 373 AC_FUNC_STRFTIME
 374 AC_FUNC_VPRINTF
 375
 376 AC_C_BIGENDIAN
 377
 378 dnl for each function found we get a definition in config.h
 379 dnl of the form HAVE_FUNCTION
 380
 381 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 382
 383 dnl Could use these to know if we need to provide a prototype
 384 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 385
 386 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 387 if test "x$enable_mmap" = "xyes"; then
 388   case "$host" in
 389   *cygwin*)
 390     # the normal mmap test does not work in cygwin
 391     AC_CHECK_FUNCS(mmap)
 392     if test "x$ac_cv_func_mmap" = "xyes"; then
 393       ac_cv_func_mmap_fixed_mapped=yes
 394     fi
 395   ;;
 396   *)
 397     AC_CHECK_HEADERS(sys/mman.h)
 398     AC_FUNC_MMAP
 399     AC_CHECK_FUNCS(mmap munmap msync)
 400     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 401                                      # include <sys/mman.h>
 402                                      #endif])
 403     if test "x$ac_cv_have_decl_madvise" = "xyes";
 404     then
 405       AC_CHECK_FUNCS(madvise)
 406     else
 407       AC_CHECK_FUNCS(posix_madvise)
 408       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 409         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 410       fi
 411     fi
 412   ;;
 413   esac
 414   if test "x$ac_cv_func_mmap" != "xyes";
 415   then
 416     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 417 dnl enable_mmap="no"
 418   fi
 419 fi
 420
 421 dnl can we use posix_fadvise
 422 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 423 #include <fcntl.h>])
 424 AC_CHECK_FUNCS(posix_fadvise)
 425
 426
 427
 428 CONFIGURE_PART(IEEE Math Checks)
 429
 430
 431 dnl actual code to check if this works
 432 AC_CHECK_FUNCS(fpclassify, ,
 433   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 434     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 435 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 436       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 437
 438 AC_CHECK_FUNCS(isinf, ,
 439   [AC_MSG_CHECKING(for isinf with <math.h>)
 440     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 441 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 442       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 443
 444 dnl finite is BSD, isfinite is C99, so prefer the latter
 445 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 446 AC_TRY_RUN([
 447 #ifdef HAVE_MATH_H
 448 #include <math.h>
 449 #endif
 450 #ifdef HAVE_FLOAT_H
 451 #include <float.h>
 452 #endif
 453 int main ()
 454 {
 455 #ifdef isfinite
 456 #ifdef LDBL_MAX
 457   if (!isfinite(LDBL_MAX)) return 1;
 458 #endif
 459 #ifdef DBL_MAX
 460   if (!isfinite(DBL_MAX)) return 1;
 461 #endif
 462 #endif
 463 return 0;
 464 }],[
 465 have_broken_isfinite=no],have_broken_isfinite=yes,[
 466 case "${target}" in
 467   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 468   *) have_broken_isfinite=no ;;
 469 esac])
 470 ])
 471 if test "x$have_broken_isfinite" = "xno"; then
 472   AC_DEFINE(HAVE_ISFINITE)
 473 else
 474 AC_CHECK_FUNCS(finite,[],
 475   [AC_CHECK_FUNCS(isfinite,[],
 476       [AC_MSG_CHECKING(for isfinite with <math.h>)
 477        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 478 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 479                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 480 fi
 481
 482 AC_FULL_IEEE
 483
 484 CONFIGURE_PART(Resolve Portability Issues)
 485
 486 dnl what does realloc do if it gets called with a NULL pointer
 487
 488 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 489 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 490               int main(void){
 491               char *x = NULL;
 492               x = realloc (x,10);
 493               if (x==NULL) return 1;
 494               return 0;
 495              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 496
 497 if test x"$rd_cv_null_realloc" = xnope; then
 498 AC_DEFINE(NO_NULL_REALLOC)
 499 fi
 500
 501 AC_LANG_PUSH(C)
 502 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 503 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 504 AC_LINK_IFELSE(
 505     AC_LANG_PROGRAM(
 506            [[#include <time.h>]],
 507            [[ctime_r(NULL,NULL,0)]]
 508                    ),
 509     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 510       AC_LINK_IFELSE(
 511           AC_LANG_PROGRAM(
 512                 [[#include <time.h>]],
 513                 [[ctime_r(NULL,NULL)]]
 514                          ),
 515           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 516           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 517       )
 518     ],
 519     [ AC_LINK_IFELSE(
 520           AC_LANG_PROGRAM(
 521                 [[#include <time.h>]],
 522                 [[ctime_r(NULL,NULL)]]
 523                          ),
 524           [AC_MSG_RESULT(no)],
 525           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 526       )
 527     ]
 528 )
 529 AC_LANG_POP(C)
 530
 531 dnl Check for pthreads
 532 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 533
 534 AC_SUBST(MULTITHREAD_CFLAGS)
 535 AC_SUBST(MULTITHREAD_LDFLAGS)
 536
 537 if test $enable_pthread != no; then
 538  ACX_PTHREAD([
 539     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 540     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 541              ],
 542              [])
 543 fi
 544
 545 dnl since we use lots of *_r functions all over the code we better
 546 dnl make sure they are known
 547
 548 if test  "x$x_rflag" != "xno"; then
 549    CPPFLAGS="$CPPFLAGS $x_rflag"
 550 fi
 551
 552 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 553
 554 AC_LANG_PUSH(C)
 555 dnl see if we have to include malloc/malloc.h
 556 AC_MSG_CHECKING([do we need malloc/malloc.h])
 557 AC_LINK_IFELSE(
 558     AC_LANG_PROGRAM(
 559            [[#include <stdlib.h>]],
 560            [[malloc(1)]]
 561                    ),
 562     [ AC_MSG_RESULT([nope, works out of the box]) ],
 563     [ AC_LINK_IFELSE(
 564           AC_LANG_PROGRAM(
 565                 [[#include <stdlib.h>
 566                   #include <malloc/malloc.h>]],
 567                 [[malloc(1)]]
 568                          ),
 569           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 570            AC_MSG_RESULT([yes we do])],
 571           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 572       )
 573     ]
 574 )
 575 AC_LANG_POP(C)
 576
 577 CONFIGURE_PART(Find 3rd-Party Libraries)
 578
 579
 580 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 581
 582 CORE_LIBS="$LIBS"
 583
 584 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 585 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 586 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,                     freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 587 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,               fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 588 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 589 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 590 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 591
 592 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 593   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 594 fi
 595
 596 ALL_LIBS="$LIBS"
 597 LIBS=
 598
 599 AC_SUBST(CORE_LIBS)
 600 AC_SUBST(ALL_LIBS)
 601
 602 CONFIGURE_PART(Prep for Building Language Bindings)
 603
 604 dnl Check for Perl.
 605 AC_PATH_PROG(PERL, perl, no)
 606
 607 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 608 [],[enable_perl=yes])
 609
 610
 611 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 612 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 613 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 614 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 615
 616 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 617         COMP_PERL=
 618 else
 619         COMP_PERL="perl_piped perl_shared"
 620         AC_MSG_CHECKING(for the perl version you are running)
 621         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 622         AC_MSG_RESULT($PERL_VERSION)
 623         if test -z "$PERLCC"; then
 624             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 625             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 626             AC_MSG_RESULT($perlcc)
 627             if test ! -x "$perlcc"; then
 628                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 629                 if test "$PERL_CC" = "no"; then
 630                     AC_MSG_WARN([
 631 I would not find the Compiler ($perlcc) that was originally used to compile
 632 your perl binary. You should either make sure that this compiler is
 633 available on your system, pick an other compiler and set PERLCC
 634 appropriately, or use a different perl setup that was compiled locally.
 635
 636 I will disable the compilation of the RRDs perl module for now.
 637 ])
 638                     COMP_PERL="perl_piped"
 639                 fi
 640             fi
 641         fi
 642 fi
 643
 644 AC_MSG_CHECKING(Perl Modules to build)
 645 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 646
 647 # Options to pass when configuring perl module
 648 ppref=$prefix
 649 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 650
 651 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 652
 653 dnl pass additional perl options when generating Makefile from Makefile.PL
 654 AC_ARG_ENABLE(perl-site-install,
 655 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 656                           together with rrdtool in $prefix/lib/perl. You have to
 657                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 658                           when you want to use them. When you set this option
 659                           the perl modules will get installed wherever
 660                           your perl setup thinks it is best.],
 661 [PERL_MAKE_OPTIONS=],[])
 662
 663 if test ! -z "$PERLCC"; then
 664    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 665
 666    if test ! -z "$PERLCCFLAGS"; then
 667        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 668    fi
 669
 670    if test -z "$PERLLD"; then
 671        PERLLD=$PERLCC
 672    fi
 673    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 674
 675    if test ! -z "$PERLLDFLAGS"; then
 676        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 677    fi
 678 fi
 679
 680 AC_ARG_WITH(perl-options,
 681 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 682                           generating Makefile from Makefile.PL. If you set this
 683                           option, interesting things may happen unless you know
 684                           what you are doing!],
 685 [PERL_MAKE_OPTIONS=$withval])
 686
 687 AC_SUBST(PERL_MAKE_OPTIONS)
 688 AC_SUBST(PERL)
 689 AC_SUBST(COMP_PERL)
 690 AC_SUBST(PERL_VERSION)
 691
 692 dnl Check for Ruby.
 693 AC_PATH_PROG(RUBY, ruby, no)
 694
 695 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 696 [],[enable_ruby=yes])
 697
 698 AC_MSG_CHECKING(if ruby modules can be built)
 699
 700 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 701         COMP_RUBY=
 702         AC_MSG_RESULT(No .. Ruby not found or disabled)
 703 else
 704         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 705                 COMP_RUBY="ruby"
 706                 AC_MSG_RESULT(YES)
 707         else
 708                 COMP_RUBY=
 709                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 710         fi
 711 fi
 712
 713
 714 dnl pass additional ruby options when generating Makefile from Makefile.PL
 715 AC_ARG_ENABLE(ruby-site-install,
 716 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 717                           together with rrdtool in $prefix/lib/ruby. You have to
 718                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 719                           for ruby to find the RRD.so file.],
 720 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 721
 722
 723 AC_ARG_WITH(ruby-options,
 724 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 725                           generating Makefile from extconf.rb. If you set this
 726                           option, interesting things may happen unless you know
 727                           what you are doing!],
 728 [RUBY_MAKE_OPTIONS=$withval])
 729
 730 AC_SUBST(RUBY_MAKE_OPTIONS)
 731 AC_SUBST(RUBY)
 732 AC_SUBST(COMP_RUBY)
 733
 734
 735 enable_tcl_site=no
 736
 737 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 738 [],[enable_tcl=yes])
 739
 740 if test  "$enable_tcl" = "yes"; then
 741   dnl Check for Tcl.
 742   withval=""
 743   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 744   enable_tcl=no
 745   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 746     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 747     if test -f "$dir/tclConfig.sh" ; then
 748         tcl_config=$dir/tclConfig.sh
 749         enable_tcl=yes
 750         AC_MSG_RESULT(yes)
 751         break
 752     else
 753         AC_MSG_RESULT(no)
 754     fi
 755   done
 756
 757   if test "$enable_tcl" = "no"; then
 758         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 759   else
 760         . $tcl_config
 761         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 762   fi
 763   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 764   [],[enable_tcl_site=yes])
 765
 766 fi
 767
 768 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 769 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 770
 771 AC_SUBST(TCL_PREFIX)
 772 AC_SUBST(TCL_SHLIB_CFLAGS)
 773 AC_SUBST(TCL_SHLIB_LD)
 774 AC_SUBST(TCL_SHLIB_SUFFIX)
 775 AC_SUBST(TCL_PACKAGE_PATH)
 776 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 777 AC_SUBST(TCL_STUB_LIB_SPEC)
 778 AC_SUBST(TCL_VERSION)
 779 AC_SUBST(TCL_PACKAGE_DIR)
 780 AC_SUBST(TCL_INC_DIR)
 781
 782 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 783 [],[enable_python=yes])
 784
 785 if test  "$enable_python" = "yes"; then
 786 dnl Check for python
 787 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 788 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 789 fi
 790
 791 if test  x$enable_python = xno; then
 792         COMP_PYTHON=
 793 else
 794         COMP_PYTHON="python"
 795 fi
 796
 797 AC_SUBST(COMP_PYTHON)
 798
 799 dnl Check for nroff
 800 AC_PATH_PROGS(NROFF, gnroff nroff)
 801 AC_PATH_PROGS(TROFF, groff troff)
 802
 803 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 804 if test -z "$RRDDOCDIR"; then
 805    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 806
 807
 808 CONFIGURE_PART(Apply Configuration Information)
 809
 810 AC_CONFIG_FILES([examples/shared-demo.pl])
 811 AC_CONFIG_FILES([examples/piped-demo.pl])
 812 AC_CONFIG_FILES([examples/stripes.pl])
 813 AC_CONFIG_FILES([examples/bigtops.pl])
 814 AC_CONFIG_FILES([examples/minmax.pl])
 815 AC_CONFIG_FILES([examples/4charts.pl])
 816 AC_CONFIG_FILES([examples/perftest.pl])
 817 AC_CONFIG_FILES([examples/Makefile])
 818 AC_CONFIG_FILES([doc/Makefile])
 819 AC_CONFIG_FILES([src/Makefile])
 820 AC_CONFIG_FILES([bindings/Makefile])
 821 AC_CONFIG_FILES([bindings/tcl/Makefile])
 822 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 823 AC_CONFIG_FILES([Makefile])
 824
 825 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 826 AC_OUTPUT
 827
 828 AC_MSG_CHECKING(in)
 829 AC_MSG_RESULT(and out again)
 830
 831 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 832 sleep 1
 833 echo $ECHO_N ".$ECHO_C" 1>&6
 834 sleep 1
 835 echo $ECHO_N ".$ECHO_C" 1>&6
 836 sleep 1
 837 echo $ECHO_N ".$ECHO_C" 1>&6
 838 sleep 1
 839 echo $ECHO_N ".$ECHO_C" 1>&6
 840 sleep 1
 841 AC_MSG_RESULT([ just kidding ;-)])
 842 echo
 843 echo "----------------------------------------------------------------"
 844 echo "Config is DONE!"
 845 echo
 846 echo "          With MMAP IO: $enable_mmap"
 847 echo "       Static programs: $staticprogs"
 848 echo "          Perl Modules: $COMP_PERL"
 849 echo "           Perl Binary: $PERL"
 850 echo "          Perl Version: $PERL_VERSION"
 851 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 852 echo "          Ruby Modules: $COMP_RUBY"
 853 echo "           Ruby Binary: $RUBY"
 854 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 855 echo "    Build Tcl Bindings: $enable_tcl"
 856 echo " Build Python Bindings: $enable_python"
 857 echo "          Build rrdcgi: $enable_rrdcgi"
 858 echo "       Build librrd MT: $enable_pthread"
 859 echo
 860 echo
 861 echo "Type 'make' to compile the software and use 'make install' to "
 862 echo "install everything to: $prefix."
 863 echo
 864 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 865 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 866 echo "place an order."
 867 echo
 868 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 869 echo "----------------------------------------------------------------"