configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.99907080300])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devel versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.299907080300
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52 /* lets enable madvise defines in NetBSD */
  53 #if defined(__NetBSD__)
  54 # if !defined(_NETBSD_SOURCE)
  55 #  define _NETBSD_SOURCE
  56 # endif
  57 #endif
  58
  59  ])
  60
  61 AH_BOTTOM([
  62 /* make sure that we pickup the correct stuff from all headers */
  63 #ifdef HAVE_FEATURES_H
  64 #define _XOPEN_SOURCE 600
  65 #define _BSD_SOURCE 1
  66 # include <features.h>
  67 #endif
  68
  69 #ifdef HAVE_SYS_TYPES_H
  70 # include <sys/types.h>
  71 #endif
  72
  73 #ifdef HAVE_SYS_PARAM_H
  74 # include <sys/param.h>
  75 #endif
  76 #ifndef MAXPATH
  77 # ifdef PATH_MAX
  78 #  define MAXPATH PATH_MAX
  79 # endif
  80 #endif
  81 #ifndef MAXPATH
  82 /* else try the BSD variant */
  83 # ifdef MAXPATHLEN
  84 #  define MAXPATH MAXPATHLEN
  85 # endif
  86 #endif
  87
  88 #ifdef HAVE_ERRNO_H
  89 # include <errno.h>
  90 #endif
  91
  92 #ifdef HAVE_SYS_MMAN_H
  93 # include <sys/mman.h>
  94 #endif
  95
  96 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
  97 /* use posix_madvise family */
  98 # define madvise posix_madvise
  99 # define MADV_NORMAL POSIX_MADV_NORMAL
 100 # define MADV_RANDOM POSIX_MADV_RANDOM
 101 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
 102 # define MADV_WILLNEED POSIX_MADV_WILLNEED
 103 # define MADV_DONTNEED POSIX_MADV_DONTNEED
 104 #endif
 105 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
 106 # define USE_MADVISE 1
 107 #endif
 108
 109 #ifdef HAVE_SYS_STAT_H
 110 # include <sys/stat.h>
 111 #endif
 112
 113 #ifdef HAVE_FCNTL_H
 114 #include <fcntl.h>
 115 #endif
 116
 117 #ifdef HAVE_UNISTD_H
 118 # include <unistd.h>
 119 #endif
 120
 121 #ifdef TIME_WITH_SYS_TIME
 122 # include <sys/time.h>
 123 # include <time.h>
 124 #else
 125 # ifdef HAVE_SYS_TIME_H
 126 #  include <sys/time.h>
 127 # else
 128 #  include <time.h>
 129 # endif
 130 #endif
 131
 132 #ifdef HAVE_SYS_TIMES_H
 133 # include <sys/times.h>
 134 #endif
 135
 136 #ifdef HAVE_SYS_RESOURCE_H
 137 # include <sys/resource.h>
 138 #if (defined(__svr4__) && defined(__sun__))
 139 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
 140    Use this instead. */
 141 extern int getrusage(int, struct rusage *);
 142 #endif /* __svr4__ && __sun__ */
 143 #endif
 144
 145
 146 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 147    make sure you are NOT using bcopy, index or rindex in the code */
 148
 149 #ifdef STDC_HEADERS
 150 # include <string.h>
 151 #else
 152 # ifndef HAVE_STRCHR
 153 #  define strchr index
 154 #  define strrchr rindex
 155 # endif
 156 char *strchr (), *strrchr ();
 157 # ifndef HAVE_MEMMOVE
 158 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 159 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 160 # endif
 161 #endif
 162
 163 #ifdef NO_NULL_REALLOC
 164 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 165 #else
 166 # define rrd_realloc(a,b) realloc((a), (b))
 167 #endif
 168
 169 #ifdef NEED_MALLOC_MALLOC_H
 170 #  include <malloc/malloc.h>
 171 #endif
 172
 173 #ifdef HAVE_STDIO_H
 174 # include <stdio.h>
 175 #endif
 176
 177 #ifdef HAVE_STDLIB_H
 178 # include <stdlib.h>
 179 #endif
 180
 181 #ifdef HAVE_CTYPE_H
 182 # include <ctype.h>
 183 #endif
 184
 185 #ifdef HAVE_DIRENT_H
 186 # include <dirent.h>
 187 # define NAMLEN(dirent) strlen((dirent)->d_name)
 188 #else
 189 # define dirent direct
 190 # define NAMLEN(dirent) (dirent)->d_namlen
 191 # ifdef HAVE_SYS_NDIR_H
 192 #  include <sys/ndir.h>
 193 # endif
 194 # ifdef HAVE_SYS_DIR_H
 195 #  include <sys/dir.h>
 196 # endif
 197 # ifdef HAVE_NDIR_H
 198 #  include <ndir.h>
 199 # endif
 200 #endif
 201
 202 #ifdef MUST_DISABLE_SIGFPE
 203 # include <signal.h>
 204 #endif
 205
 206 #ifdef MUST_DISABLE_FPMASK
 207 # include <floatingpoint.h>
 208 #endif
 209
 210
 211 #ifdef HAVE_MATH_H
 212 # include <math.h>
 213 #endif
 214
 215 #ifdef HAVE_FLOAT_H
 216 # include <float.h>
 217 #endif
 218
 219 #ifdef HAVE_IEEEFP_H
 220 # include <ieeefp.h>
 221 #endif
 222
 223 #ifdef HAVE_FP_CLASS_H
 224 # include <fp_class.h>
 225 #endif
 226
 227 /* for Solaris */
 228 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 229 #  define HAVE_ISINF 1
 230 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 231 #endif
 232
 233 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 234 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 235 #  undef isnan
 236 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 237 #endif
 238
 239 /* for OSF1 Digital Unix */
 240 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 241 #  define HAVE_ISINF 1
 242 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 243 #endif
 244
 245 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 246 #  define HAVE_ISINF 1
 247 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 248 #endif
 249
 250 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 251 #  define HAVE_ISINF 1
 252 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 253 #endif
 254
 255 /* for AIX */
 256 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 257 #  define HAVE_ISINF 1
 258 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 259 #endif
 260
 261 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 262 #  define HAVE_FINITE 1
 263 #  define finite(a) isfinite(a)
 264 #endif
 265
 266 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 267 #  define HAVE_FINITE 1
 268 #  define finite(a) (! isnan(a) && ! isinf(a))
 269 #endif
 270
 271 #ifndef HAVE_FINITE
 272 #error "Can't compile without finite function"
 273 #endif
 274
 275 #ifndef HAVE_ISINF
 276 #error "Can't compile without isinf function"
 277 #endif
 278
 279 #endif /* RRD_CONFIG_H */
 280 ])
 281
 282 dnl Process Special Options
 283 dnl -----------------------------------
 284
 285 dnl How the vertical axis label is printed
 286 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 287  [Vertical label angle: -90.0 (default) or 90.0])
 288 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 289  [Vertical label angle: -90.0 (default) or 90.0])
 290
 291 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 292 [],[enable_rrdcgi=yes])
 293
 294 dnl Check if we run on a system that has fonts
 295 AC_ARG_WITH(rrd-default-font,
 296 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 297 [RRD_DEFAULT_FONT=$withval],[
 298   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 299         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 300   else
 301         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 302   fi
 303 ])
 304
 305 dnl Use mmap in rrd_update instead of seek+write
 306 AC_ARG_ENABLE([mmap],
 307 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 308 [],
 309 [enable_mmap=yes])
 310
 311 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 312 [],[enable_pthread=yes])
 313
 314 AC_ARG_ENABLE(static-programs,
 315      [  --enable-static-programs  Build static programs],
 316      [case "${enableval}" in
 317        yes) staticprogs=yes ;;
 318        no)  staticprogs=no ;;
 319        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 320      esac],[staticprogs=no])
 321 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 322
 323
 324 CONFIGURE_PART(Audit Compilation Environment)
 325
 326
 327 dnl Check for the compiler and static/shared library creation.
 328 AC_PROG_CC
 329 AC_PROG_CPP
 330 AC_PROG_LIBTOOL
 331
 332 dnl Try to detect/use GNU features
 333 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 334
 335 dnl which flags does the compiler support?
 336 if test "x$GCC" = "xyes"; then
 337   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wc++-compat -Wold-style-definition -W; do
 338     oCFLAGS="$CFLAGS"
 339     CFLAGS="$CFLAGS $flag"
 340     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 341     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 342        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 343     if eval test \$$cachename = no; then
 344          CFLAGS="$oCFLAGS"
 345     fi
 346   done
 347 fi
 348
 349
 350
 351 AC_SUBST(RRD_DEFAULT_FONT)
 352
 353 CONFIGURE_PART(Checking for Header Files)
 354
 355 dnl Checks for header files.
 356 AC_HEADER_STDC
 357 AC_HEADER_DIRENT
 358 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 359
 360 dnl Checks for typedefs, structures, and compiler characteristics.
 361 AC_C_CONST
 362 AC_HEADER_TIME
 363 AC_STRUCT_TM
 364
 365 dnl Checks for libraries.
 366 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 367
 368 dnl add pic flag in any case this makes sure all our code is relocatable
 369 eval `./libtool --config | grep pic_flag`
 370 CFLAGS="$CFLAGS $pic_flag"
 371
 372 CONFIGURE_PART(Test Library Functions)
 373
 374 dnl Checks for library functions.
 375 AC_FUNC_STRFTIME
 376 AC_FUNC_VPRINTF
 377
 378 AC_C_BIGENDIAN
 379
 380 dnl for each function found we get a definition in config.h
 381 dnl of the form HAVE_FUNCTION
 382
 383 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 384
 385 dnl Could use these to know if we need to provide a prototype
 386 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 387
 388 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 389 if test "x$enable_mmap" = "xyes"; then
 390   case "$host" in
 391   *cygwin*)
 392     # the normal mmap test does not work in cygwin
 393     AC_CHECK_FUNCS(mmap)
 394     if test "x$ac_cv_func_mmap" = "xyes"; then
 395       ac_cv_func_mmap_fixed_mapped=yes
 396     fi
 397   ;;
 398   *)
 399     AC_CHECK_HEADERS(sys/mman.h)
 400     AC_FUNC_MMAP
 401     AC_CHECK_FUNCS(mmap munmap msync)
 402     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 403                                      # include <sys/mman.h>
 404                                      #endif])
 405     if test "x$ac_cv_have_decl_madvise" = "xyes";
 406     then
 407       AC_CHECK_FUNCS(madvise)
 408     else
 409       AC_CHECK_FUNCS(posix_madvise)
 410       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 411         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 412       fi
 413     fi
 414   ;;
 415   esac
 416   if test "x$ac_cv_func_mmap" != "xyes";
 417   then
 418     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 419 dnl enable_mmap="no"
 420   fi
 421 fi
 422
 423 dnl can we use posix_fadvise
 424 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 425 #include <fcntl.h>])
 426 AC_CHECK_FUNCS(posix_fadvise)
 427
 428
 429
 430 CONFIGURE_PART(IEEE Math Checks)
 431
 432
 433 dnl actual code to check if this works
 434 AC_CHECK_FUNCS(fpclassify, ,
 435   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 436     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 437 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 438       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 439
 440 AC_CHECK_FUNCS(isinf, ,
 441   [AC_MSG_CHECKING(for isinf with <math.h>)
 442     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 443 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 444       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 445
 446 dnl finite is BSD, isfinite is C99, so prefer the latter
 447 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 448 AC_TRY_RUN([
 449 #ifdef HAVE_MATH_H
 450 #include <math.h>
 451 #endif
 452 #ifdef HAVE_FLOAT_H
 453 #include <float.h>
 454 #endif
 455 int main ()
 456 {
 457 #ifdef isfinite
 458 #ifdef LDBL_MAX
 459   if (!isfinite(LDBL_MAX)) return 1;
 460 #endif
 461 #ifdef DBL_MAX
 462   if (!isfinite(DBL_MAX)) return 1;
 463 #endif
 464 #endif
 465 return 0;
 466 }],[
 467 have_broken_isfinite=no],have_broken_isfinite=yes,[
 468 case "${target}" in
 469   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 470   *) have_broken_isfinite=no ;;
 471 esac])
 472 ])
 473 if test "x$have_broken_isfinite" = "xno"; then
 474   AC_DEFINE(HAVE_ISFINITE)
 475 else
 476 AC_CHECK_FUNCS(finite,[],
 477   [AC_CHECK_FUNCS(isfinite,[],
 478       [AC_MSG_CHECKING(for isfinite with <math.h>)
 479        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 480 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 481                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 482 fi
 483
 484 AC_FULL_IEEE
 485
 486 CONFIGURE_PART(Resolve Portability Issues)
 487
 488 dnl what does realloc do if it gets called with a NULL pointer
 489
 490 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 491 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 492               int main(void){
 493               char *x = NULL;
 494               x = realloc (x,10);
 495               if (x==NULL) return 1;
 496               return 0;
 497              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 498
 499 if test x"$rd_cv_null_realloc" = xnope; then
 500 AC_DEFINE(NO_NULL_REALLOC)
 501 fi
 502
 503 AC_LANG_PUSH(C)
 504 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 505 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 506 AC_LINK_IFELSE(
 507     AC_LANG_PROGRAM(
 508            [[#include <time.h>]],
 509            [[ctime_r(NULL,NULL,0)]]
 510                    ),
 511     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 512       AC_LINK_IFELSE(
 513           AC_LANG_PROGRAM(
 514                 [[#include <time.h>]],
 515                 [[ctime_r(NULL,NULL)]]
 516                          ),
 517           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 518           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 519       )
 520     ],
 521     [ AC_LINK_IFELSE(
 522           AC_LANG_PROGRAM(
 523                 [[#include <time.h>]],
 524                 [[ctime_r(NULL,NULL)]]
 525                          ),
 526           [AC_MSG_RESULT(no)],
 527           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 528       )
 529     ]
 530 )
 531 AC_LANG_POP(C)
 532
 533 dnl Check for pthreads
 534 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 535
 536 AC_SUBST(MULTITHREAD_CFLAGS)
 537 AC_SUBST(MULTITHREAD_LDFLAGS)
 538
 539 if test $enable_pthread != no; then
 540  ACX_PTHREAD([
 541     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 542     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 543              ],
 544              [])
 545 fi
 546
 547 dnl since we use lots of *_r functions all over the code we better
 548 dnl make sure they are known
 549
 550 if test  "x$x_rflag" != "xno"; then
 551    CPPFLAGS="$CPPFLAGS $x_rflag"
 552 fi
 553
 554 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 555
 556 AC_LANG_PUSH(C)
 557 dnl see if we have to include malloc/malloc.h
 558 AC_MSG_CHECKING([do we need malloc/malloc.h])
 559 AC_LINK_IFELSE(
 560     AC_LANG_PROGRAM(
 561            [[#include <stdlib.h>]],
 562            [[malloc(1)]]
 563                    ),
 564     [ AC_MSG_RESULT([nope, works out of the box]) ],
 565     [ AC_LINK_IFELSE(
 566           AC_LANG_PROGRAM(
 567                 [[#include <stdlib.h>
 568                   #include <malloc/malloc.h>]],
 569                 [[malloc(1)]]
 570                          ),
 571           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 572            AC_MSG_RESULT([yes we do])],
 573           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 574       )
 575     ]
 576 )
 577 AC_LANG_POP(C)
 578
 579 CONFIGURE_PART(Find 3rd-Party Libraries)
 580
 581
 582 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 583
 584 CORE_LIBS="$LIBS"
 585
 586 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 587 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 588 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,                     freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 589 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,               fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 590 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 591 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 592 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 593
 594 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 595   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 596 fi
 597
 598 ALL_LIBS="$LIBS"
 599 LIBS=
 600
 601 AC_SUBST(CORE_LIBS)
 602 AC_SUBST(ALL_LIBS)
 603
 604 CONFIGURE_PART(Prep for Building Language Bindings)
 605
 606 dnl Check for Perl.
 607 AC_PATH_PROG(PERL, perl, no)
 608
 609 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 610 [],[enable_perl=yes])
 611
 612
 613 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 614 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 615 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 616 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 617
 618 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 619         COMP_PERL=
 620 else
 621         COMP_PERL="perl_piped perl_shared"
 622         AC_MSG_CHECKING(for the perl version you are running)
 623         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 624         AC_MSG_RESULT($PERL_VERSION)
 625         if test -z "$PERLCC"; then
 626             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 627             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 628             AC_MSG_RESULT($perlcc)
 629             if test ! -x "$perlcc"; then
 630                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 631                 if test "$PERL_CC" = "no"; then
 632                     AC_MSG_WARN([
 633 I would not find the Compiler ($perlcc) that was originally used to compile
 634 your perl binary. You should either make sure that this compiler is
 635 available on your system, pick an other compiler and set PERLCC
 636 appropriately, or use a different perl setup that was compiled locally.
 637
 638 I will disable the compilation of the RRDs perl module for now.
 639 ])
 640                     COMP_PERL="perl_piped"
 641                 fi
 642             fi
 643         fi
 644 fi
 645
 646 AC_MSG_CHECKING(Perl Modules to build)
 647 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 648
 649 # Options to pass when configuring perl module
 650 ppref=$prefix
 651 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 652
 653 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 654
 655 dnl pass additional perl options when generating Makefile from Makefile.PL
 656 AC_ARG_ENABLE(perl-site-install,
 657 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 658                           together with rrdtool in $prefix/lib/perl. You have to
 659                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 660                           when you want to use them. When you set this option
 661                           the perl modules will get installed wherever
 662                           your perl setup thinks it is best.],
 663 [PERL_MAKE_OPTIONS=],[])
 664
 665 if test ! -z "$PERLCC"; then
 666    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 667
 668    if test ! -z "$PERLCCFLAGS"; then
 669        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 670    fi
 671
 672    if test -z "$PERLLD"; then
 673        PERLLD=$PERLCC
 674    fi
 675    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 676
 677    if test ! -z "$PERLLDFLAGS"; then
 678        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 679    fi
 680 fi
 681
 682 AC_ARG_WITH(perl-options,
 683 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 684                           generating Makefile from Makefile.PL. If you set this
 685                           option, interesting things may happen unless you know
 686                           what you are doing!],
 687 [PERL_MAKE_OPTIONS=$withval])
 688
 689 AC_SUBST(PERL_MAKE_OPTIONS)
 690 AC_SUBST(PERL)
 691 AC_SUBST(COMP_PERL)
 692 AC_SUBST(PERL_VERSION)
 693
 694 dnl Check for Ruby.
 695 AC_PATH_PROG(RUBY, ruby, no)
 696
 697 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 698 [],[enable_ruby=yes])
 699
 700 AC_MSG_CHECKING(if ruby modules can be built)
 701
 702 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 703         COMP_RUBY=
 704         AC_MSG_RESULT(No .. Ruby not found or disabled)
 705 else
 706         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 707                 COMP_RUBY="ruby"
 708                 AC_MSG_RESULT(YES)
 709         else
 710                 COMP_RUBY=
 711                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 712         fi
 713 fi
 714
 715
 716 dnl pass additional ruby options when generating Makefile from Makefile.PL
 717 AC_ARG_ENABLE(ruby-site-install,
 718 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 719                           together with rrdtool in $prefix/lib/ruby. You have to
 720                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 721                           for ruby to find the RRD.so file.],
 722 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 723
 724
 725 AC_ARG_WITH(ruby-options,
 726 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 727                           generating Makefile from extconf.rb. If you set this
 728                           option, interesting things may happen unless you know
 729                           what you are doing!],
 730 [RUBY_MAKE_OPTIONS=$withval])
 731
 732 AC_SUBST(RUBY_MAKE_OPTIONS)
 733 AC_SUBST(RUBY)
 734 AC_SUBST(COMP_RUBY)
 735
 736
 737 enable_tcl_site=no
 738
 739 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 740 [],[enable_tcl=yes])
 741
 742 if test  "$enable_tcl" = "yes"; then
 743   dnl Check for Tcl.
 744   withval=""
 745   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 746   enable_tcl=no
 747   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 748     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 749     if test -f "$dir/tclConfig.sh" ; then
 750         tcl_config=$dir/tclConfig.sh
 751         enable_tcl=yes
 752         AC_MSG_RESULT(yes)
 753         break
 754     else
 755         AC_MSG_RESULT(no)
 756     fi
 757   done
 758
 759   if test "$enable_tcl" = "no"; then
 760         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 761   else
 762         . $tcl_config
 763         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 764   fi
 765   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 766   [],[enable_tcl_site=yes])
 767
 768 fi
 769
 770 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 771 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 772
 773 AC_SUBST(TCL_PREFIX)
 774 AC_SUBST(TCL_SHLIB_CFLAGS)
 775 AC_SUBST(TCL_SHLIB_LD)
 776 AC_SUBST(TCL_SHLIB_SUFFIX)
 777 AC_SUBST(TCL_PACKAGE_PATH)
 778 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 779 AC_SUBST(TCL_STUB_LIB_SPEC)
 780 AC_SUBST(TCL_VERSION)
 781 AC_SUBST(TCL_PACKAGE_DIR)
 782 AC_SUBST(TCL_INC_DIR)
 783
 784 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 785 [],[enable_python=yes])
 786
 787 if test  "$enable_python" = "yes"; then
 788 dnl Check for python
 789 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 790 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 791 fi
 792
 793 if test  x$enable_python = xno; then
 794         COMP_PYTHON=
 795 else
 796         COMP_PYTHON="python"
 797 fi
 798
 799 AC_SUBST(COMP_PYTHON)
 800
 801 dnl Check for nroff
 802 AC_PATH_PROGS(NROFF, gnroff nroff)
 803 AC_PATH_PROGS(TROFF, groff troff)
 804
 805 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 806 if test -z "$RRDDOCDIR"; then
 807    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 808
 809
 810 CONFIGURE_PART(Apply Configuration Information)
 811
 812 AC_CONFIG_FILES([examples/shared-demo.pl])
 813 AC_CONFIG_FILES([examples/piped-demo.pl])
 814 AC_CONFIG_FILES([examples/stripes.pl])
 815 AC_CONFIG_FILES([examples/bigtops.pl])
 816 AC_CONFIG_FILES([examples/minmax.pl])
 817 AC_CONFIG_FILES([examples/4charts.pl])
 818 AC_CONFIG_FILES([examples/perftest.pl])
 819 AC_CONFIG_FILES([examples/Makefile])
 820 AC_CONFIG_FILES([doc/Makefile])
 821 AC_CONFIG_FILES([src/Makefile])
 822 AC_CONFIG_FILES([bindings/Makefile])
 823 AC_CONFIG_FILES([bindings/tcl/Makefile])
 824 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 825 AC_CONFIG_FILES([Makefile])
 826
 827 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 828 AC_OUTPUT
 829
 830 AC_MSG_CHECKING(in)
 831 AC_MSG_RESULT(and out again)
 832
 833 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 834 sleep 1
 835 echo $ECHO_N ".$ECHO_C" 1>&6
 836 sleep 1
 837 echo $ECHO_N ".$ECHO_C" 1>&6
 838 sleep 1
 839 echo $ECHO_N ".$ECHO_C" 1>&6
 840 sleep 1
 841 echo $ECHO_N ".$ECHO_C" 1>&6
 842 sleep 1
 843 AC_MSG_RESULT([ just kidding ;-)])
 844 echo
 845 echo "----------------------------------------------------------------"
 846 echo "Config is DONE!"
 847 echo
 848 echo "          With MMAP IO: $enable_mmap"
 849 echo "       Static programs: $staticprogs"
 850 echo "          Perl Modules: $COMP_PERL"
 851 echo "           Perl Binary: $PERL"
 852 echo "          Perl Version: $PERL_VERSION"
 853 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 854 echo "          Ruby Modules: $COMP_RUBY"
 855 echo "           Ruby Binary: $RUBY"
 856 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 857 echo "    Build Tcl Bindings: $enable_tcl"
 858 echo " Build Python Bindings: $enable_python"
 859 echo "          Build rrdcgi: $enable_rrdcgi"
 860 echo "       Build librrd MT: $enable_pthread"
 861 echo
 862 echo
 863 echo "Type 'make' to compile the software and use 'make install' to "
 864 echo "install everything to: $prefix."
 865 echo
 866 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 867 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 868 echo "place an order."
 869 echo
 870 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 871 echo "----------------------------------------------------------------"