configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.10])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devl versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.2010
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29
  30 AC_SUBST(VERSION)
  31
  32 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  33
  34 dnl Minimum Autoconf version required.
  35 AC_PREREQ(2.59)
  36
  37 dnl At the TOP of the HEADER
  38
  39 AH_TOP([
  40
  41 #ifndef CONFIG_H
  42 #define CONFIG_H
  43 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  44 #undef MUST_DISABLE_FPMASK
  45
  46 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  47
  48 #undef MUST_DISABLE_SIGFPE
  49
  50 /* realloc does not support NULL as argument */
  51 #undef NO_NULL_REALLOC
  52
  53  ])
  54
  55 AH_BOTTOM([
  56
  57 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  58    make sure you are NOT using bcopy, index or rindex in the code */
  59
  60 #if STDC_HEADERS
  61 # include <string.h>
  62 #else
  63 # ifndef HAVE_STRCHR
  64 #  define strchr index
  65 #  define strrchr rindex
  66 # endif
  67 char *strchr (), *strrchr ();
  68 # ifndef HAVE_MEMMOVE
  69 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  70 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  71 # endif
  72 #endif
  73
  74
  75 #if NO_NULL_REALLOC
  76 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  77 #else
  78 # define rrd_realloc(a,b) realloc((a), (b))
  79 #endif
  80
  81 #if HAVE_MATH_H
  82 #  include <math.h>
  83 #endif
  84
  85 #if HAVE_FLOAT_H
  86 #  include <float.h>
  87 #endif
  88
  89 #if HAVE_IEEEFP_H
  90 #  include <ieeefp.h>
  91 #endif
  92
  93 #if HAVE_FP_CLASS_H
  94 #  include <fp_class.h>
  95 #endif
  96
  97 /* for Solaris */
  98 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
  99 #  define HAVE_ISINF 1
 100 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 101 #endif
 102
 103 /* for OSF1 Digital Unix */
 104 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 105 #  define HAVE_ISINF 1
 106 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 107 #endif
 108
 109 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 110 #  define HAVE_ISINF 1
 111 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 112 #endif
 113
 114 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 115 #  define HAVE_ISINF 1
 116 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 117 #endif
 118
 119 /* for AIX */
 120 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 121 #  define HAVE_ISINF 1
 122 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 123 #endif
 124
 125 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 126 #  define HAVE_FINITE 1
 127 #  define finite(a) isfinite(a)
 128 #endif
 129
 130 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 131 #  define HAVE_FINITE 1
 132 #  define finite(a) (! isnan(a) && ! isinf(a))
 133 #endif
 134
 135 #ifndef HAVE_FINITE
 136 #error "Can't compile without finite function"
 137 #endif
 138
 139 #ifndef HAVE_ISINF
 140 #error "Can't compile without isinf function"
 141 #endif
 142
 143 #endif /* CONFIG_H */
 144 ])
 145
 146
 147
 148 dnl Check for the compiler and static/shared library creation.
 149 AC_PROG_CC
 150 AC_PROG_CPP
 151 AC_PROG_LIBTOOL
 152
 153 dnl Check if we run on a system that has fonts
 154 AC_ARG_WITH(rrd-default-font,
 155 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 156 [RRD_DEFAULT_FONT=$withval],[
 157   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 158         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 159   else
 160         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 161   fi
 162 ])
 163
 164 AC_SUBST(RRD_DEFAULT_FONT)
 165
 166 dnl Checks for header files.
 167 AC_HEADER_STDC
 168 AC_HEADER_DIRENT
 169 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 170
 171 dnl Checks for typedefs, structures, and compiler characteristics.
 172 AC_C_CONST
 173 AC_HEADER_TIME
 174 AC_STRUCT_TM
 175
 176 dnl Checks for libraries.
 177 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 178
 179 dnl add pic flag in any case this makes sure all our code is relocatable
 180 eval `./libtool --config | grep pic_flag`
 181 CFLAGS="$CFLAGS $pic_flag"
 182
 183 dnl Checks for library functions.
 184 AC_FUNC_STRFTIME
 185 AC_FUNC_VPRINTF
 186
 187 AC_C_BIGENDIAN
 188
 189 dnl for each function found we get a definition in config.h
 190 dnl of the form HAVE_FUNCTION
 191
 192 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 193
 194 dnl Use mmap in rrd_update instead of seek+write
 195 AC_ARG_ENABLE([mmap],
 196 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 197 [],
 198 [enable_mmap=yes])
 199
 200 if test "x$enable_mmap" = xyes; then
 201   AC_FUNC_MMAP
 202 fi
 203
 204 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 205 dnl actual code to check if this works
 206 AC_CHECK_FUNCS(fpclassify, ,
 207   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 208     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 209 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 210       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 211 AC_CHECK_FUNCS(finite, ,
 212   [AC_CHECK_FUNCS(isfinite, ,
 213     [AC_MSG_CHECKING(for isfinite with <math.h>)
 214     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 215 volatile int x;volatile float f;  ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 216       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 217 AC_CHECK_FUNCS(isinf, ,
 218   [AC_MSG_CHECKING(for isinf with <math.h>)
 219     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 220 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 221       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 222
 223 AC_FULL_IEEE
 224
 225 dnl How the vertical axis label is printed
 226 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 227  [Vertical label angle: 90.0 (default) or 270.0])
 228 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 229  [Vertical label angle: 90.0 (default) or 270.0])
 230
 231
 232 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 233 [],[enable_rrdcgi=yes])
 234 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 235
 236 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 237 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.2,  http://www.gzip.org/zlib/, "")
 238 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 239 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 240
 241 save_LIBS=${LIBS}
 242 save_CPPFLAGS=${CPPFLAGS}
 243 save_LDFLAGS=${LDFLAGS}
 244
 245 if test $enable_rrdcgi != no; then
 246 EX_CHECK_ALL(cgi,        cgiInit,                   cgi.h,                  cgilib,      0.5,    http://www.infodrom.org/projects/cgilib, "")
 247 fi
 248
 249 CGI_LIBS=${LIBS}
 250 CGI_CPPFLAGS=${CPPFLAGS}
 251 CGI_LDFLAGS=${LDFLAGS}
 252
 253 AC_SUBST(CGI_LIBS)
 254 AC_SUBST(CGI_CPPFLAGS)
 255 AC_SUBST(CGI_LDFLAGS)
 256
 257 LIBS=${save_LIBS}
 258 CPPFLAGS=${save_CPPFLAGS}
 259 LDFLAGS=${save_LDFLAGS}
 260
 261 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 262   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 263 fi
 264
 265 AC_LANG_PUSH(C)
 266 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 267 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 268 AC_LINK_IFELSE(
 269     AC_LANG_PROGRAM(
 270            [[#include <time.h>]],
 271            [[ctime_r(NULL,NULL,0)]]
 272                    ),
 273     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 274       AC_LINK_IFELSE(
 275           AC_LANG_PROGRAM(
 276                 [[#include <time.h>]],
 277                 [[ctime_r(NULL,NULL)]]
 278                          ),
 279           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 280           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 281       )
 282     ],
 283     [ AC_LINK_IFELSE(
 284           AC_LANG_PROGRAM(
 285                 [[#include <time.h>]],
 286                 [[ctime_r(NULL,NULL)]]
 287                          ),
 288           [AC_MSG_RESULT(no)],
 289           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 290       )
 291     ]
 292 )
 293 AC_LANG_POP(C)
 294
 295 dnl Check for pthreads
 296 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 297
 298 AC_SUBST(MULTITHREAD_CFLAGS)
 299 AC_SUBST(MULTITHREAD_LDFLAGS)
 300
 301
 302 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 303 [],[enable_pthread=yes])
 304
 305
 306 if test $enable_pthread != no; then
 307  ACX_PTHREAD([
 308     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 309     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 310              ],
 311              [])
 312 fi
 313
 314 dnl since we use lots of *_r functions all over the code we better
 315 dnl make sure they are known
 316
 317 if test  "x$x_rflag" != "xno"; then
 318    CPPFLAGS="$CPPFLAGS $x_rflag"
 319 fi
 320
 321
 322 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 323
 324 dnl Check for Perl.
 325 AC_PATH_PROG(PERL, perl, no)
 326
 327 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 328 [],[enable_perl=yes])
 329
 330
 331 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 332 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 333 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 334 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 335
 336 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 337         COMP_PERL=
 338 else
 339         COMP_PERL="perl_piped perl_shared"
 340         AC_MSG_CHECKING(for the perl version you are running)
 341         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 342         AC_MSG_RESULT($PERL_VERSION)
 343         if test -z "$PERLCC"; then
 344             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 345             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 346             AC_MSG_RESULT($perlcc)
 347             if test ! -x "$perlcc"; then
 348                 AC_PATH_PROG(PERL_CC, "${perlcc}", no)
 349                 if test "$PERL_CC" = "no"; then
 350                     AC_MSG_WARN([
 351 I would not find the Compiler ($perlcc) that was originally used to compile
 352 your perl binary. You should either make sure that this compiler is
 353 available on your system, pick an other compiler and set PERLCC
 354 appropriately, or use a different perl setup that was compiled locally.
 355
 356 I will disable the compilation of the RRDs perl module for now.
 357 ])
 358                     COMP_PERL="perl_piped"
 359                 fi
 360             fi
 361         fi
 362 fi
 363 AC_MSG_CHECKING(Perl Modules to build)
 364 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 365
 366 # Options to pass when configuring perl module
 367 ppref=$prefix
 368 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 369
 370 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 371
 372 dnl pass additional perl options when generating Makefile from Makefile.PL
 373 AC_ARG_ENABLE(perl-site-install,
 374 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 375                           together with rrdtool in $prefix/lib/perl. You have to
 376                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 377                           when you want to use them. When you set this option
 378                           the perl modules will get installed wherever
 379                           your perl setup thinks it is best.],
 380 [PERL_MAKE_OPTIONS=],[])
 381
 382 if test ! -z "$PERLCC"; then
 383    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 384
 385    if test ! -z "$PERLCCFLAGS"; then
 386        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 387    fi
 388
 389    if test -z "$PERLLD"; then
 390        PERLLD=$PERLCC
 391    fi
 392    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 393
 394    if test ! -z "$PERLLDFLAGS"; then
 395        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 396    fi
 397 fi
 398
 399 AC_ARG_WITH(perl-options,
 400 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 401                           generating Makefile from Makefile.PL. If you set this
 402                           option, interesting things may happen unless you know
 403                           what you are doing!],
 404 [PERL_MAKE_OPTIONS=$withval])
 405
 406 AC_SUBST(PERL_MAKE_OPTIONS)
 407 AC_SUBST(PERL)
 408 AC_SUBST(COMP_PERL)
 409 AC_SUBST(PERL_VERSION)
 410
 411 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 412 [],[enable_tcl=yes])
 413
 414 if test  "$enable_tcl" = "yes"; then
 415   dnl Check for Tcl.
 416   withval=""
 417   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 418   enable_tcl=no
 419   for dir in $withval /usr/lib /usr/local/lib; do
 420     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 421     if test -f "$dir/tclConfig.sh" ; then
 422         tcl_config=$dir/tclConfig.sh
 423         enable_tcl=yes
 424         AC_MSG_RESULT(yes)
 425         break
 426     else
 427         AC_MSG_RESULT(no)
 428     fi
 429   done
 430
 431   if test "$enable_tcl" = "no"; then
 432         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 433   else
 434         . $tcl_config
 435         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 436   fi
 437 fi
 438
 439 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 440
 441 AC_SUBST(TCL_PREFIX)
 442 AC_SUBST(TCL_SHLIB_CFLAGS)
 443 AC_SUBST(TCL_SHLIB_LD)
 444 AC_SUBST(TCL_SHLIB_SUFFIX)
 445 AC_SUBST(TCL_PACKAGE_PATH)
 446 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 447 AC_SUBST(TCL_VERSION)
 448 AC_SUBST(TCL_PACKAGE_DIR)
 449
 450 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 451 [],[enable_python=yes])
 452
 453 if test  "$enable_python" = "yes"; then
 454 dnl Check for python
 455 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 456 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 457 fi
 458
 459 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
 460
 461 dnl Check for nroff
 462 AC_PATH_PROGS(NROFF, gnroff nroff)
 463 AC_PATH_PROGS(TROFF, groff troff)
 464
 465 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 466 if test -z "$RRDDOCDIR"; then
 467    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 468
 469 dnl Does the compiler like -Wall and -pedantic?
 470 if test "$GCC" = "yes"; then
 471   oCFLAGS=$CFLAGS
 472   CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 473   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 474                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 475                ]
 476         )
 477   if test $rd_cv_gcc_opt = no; then
 478          CFLAGS=$oCFLAGS
 479   fi
 480 fi
 481
 482 dnl what does realloc do if it gets called with a NULL pointer
 483
 484 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 485 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 486               int main(void){
 487               char *x = NULL;
 488               x = realloc (x,10);
 489               if (x==NULL) return 1;
 490               return 0;
 491              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 492
 493 if test x"$rd_cv_null_realloc" = xnope; then
 494 AC_DEFINE(NO_NULL_REALLOC)
 495 fi
 496
 497 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 498           examples/piped-demo.pl                        \
 499           examples/stripes.pl                           \
 500           examples/bigtops.pl                           \
 501           examples/minmax.pl                            \
 502           examples/cgi-demo.cgi                         \
 503           examples/4charts.pl                           \
 504           examples/Makefile                             \
 505           doc/Makefile                                  \
 506           src/Makefile                                  \
 507           bindings/Makefile                             \
 508           bindings/tcl/Makefile                         \
 509           bindings/tcl/ifOctets.tcl                     \
 510           bindings/python/Makefile                      \
 511           Makefile])
 512 AC_CONFIG_COMMANDS([default],[[\
 513           chmod +x examples/*.cgi examples/*.pl]],[[]])
 514 AC_OUTPUT
 515
 516 AC_MSG_CHECKING(in)
 517 AC_MSG_RESULT(and out again)
 518
 519 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 520 sleep 1
 521 echo $ECHO_N ".$ECHO_C" 1>&6
 522 sleep 1
 523 echo $ECHO_N ".$ECHO_C" 1>&6
 524 sleep 1
 525 echo $ECHO_N ".$ECHO_C" 1>&6
 526 sleep 1
 527 echo $ECHO_N ".$ECHO_C" 1>&6
 528 sleep 1
 529 AC_MSG_RESULT([ just kidding ;-)])
 530 echo
 531 echo "----------------------------------------------------------------"
 532 echo "Config is DONE!"
 533 echo
 534 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 535 echo "          Perl Modules: $COMP_PERL"
 536 echo "           Perl Binary: $PERL"
 537 echo "          Perl Version: $PERL_VERSION"
 538 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 539 echo "    Build Tcl Bindings: $enable_tcl"
 540 echo " Build Python Bindings: $enable_python"
 541 echo "          Build rrdcgi: $enable_rrdcgi"
 542 echo "       Build librrd MT: $enable_pthread"
 543 echo
 544 echo
 545 echo "Type 'make' to compile the software and use 'make install' to "
 546 echo "install everything to: $prefix."
 547 echo
 548 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 549 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 550 echo "place an order."
 551 echo
 552 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 553 echo "----------------------------------------------------------------"