configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(collectd, 3.10.3)
   3 AC_CONFIG_SRCDIR(src/collectd.c)
   4 AC_CONFIG_HEADERS(src/config.h)
   5 AM_INIT_AUTOMAKE(dist-bzip2)
   6 AC_LANG(C)
   7
   8 AC_PREFIX_DEFAULT("/opt/collectd")
   9
  10 #
  11 # Checks for programs.
  12 #
  13 AC_PROG_CC
  14 AC_PROG_CPP
  15 AC_PROG_INSTALL
  16 AC_PROG_LN_S
  17 AC_PROG_MAKE_SET
  18 AM_CONDITIONAL(COMPILER_IS_GCC, test "x$GCC" = "xyes")
  19
  20 dnl configure libtool
  21 AC_DISABLE_STATIC
  22 AC_LIBLTDL_CONVENIENCE
  23 AC_SUBST(LTDLINCL)
  24 AC_SUBST(LIBLTDL)
  25 AC_LIBTOOL_DLOPEN
  26 AC_PROG_LIBTOOL
  27 #AC_PROG_RANLIB
  28 AC_CONFIG_SUBDIRS(libltdl src/libconfig)
  29
  30 #
  31 # Checks for header files.
  32 #
  33 AC_HEADER_STDC
  34 AC_HEADER_SYS_WAIT
  35 AC_HEADER_DIRENT
  36 AC_CHECK_HEADERS(stdint.h)
  37 AC_CHECK_HEADERS(stdio.h)
  38 AC_CHECK_HEADERS(errno.h)
  39 AC_CHECK_HEADERS(math.h)
  40 AC_CHECK_HEADERS(syslog.h)
  41 AC_CHECK_HEADERS(fcntl.h)
  42 AC_CHECK_HEADERS(signal.h)
  43 AC_CHECK_HEADERS(assert.h)
  44 AC_CHECK_HEADERS(sys/types.h)
  45 AC_CHECK_HEADERS(sys/socket.h)
  46 AC_CHECK_HEADERS(sys/select.h)
  47 AC_CHECK_HEADERS(sys/poll.h)
  48 AC_CHECK_HEADERS(netdb.h)
  49 AC_CHECK_HEADERS(arpa/inet.h)
  50 AC_CHECK_HEADERS(sys/resource.h)
  51 AC_CHECK_HEADERS(sys/param.h)
  52
  53 # For ping library
  54 AC_CHECK_HEADERS(netinet/in_systm.h, [], [],
  55 [#if HAVE_STDINT_H
  56 # include <stdint.h>
  57 #endif
  58 #if HAVE_SYS_TYPES_H
  59 # include <sys/types.h>
  60 #endif
  61 ])
  62 AC_CHECK_HEADERS(netinet/in.h, [], [],
  63 [#if HAVE_STDINT_H
  64 # include <stdint.h>
  65 #endif
  66 #if HAVE_SYS_TYPES_H
  67 # include <sys/types.h>
  68 #endif
  69 #if HAVE_NETINET_IN_SYSTM_H
  70 # include <netinet/in_systm.h>
  71 #endif
  72 ])
  73 AC_CHECK_HEADERS(netinet/ip.h, [], [],
  74 [#if HAVE_STDINT_H
  75 # include <stdint.h>
  76 #endif
  77 #if HAVE_SYS_TYPES_H
  78 # include <sys/types.h>
  79 #endif
  80 #if HAVE_NETINET_IN_SYSTM_H
  81 # include <netinet/in_systm.h>
  82 #endif
  83 #if HAVE_NETINET_IN_H
  84 # include <netinet/in.h>
  85 #endif
  86 ])
  87 AC_CHECK_HEADERS(netinet/ip_icmp.h, [], [],
  88 [#if HAVE_STDINT_H
  89 # include <stdint.h>
  90 #endif
  91 #if HAVE_SYS_TYPES_H
  92 # include <sys/types.h>
  93 #endif
  94 #if HAVE_NETINET_IN_SYSTM_H
  95 # include <netinet/in_systm.h>
  96 #endif
  97 #if HAVE_NETINET_IN_H
  98 # include <netinet/in.h>
  99 #endif
 100 #if HAVE_NETINET_IP_H
 101 # include <netinet/ip.h>
 102 #endif
 103 ])
 104 AC_CHECK_HEADERS(netinet/ip_var.h, [], [],
 105 [#if HAVE_STDINT_H
 106 # include <stdint.h>
 107 #endif
 108 #if HAVE_SYS_TYPES_H
 109 # include <sys/types.h>
 110 #endif
 111 #if HAVE_NETINET_IN_SYSTM_H
 112 # include <netinet/in_systm.h>
 113 #endif
 114 #if HAVE_NETINET_IN_H
 115 # include <netinet/in.h>
 116 #endif
 117 #if HAVE_NETINET_IP_H
 118 # include <netinet/ip.h>
 119 #endif
 120 ])
 121 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
 122 [#if HAVE_STDINT_H
 123 # include <stdint.h>
 124 #endif
 125 #if HAVE_SYS_TYPES_H
 126 # include <sys/types.h>
 127 #endif
 128 #if HAVE_NETINET_IN_SYSTM_H
 129 # include <netinet/in_systm.h>
 130 #endif
 131 #if HAVE_NETINET_IN_H
 132 # include <netinet/in.h>
 133 #endif
 134 ])
 135 AC_CHECK_HEADERS(netinet/icmp6.h, [], [],
 136 [#if HAVE_STDINT_H
 137 # include <stdint.h>
 138 #endif
 139 #if HAVE_SYS_TYPES_H
 140 # include <sys/types.h>
 141 #endif
 142 #if HAVE_NETINET_IN_SYSTM_H
 143 # include <netinet/in_systm.h>
 144 #endif
 145 #if HAVE_NETINET_IN_H
 146 # include <netinet/in.h>
 147 #endif
 148 #if HAVE_NETINET_IP6_H
 149 # include <netinet/ip6.h>
 150 #endif
 151 ])
 152
 153 # For cpu modules
 154 AC_CHECK_HEADERS(sys/sysctl.h sys/dkstat.h)
 155 AC_CHECK_HEADERS(mach/mach_init.h)
 156 AC_CHECK_HEADERS(mach/host_priv.h)
 157 AC_CHECK_HEADERS(mach/mach_error.h)
 158 AC_CHECK_HEADERS(mach/mach_host.h)
 159 AC_CHECK_HEADERS(mach/mach_port.h)
 160 AC_CHECK_HEADERS(mach/mach_types.h)
 161 AC_CHECK_HEADERS(mach/message.h)
 162 AC_CHECK_HEADERS(mach/processor_set.h)
 163 AC_CHECK_HEADERS(mach/processor.h)
 164 AC_CHECK_HEADERS(mach/processor_info.h)
 165 AC_CHECK_HEADERS(mach/task.h)
 166 AC_CHECK_HEADERS(mach/thread_act.h)
 167 AC_CHECK_HEADERS(mach/vm_region.h)
 168 AC_CHECK_HEADERS(mach/vm_map.h)
 169 AC_CHECK_HEADERS(mach/vm_prot.h)
 170 AC_CHECK_HEADERS(mach/vm_statistics.h)
 171 AC_CHECK_HEADERS(mach/kern_return.h)
 172
 173 # For hddtemp module
 174 AC_CHECK_HEADERS(linux/major.h)
 175
 176 # For the apple_sensors module
 177 AC_CHECK_HEADERS(CoreFoundation/CoreFoundation.h)
 178 AC_CHECK_HEADERS(IOKit/IOKitLib.h)
 179 AC_CHECK_HEADERS(IOKit/IOTypes.h)
 180
 181 # For the battery plugin
 182 AC_CHECK_HEADERS(IOKit/ps/IOPowerSources.h, [], [],
 183 [
 184 #if HAVE_IOKIT_IOKITLIB_H
 185 #  include <IOKit/IOKitLib.h>
 186 #endif
 187 #if HAVE_IOKIT_IOTYPES_H
 188 #  include <IOKit/IOTypes.h>
 189 #endif
 190 ])
 191 AC_CHECK_HEADERS(IOKit/ps/IOPSKeys.h)
 192
 193 # For the `disk' plugin
 194 AC_CHECK_HEADERS(IOKit/IOBSD.h)
 195 AC_CHECK_HEADERS(IOKit/storage/IOBlockStorageDriver.h)
 196
 197 # For load module
 198 AC_CHECK_HEADERS(sys/loadavg.h)
 199
 200 # For the processes plugin
 201 AC_CHECK_HEADERS(linux/config.h)
 202
 203 # For the swap module
 204 AC_CHECK_HEADERS(sys/swap.h)
 205
 206 # For users module
 207 AC_CHECK_HEADERS(utmp.h)
 208 AC_CHECK_HEADERS(utmpx.h)
 209
 210 # For traffic plugin
 211 AC_CHECK_HEADERS(ifaddrs.h)
 212 AC_CHECK_HEADERS(net/if.h, [], [],
 213 [
 214 #if HAVE_SYS_TYPES_H
 215 #  include <sys/types.h>
 216 #endif
 217 #if HAVE_SYS_SOCKET_H
 218 #  include <sys/socket.h>
 219 #endif
 220 ])
 221 AC_CHECK_HEADERS(linux/if.h, [], [],
 222 [
 223 #if HAVE_SYS_TYPES_H
 224 #  include <sys/types.h>
 225 #endif
 226 #if HAVE_SYS_SOCKET_H
 227 #  include <sys/socket.h>
 228 #endif
 229 ])
 230 AC_CHECK_HEADERS(linux/netdevice.h, [], [],
 231 [
 232 #if HAVE_SYS_TYPES_H
 233 #  include <sys/types.h>
 234 #endif
 235 #if HAVE_SYS_SOCKET_H
 236 #  include <sys/socket.h>
 237 #endif
 238 #if HAVE_LINUX_IF_H
 239 # include <linux/if.h>
 240 #endif
 241 ])
 242
 243 # For apache plugin
 244 AC_CHECK_HEADERS(curl/curl.h)
 245
 246 # For quota module
 247 AC_CHECK_HEADERS(grp.h pwd.h sys/ucred.h)
 248 AC_CHECK_HEADERS(ctype.h)
 249 AC_CHECK_HEADERS(limits.h)
 250 AC_CHECK_HEADERS(sys/quota.h)
 251 AC_CHECK_HEADERS(xfs/xqm.h)
 252
 253 # For mount interface
 254 AC_CHECK_HEADERS(fs_info.h)
 255 AC_CHECK_HEADERS(fshelp.h)
 256 AC_CHECK_HEADERS(paths.h)
 257 AC_CHECK_HEADERS(mntent.h)
 258 AC_CHECK_HEADERS(mnttab.h)
 259 AC_CHECK_HEADERS(sys/fstyp.h)
 260 AC_CHECK_HEADERS(sys/fs_types.h)
 261 AC_CHECK_HEADERS(sys/mntent.h)
 262 AC_CHECK_HEADERS(sys/mnttab.h)
 263 AC_CHECK_HEADERS(sys/mount.h)
 264 AC_CHECK_HEADERS(sys/statfs.h)
 265 AC_CHECK_HEADERS(sys/statvfs.h)
 266 AC_CHECK_HEADERS(sys/vfs.h)
 267 AC_CHECK_HEADERS(sys/vfstab.h)
 268
 269 # For the swap plugin, FreeBSD
 270 AC_CHECK_HEADERS(kvm.h)
 271
 272 # For debugging interface (variable number of arguments)
 273 AC_CHECK_HEADERS(stdarg.h)
 274
 275 # Regular expressions for the ignorelist.
 276 AC_CHECK_HEADERS(regex.h)
 277
 278 dnl Checking for libraries
 279 AC_CHECK_LIB(m, ext)
 280
 281 #
 282 # Checks for typedefs, structures, and compiler characteristics.
 283 #
 284 AC_C_CONST
 285 AC_TYPE_PID_T
 286 AC_TYPE_SIZE_T
 287 AC_TYPE_UID_T
 288 AC_HEADER_TIME
 289
 290 #
 291 # Checks for library functions.
 292 #
 293 AC_PROG_GCC_TRADITIONAL
 294 AC_CHECK_FUNCS(gettimeofday select strdup strtol)
 295 AC_CHECK_FUNCS(getaddrinfo getnameinfo)
 296 AC_CHECK_FUNCS(strchr memcpy strstr strcmp strncmp strncpy strlen)
 297 AC_CHECK_FUNCS(strncasecmp strcasecmp)
 298 AC_CHECK_FUNCS(openlog syslog closelog)
 299
 300 socket_needs_socket="no"
 301 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [socket_needs_socket="yes"], AC_MSG_ERROR(cannot find socket)))
 302 AM_CONDITIONAL(BUILD_WITH_LIBSOCKET, test "x$socket_needs_socket" = "xyes")
 303
 304 nanosleep_needs_rt="no"
 305 AC_CHECK_FUNCS(nanosleep, [], AC_CHECK_LIB(rt, nanosleep, [nanosleep_needs_rt="yes"], AC_MSG_ERROR(cannot find nanosleep)))
 306 AM_CONDITIONAL(BUILD_WITH_LIBRT, test "x$nanosleep_needs_rt" = "xyes")
 307
 308 # Regular expressions for the ignorelist.
 309 AC_CHECK_FUNCS(regcomp regerror regexec regfree)
 310
 311 # For cpu module
 312 AC_CHECK_FUNCS(sysctlbyname, [have_sysctlbyname="yes"], [have_sysctlbyname="no"])
 313
 314 # For df module
 315 AC_CHECK_FUNCS(statfs statvfs)
 316
 317 # For load module
 318 AC_CHECK_FUNCS(getloadavg, [have_getloadavg="yes"], [have_getloadavg="no"])
 319
 320 # For the `processes' plugin
 321 AC_CHECK_FUNCS(thread_info)
 322
 323 # For users module
 324 AC_CHECK_FUNCS(getutent getutxent)
 325
 326 # For quota module
 327 AC_CHECK_FUNCS(quotactl)
 328 AC_CHECK_FUNCS(getgrgid getpwuid)
 329
 330 # For traffic module
 331 AC_CHECK_FUNCS(getifaddrs)
 332
 333 # For mount interface
 334 #AC_CHECK_FUNCS(getfsent getvfsent)
 335
 336 have_getfsstat="no"
 337 AC_CHECK_FUNCS(getfsstat, [have_getfsstat="yes"])
 338 have_getvfsstat="no"
 339 AC_CHECK_FUNCS(getvfsstat, [have_getvfsstat="yes"])
 340 have_listmntent="no"
 341 AC_CHECK_FUNCS(listmntent, [have_listmntent="yes"])
 342
 343 have_getmntent="no"
 344 AC_CHECK_FUNCS(getmntent, [have_getmntent="c"])
 345 if test "x$have_getmntent" = "xno"; then
 346         AC_CHECK_LIB(sun, getmntent, [have_getmntent="sun"])
 347 fi
 348 if test "x$have_getmntent" = "xno"; then
 349         AC_CHECK_LIB(seq, getmntent, [have_getmntent="seq"])
 350 fi
 351 if test "x$have_getmntent" = "xno"; then
 352         AC_CHECK_LIB(gen, getmntent, [have_getmntent="gen"])
 353 fi
 354
 355 if test "x$have_getmntent" = "xc"; then
 356         AC_CACHE_CHECK([whether getmntent takes one argument],
 357                 [have_one_getmntent],
 358                 AC_COMPILE_IFELSE(
 359                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 360 #include <mntent.h>
 361 #include "$srcdir/src/utils_mount.h"]],
 362                                 [[
 363                                  FILE *fh;
 364                                  struct mntent *me;
 365                                  fh = setmntent ("/etc/mtab", "r");
 366                                  me = getmntent (fh);
 367                                 ]]
 368                         ),
 369                         [have_one_getmntent="yes"],
 370                         [have_one_getmntent="no"]
 371                 )
 372         )
 373         AC_CACHE_CHECK([whether getmntent takes two arguments],
 374                 [have_two_getmntent],
 375                 AC_COMPILE_IFELSE(
 376                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 377 #include <sys/mnttab.h>
 378 #include "$srcdir/src/utils_mount.h"]],
 379                                 [[
 380                                  FILE *fh;
 381                                  struct mnttab mt;
 382                                  int status;
 383                                  fh = fopen ("/etc/mnttab", "r");
 384                                  status = getmntent (fh, &mt);
 385                                 ]]
 386                         ),
 387                         [have_two_getmntent="yes"],
 388                         [have_two_getmntent="no"]
 389                 )
 390         )
 391 fi
 392
 393 # Check for different versions of `getmntent' here..
 394
 395 if test "x$have_getmntent" = "xc"; then
 396         if test "x$have_one_getmntent" = "xyes"; then
 397                 AC_DEFINE(HAVE_ONE_GETMNTENT, 1,
 398                           [Define if the function getmntent exists and takes one argument.])
 399         fi
 400         if test "x$have_two_getmntent" = "xyes"; then
 401                 AC_DEFINE(HAVE_TWO_GETMNTENT, 1,
 402                           [Define if the function getmntent exists and takes two arguments.])
 403         fi
 404 fi
 405 if test "x$have_getmntent" = "xsun"; then
 406         AC_DEFINE(HAVE_SUN_GETMNTENT, 1,
 407                   [Define if the function getmntent exists. It's the version from libsun.])
 408 fi
 409 if test "x$have_getmntent" = "xseq"; then
 410         AC_DEFINE(HAVE_SEQ_GETMNTENT, 1,
 411                   [Define if the function getmntent exists. It's the version from libseq.])
 412 fi
 413 if test "x$have_getmntent" = "xgen"; then
 414         AC_DEFINE(HAVE_GEN_GETMNTENT, 1,
 415                   [Define if the function getmntent exists. It's the version from libgen.])
 416 fi
 417
 418 # Check for structures
 419 AC_CHECK_MEMBERS([struct if_data.ifi_ibytes, struct if_data.ifi_opackets, struct if_data.ifi_ierrors],
 420         [AC_DEFINE(HAVE_STRUCT_IF_DATA, 1, [Define if struct if_data exists and is usable.])],
 421         [],
 422         [
 423         #include <sys/types.h>
 424         #include <sys/socket.h>
 425         #include <net/if.h>
 426         ])
 427 AC_CHECK_MEMBERS([struct net_device_stats.rx_bytes, struct net_device_stats.tx_packets, struct net_device_stats.rx_errors],
 428         [AC_DEFINE(HAVE_STRUCT_NET_DEVICE_STATS, 1, [Define if struct net_device_stats exists and is usable.])],
 429         [],
 430         [
 431         #include <sys/types.h>
 432         #include <sys/socket.h>
 433         #include <linux/if.h>
 434         #include <linux/netdevice.h>
 435         ])
 436
 437 AC_MSG_CHECKING([for kernel type ($host_os)])
 438 case $host_os in
 439         *linux*)
 440         AC_DEFINE([KERNEL_LINUX], 1, [True if program is to be compiled for a Linux kernel])
 441         ac_system="Linux"
 442         ;;
 443         *solaris*)
 444         AC_DEFINE([KERNEL_SOLARIS], 1, [True if program is to be compiled for a Solaris kernel])
 445         ac_system="Solaris"
 446         ;;
 447         *)
 448         ac_system="unknown"
 449 esac
 450 AC_MSG_RESULT([$ac_system])
 451
 452 with_libresolv="yes"
 453 AC_CHECK_LIB(resolv, res_search,
 454 [
 455         AC_DEFINE(HAVE_LIBRESOLV, 1, [Define to 1 if you have the 'resolv' library (-lresolv).])
 456 ],
 457 [with_libresolv="no"])
 458 AM_CONDITIONAL(BUILD_WITH_LIBRESOLV, test "x$with_libresolv" = "xyes")
 459
 460
 461 m4_divert_once([HELP_WITH], [
 462 collectd additional packages:])
 463
 464 # AC_ARG_WITH (package, help-string, [action-if-given], [action-if-not-given])
 465 AC_ARG_WITH(rrdtool, [AS_HELP_STRING([--with-rrdtool@<:@=PREFIX@:>@], [Path to rrdtool.])],
 466 [       if test "x$withval" != "xno" && test "x$withval" != "xyes"
 467         then
 468                 LDFLAGS="$LDFLAGS -L$withval/lib"
 469                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 470                 with_rrdtool="yes"
 471         fi
 472 ], [with_rrdtool="yes"])
 473 if test "x$with_rrdtool" = "xyes"
 474 then
 475         AC_CHECK_LIB(rrd, rrd_update,
 476         [
 477                 AC_DEFINE(HAVE_LIBRRD, 1, [Define to 1 if you have the rrd library (-lrrd).])
 478         ],
 479         [with_rrdtool="no (librrd not found)"], [-lm])
 480 fi
 481 if test "x$with_rrdtool" = "xyes"
 482 then
 483         AC_CHECK_HEADERS(rrd.h,, [with_rrdtool="no (rrd.h not found)"])
 484 fi
 485 if test "x$with_rrdtool" = "xyes"
 486 then
 487         collect_rrdtool=1
 488 else
 489         collect_rrdtool=0
 490 fi
 491 AC_DEFINE_UNQUOTED(COLLECT_RRDTOOL, [$collect_rrdtool],
 492         [Wether or not to use rrdtool library])
 493 AM_CONDITIONAL(BUILD_WITH_RRDTOOL, test "x$with_rrdtool" = "xyes")
 494
 495 #AC_ARG_WITH(pth, [AS_HELP_STRING([--with-pth=@<:@=PREFIX@:>@], [Path to pth (experimental).]),
 496 #[      if test "x$withval" != "xno" && test "x$withval" != "xyes"
 497 #       then
 498 #               LDFLAGS="$LDFLAGS -L$withval/lib"
 499 #               CPPFLAGS="$CPPFLAGS -I$withval/include"
 500 #               with_pth="yes"
 501 #       fi
 502 #], [with_pth="no"])
 503 #if test "x$with_pth" = "xyes"
 504 #then
 505 #       AC_CHECK_LIB(pth, pth_init,, [with_pth="no (libpth not found)"], [])
 506 #fi
 507 #if test "x$with_pth" = "xyes"
 508 #then
 509 #       AC_CHECK_HEADERS(pth.h,, [with_pth="no (pth.h not found)"])
 510 #fi
 511 #if test "x$with_pth" = "xyes"
 512 #then
 513 #       collect_pth=1
 514 #else
 515 #       collect_pth=0
 516 #fi
 517 #AC_DEFINE_UNQUOTED(COLLECT_PTH, [$collect_pth],
 518 #       [Wether or not to use pth (portable threads) library])
 519 #AM_CONDITIONAL(BUILD_WITH_PTH, test "x$with_pth" = "xyes")
 520
 521 if test "$ac_system" = "Solaris"
 522 then
 523         with_kstat="yes"
 524         with_devinfo="yes"
 525 else
 526         with_kstat="no (Solaris only)"
 527         with_devinfo="no (Solaris only)"
 528 fi
 529
 530 if test "x$with_kstat" = "xyes"
 531 then
 532         AC_CHECK_LIB(kstat, kstat_open,, [with_kstat="no (libkstat not found)"])
 533 fi
 534 if test "x$with_kstat" = "xyes"
 535 then
 536         AC_CHECK_LIB(devinfo, di_init,, [with_devinfo="no (not found)"])
 537         AC_CHECK_HEADERS(kstat.h,, [with_kstat="no (kstat.h not found)"])
 538 fi
 539 if test "x$with_kstat" = "xyes"
 540 then
 541         collect_kstat=1
 542 else
 543         collect_kstat=0
 544 fi
 545 AC_DEFINE_UNQUOTED(COLLECT_KSTAT, [$collect_kstat],
 546         [Wether or not to use kstat library (Solaris)])
 547 AM_CONDITIONAL(BUILD_WITH_LIBKSTAT, test "x$with_kstat" = "xyes")
 548 AM_CONDITIONAL(BUILD_WITH_LIBDEVINFO, test "x$with_devinfo" = "xyes")
 549
 550 ### BEGIN of check for libcurl ###
 551 with_curl_config="curl-config"
 552 with_curl_prefix=0
 553 with_curl_libs=""
 554 AC_ARG_WITH(libcurl, [AS_HELP_STRING([--with-libcurl@<:@=PREFIX@:>@], [Path to libcurl.])],
 555 [
 556         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 557         then
 558                 if test -x "$withval/bin/curl-config"
 559                 then
 560                         with_curl_config="$withval/bin/curl-config"
 561                         with_curl_prefix=1
 562                 fi
 563         fi
 564         if test "x$withval" = "xno"
 565         then
 566                 with_libcurl="no"
 567         else
 568                 with_libcurl="yes"
 569         fi
 570 ],
 571 [
 572         with_libcurl="yes"
 573 ])
 574 if test "x$with_libcurl" = "xyes"
 575 then
 576         with_curl_libs=`$with_curl_config --libs 2>/dev/null`
 577         curl_config_status=$?
 578
 579         if test $curl_config_status -ne 0
 580         then
 581                 with_libcurl="no"
 582         else
 583                 AC_CHECK_LIB(curl, curl_easy_init,
 584                 [
 585                         BUILD_WITH_LIBCURL_LIBS="$with_curl_libs"
 586                         AC_SUBST(BUILD_WITH_LIBCURL_LIBS)
 587                 ],
 588                 [
 589                         with_libcurl="no"
 590                 ],
 591                 [$with_curl_libs])
 592         fi
 593 fi
 594 if test "x$with_libcurl" = "xyes" -a $with_curl_prefix -ne 0
 595 then
 596         with_curl_prefix=`$with_curl_config --libs 2>/dev/null`
 597         curl_config_status=$?
 598
 599         if test $curl_config_status -ne 0
 600         then
 601                 with_libcurl="no"
 602         else
 603                 if test -d "$with_curl_prefix/include"
 604                 then
 605                         CPPFLAGS="$CPPFLAGS -I$with_curl_prefix/include"
 606                 fi
 607         fi
 608 fi
 609
 610 with_libcurl_numeric=0
 611 if test "x$with_libcurl" = "xyes"
 612 then
 613         with_libcurl_numeric=1
 614 fi
 615 AC_DEFINE_UNQUOTED(HAVE_LIBCURL, [$with_libcurl_numeric], [Define to 1 if you have the 'curl' library (-lcurl).])
 616 AM_CONDITIONAL(BUILD_WITH_LIBCURL, test "x$with_libcurl" = "xyes")
 617 ### END of check for libcurl ###
 618
 619 with_libiokit="no"
 620 collectd_libiokit=0
 621 AC_CHECK_LIB(IOKit, IOServiceGetMatchingServices,
 622 [
 623         with_libiokit="yes"
 624         collectd_libiokit=1
 625 ],
 626 [
 627         with_libiokit="no"
 628         collectd_libiokit=0
 629 ])
 630 AC_DEFINE_UNQUOTED(COLLECT_LIBIOKIT, [$collect_libiokit], [Wether or not to use the IOKit library])
 631 AM_CONDITIONAL(BUILD_WITH_LIBIOKIT, test "x$with_libiokit" = "xyes")
 632
 633 with_libstatgrab="yes"
 634 with_libdevstat="no"
 635 AC_ARG_WITH(libstatgrab, [AS_HELP_STRING([--with-libstatgrab@<:@=PREFIX@:>@], [Path to libstatgrab.])],
 636 [
 637         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 638         then
 639                 LDFLAGS="$LDFLAGS -L$withval/lib"
 640                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 641                 with_libstatgrab="yes"
 642         fi
 643 ],
 644 [
 645         if test "x$ac_system" == "xunknown"
 646         then
 647                 with_libstatgrab="yes"
 648         else
 649                 with_libstatgrab="no"
 650         fi
 651 ])
 652 if test "x$with_libstatgrab" = "xyes"
 653 then
 654         AC_CHECK_LIB(statgrab, sg_init, [with_libstatgrab="yes"], [with_libstatgrab="no (libstatgrab not found)"])
 655 fi
 656 if test "x$with_libstatgrab" = "xyes"
 657 then
 658         AC_CHECK_HEADERS(statgrab.h,,    [with_libstatgrab="no (statgrab.h not found)"])
 659 fi
 660 if test "x$with_libstatgrab" = "xyes"
 661 then
 662         AC_CHECK_LIB(devstat, getdevs, [with_libdevstat="yes"], [with_libdevstat="no"])
 663 fi
 664 if test "x$with_libstatgrab" = "xyes"
 665 then
 666         collect_libstatgrab=1
 667 else
 668         collect_libstatgrab=0
 669 fi
 670 AC_DEFINE_UNQUOTED(COLLECT_LIBSTATGRAB, [$collect_libstatgrab],
 671         [Wether or not to use statgrab library])
 672 AM_CONDITIONAL(BUILD_WITH_LIBSTATGRAB, test "x$with_libstatgrab" = "xyes")
 673 AM_CONDITIONAL(BUILD_WITH_LIBDEVSTAT,  test "x$with_libdevstat"  = "xyes")
 674
 675 AC_CHECK_LIB(kvm, kvm_getswapinfo, [with_libkvm="yes"], [with_libkvm="no"])
 676 if test "x$with_libkvm" = "xyes"
 677 then
 678         AC_DEFINE(HAVE_LIBKVM, 1, [Define to 1 if you have the 'kvm' library (-lkvm)])
 679 fi
 680 AM_CONDITIONAL(BUILD_WITH_LIBKVM, test "x$with_libkvm" = "xyes")
 681
 682 AC_ARG_WITH(lm-sensors, [AS_HELP_STRING([--with-lm-sensors@<:@=PREFIX@:>@], [Path to lm_sensors.])],
 683 [
 684         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 685         then
 686                 LDFLAGS="$LDFLAGS -L$withval/lib"
 687                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 688                 with_lm_sensors="yes"
 689         fi
 690 ],
 691 [
 692         if test "x$ac_system" = "xLinux"
 693         then
 694                 with_lm_sensors="yes"
 695         else
 696                 with_lm_sensors="no"
 697         fi
 698 ])
 699 if test "x$with_lm_sensors" = "xyes"
 700 then
 701         AC_CHECK_LIB(sensors, sensors_init,
 702         [
 703                 AC_DEFINE(HAVE_LIBSENSORS, 1, [Define to 1 if you have the sensors library (-lsensors).])
 704         ],
 705         [with_lm_sensors="no (libsensors not found)"])
 706 fi
 707 if test "x$with_lm_sensors" = "xyes"
 708 then
 709         AC_CHECK_HEADERS(sensors/sensors.h,
 710         [
 711                 AC_DEFINE(HAVE_SENSORS_SENSORS_H, 1, [Define to 1 if you have the <sensors/sensors.h> header file.])
 712         ],
 713         [with_lm_sensors="no (sensors/sensors.h not found)"])
 714 fi
 715 if test "x$with_lm_sensors" = "xyes"
 716 then
 717         collect_lm_sensors=1
 718 else
 719         collect_lm_sensors=0
 720 fi
 721 AC_DEFINE_UNQUOTED(COLLECT_LM_SENSORS, [$collect_lm_sensors],
 722         [Wether or not to use sensors library])
 723 AM_CONDITIONAL(BUILD_WITH_LM_SENSORS, test "x$with_lm_sensors" = "xyes")
 724
 725 AC_ARG_WITH(libmysql, [AS_HELP_STRING([--with-libmysql@<:@=PREFIX@:>@], [Path to libmysql.])],
 726 [
 727         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 728         then
 729                 LDFLAGS="$LDFLAGS -L$withval/lib"
 730                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 731                 with_libmysql="yes"
 732         fi
 733 ],
 734 [
 735         with_libmysql="yes"
 736 ])
 737 if test "x$with_libmysql" = "xyes"
 738 then
 739         AC_CHECK_LIB(mysqlclient, mysql_init,
 740         [
 741                 AC_DEFINE(HAVE_LIBMYSQLCLIENT, 1, [Define to 1 if you have the mysqlclient library (-lmysqlclient).])
 742         ], [with_libmysql="no (libmysql not found)"])
 743 fi
 744 if test "x$with_libmysql" = "xyes"
 745 then
 746         AC_CHECK_HEADERS(mysql/mysql.h,
 747         [
 748                 AC_DEFINE(HAVE_MYSQL_MYSQL_H, 1, [Define to 1 if you have the <mysql/mysql.h> header file.])
 749         ], [with_libmysql="no (mysql/mysql.h not found)"])
 750 fi
 751 if test "x$with_libmysql" = "xyes"
 752 then
 753         collect_libmysql=1
 754 else
 755         collect_libmysql=0
 756 fi
 757 AC_DEFINE_UNQUOTED(COLLECT_LIBMYSQL, [$collect_libmysql],
 758         [Wether or not to use mysql library])
 759 AM_CONDITIONAL(BUILD_WITH_LIBMYSQL, test "x$with_libmysql" = "xyes")
 760
 761 #with_liboping="yes"
 762 with_own_liboping="no"
 763 liboping_LDFLAGS="$LDFLAGS"
 764 liboping_CPPFLAGS="$CPPFLAGS"
 765 AC_ARG_WITH(liboping, [AS_HELP_STRING([--with-liboping@<:@=PREFIX@:>@], [Path to liboping.])],
 766 [
 767         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 768         then
 769                 if test -d "$withval/lib"
 770                 then
 771                         liboping_LDFLAGS="$LDFLAGS -L$withval/lib"
 772                 fi
 773                 if test -d "$withval/include"
 774                 then
 775                         liboping_CPPFLAGS="$CPPFLAGS -I$withval/include"
 776                 fi
 777         fi
 778         if test "x$withval" = "xno"
 779         then
 780                 with_liboping="no"
 781                 with_own_liboping="no"
 782         fi
 783 ],
 784 [
 785         #753
 786         with_liboping="yes"
 787 ])
 788
 789 if test "x$with_liboping" = "xyes"
 790 then
 791         save_LDFLAGS="$LDFLAGS"
 792         save_CPPFLAGS="$CPPFLAGS"
 793         LDFLAGS="$liboping_LDFLAGS"
 794         CPPFLAGS="$liboping_CPPFLAGS"
 795         AC_CHECK_LIB(oping, ping_construct,
 796         [
 797                 with_liboping="yes"
 798                 with_own_liboping="no"
 799         ],
 800         [
 801                 with_liboping="yes"
 802                 with_own_liboping="yes"
 803                 LDFLAGS="$save_LDFLAGS"
 804                 CPPFLAGS="$save_CPPFLAGS"
 805         ])
 806 fi
 807 AM_CONDITIONAL(BUILD_WITH_LIBOPING, test "x$with_liboping" = "xyes")
 808 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOPING, test "x$with_own_liboping" = "xyes")
 809 if test "x$with_liboping" = "xyes" -a "x$with_own_liboping" = "xyes"
 810 then
 811         with_liboping="yes (shipped version)"
 812 fi
 813
 814 # Define `step' and `hearbeat' values..
 815 declare -i collectd_step=10
 816 declare -i collectd_heartbeat=25
 817 AC_ARG_WITH(step, [AS_HELP_STRING([--with-step=SECONDS], [Interval in which plugins are queried.])],
 818 [
 819         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 820         then
 821                 declare -i tmp_collectd_step="$withval"
 822                 if test $tmp_collectd_step -gt 0
 823                 then
 824                         collectd_step=$tmp_collectd_step
 825                         let "collectd_heartbeat=$collectd_step*2"
 826                 fi
 827         fi
 828 ], [])
 829 AC_ARG_WITH(heartbeat, [AS_HELP_STRING([--with-heartbeat=SECONDS], [Heartbeat of the DS in generated RRD files.])],
 830 [
 831         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 832         then
 833                 declare -i tmp_collectd_heartbeat="$withval"
 834                 if test $tmp_collectd_heartbeat -gt 0
 835                 then
 836                         collectd_heartbeat=$tmp_collectd_heartbeat
 837                 fi
 838         fi
 839 ], [])
 840
 841 if test $collectd_step -ne 10
 842 then
 843         AC_DEFINE_UNQUOTED(COLLECTD_STEP, "$collectd_step", [Interval in which plugins are queried.])
 844 fi
 845 if test $collectd_heartbeat -ne 25
 846 then
 847         AC_DEFINE_UNQUOTED(COLLECTD_HEARTBEAT, "$collectd_heartbeat", [Interval in which plugins are queried.])
 848 fi
 849
 850 # Check for enabled/disabled features
 851 #
 852
 853 # AC_COLLECTD(name, enable/disable, info-text, feature/module)
 854 # ------------------------------------------------------------
 855 dnl
 856 m4_define([my_toupper], [m4_translit([$1], m4_defn([m4_cr_letters]), m4_defn([m4_cr_LETTERS]))])
 857 dnl
 858 AC_DEFUN(
 859         [AC_COLLECTD],
 860         [
 861         m4_if([$1], [], [AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 1st argument must not be empty])])dnl
 862         m4_if(
 863                 [$2],
 864                 [enable],
 865                 [dnl
 866                 m4_define([EnDis],[disabled])dnl
 867                 m4_define([YesNo],[no])dnl
 868                 ],dnl
 869                 [m4_if(
 870                         [$2],
 871                         [disable],
 872                         [dnl
 873                         m4_define([EnDis],[enabled])dnl
 874                         m4_define([YesNo],[yes])dnl
 875                         ],
 876                         [dnl
 877                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 2nd argument must be either enable or disable])dnl
 878                         ]dnl
 879                 )]dnl
 880         )dnl
 881         m4_if([$3], [feature], [],
 882                 [m4_if(
 883                         [$3], [module], [],
 884                         [dnl
 885                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 3rd argument must be either feature or disable])dnl
 886                         ]dnl
 887                 )]dnl
 888         )dnl
 889         AC_ARG_ENABLE(
 890                 [$1],
 891                 AS_HELP_STRING([--$2-$1], [$2 $4 (EnDis by def)]),
 892                 [],
 893                 enable_$1='[YesNo]'dnl
 894         )# AC_ARG_ENABLE
 895 if test "x$enable_$1" = "xno"
 896 then
 897         collectd_$1=0
 898 else
 899         if test "x$enable_$1" = "xyes"
 900         then
 901                 collectd_$1=1
 902         else
 903                 AC_MSG_NOTICE([please specify either --enable-$1 or --disable-$1; enabling $1.])
 904                 collectd_$1=1
 905                 enable_$1='yes'
 906         fi
 907 fi
 908         AC_DEFINE_UNQUOTED([COLLECT_]my_toupper([$1]), [$collectd_$1], [wether or not to enable $3 $4])
 909         AM_CONDITIONAL([BUILD_]my_toupper([$3])[_]my_toupper([$1]), [test "x$enable_$1" = "xyes"])dnl
 910         ]dnl
 911 )# AC_COLLECTD(name, enable/disable, info-text, feature/module)
 912
 913 m4_divert_once([HELP_ENABLE], [
 914 collectd features:])
 915 AC_COLLECTD([debug],     [enable],  [feature], [debugging])
 916 AC_COLLECTD([daemon],    [disable], [feature], [daemon mode])
 917 AC_COLLECTD([getifaddrs],[enable],  [feature], [getifaddrs under Linux])
 918
 919 m4_divert_once([HELP_ENABLE], [
 920 collectd modules:])
 921 AC_COLLECTD([apache],    [disable], [module], [Apache httpd statistics])
 922 AC_COLLECTD([apcups],    [disable], [module], [Statistics of UPSes by APC])
 923 AC_COLLECTD([apple_sensors], [disable], [module], [Apple's hardware sensors])
 924 AC_COLLECTD([battery],   [disable], [module], [battery statistics])
 925 AC_COLLECTD([cpu],       [disable], [module], [cpu usage statistics])
 926 AC_COLLECTD([cpufreq],   [disable], [module], [system cpu frequency statistics])
 927 AC_COLLECTD([disk],      [disable], [module], [disk/partition statistics])
 928 AC_COLLECTD([df],        [disable], [module], [df statistics])
 929 AC_COLLECTD([quota],     [enable],  [module], [quota statistics (experimental)])
 930 AC_COLLECTD([hddtemp],   [disable], [module], [hdd temperature statistics])
 931 AC_COLLECTD([load],      [disable], [module], [system load statistics])
 932 AC_COLLECTD([memory],    [disable], [module], [memory statistics])
 933 AC_COLLECTD([multimeter],[disable], [module], [multimeter statistics])
 934 AC_COLLECTD([mysql],     [disable], [module], [mysql statistics])
 935 AC_COLLECTD([nfs],       [disable], [module], [nfs statistics])
 936 AC_COLLECTD([ntpd],      [disable], [module], [nfs statistics])
 937 AC_COLLECTD([ping],      [disable], [module], [ping statistics])
 938 AC_COLLECTD([processes], [disable], [module], [processes statistics])
 939 AC_COLLECTD([sensors],   [disable], [module], [lm_sensors statistics])
 940 AC_COLLECTD([serial],    [disable], [module], [serial statistics])
 941 AC_COLLECTD([swap],      [disable], [module], [swap statistics])
 942 AC_COLLECTD([tape],      [disable], [module], [tape statistics])
 943 AC_COLLECTD([traffic],   [disable], [module], [system traffic statistics])
 944 AC_COLLECTD([users],     [disable], [module], [user count statistics])
 945 AC_COLLECTD([vserver],   [disable], [module], [vserver statistics])
 946 AC_COLLECTD([wireless],  [disable], [module], [wireless link statistics])
 947
 948 AC_OUTPUT(Makefile src/Makefile src/collectd.conf src/libconfig/Makefile src/liboping/Makefile)
 949
 950 cat <<EOF;
 951
 952 Configuration:
 953   Libraries:
 954     libcurl . . . . . . $with_libcurl
 955     libiokit  . . . . . $with_libiokit
 956     liboping  . . . . . $with_liboping
 957     librrd  . . . . . . $with_rrdtool
 958     lm_sensors  . . . . $with_lm_sensors
 959     libstatgrab . . . . $with_libstatgrab
 960     libkstat  . . . . . $with_kstat
 961     libmysql  . . . . . $with_libmysql
 962
 963   Features:
 964     debug . . . . . . . $enable_debug
 965     daemon mode . . . . $enable_daemon
 966     step  . . . . . . . $collectd_step seconds
 967     heartbeat . . . . . $collectd_heartbeat seconds
 968
 969   Modules:
 970     apache  . . . . . . $enable_apache
 971     apcups  . . . . . . $enable_apcups
 972     apple_sensors . . . $enable_apple_sensors
 973     battery . . . . . . $enable_battery
 974     cpu . . . . . . . . $enable_cpu
 975     cpufreq . . . . . . $enable_cpufreq
 976     df  . . . . . . . . $enable_df
 977     disk  . . . . . . . $enable_disk
 978     hddtemp . . . . . . $enable_hddtemp
 979     load  . . . . . . . $enable_load
 980     memory  . . . . . . $enable_memory
 981     multimeter  . . . . $enable_multimeter
 982     mysql . . . . . . . $enable_mysql
 983     nfs . . . . . . . . $enable_nfs
 984     ntpd  . . . . . . . $enable_ntpd
 985     ping  . . . . . . . $enable_ping
 986     processes . . . . . $enable_processes
 987     sensors . . . . . . $enable_sensors
 988     serial  . . . . . . $enable_serial
 989     swap  . . . . . . . $enable_swap
 990     tape  . . . . . . . $enable_tape
 991     traffic . . . . . . $enable_traffic
 992     users . . . . . . . $enable_users
 993     vserver . . . . . . $enable_vserver
 994     wireless  . . . . . $enable_wireless
 995
 996 EOF