configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(collectd, 3.11.2)
   3 AC_CONFIG_SRCDIR(src/collectd.c)
   4 AC_CONFIG_HEADERS(src/config.h)
   5 AM_INIT_AUTOMAKE(dist-bzip2)
   6 AC_LANG(C)
   7
   8 AC_PREFIX_DEFAULT("/opt/collectd")
   9
  10 #
  11 # Checks for programs.
  12 #
  13 AC_PROG_CC
  14 AC_PROG_CPP
  15 AC_PROG_INSTALL
  16 AC_PROG_LN_S
  17 AC_PROG_MAKE_SET
  18 AM_CONDITIONAL(COMPILER_IS_GCC, test "x$GCC" = "xyes")
  19
  20 dnl configure libtool
  21 AC_DISABLE_STATIC
  22 AC_LIBLTDL_CONVENIENCE
  23 AC_SUBST(LTDLINCL)
  24 AC_SUBST(LIBLTDL)
  25 AC_LIBTOOL_DLOPEN
  26 AC_PROG_LIBTOOL
  27 AC_PROG_LEX
  28 AC_PROG_YACC
  29 AC_CONFIG_SUBDIRS(libltdl)
  30
  31 #
  32 # Checks for header files.
  33 #
  34 AC_HEADER_STDC
  35 AC_HEADER_SYS_WAIT
  36 AC_HEADER_DIRENT
  37 AC_CHECK_HEADERS(stdint.h)
  38 AC_CHECK_HEADERS(stdio.h)
  39 AC_CHECK_HEADERS(errno.h)
  40 AC_CHECK_HEADERS(math.h)
  41 AC_CHECK_HEADERS(syslog.h)
  42 AC_CHECK_HEADERS(fcntl.h)
  43 AC_CHECK_HEADERS(signal.h)
  44 AC_CHECK_HEADERS(assert.h)
  45 AC_CHECK_HEADERS(sys/types.h)
  46 AC_CHECK_HEADERS(sys/socket.h)
  47 AC_CHECK_HEADERS(sys/select.h)
  48 AC_CHECK_HEADERS(poll.h)
  49 AC_CHECK_HEADERS(netdb.h)
  50 AC_CHECK_HEADERS(arpa/inet.h)
  51 AC_CHECK_HEADERS(sys/resource.h)
  52 AC_CHECK_HEADERS(sys/param.h)
  53
  54 # For ping library
  55 AC_CHECK_HEADERS(netinet/in_systm.h, [], [],
  56 [#if HAVE_STDINT_H
  57 # include <stdint.h>
  58 #endif
  59 #if HAVE_SYS_TYPES_H
  60 # include <sys/types.h>
  61 #endif
  62 ])
  63 AC_CHECK_HEADERS(netinet/in.h, [], [],
  64 [#if HAVE_STDINT_H
  65 # include <stdint.h>
  66 #endif
  67 #if HAVE_SYS_TYPES_H
  68 # include <sys/types.h>
  69 #endif
  70 #if HAVE_NETINET_IN_SYSTM_H
  71 # include <netinet/in_systm.h>
  72 #endif
  73 ])
  74 AC_CHECK_HEADERS(netinet/ip.h, [], [],
  75 [#if HAVE_STDINT_H
  76 # include <stdint.h>
  77 #endif
  78 #if HAVE_SYS_TYPES_H
  79 # include <sys/types.h>
  80 #endif
  81 #if HAVE_NETINET_IN_SYSTM_H
  82 # include <netinet/in_systm.h>
  83 #endif
  84 #if HAVE_NETINET_IN_H
  85 # include <netinet/in.h>
  86 #endif
  87 ])
  88 AC_CHECK_HEADERS(netinet/ip_icmp.h, [], [],
  89 [#if HAVE_STDINT_H
  90 # include <stdint.h>
  91 #endif
  92 #if HAVE_SYS_TYPES_H
  93 # include <sys/types.h>
  94 #endif
  95 #if HAVE_NETINET_IN_SYSTM_H
  96 # include <netinet/in_systm.h>
  97 #endif
  98 #if HAVE_NETINET_IN_H
  99 # include <netinet/in.h>
 100 #endif
 101 #if HAVE_NETINET_IP_H
 102 # include <netinet/ip.h>
 103 #endif
 104 ])
 105 AC_CHECK_HEADERS(netinet/ip_var.h, [], [],
 106 [#if HAVE_STDINT_H
 107 # include <stdint.h>
 108 #endif
 109 #if HAVE_SYS_TYPES_H
 110 # include <sys/types.h>
 111 #endif
 112 #if HAVE_NETINET_IN_SYSTM_H
 113 # include <netinet/in_systm.h>
 114 #endif
 115 #if HAVE_NETINET_IN_H
 116 # include <netinet/in.h>
 117 #endif
 118 #if HAVE_NETINET_IP_H
 119 # include <netinet/ip.h>
 120 #endif
 121 ])
 122 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
 123 [#if HAVE_STDINT_H
 124 # include <stdint.h>
 125 #endif
 126 #if HAVE_SYS_TYPES_H
 127 # include <sys/types.h>
 128 #endif
 129 #if HAVE_NETINET_IN_SYSTM_H
 130 # include <netinet/in_systm.h>
 131 #endif
 132 #if HAVE_NETINET_IN_H
 133 # include <netinet/in.h>
 134 #endif
 135 ])
 136 AC_CHECK_HEADERS(netinet/icmp6.h, [], [],
 137 [#if HAVE_STDINT_H
 138 # include <stdint.h>
 139 #endif
 140 #if HAVE_SYS_TYPES_H
 141 # include <sys/types.h>
 142 #endif
 143 #if HAVE_NETINET_IN_SYSTM_H
 144 # include <netinet/in_systm.h>
 145 #endif
 146 #if HAVE_NETINET_IN_H
 147 # include <netinet/in.h>
 148 #endif
 149 #if HAVE_NETINET_IP6_H
 150 # include <netinet/ip6.h>
 151 #endif
 152 ])
 153 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 154 [#if HAVE_STDINT_H
 155 # include <stdint.h>
 156 #endif
 157 #if HAVE_SYS_TYPES_H
 158 # include <sys/types.h>
 159 #endif
 160 #if HAVE_NETINET_IN_SYSTM_H
 161 # include <netinet/in_systm.h>
 162 #endif
 163 #if HAVE_NETINET_IN_H
 164 # include <netinet/in.h>
 165 #endif
 166 #if HAVE_NETINET_IP_H
 167 # include <netinet/ip.h>
 168 #endif
 169 ])
 170 AC_CHECK_HEADERS(netinet/udp.h, [], [],
 171 [#if HAVE_STDINT_H
 172 # include <stdint.h>
 173 #endif
 174 #if HAVE_SYS_TYPES_H
 175 # include <sys/types.h>
 176 #endif
 177 #if HAVE_NETINET_IN_SYSTM_H
 178 # include <netinet/in_systm.h>
 179 #endif
 180 #if HAVE_NETINET_IN_H
 181 # include <netinet/in.h>
 182 #endif
 183 #if HAVE_NETINET_IP_H
 184 # include <netinet/ip.h>
 185 #endif
 186 ])
 187
 188 # For cpu modules
 189 AC_CHECK_HEADERS(sys/sysctl.h sys/dkstat.h)
 190 AC_CHECK_HEADERS(mach/mach_init.h)
 191 AC_CHECK_HEADERS(mach/host_priv.h)
 192 AC_CHECK_HEADERS(mach/mach_error.h)
 193 AC_CHECK_HEADERS(mach/mach_host.h)
 194 AC_CHECK_HEADERS(mach/mach_port.h)
 195 AC_CHECK_HEADERS(mach/mach_types.h)
 196 AC_CHECK_HEADERS(mach/message.h)
 197 AC_CHECK_HEADERS(mach/processor_set.h)
 198 AC_CHECK_HEADERS(mach/processor.h)
 199 AC_CHECK_HEADERS(mach/processor_info.h)
 200 AC_CHECK_HEADERS(mach/task.h)
 201 AC_CHECK_HEADERS(mach/thread_act.h)
 202 AC_CHECK_HEADERS(mach/vm_region.h)
 203 AC_CHECK_HEADERS(mach/vm_map.h)
 204 AC_CHECK_HEADERS(mach/vm_prot.h)
 205 AC_CHECK_HEADERS(mach/vm_statistics.h)
 206 AC_CHECK_HEADERS(mach/kern_return.h)
 207
 208 # For hddtemp module
 209 AC_CHECK_HEADERS(linux/major.h)
 210
 211 # For the apple_sensors module
 212 AC_CHECK_HEADERS(CoreFoundation/CoreFoundation.h)
 213 AC_CHECK_HEADERS(IOKit/IOKitLib.h)
 214 AC_CHECK_HEADERS(IOKit/IOTypes.h)
 215
 216 # For the battery plugin
 217 AC_CHECK_HEADERS(IOKit/ps/IOPowerSources.h, [], [],
 218 [
 219 #if HAVE_IOKIT_IOKITLIB_H
 220 #  include <IOKit/IOKitLib.h>
 221 #endif
 222 #if HAVE_IOKIT_IOTYPES_H
 223 #  include <IOKit/IOTypes.h>
 224 #endif
 225 ])
 226 AC_CHECK_HEADERS(IOKit/ps/IOPSKeys.h)
 227
 228 # For the `disk' plugin
 229 AC_CHECK_HEADERS(IOKit/IOBSD.h)
 230 AC_CHECK_HEADERS(IOKit/storage/IOBlockStorageDriver.h)
 231
 232 # For load module
 233 AC_CHECK_HEADERS(sys/loadavg.h)
 234
 235 # For the processes plugin
 236 AC_CHECK_HEADERS(linux/config.h)
 237
 238 # For the swap module
 239 AC_CHECK_HEADERS(sys/swap.h)
 240
 241 # For users module
 242 AC_CHECK_HEADERS(utmp.h)
 243 AC_CHECK_HEADERS(utmpx.h)
 244
 245 # For interface plugin
 246 AC_CHECK_HEADERS(ifaddrs.h)
 247 AC_CHECK_HEADERS(net/if.h, [], [],
 248 [
 249 #if HAVE_SYS_TYPES_H
 250 #  include <sys/types.h>
 251 #endif
 252 #if HAVE_SYS_SOCKET_H
 253 #  include <sys/socket.h>
 254 #endif
 255 ])
 256 AC_CHECK_HEADERS(linux/if.h, [], [],
 257 [
 258 #if HAVE_SYS_TYPES_H
 259 #  include <sys/types.h>
 260 #endif
 261 #if HAVE_SYS_SOCKET_H
 262 #  include <sys/socket.h>
 263 #endif
 264 ])
 265 AC_CHECK_HEADERS(linux/netdevice.h, [], [],
 266 [
 267 #if HAVE_SYS_TYPES_H
 268 #  include <sys/types.h>
 269 #endif
 270 #if HAVE_SYS_SOCKET_H
 271 #  include <sys/socket.h>
 272 #endif
 273 #if HAVE_LINUX_IF_H
 274 # include <linux/if.h>
 275 #endif
 276 ])
 277
 278 # For apache plugin
 279 AC_CHECK_HEADERS(curl/curl.h)
 280
 281 # For quota module
 282 AC_CHECK_HEADERS(grp.h pwd.h sys/ucred.h)
 283 AC_CHECK_HEADERS(ctype.h)
 284 AC_CHECK_HEADERS(limits.h)
 285 AC_CHECK_HEADERS(sys/quota.h)
 286 AC_CHECK_HEADERS(xfs/xqm.h)
 287
 288 # For mount interface
 289 AC_CHECK_HEADERS(fs_info.h)
 290 AC_CHECK_HEADERS(fshelp.h)
 291 AC_CHECK_HEADERS(paths.h)
 292 AC_CHECK_HEADERS(mntent.h)
 293 AC_CHECK_HEADERS(mnttab.h)
 294 AC_CHECK_HEADERS(sys/fstyp.h)
 295 AC_CHECK_HEADERS(sys/fs_types.h)
 296 AC_CHECK_HEADERS(sys/mntent.h)
 297 AC_CHECK_HEADERS(sys/mnttab.h)
 298 AC_CHECK_HEADERS(sys/mount.h)
 299 AC_CHECK_HEADERS(sys/statfs.h)
 300 AC_CHECK_HEADERS(sys/statvfs.h)
 301 AC_CHECK_HEADERS(sys/vfs.h)
 302 AC_CHECK_HEADERS(sys/vfstab.h)
 303
 304 # For the swap plugin, FreeBSD
 305 AC_CHECK_HEADERS(kvm.h)
 306
 307 # For the email plugin
 308 AC_CHECK_HEADERS(linux/un.h, [], [],
 309 [
 310 #if HAVE_SYS_SOCKET_H
 311 #       include <sys/socket.h>
 312 #endif
 313 ])
 314 AC_CHECK_HEADERS(sys/un.h)
 315 AC_CHECK_HEADERS(grp.h)
 316
 317 # For debugging interface (variable number of arguments)
 318 AC_CHECK_HEADERS(stdarg.h)
 319
 320 # Regular expressions for the ignorelist.
 321 AC_CHECK_HEADERS(regex.h)
 322
 323 # For the dns plugin
 324 AC_CHECK_HEADERS(arpa/nameser.h arpa/nameser_compat.h)
 325
 326 AC_CHECK_HEADERS(net/if_arp.h)
 327 AC_CHECK_HEADERS(net/if_ppp.h)
 328 AC_CHECK_HEADERS(netinet/if_ether.h)
 329
 330 # For the multimeter plugin
 331 AC_CHECK_HEADERS(termios.h)
 332 AC_CHECK_HEADERS(sys/ioctl.h)
 333
 334 #
 335 # Checking for libraries
 336 #
 337 AC_CHECK_LIB(m, ext)
 338
 339 #
 340 # Checks for typedefs, structures, and compiler characteristics.
 341 #
 342 AC_C_CONST
 343 AC_TYPE_PID_T
 344 AC_TYPE_SIZE_T
 345 AC_TYPE_UID_T
 346 AC_HEADER_TIME
 347
 348 #
 349 # Checks for library functions.
 350 #
 351 AC_PROG_GCC_TRADITIONAL
 352 AC_CHECK_FUNCS(gettimeofday select strdup strtol)
 353 AC_CHECK_FUNCS(getaddrinfo getnameinfo)
 354 AC_CHECK_FUNCS(strchr memcpy strstr strcmp strncmp strncpy strlen)
 355 AC_CHECK_FUNCS(strncasecmp strcasecmp)
 356 AC_CHECK_FUNCS(openlog syslog closelog)
 357
 358 socket_needs_socket="no"
 359 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [socket_needs_socket="yes"], AC_MSG_ERROR(cannot find socket)))
 360 AM_CONDITIONAL(BUILD_WITH_LIBSOCKET, test "x$socket_needs_socket" = "xyes")
 361
 362 nanosleep_needs_rt="no"
 363 AC_CHECK_FUNCS(nanosleep, [], AC_CHECK_LIB(rt, nanosleep, [nanosleep_needs_rt="yes"], AC_MSG_ERROR(cannot find nanosleep)))
 364 AM_CONDITIONAL(BUILD_WITH_LIBRT, test "x$nanosleep_needs_rt" = "xyes")
 365
 366 # Regular expressions for the ignorelist.
 367 AC_CHECK_FUNCS(regcomp regerror regexec regfree)
 368
 369 # For cpu module
 370 AC_CHECK_FUNCS(sysctlbyname, [have_sysctlbyname="yes"], [have_sysctlbyname="no"])
 371
 372 # For df module
 373 AC_CHECK_FUNCS(statfs statvfs)
 374
 375 # For load module
 376 AC_CHECK_FUNCS(getloadavg, [have_getloadavg="yes"], [have_getloadavg="no"])
 377
 378 # For the `processes' plugin
 379 AC_CHECK_FUNCS(thread_info)
 380
 381 # For users module
 382 AC_CHECK_FUNCS(getutent getutxent)
 383
 384 # For quota module
 385 AC_CHECK_FUNCS(quotactl)
 386 AC_CHECK_FUNCS(getgrgid getpwuid)
 387
 388 # For interface module
 389 AC_CHECK_FUNCS(getifaddrs)
 390
 391 # Check for NAN
 392 nan_type="none"
 393 if test "x$nan_type" = "xnone"; then
 394   AC_CACHE_CHECK([whether NAN is defined by default],
 395     [have_nan_default],
 396     AC_COMPILE_IFELSE(
 397       AC_LANG_PROGRAM(
 398       [[
 399 #include <stdlib.h>
 400 #include <math.h>
 401 static float foo = NAN;
 402       ]],
 403       [[
 404        if (isnan (foo))
 405         return 0;
 406        else
 407         return 1;
 408       ]]),
 409       [have_nan_default="yes"],
 410       [have_nan_default="no"]
 411     )
 412   )
 413   if test "x$have_nan_default" = "xyes"
 414   then
 415    nan_type="default"
 416    AC_DEFINE(NAN_STATIC_DEFAULT, 1,
 417      [Define if NAN is defined by default and can initialize static variables.])
 418   fi
 419 fi
 420 if test "x$nan_type" = "xnone"; then
 421   AC_CACHE_CHECK([whether NAN is defined by __USE_ISOC99],
 422     [have_nan_isoc],
 423     AC_COMPILE_IFELSE(
 424       AC_LANG_PROGRAM(
 425       [[
 426 #include <stdlib.h>
 427 #define __USE_ISOC99 1
 428 #include <math.h>
 429 static float foo = NAN;
 430       ]],
 431       [[
 432        if (isnan (foo))
 433         return 0;
 434        else
 435         return 1;
 436       ]]),
 437       [have_nan_isoc="yes"],
 438       [have_nan_isoc="no"]
 439     )
 440   )
 441   if test "x$have_nan_isoc" = "xyes"
 442   then
 443    nan_type="isoc99"
 444    AC_DEFINE(NAN_STATIC_ISOC, 1,
 445      [Define if NAN is defined by __USE_ISOC99 and can initialize static variables.])
 446   fi
 447 fi
 448 if test "x$nan_type" = "xnone"; then
 449   AC_CACHE_CHECK([whether NAN can be defined by 0/0],
 450     [have_nan_zero],
 451     AC_RUN_IFELSE(
 452       AC_LANG_PROGRAM(
 453       [[
 454 #include <stdlib.h>
 455 #include <math.h>
 456 #define NAN (0.0 / 0.0)
 457 #ifndef isnan
 458 # define isnan(f) ((f) != (f))
 459 #endif
 460 static float foo = NAN;
 461       ]],
 462       [[
 463        if (isnan (foo))
 464         return 0;
 465        else
 466         return 1;
 467       ]]),
 468       [have_nan_zero="yes"],
 469       [have_nan_zero="no"]
 470     )
 471   )
 472   if test "x$have_nan_zero" = "xyes"
 473   then
 474    nan_type="zero"
 475    AC_DEFINE(NAN_ZERO_ZERO, 1,
 476      [Define if NAN can be defined as (0.0 / 0.0)])
 477   fi
 478 fi
 479 if test "x$nan_type" = "xnone"; then
 480   AC_MSG_ERROR([Didn't find out how to statically initialize variables to NAN. Sorry.])
 481 fi
 482
 483 # For mount interface
 484 #AC_CHECK_FUNCS(getfsent getvfsent)
 485
 486 have_getfsstat="no"
 487 AC_CHECK_FUNCS(getfsstat, [have_getfsstat="yes"])
 488 have_getvfsstat="no"
 489 AC_CHECK_FUNCS(getvfsstat, [have_getvfsstat="yes"])
 490 have_listmntent="no"
 491 AC_CHECK_FUNCS(listmntent, [have_listmntent="yes"])
 492
 493 have_getmntent="no"
 494 AC_CHECK_FUNCS(getmntent, [have_getmntent="c"])
 495 if test "x$have_getmntent" = "xno"; then
 496         AC_CHECK_LIB(sun, getmntent, [have_getmntent="sun"])
 497 fi
 498 if test "x$have_getmntent" = "xno"; then
 499         AC_CHECK_LIB(seq, getmntent, [have_getmntent="seq"])
 500 fi
 501 if test "x$have_getmntent" = "xno"; then
 502         AC_CHECK_LIB(gen, getmntent, [have_getmntent="gen"])
 503 fi
 504
 505 if test "x$have_getmntent" = "xc"; then
 506         AC_CACHE_CHECK([whether getmntent takes one argument],
 507                 [have_one_getmntent],
 508                 AC_COMPILE_IFELSE(
 509                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 510 #include <mntent.h>
 511 #include "$srcdir/src/utils_mount.h"]],
 512                                 [[
 513                                  FILE *fh;
 514                                  struct mntent *me;
 515                                  fh = setmntent ("/etc/mtab", "r");
 516                                  me = getmntent (fh);
 517                                 ]]
 518                         ),
 519                         [have_one_getmntent="yes"],
 520                         [have_one_getmntent="no"]
 521                 )
 522         )
 523         AC_CACHE_CHECK([whether getmntent takes two arguments],
 524                 [have_two_getmntent],
 525                 AC_COMPILE_IFELSE(
 526                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 527 #include <sys/mnttab.h>
 528 #include "$srcdir/src/utils_mount.h"]],
 529                                 [[
 530                                  FILE *fh;
 531                                  struct mnttab mt;
 532                                  int status;
 533                                  fh = fopen ("/etc/mnttab", "r");
 534                                  status = getmntent (fh, &mt);
 535                                 ]]
 536                         ),
 537                         [have_two_getmntent="yes"],
 538                         [have_two_getmntent="no"]
 539                 )
 540         )
 541 fi
 542
 543 # Check for different versions of `getmntent' here..
 544
 545 if test "x$have_getmntent" = "xc"; then
 546         if test "x$have_one_getmntent" = "xyes"; then
 547                 AC_DEFINE(HAVE_ONE_GETMNTENT, 1,
 548                           [Define if the function getmntent exists and takes one argument.])
 549         fi
 550         if test "x$have_two_getmntent" = "xyes"; then
 551                 AC_DEFINE(HAVE_TWO_GETMNTENT, 1,
 552                           [Define if the function getmntent exists and takes two arguments.])
 553         fi
 554 fi
 555 if test "x$have_getmntent" = "xsun"; then
 556         AC_DEFINE(HAVE_SUN_GETMNTENT, 1,
 557                   [Define if the function getmntent exists. It's the version from libsun.])
 558 fi
 559 if test "x$have_getmntent" = "xseq"; then
 560         AC_DEFINE(HAVE_SEQ_GETMNTENT, 1,
 561                   [Define if the function getmntent exists. It's the version from libseq.])
 562 fi
 563 if test "x$have_getmntent" = "xgen"; then
 564         AC_DEFINE(HAVE_GEN_GETMNTENT, 1,
 565                   [Define if the function getmntent exists. It's the version from libgen.])
 566 fi
 567
 568 # Check for structures
 569 AC_CHECK_MEMBERS([struct if_data.ifi_ibytes, struct if_data.ifi_opackets, struct if_data.ifi_ierrors],
 570         [AC_DEFINE(HAVE_STRUCT_IF_DATA, 1, [Define if struct if_data exists and is usable.])],
 571         [],
 572         [
 573         #include <sys/types.h>
 574         #include <sys/socket.h>
 575         #include <net/if.h>
 576         ])
 577 AC_CHECK_MEMBERS([struct net_device_stats.rx_bytes, struct net_device_stats.tx_packets, struct net_device_stats.rx_errors],
 578         [AC_DEFINE(HAVE_STRUCT_NET_DEVICE_STATS, 1, [Define if struct net_device_stats exists and is usable.])],
 579         [],
 580         [
 581         #include <sys/types.h>
 582         #include <sys/socket.h>
 583         #include <linux/if.h>
 584         #include <linux/netdevice.h>
 585         ])
 586
 587 AC_CHECK_MEMBERS([struct udphdr.uh_dport, struct udphdr.uh_sport], [], [],
 588 [#if HAVE_STDINT_H
 589 # include <stdint.h>
 590 #endif
 591 #if HAVE_SYS_TYPES_H
 592 # include <sys/types.h>
 593 #endif
 594 #if HAVE_NETINET_IN_SYSTM_H
 595 # include <netinet/in_systm.h>
 596 #endif
 597 #if HAVE_NETINET_IN_H
 598 # include <netinet/in.h>
 599 #endif
 600 #if HAVE_NETINET_IP_H
 601 # include <netinet/ip.h>
 602 #endif
 603 #if HAVE_NETINET_UDP_H
 604 # include <netinet/udp.h>
 605 #endif
 606 ])
 607 AC_CHECK_MEMBERS([struct udphdr.dest, struct udphdr.source], [], [],
 608 [#if HAVE_STDINT_H
 609 # include <stdint.h>
 610 #endif
 611 #if HAVE_SYS_TYPES_H
 612 # include <sys/types.h>
 613 #endif
 614 #if HAVE_NETINET_IN_SYSTM_H
 615 # include <netinet/in_systm.h>
 616 #endif
 617 #if HAVE_NETINET_IN_H
 618 # include <netinet/in.h>
 619 #endif
 620 #if HAVE_NETINET_IP_H
 621 # include <netinet/ip.h>
 622 #endif
 623 #if HAVE_NETINET_UDP_H
 624 # include <netinet/udp.h>
 625 #endif
 626 ])
 627
 628 AC_MSG_CHECKING([for kernel type ($host_os)])
 629 case $host_os in
 630         *linux*)
 631         AC_DEFINE([KERNEL_LINUX], 1, [True if program is to be compiled for a Linux kernel])
 632         ac_system="Linux"
 633         ;;
 634         *solaris*)
 635         AC_DEFINE([KERNEL_SOLARIS], 1, [True if program is to be compiled for a Solaris kernel])
 636         ac_system="Solaris"
 637         ;;
 638         *)
 639         ac_system="unknown"
 640 esac
 641 AC_MSG_RESULT([$ac_system])
 642
 643 with_libresolv="yes"
 644 AC_CHECK_LIB(resolv, res_search,
 645 [
 646         AC_DEFINE(HAVE_LIBRESOLV, 1, [Define to 1 if you have the 'resolv' library (-lresolv).])
 647 ],
 648 [with_libresolv="no"])
 649 AM_CONDITIONAL(BUILD_WITH_LIBRESOLV, test "x$with_libresolv" = "xyes")
 650
 651
 652 m4_divert_once([HELP_WITH], [
 653 collectd additional packages:])
 654
 655 # AC_ARG_WITH (package, help-string, [action-if-given], [action-if-not-given])
 656 AC_ARG_WITH(rrdtool, [AS_HELP_STRING([--with-rrdtool@<:@=PREFIX@:>@], [Path to rrdtool.])],
 657 [       if test "x$withval" != "xno" && test "x$withval" != "xyes"
 658         then
 659                 LDFLAGS="$LDFLAGS -L$withval/lib"
 660                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 661                 with_rrdtool="yes"
 662         fi
 663 ], [with_rrdtool="yes"])
 664 if test "x$with_rrdtool" = "xyes"
 665 then
 666         AC_CHECK_LIB(rrd, rrd_update,
 667         [
 668                 AC_DEFINE(HAVE_LIBRRD, 1, [Define to 1 if you have the rrd library (-lrrd).])
 669         ],
 670         [with_rrdtool="no (librrd not found)"], [-lm])
 671 fi
 672 if test "x$with_rrdtool" = "xyes"
 673 then
 674         AC_CHECK_HEADERS(rrd.h,, [with_rrdtool="no (rrd.h not found)"])
 675 fi
 676 if test "x$with_rrdtool" = "xyes"
 677 then
 678         collect_rrdtool=1
 679 else
 680         collect_rrdtool=0
 681 fi
 682 AC_DEFINE_UNQUOTED(COLLECT_RRDTOOL, [$collect_rrdtool],
 683         [Wether or not to use rrdtool library])
 684 AM_CONDITIONAL(BUILD_WITH_RRDTOOL, test "x$with_rrdtool" = "xyes")
 685
 686 AC_ARG_WITH(libpthread, [AS_HELP_STRING([--with-libpthread=@<:@=PREFIX@:>@], [Path to libpthread.])],
 687 [       if test "x$withval" != "xno" -a "x$withval" != "xyes"
 688         then
 689                 LDFLAGS="$LDFLAGS -L$withval/lib"
 690                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 691                 with_libpthread="yes"
 692         else
 693                 if test "x$withval" = "xno"
 694                 then
 695                         with_libpthread="no (disabled)"
 696                 fi
 697         fi
 698 ], [with_libpthread="yes"])
 699 if test "x$with_libpthread" = "xyes"
 700 then
 701         AC_CHECK_LIB(pthread, pthread_create, [with_libpthread="yes"], [with_libpthread="no (libpthread not found)"], [])
 702 fi
 703 if test "x$with_libpthread" = "xyes"
 704 then
 705         AC_CHECK_HEADERS(pthread.h,, [with_libpthread="no (pthread.h not found)"])
 706 fi
 707 if test "x$with_libpthread" = "xyes"
 708 then
 709         collect_pthread=1
 710 else
 711         collect_pthread=0
 712 fi
 713 AC_DEFINE_UNQUOTED(HAVE_LIBPTHREAD, [$collect_pthread],
 714         [Wether or not to use pthread (POSIX threads) library])
 715 AM_CONDITIONAL(BUILD_WITH_LIBPTHREAD, test "x$with_libpthread" = "xyes")
 716
 717 if test "$ac_system" = "Solaris"
 718 then
 719         with_kstat="yes"
 720         with_devinfo="yes"
 721 else
 722         with_kstat="no (Solaris only)"
 723         with_devinfo="no (Solaris only)"
 724 fi
 725
 726 if test "x$with_kstat" = "xyes"
 727 then
 728         AC_CHECK_LIB(kstat, kstat_open, [with_kstat="yes"], [with_kstat="no (libkstat not found)"], [])
 729 fi
 730 if test "x$with_kstat" = "xyes"
 731 then
 732         AC_CHECK_LIB(devinfo, di_init, [with_devinfo="yes"], [with_devinfo="no (not found)"], [])
 733         AC_CHECK_HEADERS(kstat.h,, [with_kstat="no (kstat.h not found)"])
 734 fi
 735 if test "x$with_kstat" = "xyes"
 736 then
 737         collect_kstat=1
 738 else
 739         collect_kstat=0
 740 fi
 741 AC_DEFINE_UNQUOTED(COLLECT_KSTAT, [$collect_kstat],
 742         [Wether or not to use kstat library (Solaris)])
 743 AM_CONDITIONAL(BUILD_WITH_LIBKSTAT, test "x$with_kstat" = "xyes")
 744 AM_CONDITIONAL(BUILD_WITH_LIBDEVINFO, test "x$with_devinfo" = "xyes")
 745
 746 ### BEGIN of check for libcurl ###
 747 with_curl_config="curl-config"
 748 with_curl_prefix=0
 749 with_curl_libs=""
 750 AC_ARG_WITH(libcurl, [AS_HELP_STRING([--with-libcurl@<:@=PREFIX@:>@], [Path to libcurl.])],
 751 [
 752         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 753         then
 754                 if test -x "$withval/bin/curl-config"
 755                 then
 756                         with_curl_config="$withval/bin/curl-config"
 757                         with_curl_prefix=1
 758                 fi
 759         fi
 760         if test "x$withval" = "xno"
 761         then
 762                 with_libcurl="no"
 763         else
 764                 with_libcurl="yes"
 765         fi
 766 ],
 767 [
 768         with_libcurl="yes"
 769 ])
 770 if test "x$with_libcurl" = "xyes"
 771 then
 772         with_curl_libs=`$with_curl_config --libs 2>/dev/null`
 773         curl_config_status=$?
 774
 775         if test $curl_config_status -ne 0
 776         then
 777                 with_libcurl="no"
 778         else
 779                 AC_CHECK_LIB(curl, curl_easy_init,
 780                 [
 781                         BUILD_WITH_LIBCURL_LIBS="$with_curl_libs"
 782                         AC_SUBST(BUILD_WITH_LIBCURL_LIBS)
 783                 ],
 784                 [
 785                         with_libcurl="no"
 786                 ],
 787                 [$with_curl_libs])
 788         fi
 789 fi
 790 if test "x$with_libcurl" = "xyes" -a $with_curl_prefix -ne 0
 791 then
 792         with_curl_prefix=`$with_curl_config --libs 2>/dev/null`
 793         curl_config_status=$?
 794
 795         if test $curl_config_status -ne 0
 796         then
 797                 with_libcurl="no"
 798         else
 799                 if test -d "$with_curl_prefix/include"
 800                 then
 801                         CPPFLAGS="$CPPFLAGS -I$with_curl_prefix/include"
 802                 fi
 803         fi
 804 fi
 805
 806 with_libcurl_numeric=0
 807 if test "x$with_libcurl" = "xyes"
 808 then
 809         with_libcurl_numeric=1
 810 fi
 811 AC_DEFINE_UNQUOTED(HAVE_LIBCURL, [$with_libcurl_numeric], [Define to 1 if you have the 'curl' library (-lcurl).])
 812 AM_CONDITIONAL(BUILD_WITH_LIBCURL, test "x$with_libcurl" = "xyes")
 813 ### END of check for libcurl ###
 814
 815 with_libiokit="no"
 816 collectd_libiokit=0
 817 AC_CHECK_LIB(IOKit, IOServiceGetMatchingServices,
 818 [
 819         with_libiokit="yes"
 820         collectd_libiokit=1
 821 ],
 822 [
 823         with_libiokit="no"
 824         collectd_libiokit=0
 825 ])
 826 AC_DEFINE_UNQUOTED(COLLECT_LIBIOKIT, [$collect_libiokit], [Wether or not to use the IOKit library])
 827 AM_CONDITIONAL(BUILD_WITH_LIBIOKIT, test "x$with_libiokit" = "xyes")
 828
 829 with_libstatgrab="yes"
 830 with_libdevstat="no"
 831 AC_ARG_WITH(libstatgrab, [AS_HELP_STRING([--with-libstatgrab@<:@=PREFIX@:>@], [Path to libstatgrab.])],
 832 [
 833         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 834         then
 835                 LDFLAGS="$LDFLAGS -L$withval/lib"
 836                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 837                 with_libstatgrab="yes"
 838         fi
 839 ],
 840 [
 841         if test "x$ac_system" == "xunknown"
 842         then
 843                 with_libstatgrab="yes"
 844         else
 845                 with_libstatgrab="no"
 846         fi
 847 ])
 848 if test "x$with_libstatgrab" = "xyes"
 849 then
 850         AC_CHECK_LIB(statgrab, sg_init, [with_libstatgrab="yes"], [with_libstatgrab="no (libstatgrab not found)"])
 851 fi
 852 if test "x$with_libstatgrab" = "xyes"
 853 then
 854         AC_CHECK_HEADERS(statgrab.h,,    [with_libstatgrab="no (statgrab.h not found)"])
 855 fi
 856 if test "x$with_libstatgrab" = "xyes"
 857 then
 858         AC_CHECK_LIB(devstat, getdevs, [with_libdevstat="yes"], [with_libdevstat="no"])
 859 fi
 860 if test "x$with_libstatgrab" = "xyes"
 861 then
 862         collect_libstatgrab=1
 863 else
 864         collect_libstatgrab=0
 865 fi
 866 AC_DEFINE_UNQUOTED(COLLECT_LIBSTATGRAB, [$collect_libstatgrab],
 867         [Wether or not to use statgrab library])
 868 AM_CONDITIONAL(BUILD_WITH_LIBSTATGRAB, test "x$with_libstatgrab" = "xyes")
 869 AM_CONDITIONAL(BUILD_WITH_LIBDEVSTAT,  test "x$with_libdevstat"  = "xyes")
 870
 871 AC_CHECK_LIB(kvm, kvm_getswapinfo, [with_libkvm="yes"], [with_libkvm="no"])
 872 if test "x$with_libkvm" = "xyes"
 873 then
 874         AC_DEFINE(HAVE_LIBKVM, 1, [Define to 1 if you have the 'kvm' library (-lkvm)])
 875 fi
 876 AM_CONDITIONAL(BUILD_WITH_LIBKVM, test "x$with_libkvm" = "xyes")
 877
 878 AC_ARG_WITH(lm-sensors, [AS_HELP_STRING([--with-lm-sensors@<:@=PREFIX@:>@], [Path to lm_sensors.])],
 879 [
 880         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 881         then
 882                 LDFLAGS="$LDFLAGS -L$withval/lib"
 883                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 884                 with_lm_sensors="yes"
 885         fi
 886 ],
 887 [
 888         if test "x$ac_system" = "xLinux"
 889         then
 890                 with_lm_sensors="yes"
 891         else
 892                 with_lm_sensors="no"
 893         fi
 894 ])
 895 if test "x$with_lm_sensors" = "xyes"
 896 then
 897         AC_CHECK_LIB(sensors, sensors_init,
 898         [
 899                 AC_DEFINE(HAVE_LIBSENSORS, 1, [Define to 1 if you have the sensors library (-lsensors).])
 900         ],
 901         [with_lm_sensors="no (libsensors not found)"])
 902 fi
 903 if test "x$with_lm_sensors" = "xyes"
 904 then
 905         AC_CHECK_HEADERS(sensors/sensors.h,
 906         [
 907                 AC_DEFINE(HAVE_SENSORS_SENSORS_H, 1, [Define to 1 if you have the <sensors/sensors.h> header file.])
 908         ],
 909         [with_lm_sensors="no (sensors/sensors.h not found)"])
 910 fi
 911 if test "x$with_lm_sensors" = "xyes"
 912 then
 913         collect_lm_sensors=1
 914 else
 915         collect_lm_sensors=0
 916 fi
 917 AC_DEFINE_UNQUOTED(COLLECT_LM_SENSORS, [$collect_lm_sensors],
 918         [Wether or not to use sensors library])
 919 AM_CONDITIONAL(BUILD_WITH_LM_SENSORS, test "x$with_lm_sensors" = "xyes")
 920
 921 AC_ARG_WITH(libmysql, [AS_HELP_STRING([--with-libmysql@<:@=PREFIX@:>@], [Path to libmysql.])],
 922 [
 923         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 924         then
 925                 LDFLAGS="$LDFLAGS -L$withval/lib"
 926                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 927                 with_libmysql="yes"
 928         fi
 929 ],
 930 [
 931         with_libmysql="yes"
 932 ])
 933 if test "x$with_libmysql" = "xyes"
 934 then
 935         AC_CHECK_LIB(mysqlclient, mysql_init,
 936         [
 937                 AC_DEFINE(HAVE_LIBMYSQLCLIENT, 1, [Define to 1 if you have the mysqlclient library (-lmysqlclient).])
 938         ], [with_libmysql="no (libmysql not found)"])
 939 fi
 940 if test "x$with_libmysql" = "xyes"
 941 then
 942         AC_CHECK_HEADERS(mysql/mysql.h,
 943         [
 944                 AC_DEFINE(HAVE_MYSQL_MYSQL_H, 1, [Define to 1 if you have the <mysql/mysql.h> header file.])
 945         ], [with_libmysql="no (mysql/mysql.h not found)"])
 946 fi
 947 if test "x$with_libmysql" = "xyes"
 948 then
 949         collect_libmysql=1
 950 else
 951         collect_libmysql=0
 952 fi
 953 AC_DEFINE_UNQUOTED(COLLECT_LIBMYSQL, [$collect_libmysql],
 954         [Wether or not to use mysql library])
 955 AM_CONDITIONAL(BUILD_WITH_LIBMYSQL, test "x$with_libmysql" = "xyes")
 956
 957 #with_liboping="yes"
 958 with_own_liboping="no"
 959 liboping_LDFLAGS="$LDFLAGS"
 960 liboping_CPPFLAGS="$CPPFLAGS"
 961 AC_ARG_WITH(liboping, [AS_HELP_STRING([--with-liboping@<:@=PREFIX@:>@], [Path to liboping.])],
 962 [
 963         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 964         then
 965                 if test -d "$withval/lib"
 966                 then
 967                         liboping_LDFLAGS="$LDFLAGS -L$withval/lib"
 968                 fi
 969                 if test -d "$withval/include"
 970                 then
 971                         liboping_CPPFLAGS="$CPPFLAGS -I$withval/include"
 972                 fi
 973         fi
 974         if test "x$withval" = "xno"
 975         then
 976                 with_liboping="no"
 977                 with_own_liboping="no"
 978         fi
 979 ],
 980 [
 981         #753
 982         with_liboping="yes"
 983 ])
 984
 985 if test "x$with_liboping" = "xyes"
 986 then
 987         save_LDFLAGS="$LDFLAGS"
 988         save_CPPFLAGS="$CPPFLAGS"
 989         LDFLAGS="$liboping_LDFLAGS"
 990         CPPFLAGS="$liboping_CPPFLAGS"
 991         AC_CHECK_LIB(oping, ping_construct,
 992         [
 993                 with_liboping="yes"
 994                 with_own_liboping="no"
 995         ],
 996         [
 997                 with_liboping="yes"
 998                 with_own_liboping="yes"
 999                 LDFLAGS="$save_LDFLAGS"
1000                 CPPFLAGS="$save_CPPFLAGS"
1001         ])
1002 fi
1003 AM_CONDITIONAL(BUILD_WITH_LIBOPING, test "x$with_liboping" = "xyes")
1004 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOPING, test "x$with_own_liboping" = "xyes")
1005 if test "x$with_liboping" = "xyes" -a "x$with_own_liboping" = "xyes"
1006 then
1007         with_liboping="yes (shipped version)"
1008 fi
1009
1010 AC_ARG_WITH(libpcap, [AS_HELP_STRING([--with-libpcap@<:@=PREFIX@:>@], [Path to libpcap.])],
1011 [
1012         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1013         then
1014                 LDFLAGS="$LDFLAGS -L$withval/lib"
1015                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1016                 with_libpcap="yes"
1017         fi
1018 ],
1019 [
1020         with_libpcap="yes"
1021 ])
1022 if test "x$with_libpcap" = "xyes"
1023 then
1024         AC_CHECK_LIB(pcap, pcap_open_live,
1025         [
1026                 AC_DEFINE(HAVE_LIBPCAP, 1, [Define to 1 if you have the pcap library (-lpcap).])
1027         ], [with_libpcap="no (libpcap not found)"])
1028 fi
1029 if test "x$with_libpcap" = "xyes"
1030 then
1031         AC_CHECK_HEADERS(pcap.h,
1032         [
1033                 AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1034         ], [with_libpcap="no (pcap.h not found)"])
1035 fi
1036 if test "x$with_libpcap" = "xyes"
1037 then
1038         collect_libpcap=1
1039 else
1040         collect_libpcap=0
1041 fi
1042 AC_DEFINE_UNQUOTED(COLLECT_LIBPCAP, [$collect_libpcap],
1043         [Wether or not to use the pcap library])
1044 AM_CONDITIONAL(BUILD_WITH_LIBPCAP, test "x$with_libpcap" = "xyes")
1045
1046 AC_ARG_WITH(libiptc, [AS_HELP_STRING([--with-libiptc@<:@=PREFIX@:>@], [Path to libiptc.])],
1047 [
1048         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1049         then
1050                 LDFLAGS="$LDFLAGS -L$withval/lib"
1051                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1052                 with_libiptc="yes"
1053         fi
1054 ],
1055 [
1056         if test "x$ac_system" = "xLinux"
1057         then
1058                 with_libiptc="yes"
1059         else
1060                 with_libiptc="no (Linux only)"
1061         fi
1062 ])
1063 if test "x$with_libiptc" = "xyes"
1064 then
1065         AC_CHECK_LIB(iptc, iptc_init,
1066         [
1067                 AC_DEFINE(HAVE_LIBIPTC, 1, [Define to 1 if you have the iptc library (-liptc).])
1068         ], [with_libiptc="no (libiptc not found)"])
1069 fi
1070 if test "x$with_libiptc" = "xyes"
1071 then
1072         AC_CHECK_HEADERS(libiptc/libiptc.h,
1073         [
1074                 AC_DEFINE(HAVE_LIBIPTC_LIBIPTC_H, 1, [Define to 1 if you have the <libiptc/libiptc.h> header file.])
1075         ], [with_libiptc="no (libiptc/libiptc.h not found)"])
1076 fi
1077 if test "x$with_libiptc" = "xyes"
1078 then
1079         collect_libiptc=1
1080 else
1081         collect_libiptc=0
1082 fi
1083 AM_CONDITIONAL(BUILD_WITH_LIBIPTC, test "x$with_libiptc" = "xyes")
1084
1085 # Define `step' and `hearbeat' values..
1086 declare -i collectd_step=10
1087 declare -i collectd_heartbeat=25
1088 AC_ARG_WITH(step, [AS_HELP_STRING([--with-step=SECONDS], [Interval in which plugins are queried.])],
1089 [
1090         if test "x$withval" != "xno" -a "x$withval" != "xyes"
1091         then
1092                 declare -i tmp_collectd_step="$withval"
1093                 if test $tmp_collectd_step -gt 0
1094                 then
1095                         collectd_step=$tmp_collectd_step
1096                         let "collectd_heartbeat=$collectd_step*2"
1097                 fi
1098         fi
1099 ], [])
1100 AC_ARG_WITH(heartbeat, [AS_HELP_STRING([--with-heartbeat=SECONDS], [Heartbeat of the DS in generated RRD files.])],
1101 [
1102         if test "x$withval" != "xno" -a "x$withval" != "xyes"
1103         then
1104                 declare -i tmp_collectd_heartbeat="$withval"
1105                 if test $tmp_collectd_heartbeat -gt 0
1106                 then
1107                         collectd_heartbeat=$tmp_collectd_heartbeat
1108                 fi
1109         fi
1110 ], [])
1111
1112 if test $collectd_step -ne 10
1113 then
1114         AC_DEFINE_UNQUOTED(COLLECTD_STEP, "$collectd_step", [Interval in which plugins are queried.])
1115 fi
1116 if test $collectd_heartbeat -ne 25
1117 then
1118         AC_DEFINE_UNQUOTED(COLLECTD_HEARTBEAT, "$collectd_heartbeat", [Interval in which plugins are queried.])
1119 fi
1120
1121 # Check for enabled/disabled features
1122 #
1123
1124 # AC_COLLECTD(name, enable/disable, info-text, feature/module)
1125 # ------------------------------------------------------------
1126 dnl
1127 m4_define([my_toupper], [m4_translit([$1], m4_defn([m4_cr_letters]), m4_defn([m4_cr_LETTERS]))])
1128 dnl
1129 AC_DEFUN(
1130         [AC_COLLECTD],
1131         [
1132         m4_if([$1], [], [AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 1st argument must not be empty])])dnl
1133         m4_if(
1134                 [$2],
1135                 [enable],
1136                 [dnl
1137                 m4_define([EnDis],[disabled])dnl
1138                 m4_define([YesNo],[no])dnl
1139                 ],dnl
1140                 [m4_if(
1141                         [$2],
1142                         [disable],
1143                         [dnl
1144                         m4_define([EnDis],[enabled])dnl
1145                         m4_define([YesNo],[yes])dnl
1146                         ],
1147                         [dnl
1148                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 2nd argument must be either enable or disable])dnl
1149                         ]dnl
1150                 )]dnl
1151         )dnl
1152         m4_if([$3], [feature], [],
1153                 [m4_if(
1154                         [$3], [module], [],
1155                         [dnl
1156                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 3rd argument must be either feature or disable])dnl
1157                         ]dnl
1158                 )]dnl
1159         )dnl
1160         AC_ARG_ENABLE(
1161                 [$1],
1162                 AS_HELP_STRING([--$2-$1], [$2 $4 (EnDis by def)]),
1163                 [],
1164                 enable_$1='[YesNo]'dnl
1165         )# AC_ARG_ENABLE
1166 if test "x$enable_$1" = "xno"
1167 then
1168         collectd_$1=0
1169 else
1170         if test "x$enable_$1" = "xyes"
1171         then
1172                 collectd_$1=1
1173         else
1174                 AC_MSG_NOTICE([please specify either --enable-$1 or --disable-$1; enabling $1.])
1175                 collectd_$1=1
1176                 enable_$1='yes'
1177         fi
1178 fi
1179         AC_DEFINE_UNQUOTED([COLLECT_]my_toupper([$1]), [$collectd_$1], [wether or not to enable $3 $4])
1180         AM_CONDITIONAL([BUILD_]my_toupper([$3])[_]my_toupper([$1]), [test "x$enable_$1" = "xyes"])dnl
1181         ]dnl
1182 )# AC_COLLECTD(name, enable/disable, info-text, feature/module)
1183
1184 m4_divert_once([HELP_ENABLE], [
1185 collectd features:])
1186 AC_COLLECTD([debug],     [enable],  [feature], [debugging])
1187 AC_COLLECTD([daemon],    [disable], [feature], [daemon mode])
1188 AC_COLLECTD([getifaddrs],[enable],  [feature], [getifaddrs under Linux])
1189
1190 m4_divert_once([HELP_ENABLE], [
1191 collectd modules:])
1192 AC_COLLECTD([apache],    [disable], [module], [Apache httpd statistics])
1193 AC_COLLECTD([apcups],    [disable], [module], [Statistics of UPSes by APC])
1194 AC_COLLECTD([apple_sensors], [disable], [module], [Apple's hardware sensors])
1195 AC_COLLECTD([battery],   [disable], [module], [battery statistics])
1196 AC_COLLECTD([cpu],       [disable], [module], [cpu usage statistics])
1197 AC_COLLECTD([cpufreq],   [disable], [module], [system cpu frequency statistics])
1198 AC_COLLECTD([disk],      [disable], [module], [disk/partition statistics])
1199 AC_COLLECTD([csv],       [disable], [module], [csv output plugin])
1200 AC_COLLECTD([df],        [disable], [module], [df statistics])
1201 AC_COLLECTD([dns],       [disable], [module], [dns statistics])
1202 AC_COLLECTD([email],     [disable], [module], [email statistics])
1203 AC_COLLECTD([entropy],   [disable], [module], [entropy statistics])
1204 AC_COLLECTD([exec],      [disable], [module], [exec of external programs])
1205 AC_COLLECTD([hddtemp],   [disable], [module], [hdd temperature statistics])
1206 AC_COLLECTD([interface], [disable], [module], [interface statistics])
1207 AC_COLLECTD([iptables],  [disable], [module], [IPtables statistics])
1208 AC_COLLECTD([irq],       [disable], [module], [irq statistics])
1209 AC_COLLECTD([load],      [disable], [module], [system load statistics])
1210 AC_COLLECTD([mbmon],     [disable], [module], [motherboard monitor statistics])
1211 AC_COLLECTD([memory],    [disable], [module], [memory statistics])
1212 AC_COLLECTD([multimeter],[disable], [module], [multimeter statistics])
1213 AC_COLLECTD([mysql],     [disable], [module], [mysql statistics])
1214 AC_COLLECTD([network],   [disable], [module], [network functionality])
1215 AC_COLLECTD([nfs],       [disable], [module], [nfs statistics])
1216 AC_COLLECTD([ntpd],      [disable], [module], [ntpd statistics])
1217 AC_COLLECTD([ping],      [disable], [module], [ping statistics])
1218 AC_COLLECTD([processes], [disable], [module], [processes statistics])
1219 AC_COLLECTD([sensors],   [disable], [module], [lm_sensors statistics])
1220 AC_COLLECTD([serial],    [disable], [module], [serial statistics])
1221 AC_COLLECTD([logfile],   [disable], [module], [logfile log facility])
1222 AC_COLLECTD([swap],      [disable], [module], [swap statistics])
1223 AC_COLLECTD([syslog],    [disable], [module], [syslog log facility])
1224 AC_COLLECTD([tape],      [disable], [module], [tape statistics])
1225 AC_COLLECTD([unixsock],  [disable], [module], [UNIX socket plugin])
1226 AC_COLLECTD([users],     [disable], [module], [user count statistics])
1227 AC_COLLECTD([vserver],   [disable], [module], [vserver statistics])
1228 AC_COLLECTD([wireless],  [disable], [module], [wireless link statistics])
1229
1230 AC_OUTPUT(Makefile src/Makefile src/collectd.conf src/liboconfig/Makefile src/liboping/Makefile)
1231
1232 cat <<EOF;
1233
1234 Configuration:
1235   Libraries:
1236     libcurl . . . . . . $with_libcurl
1237     libiokit  . . . . . $with_libiokit
1238     liboping  . . . . . $with_liboping
1239     librrd  . . . . . . $with_rrdtool
1240     lm_sensors  . . . . $with_lm_sensors
1241     libstatgrab . . . . $with_libstatgrab
1242     libkstat  . . . . . $with_kstat
1243     libmysql  . . . . . $with_libmysql
1244     libpcap . . . . . . $with_libpcap
1245     libiptc . . . . . . $with_libiptc
1246     libpthread  . . . . $with_libpthread
1247
1248   Features:
1249     debug . . . . . . . $enable_debug
1250     daemon mode . . . . $enable_daemon
1251     step  . . . . . . . $collectd_step seconds
1252     heartbeat . . . . . $collectd_heartbeat seconds
1253
1254   Modules:
1255     apache  . . . . . . $enable_apache
1256     apcups  . . . . . . $enable_apcups
1257     apple_sensors . . . $enable_apple_sensors
1258     battery . . . . . . $enable_battery
1259     cpu . . . . . . . . $enable_cpu
1260     cpufreq . . . . . . $enable_cpufreq
1261     csv . . . . . . . . $enable_csv
1262     df  . . . . . . . . $enable_df
1263     disk  . . . . . . . $enable_disk
1264     dns . . . . . . . . $enable_dns
1265     email . . . . . . . $enable_email
1266     entropy . . . . . . $enable_entropy
1267     exec  . . . . . . . $enable_exec
1268     hddtemp . . . . . . $enable_hddtemp
1269     interface . . . . . $enable_interface
1270     iptables  . . . . . $enable_iptables
1271     irq . . . . . . . . $enable_irq
1272     load  . . . . . . . $enable_load
1273     mbmon . . . . . . . $enable_mbmon
1274     memory  . . . . . . $enable_memory
1275     multimeter  . . . . $enable_multimeter
1276     mysql . . . . . . . $enable_mysql
1277     network . . . . . . $enable_network
1278     nfs . . . . . . . . $enable_nfs
1279     ntpd  . . . . . . . $enable_ntpd
1280     ping  . . . . . . . $enable_ping
1281     processes . . . . . $enable_processes
1282     sensors . . . . . . $enable_sensors
1283     serial  . . . . . . $enable_serial
1284     logfile . . . . . . $enable_logfile
1285     swap  . . . . . . . $enable_swap
1286     syslog  . . . . . . $enable_syslog
1287     tape  . . . . . . . $enable_tape
1288     unixsock  . . . . . $enable_unixsock
1289     users . . . . . . . $enable_users
1290     vserver . . . . . . $enable_vserver
1291     wireless  . . . . . $enable_wireless
1292
1293 EOF