git-cvsimport-script

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2);
  27
  28 $SIG{'PIPE'}="IGNORE";
  29 $ENV{'TZ'}="UTC";
  30
  31 our($opt_h,$opt_o,$opt_v,$opt_d,$opt_p,$opt_C,$opt_z);
  32
  33 sub usage() {
  34         print STDERR <<END;
  35 Usage: ${\basename $0}     # fetch/update GIT from CVS
  36        [ -o branch-for-HEAD ] [ -h ] [ -v ] [ -d CVSROOT ]
  37        [ -p opts-for-cvsps ] [ -C GIT_repository ] [ -z fuzz ]
  38        [ CVS_module ]
  39 END
  40         exit(1);
  41 }
  42
  43 getopts("hqvo:d:p:C:z:") or usage();
  44 usage if $opt_h;
  45
  46 @ARGV <= 1 or usage();
  47
  48 if($opt_d) {
  49         $ENV{"CVSROOT"} = $opt_d;
  50 } elsif(-f 'CVS/Root') {
  51         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  52         $opt_d = <$f>;
  53         chomp $opt_d;
  54         close $f;
  55         $ENV{"CVSROOT"} = $opt_d;
  56 } elsif($ENV{"CVSROOT"}) {
  57         $opt_d = $ENV{"CVSROOT"};
  58 } else {
  59         die "CVSROOT needs to be set";
  60 }
  61 $opt_o ||= "origin";
  62 my $git_tree = $opt_C;
  63 $git_tree ||= ".";
  64
  65 my $cvs_tree;
  66 if ($#ARGV == 0) {
  67         $cvs_tree = $ARGV[0];
  68 } elsif (-f 'CVS/Repository') {
  69         open my $f, '<', 'CVS/Repository' or
  70             die 'Failed to open CVS/Repository';
  71         $cvs_tree = <$f>;
  72         chomp $cvs_tree;
  73         close $f
  74 } else {
  75         usage();
  76 }
  77
  78 select(STDERR); $|=1; select(STDOUT);
  79
  80
  81 package CVSconn;
  82 # Basic CVS dialog.
  83 # We're only interested in connecting and downloading, so ...
  84
  85 use File::Spec;
  86 use File::Temp qw(tempfile);
  87 use POSIX qw(strftime dup2);
  88
  89 sub new {
  90         my($what,$repo,$subdir) = @_;
  91         $what=ref($what) if ref($what);
  92
  93         my $self = {};
  94         $self->{'buffer'} = "";
  95         bless($self,$what);
  96
  97         $repo =~ s#/+$##;
  98         $self->{'fullrep'} = $repo;
  99         $self->conn();
 100
 101         $self->{'subdir'} = $subdir;
 102         $self->{'lines'} = undef;
 103
 104         return $self;
 105 }
 106
 107 sub conn {
 108         my $self = shift;
 109         my $repo = $self->{'fullrep'};
 110         if($repo =~ s/^:pserver:(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 111                 my($user,$pass,$serv,$port) = ($1,$2,$3,$4);
 112                 $user="anonymous" unless defined $user;
 113                 my $rr2 = "-";
 114                 unless($port) {
 115                         $rr2 = ":pserver:$user\@$serv:$repo";
 116                         $port=2401;
 117                 }
 118                 my $rr = ":pserver:$user\@$serv:$port$repo";
 119
 120                 unless($pass) {
 121                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 122                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 123                                 while(<H>) {
 124                                         chomp;
 125                                         s/^\/\d+\s+//;
 126                                         my ($w,$p) = split(/\s/,$_,2);
 127                                         if($w eq $rr or $w eq $rr2) {
 128                                                 $pass = $p;
 129                                                 last;
 130                                         }
 131                                 }
 132                         };
 133                 }
 134                 $pass="A" unless $pass;
 135
 136                 my $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 137                 die "Socket to $serv: $!\n" unless defined $s;
 138                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 139                         or die "Write to $serv: $!\n";
 140                 $s->flush();
 141
 142                 my $rep = <$s>;
 143
 144                 if($rep ne "I LOVE YOU\n") {
 145                         $rep="<unknown>" unless $rep;
 146                         die "AuthReply: $rep\n";
 147                 }
 148                 $self->{'socketo'} = $s;
 149                 $self->{'socketi'} = $s;
 150         } else { # local or ext: Fork off our own cvs server.
 151                 my $pr = IO::Pipe->new();
 152                 my $pw = IO::Pipe->new();
 153                 my $pid = fork();
 154                 die "Fork: $!\n" unless defined $pid;
 155                 my $cvs = 'cvs';
 156                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 157                 my $rsh = 'rsh';
 158                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 159
 160                 my @cvs = ($cvs, 'server');
 161                 my ($local, $user, $host);
 162                 $local = $repo =~ s/:local://;
 163                 if (!$local) {
 164                     $repo =~ s/:ext://;
 165                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 166                     ($user, $host) = ($1, $2);
 167                 }
 168                 if (!$local) {
 169                     if ($user) {
 170                         unshift @cvs, $rsh, '-l', $user, $host;
 171                     } else {
 172                         unshift @cvs, $rsh, $host;
 173                     }
 174                 }
 175
 176                 unless($pid) {
 177                         $pr->writer();
 178                         $pw->reader();
 179                         dup2($pw->fileno(),0);
 180                         dup2($pr->fileno(),1);
 181                         $pr->close();
 182                         $pw->close();
 183                         exec(@cvs);
 184                 }
 185                 $pw->writer();
 186                 $pr->reader();
 187                 $self->{'socketo'} = $pw;
 188                 $self->{'socketi'} = $pr;
 189         }
 190         $self->{'socketo'}->write("Root $repo\n");
 191
 192         # Trial and error says that this probably is the minimum set
 193         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E F Checked-in Created Updated Merged Removed\n");
 194
 195         $self->{'socketo'}->write("valid-requests\n");
 196         $self->{'socketo'}->flush();
 197
 198         chomp(my $rep=$self->readline());
 199         if($rep !~ s/^Valid-requests\s*//) {
 200                 $rep="<unknown>" unless $rep;
 201                 die "Expected Valid-requests from server, but got: $rep\n";
 202         }
 203         chomp(my $res=$self->readline());
 204         die "validReply: $res\n" if $res ne "ok";
 205
 206         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 207         $self->{'repo'} = $repo;
 208 }
 209
 210 sub readline {
 211         my($self) = @_;
 212         return $self->{'socketi'}->getline();
 213 }
 214
 215 sub _file {
 216         # Request a file with a given revision.
 217         # Trial and error says this is a good way to do it. :-/
 218         my($self,$fn,$rev) = @_;
 219         $self->{'socketo'}->write("Argument -N\n") or return undef;
 220         $self->{'socketo'}->write("Argument -P\n") or return undef;
 221         # $self->{'socketo'}->write("Argument -ko\n") or return undef;
 222         # -ko: Linus' version doesn't use it
 223         $self->{'socketo'}->write("Argument -r\n") or return undef;
 224         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 225         $self->{'socketo'}->write("Argument --\n") or return undef;
 226         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 227         $self->{'socketo'}->write("Directory .\n") or return undef;
 228         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 229         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 230         $self->{'socketo'}->write("co\n") or return undef;
 231         $self->{'socketo'}->flush() or return undef;
 232         $self->{'lines'} = 0;
 233         return 1;
 234 }
 235 sub _line {
 236         # Read a line from the server.
 237         # ... except that 'line' may be an entire file. ;-)
 238         my($self, $fh) = @_;
 239         die "Not in lines" unless defined $self->{'lines'};
 240
 241         my $line;
 242         my $res=0;
 243         while(defined($line = $self->readline())) {
 244                 # M U gnupg-cvs-rep/AUTHORS
 245                 # Updated gnupg-cvs-rep/
 246                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 247                 # /AUTHORS/1.1///T1.1
 248                 # u=rw,g=rw,o=rw
 249                 # 0
 250                 # ok
 251
 252                 if($line =~ s/^(?:Created|Updated) //) {
 253                         $line = $self->readline(); # path
 254                         $line = $self->readline(); # Entries line
 255                         my $mode = $self->readline(); chomp $mode;
 256                         $self->{'mode'} = $mode;
 257                         defined (my $cnt = $self->readline())
 258                                 or die "EOF from server after 'Changed'\n";
 259                         chomp $cnt;
 260                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 261                         $line="";
 262                         $res=0;
 263                         while($cnt) {
 264                                 my $buf;
 265                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 266                                 die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 267                                 print $fh $buf;
 268                                 $res += $num;
 269                                 $cnt -= $num;
 270                         }
 271                 } elsif($line =~ s/^ //) {
 272                         print $fh $line;
 273                         $res += length($line);
 274                 } elsif($line =~ /^M\b/) {
 275                         # output, do nothing
 276                 } elsif($line =~ /^Mbinary\b/) {
 277                         my $cnt;
 278                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 279                         chomp $cnt;
 280                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 281                         $line="";
 282                         while($cnt) {
 283                                 my $buf;
 284                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 285                                 die "S: Mbinary $cnt: $num: $!\n" if not defined $num or $num<=0;
 286                                 print $fh $buf;
 287                                 $res += $num;
 288                                 $cnt -= $num;
 289                         }
 290                 } else {
 291                         chomp $line;
 292                         if($line eq "ok") {
 293                                 # print STDERR "S: ok (".length($res).")\n";
 294                                 return $res;
 295                         } elsif($line =~ s/^E //) {
 296                                 # print STDERR "S: $line\n";
 297                         } else {
 298                                 die "Unknown: $line\n";
 299                         }
 300                 }
 301         }
 302 }
 303 sub file {
 304         my($self,$fn,$rev) = @_;
 305         my $res;
 306
 307         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 308                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 309
 310         $self->_file($fn,$rev) and $res = $self->_line($fh);
 311
 312         if (!defined $res) {
 313             # retry
 314             $self->conn();
 315             $self->_file($fn,$rev)
 316                     or die "No file command send\n";
 317             $res = $self->_line($fh);
 318             die "No input: $fn $rev\n" unless defined $res;
 319         }
 320
 321         return ($name, $res);
 322 }
 323
 324
 325 package main;
 326
 327 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 328
 329
 330 sub pdate($) {
 331         my($d) = @_;
 332         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 333                 or die "Unparseable date: $d\n";
 334         my $y=$1; $y-=1900 if $y>1900;
 335         return timegm($6||0,$5,$4,$3,$2-1,$y);
 336 }
 337
 338 sub pmode($) {
 339         my($mode) = @_;
 340         my $m = 0;
 341         my $mm = 0;
 342         my $um = 0;
 343         for my $x(split(//,$mode)) {
 344                 if($x eq ",") {
 345                         $m |= $mm&$um;
 346                         $mm = 0;
 347                         $um = 0;
 348                 } elsif($x eq "u") { $um |= 0700;
 349                 } elsif($x eq "g") { $um |= 0070;
 350                 } elsif($x eq "o") { $um |= 0007;
 351                 } elsif($x eq "r") { $mm |= 0444;
 352                 } elsif($x eq "w") { $mm |= 0222;
 353                 } elsif($x eq "x") { $mm |= 0111;
 354                 } elsif($x eq "=") { # do nothing
 355                 } else { die "Unknown mode: $mode\n";
 356                 }
 357         }
 358         $m |= $mm&$um;
 359         return $m;
 360 }
 361
 362 sub getwd() {
 363         my $pwd = `pwd`;
 364         chomp $pwd;
 365         return $pwd;
 366 }
 367
 368 -d $git_tree
 369         or mkdir($git_tree,0777)
 370         or die "Could not create $git_tree: $!";
 371 chdir($git_tree);
 372
 373 my $last_branch = "";
 374 my $orig_branch = "";
 375 my %branch_date;
 376
 377 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 378 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 379 $ENV{"GIT_DIR"} = $git_dir;
 380 my $orig_git_index;
 381 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 382 my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 383                                     DIR => File::Spec->tmpdir());
 384 close ($git_ih);
 385 $ENV{GIT_INDEX_FILE} = $git_index;
 386 unless(-d $git_dir) {
 387         system("git-init-db");
 388         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 389         system("git-read-tree");
 390         die "Cannot init an empty tree: $?\n" if $?;
 391
 392         $last_branch = $opt_o;
 393         $orig_branch = "";
 394 } else {
 395         -f "$git_dir/refs/heads/$opt_o"
 396                 or die "Branch '$opt_o' does not exist.\n".
 397                        "Either use the correct '-o branch' option,\n".
 398                        "or import to a new repository.\n";
 399
 400         $last_branch = basename(readlink("$git_dir/HEAD"));
 401         unless($last_branch) {
 402                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 403                 $last_branch = "master";
 404         }
 405         $orig_branch = $last_branch;
 406
 407         # populate index
 408         system('git-read-tree', $last_branch);
 409         die "read-tree failed: $?\n" if $?;
 410
 411         # Get the last import timestamps
 412         opendir(D,"$git_dir/refs/heads");
 413         while(defined(my $head = readdir(D))) {
 414                 next if $head =~ /^\./;
 415                 open(F,"$git_dir/refs/heads/$head")
 416                         or die "Bad head branch: $head: $!\n";
 417                 chomp(my $ftag = <F>);
 418                 close(F);
 419                 open(F,"git-cat-file commit $ftag |");
 420                 while(<F>) {
 421                         next unless /^author\s.*\s(\d+)\s[-+]\d{4}$/;
 422                         $branch_date{$head} = $1;
 423                         last;
 424                 }
 425                 close(F);
 426         }
 427         closedir(D);
 428 }
 429
 430 -d $git_dir
 431         or die "Could not create git subdir ($git_dir).\n";
 432
 433 my $pid = open(CVS,"-|");
 434 die "Cannot fork: $!\n" unless defined $pid;
 435 unless($pid) {
 436         my @opt;
 437         @opt = split(/,/,$opt_p) if defined $opt_p;
 438         unshift @opt, '-z', $opt_z if defined $opt_z;
 439         exec("cvsps",@opt,"-u","-A","--cvs-direct",'--root',$opt_d,$cvs_tree);
 440         die "Could not start cvsps: $!\n";
 441 }
 442
 443
 444 ## cvsps output:
 445 #---------------------
 446 #PatchSet 314
 447 #Date: 1999/09/18 13:03:59
 448 #Author: wkoch
 449 #Branch: STABLE-BRANCH-1-0
 450 #Ancestor branch: HEAD
 451 #Tag: (none)
 452 #Log:
 453 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 454 #Members:
 455 #       README:1.57->1.57.2.1
 456 #       VERSION:1.96->1.96.2.1
 457 #
 458 #---------------------
 459
 460 my $state = 0;
 461
 462 my($patchset,$date,$author,$branch,$ancestor,$tag,$logmsg);
 463 my(@old,@new);
 464 my $commit = sub {
 465         my $pid;
 466         while(@old) {
 467                 my @o2;
 468                 if(@old > 55) {
 469                         @o2 = splice(@old,0,50);
 470                 } else {
 471                         @o2 = @old;
 472                         @old = ();
 473                 }
 474                 system("git-update-cache","--force-remove","--",@o2);
 475                 die "Cannot remove files: $?\n" if $?;
 476         }
 477         while(@new) {
 478                 my @n2;
 479                 if(@new > 12) {
 480                         @n2 = splice(@new,0,10);
 481                 } else {
 482                         @n2 = @new;
 483                         @new = ();
 484                 }
 485                 system("git-update-cache","--add",
 486                         (map { ('--cacheinfo', @$_) } @n2));
 487                 die "Cannot add files: $?\n" if $?;
 488         }
 489
 490         $pid = open(C,"-|");
 491         die "Cannot fork: $!" unless defined $pid;
 492         unless($pid) {
 493                 exec("git-write-tree");
 494                 die "Cannot exec git-write-tree: $!\n";
 495         }
 496         chomp(my $tree = <C>);
 497         length($tree) == 40
 498                 or die "Cannot get tree id ($tree): $!\n";
 499         close(C)
 500                 or die "Error running git-write-tree: $?\n";
 501         print "Tree ID $tree\n" if $opt_v;
 502
 503         my $parent = "";
 504         if(open(C,"$git_dir/refs/heads/$last_branch")) {
 505                 chomp($parent = <C>);
 506                 close(C);
 507                 length($parent) == 40
 508                         or die "Cannot get parent id ($parent): $!\n";
 509                 print "Parent ID $parent\n" if $opt_v;
 510         }
 511
 512         my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 513         my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 514         $pid = fork();
 515         die "Fork: $!\n" unless defined $pid;
 516         unless($pid) {
 517                 $pr->writer();
 518                 $pw->reader();
 519                 dup2($pw->fileno(),0);
 520                 dup2($pr->fileno(),1);
 521                 $pr->close();
 522                 $pw->close();
 523
 524                 my @par = ();
 525                 @par = ("-p",$parent) if $parent;
 526                 exec("env",
 527                         "GIT_AUTHOR_NAME=$author",
 528                         "GIT_AUTHOR_EMAIL=$author",
 529                         "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 530                         "GIT_COMMITTER_NAME=$author",
 531                         "GIT_COMMITTER_EMAIL=$author",
 532                         "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 533                         "git-commit-tree", $tree,@par);
 534                 die "Cannot exec git-commit-tree: $!\n";
 535         }
 536         $pw->writer();
 537         $pr->reader();
 538
 539         # compatibility with git2cvs
 540         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 541         $logmsg =~ s/[\s\n]+\z//;
 542
 543         print $pw "$logmsg\n"
 544                 or die "Error writing to git-commit-tree: $!\n";
 545         $pw->close();
 546
 547         print "Committed patch $patchset ($branch)\n" if $opt_v;
 548         chomp(my $cid = <$pr>);
 549         length($cid) == 40
 550                 or die "Cannot get commit id ($cid): $!\n";
 551         print "Commit ID $cid\n" if $opt_v;
 552         $pr->close();
 553
 554         waitpid($pid,0);
 555         die "Error running git-commit-tree: $?\n" if $?;
 556
 557         open(C,">$git_dir/refs/heads/$branch")
 558                 or die "Cannot open branch $branch for update: $!\n";
 559         print C "$cid\n"
 560                 or die "Cannot write branch $branch for update: $!\n";
 561         close(C)
 562                 or die "Cannot write branch $branch for update: $!\n";
 563
 564         if($tag) {
 565                 open(C,">$git_dir/refs/tags/$tag")
 566                         or die "Cannot create tag $tag: $!\n";
 567                 print C "$cid\n"
 568                         or die "Cannot write tag $branch: $!\n";
 569                 close(C)
 570                         or die "Cannot write tag $branch: $!\n";
 571                 print "Created tag '$tag' on '$branch'\n" if $opt_v;
 572         }
 573 };
 574
 575 while(<CVS>) {
 576         chomp;
 577         if($state == 0 and /^-+$/) {
 578                 $state = 1;
 579         } elsif($state == 0) {
 580                 $state = 1;
 581                 redo;
 582         } elsif(($state==0 or $state==1) and s/^PatchSet\s+//) {
 583                 $patchset = 0+$_;
 584                 $state=2;
 585         } elsif($state == 2 and s/^Date:\s+//) {
 586                 $date = pdate($_);
 587                 unless($date) {
 588                         print STDERR "Could not parse date: $_\n";
 589                         $state=0;
 590                         next;
 591                 }
 592                 $state=3;
 593         } elsif($state == 3 and s/^Author:\s+//) {
 594                 s/\s+$//;
 595                 $author = $_;
 596                 $state = 4;
 597         } elsif($state == 4 and s/^Branch:\s+//) {
 598                 s/\s+$//;
 599                 $branch = $_;
 600                 $state = 5;
 601         } elsif($state == 5 and s/^Ancestor branch:\s+//) {
 602                 s/\s+$//;
 603                 $ancestor = $_;
 604                 $ancestor = $opt_o if $ancestor eq "HEAD";
 605                 $state = 6;
 606         } elsif($state == 5) {
 607                 $ancestor = undef;
 608                 $state = 6;
 609                 redo;
 610         } elsif($state == 6 and s/^Tag:\s+//) {
 611                 s/\s+$//;
 612                 if($_ eq "(none)") {
 613                         $tag = undef;
 614                 } else {
 615                         $tag = $_;
 616                 }
 617                 $state = 7;
 618         } elsif($state == 7 and /^Log:/) {
 619                 $logmsg = "";
 620                 $state = 8;
 621         } elsif($state == 8 and /^Members:/) {
 622                 $branch = $opt_o if $branch eq "HEAD";
 623                 if(defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 624                         # skip
 625                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 626                         $state = 11;
 627                         next;
 628                 }
 629                 if($ancestor) {
 630                         if(-f "$git_dir/refs/heads/$branch") {
 631                                 print STDERR "Branch $branch already exists!\n";
 632                                 $state=11;
 633                                 next;
 634                         }
 635                         unless(open(H,"$git_dir/refs/heads/$ancestor")) {
 636                                 print STDERR "Branch $ancestor does not exist!\n";
 637                                 $state=11;
 638                                 next;
 639                         }
 640                         chomp(my $id = <H>);
 641                         close(H);
 642                         unless(open(H,"> $git_dir/refs/heads/$branch")) {
 643                                 print STDERR "Could not create branch $branch: $!\n";
 644                                 $state=11;
 645                                 next;
 646                         }
 647                         print H "$id\n"
 648                                 or die "Could not write branch $branch: $!";
 649                         close(H)
 650                                 or die "Could not write branch $branch: $!";
 651                 }
 652                 if(($ancestor || $branch) ne $last_branch) {
 653                         print "Switching from $last_branch to $branch\n" if $opt_v;
 654                         system("git-read-tree", $branch);
 655                         die "read-tree failed: $?\n" if $?;
 656                 }
 657                 $last_branch = $branch if $branch ne $last_branch;
 658                 $state = 9;
 659         } elsif($state == 8) {
 660                 $logmsg .= "$_\n";
 661         } elsif($state == 9 and /^\s+(\S+):(INITIAL|\d(?:\.\d+)+)->(\d(?:\.\d+)+)\s*$/) {
 662 #       VERSION:1.96->1.96.2.1
 663                 my $init = ($2 eq "INITIAL");
 664                 my $fn = $1;
 665                 my $rev = $3;
 666                 $fn =~ s#^/+##;
 667                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 668                 print "".($init ? "New" : "Update")." $fn: $size bytes.\n" if $opt_v;
 669                 open my $F, '-|', "git-write-blob $tmpname"
 670                         or die "Cannot create object: $!\n";
 671                 my $sha = <$F>;
 672                 chomp $sha;
 673                 close $F;
 674                 unlink($tmpname);
 675                 my $mode = pmode($cvs->{'mode'});
 676                 push(@new,[$mode, $sha, $fn]); # may be resurrected!
 677         } elsif($state == 9 and /^\s+(\S+):\d(?:\.\d+)+->(\d(?:\.\d+)+)\(DEAD\)\s*$/) {
 678                 my $fn = $1;
 679                 $fn =~ s#^/+##;
 680                 push(@old,$fn);
 681         } elsif($state == 9 and /^\s*$/) {
 682                 $state = 10;
 683         } elsif(($state == 9 or $state == 10) and /^-+$/) {
 684                 &$commit();
 685                 $state = 1;
 686         } elsif($state == 11 and /^-+$/) {
 687                 $state = 1;
 688         } elsif(/^-+$/) { # end of unknown-line processing
 689                 $state = 1;
 690         } elsif($state != 11) { # ignore stuff when skipping
 691                 print "* UNKNOWN LINE * $_\n";
 692         }
 693 }
 694 &$commit() if $branch and $state != 11;
 695
 696 unlink($git_index);
 697
 698 # Now switch back to the branch we were in before all of this happened
 699 if($orig_branch) {
 700         print "DONE\n" if $opt_v;
 701 } else {
 702         $orig_branch = "master";
 703         print "DONE; creating $orig_branch branch\n" if $opt_v;
 704         system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 705                 unless -f "$git_dir/refs/heads/master";
 706         unlink("$git_dir/HEAD");
 707         symlink("refs/heads/$orig_branch","$git_dir/HEAD");
 708         if (defined $orig_git_index) {
 709             $ENV{GIT_INDEX_FILE} = $orig_git_index;
 710         } else {
 711             delete $ENV{GIT_INDEX_FILE};
 712         }
 713         system('git checkout');
 714         die "checkout failed: $?\n" if $?;
 715 }