git-cvsimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2 ENOENT);
  27 use IPC::Open2;
  28
  29 $SIG{'PIPE'}="IGNORE";
  30 $ENV{'TZ'}="UTC";
  31
  32 our($opt_h,$opt_o,$opt_v,$opt_k,$opt_u,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i,$opt_P, $opt_s,$opt_m,$opt_M,$opt_A,$opt_S,$opt_L);
  33 my (%conv_author_name, %conv_author_email);
  34
  35 sub usage() {
  36         print STDERR <<END;
  37 Usage: ${\basename $0}     # fetch/update GIT from CVS
  38        [-o branch-for-HEAD] [-h] [-v] [-d CVSROOT] [-A author-conv-file]
  39        [-p opts-for-cvsps] [-C GIT_repository] [-z fuzz] [-i] [-k] [-u]
  40        [-s subst] [-m] [-M regex] [-S regex] [CVS_module]
  41 END
  42         exit(1);
  43 }
  44
  45 sub read_author_info($) {
  46         my ($file) = @_;
  47         my $user;
  48         open my $f, '<', "$file" or die("Failed to open $file: $!\n");
  49
  50         while (<$f>) {
  51                 # Expected format is this:
  52                 #   exon=Andreas Ericsson <ae@op5.se>
  53                 if (m/^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/) {
  54                         $user = $1;
  55                         $conv_author_name{$user} = $2;
  56                         $conv_author_email{$user} = $3;
  57                 }
  58                 # However, we also read from CVSROOT/users format
  59                 # to ease migration.
  60                 elsif (/^(\w+):(['"]?)(.+?)\2\s*$/) {
  61                         my $mapped;
  62                         ($user, $mapped) = ($1, $3);
  63                         if ($mapped =~ /^\s*(.*?)\s*<(.*)>\s*$/) {
  64                                 $conv_author_name{$user} = $1;
  65                                 $conv_author_email{$user} = $2;
  66                         }
  67                         elsif ($mapped =~ /^<?(.*)>?$/) {
  68                                 $conv_author_name{$user} = $user;
  69                                 $conv_author_email{$user} = $1;
  70                         }
  71                 }
  72                 # NEEDSWORK: Maybe warn on unrecognized lines?
  73         }
  74         close ($f);
  75 }
  76
  77 sub write_author_info($) {
  78         my ($file) = @_;
  79         open my $f, '>', $file or
  80           die("Failed to open $file for writing: $!");
  81
  82         foreach (keys %conv_author_name) {
  83                 print $f "$_=$conv_author_name{$_} <$conv_author_email{$_}>\n";
  84         }
  85         close ($f);
  86 }
  87
  88 getopts("hivmkuo:d:p:C:z:s:M:P:A:S:L:") or usage();
  89 usage if $opt_h;
  90
  91 @ARGV <= 1 or usage();
  92
  93 if($opt_d) {
  94         $ENV{"CVSROOT"} = $opt_d;
  95 } elsif(-f 'CVS/Root') {
  96         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  97         $opt_d = <$f>;
  98         chomp $opt_d;
  99         close $f;
 100         $ENV{"CVSROOT"} = $opt_d;
 101 } elsif($ENV{"CVSROOT"}) {
 102         $opt_d = $ENV{"CVSROOT"};
 103 } else {
 104         die "CVSROOT needs to be set";
 105 }
 106 $opt_o ||= "origin";
 107 $opt_s ||= "-";
 108 my $git_tree = $opt_C;
 109 $git_tree ||= ".";
 110
 111 my $cvs_tree;
 112 if ($#ARGV == 0) {
 113         $cvs_tree = $ARGV[0];
 114 } elsif (-f 'CVS/Repository') {
 115         open my $f, '<', 'CVS/Repository' or
 116             die 'Failed to open CVS/Repository';
 117         $cvs_tree = <$f>;
 118         chomp $cvs_tree;
 119         close $f;
 120 } else {
 121         usage();
 122 }
 123
 124 our @mergerx = ();
 125 if ($opt_m) {
 126         @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
 127 }
 128 if ($opt_M) {
 129         push (@mergerx, qr/$opt_M/);
 130 }
 131
 132 select(STDERR); $|=1; select(STDOUT);
 133
 134
 135 package CVSconn;
 136 # Basic CVS dialog.
 137 # We're only interested in connecting and downloading, so ...
 138
 139 use File::Spec;
 140 use File::Temp qw(tempfile);
 141 use POSIX qw(strftime dup2);
 142
 143 sub new {
 144         my($what,$repo,$subdir) = @_;
 145         $what=ref($what) if ref($what);
 146
 147         my $self = {};
 148         $self->{'buffer'} = "";
 149         bless($self,$what);
 150
 151         $repo =~ s#/+$##;
 152         $self->{'fullrep'} = $repo;
 153         $self->conn();
 154
 155         $self->{'subdir'} = $subdir;
 156         $self->{'lines'} = undef;
 157
 158         return $self;
 159 }
 160
 161 sub conn {
 162         my $self = shift;
 163         my $repo = $self->{'fullrep'};
 164         if($repo =~ s/^:pserver:(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 165                 my($user,$pass,$serv,$port) = ($1,$2,$3,$4);
 166                 $user="anonymous" unless defined $user;
 167                 my $rr2 = "-";
 168                 unless($port) {
 169                         $rr2 = ":pserver:$user\@$serv:$repo";
 170                         $port=2401;
 171                 }
 172                 my $rr = ":pserver:$user\@$serv:$port$repo";
 173
 174                 unless($pass) {
 175                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 176                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 177                                 while(<H>) {
 178                                         chomp;
 179                                         s/^\/\d+\s+//;
 180                                         my ($w,$p) = split(/\s/,$_,2);
 181                                         if($w eq $rr or $w eq $rr2) {
 182                                                 $pass = $p;
 183                                                 last;
 184                                         }
 185                                 }
 186                         };
 187                 }
 188                 $pass="A" unless $pass;
 189
 190                 my $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 191                 die "Socket to $serv: $!\n" unless defined $s;
 192                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 193                         or die "Write to $serv: $!\n";
 194                 $s->flush();
 195
 196                 my $rep = <$s>;
 197
 198                 if($rep ne "I LOVE YOU\n") {
 199                         $rep="<unknown>" unless $rep;
 200                         die "AuthReply: $rep\n";
 201                 }
 202                 $self->{'socketo'} = $s;
 203                 $self->{'socketi'} = $s;
 204         } else { # local or ext: Fork off our own cvs server.
 205                 my $pr = IO::Pipe->new();
 206                 my $pw = IO::Pipe->new();
 207                 my $pid = fork();
 208                 die "Fork: $!\n" unless defined $pid;
 209                 my $cvs = 'cvs';
 210                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 211                 my $rsh = 'rsh';
 212                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 213
 214                 my @cvs = ($cvs, 'server');
 215                 my ($local, $user, $host);
 216                 $local = $repo =~ s/:local://;
 217                 if (!$local) {
 218                     $repo =~ s/:ext://;
 219                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 220                     ($user, $host) = ($1, $2);
 221                 }
 222                 if (!$local) {
 223                     if ($user) {
 224                         unshift @cvs, $rsh, '-l', $user, $host;
 225                     } else {
 226                         unshift @cvs, $rsh, $host;
 227                     }
 228                 }
 229
 230                 unless($pid) {
 231                         $pr->writer();
 232                         $pw->reader();
 233                         dup2($pw->fileno(),0);
 234                         dup2($pr->fileno(),1);
 235                         $pr->close();
 236                         $pw->close();
 237                         exec(@cvs);
 238                 }
 239                 $pw->writer();
 240                 $pr->reader();
 241                 $self->{'socketo'} = $pw;
 242                 $self->{'socketi'} = $pr;
 243         }
 244         $self->{'socketo'}->write("Root $repo\n");
 245
 246         # Trial and error says that this probably is the minimum set
 247         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E Checked-in Created Updated Merged Removed\n");
 248
 249         $self->{'socketo'}->write("valid-requests\n");
 250         $self->{'socketo'}->flush();
 251
 252         chomp(my $rep=$self->readline());
 253         if($rep !~ s/^Valid-requests\s*//) {
 254                 $rep="<unknown>" unless $rep;
 255                 die "Expected Valid-requests from server, but got: $rep\n";
 256         }
 257         chomp(my $res=$self->readline());
 258         die "validReply: $res\n" if $res ne "ok";
 259
 260         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 261         $self->{'repo'} = $repo;
 262 }
 263
 264 sub readline {
 265         my($self) = @_;
 266         return $self->{'socketi'}->getline();
 267 }
 268
 269 sub _file {
 270         # Request a file with a given revision.
 271         # Trial and error says this is a good way to do it. :-/
 272         my($self,$fn,$rev) = @_;
 273         $self->{'socketo'}->write("Argument -N\n") or return undef;
 274         $self->{'socketo'}->write("Argument -P\n") or return undef;
 275         # -kk: Linus' version doesn't use it - defaults to off
 276         if ($opt_k) {
 277             $self->{'socketo'}->write("Argument -kk\n") or return undef;
 278         }
 279         $self->{'socketo'}->write("Argument -r\n") or return undef;
 280         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 281         $self->{'socketo'}->write("Argument --\n") or return undef;
 282         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 283         $self->{'socketo'}->write("Directory .\n") or return undef;
 284         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 285         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 286         $self->{'socketo'}->write("co\n") or return undef;
 287         $self->{'socketo'}->flush() or return undef;
 288         $self->{'lines'} = 0;
 289         return 1;
 290 }
 291 sub _line {
 292         # Read a line from the server.
 293         # ... except that 'line' may be an entire file. ;-)
 294         my($self, $fh) = @_;
 295         die "Not in lines" unless defined $self->{'lines'};
 296
 297         my $line;
 298         my $res=0;
 299         while(defined($line = $self->readline())) {
 300                 # M U gnupg-cvs-rep/AUTHORS
 301                 # Updated gnupg-cvs-rep/
 302                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 303                 # /AUTHORS/1.1///T1.1
 304                 # u=rw,g=rw,o=rw
 305                 # 0
 306                 # ok
 307
 308                 if($line =~ s/^(?:Created|Updated) //) {
 309                         $line = $self->readline(); # path
 310                         $line = $self->readline(); # Entries line
 311                         my $mode = $self->readline(); chomp $mode;
 312                         $self->{'mode'} = $mode;
 313                         defined (my $cnt = $self->readline())
 314                                 or die "EOF from server after 'Changed'\n";
 315                         chomp $cnt;
 316                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 317                         $line="";
 318                         $res = $self->_fetchfile($fh, $cnt);
 319                 } elsif($line =~ s/^ //) {
 320                         print $fh $line;
 321                         $res += length($line);
 322                 } elsif($line =~ /^M\b/) {
 323                         # output, do nothing
 324                 } elsif($line =~ /^Mbinary\b/) {
 325                         my $cnt;
 326                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 327                         chomp $cnt;
 328                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 329                         $line="";
 330                         $res += $self->_fetchfile($fh, $cnt);
 331                 } else {
 332                         chomp $line;
 333                         if($line eq "ok") {
 334                                 # print STDERR "S: ok (".length($res).")\n";
 335                                 return $res;
 336                         } elsif($line =~ s/^E //) {
 337                                 # print STDERR "S: $line\n";
 338                         } elsif($line =~ /^(Remove-entry|Removed) /i) {
 339                                 $line = $self->readline(); # filename
 340                                 $line = $self->readline(); # OK
 341                                 chomp $line;
 342                                 die "Unknown: $line" if $line ne "ok";
 343                                 return -1;
 344                         } else {
 345                                 die "Unknown: $line\n";
 346                         }
 347                 }
 348         }
 349         return undef;
 350 }
 351 sub file {
 352         my($self,$fn,$rev) = @_;
 353         my $res;
 354
 355         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 356                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 357
 358         $self->_file($fn,$rev) and $res = $self->_line($fh);
 359
 360         if (!defined $res) {
 361             print STDERR "Server has gone away while fetching $fn $rev, retrying...\n";
 362             truncate $fh, 0;
 363             $self->conn();
 364             $self->_file($fn,$rev) or die "No file command send";
 365             $res = $self->_line($fh);
 366             die "Retry failed" unless defined $res;
 367         }
 368         close ($fh);
 369
 370         return ($name, $res);
 371 }
 372 sub _fetchfile {
 373         my ($self, $fh, $cnt) = @_;
 374         my $res = 0;
 375         my $bufsize = 1024 * 1024;
 376         while($cnt) {
 377             if ($bufsize > $cnt) {
 378                 $bufsize = $cnt;
 379             }
 380             my $buf;
 381             my $num = $self->{'socketi'}->read($buf,$bufsize);
 382             die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 383             print $fh $buf;
 384             $res += $num;
 385             $cnt -= $num;
 386         }
 387         return $res;
 388 }
 389
 390
 391 package main;
 392
 393 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 394
 395
 396 sub pdate($) {
 397         my($d) = @_;
 398         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 399                 or die "Unparseable date: $d\n";
 400         my $y=$1; $y-=1900 if $y>1900;
 401         return timegm($6||0,$5,$4,$3,$2-1,$y);
 402 }
 403
 404 sub pmode($) {
 405         my($mode) = @_;
 406         my $m = 0;
 407         my $mm = 0;
 408         my $um = 0;
 409         for my $x(split(//,$mode)) {
 410                 if($x eq ",") {
 411                         $m |= $mm&$um;
 412                         $mm = 0;
 413                         $um = 0;
 414                 } elsif($x eq "u") { $um |= 0700;
 415                 } elsif($x eq "g") { $um |= 0070;
 416                 } elsif($x eq "o") { $um |= 0007;
 417                 } elsif($x eq "r") { $mm |= 0444;
 418                 } elsif($x eq "w") { $mm |= 0222;
 419                 } elsif($x eq "x") { $mm |= 0111;
 420                 } elsif($x eq "=") { # do nothing
 421                 } else { die "Unknown mode: $mode\n";
 422                 }
 423         }
 424         $m |= $mm&$um;
 425         return $m;
 426 }
 427
 428 sub getwd() {
 429         my $pwd = `pwd`;
 430         chomp $pwd;
 431         return $pwd;
 432 }
 433
 434 sub is_sha1 {
 435         my $s = shift;
 436         return $s =~ /^[a-f0-9]{40}$/;
 437 }
 438
 439 sub get_headref ($$) {
 440     my $name    = shift;
 441     my $git_dir = shift;
 442
 443     my $f = "$git_dir/refs/heads/$name";
 444     if(open(my $fh, $f)) {
 445             chomp(my $r = <$fh>);
 446             is_sha1($r) or die "Cannot get head id for $name ($r): $!";
 447             return $r;
 448     }
 449     die "unable to open $f: $!" unless $! == POSIX::ENOENT;
 450     return undef;
 451 }
 452
 453 -d $git_tree
 454         or mkdir($git_tree,0777)
 455         or die "Could not create $git_tree: $!";
 456 chdir($git_tree);
 457
 458 my $last_branch = "";
 459 my $orig_branch = "";
 460 my %branch_date;
 461 my $tip_at_start = undef;
 462
 463 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 464 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 465 $ENV{"GIT_DIR"} = $git_dir;
 466 my $orig_git_index;
 467 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 468 my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 469                                     DIR => File::Spec->tmpdir());
 470 close ($git_ih);
 471 $ENV{GIT_INDEX_FILE} = $git_index;
 472 unless(-d $git_dir) {
 473         system("git-init-db");
 474         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 475         system("git-read-tree");
 476         die "Cannot init an empty tree: $?\n" if $?;
 477
 478         $last_branch = $opt_o;
 479         $orig_branch = "";
 480 } else {
 481         -f "$git_dir/refs/heads/$opt_o"
 482                 or die "Branch '$opt_o' does not exist.\n".
 483                        "Either use the correct '-o branch' option,\n".
 484                        "or import to a new repository.\n";
 485
 486         open(F, "git-symbolic-ref HEAD |") or
 487                 die "Cannot run git-symbolic-ref: $!\n";
 488         chomp ($last_branch = <F>);
 489         $last_branch = basename($last_branch);
 490         close(F);
 491         unless($last_branch) {
 492                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 493                 $last_branch = "master";
 494         }
 495         $orig_branch = $last_branch;
 496         $tip_at_start = `git-rev-parse --verify HEAD`;
 497
 498         # populate index
 499         system('git-read-tree', $last_branch);
 500         die "read-tree failed: $?\n" if $?;
 501
 502         # Get the last import timestamps
 503         opendir(D,"$git_dir/refs/heads");
 504         while(defined(my $head = readdir(D))) {
 505                 next if $head =~ /^\./;
 506                 open(F,"$git_dir/refs/heads/$head")
 507                         or die "Bad head branch: $head: $!\n";
 508                 chomp(my $ftag = <F>);
 509                 close(F);
 510                 open(F,"git-cat-file commit $ftag |");
 511                 while(<F>) {
 512                         next unless /^author\s.*\s(\d+)\s[-+]\d{4}$/;
 513                         $branch_date{$head} = $1;
 514                         last;
 515                 }
 516                 close(F);
 517         }
 518         closedir(D);
 519 }
 520
 521 -d $git_dir
 522         or die "Could not create git subdir ($git_dir).\n";
 523
 524 # now we read (and possibly save) author-info as well
 525 -f "$git_dir/cvs-authors" and
 526   read_author_info("$git_dir/cvs-authors");
 527 if ($opt_A) {
 528         read_author_info($opt_A);
 529         write_author_info("$git_dir/cvs-authors");
 530 }
 531
 532 my $pid = open(CVS,"-|");
 533 die "Cannot fork: $!\n" unless defined $pid;
 534 unless($pid) {
 535         my @opt;
 536         @opt = split(/,/,$opt_p) if defined $opt_p;
 537         unshift @opt, '-z', $opt_z if defined $opt_z;
 538         unshift @opt, '-q'         unless defined $opt_v;
 539         unless (defined($opt_p) && $opt_p =~ m/--no-cvs-direct/) {
 540                 push @opt, '--cvs-direct';
 541         }
 542         if ($opt_P) {
 543             exec("cat", $opt_P);
 544         } else {
 545             exec("cvsps","--norc",@opt,"-u","-A",'--root',$opt_d,$cvs_tree);
 546             die "Could not start cvsps: $!\n";
 547         }
 548 }
 549
 550
 551 ## cvsps output:
 552 #---------------------
 553 #PatchSet 314
 554 #Date: 1999/09/18 13:03:59
 555 #Author: wkoch
 556 #Branch: STABLE-BRANCH-1-0
 557 #Ancestor branch: HEAD
 558 #Tag: (none)
 559 #Log:
 560 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 561 #Members:
 562 #       README:1.57->1.57.2.1
 563 #       VERSION:1.96->1.96.2.1
 564 #
 565 #---------------------
 566
 567 my $state = 0;
 568
 569 sub update_index (\@\@) {
 570         my $old = shift;
 571         my $new = shift;
 572         open(my $fh, '|-', qw(git-update-index -z --index-info))
 573                 or die "unable to open git-update-index: $!";
 574         print $fh
 575                 (map { "0 0000000000000000000000000000000000000000\t$_\0" }
 576                         @$old),
 577                 (map { '100' . sprintf('%o', $_->[0]) . " $_->[1]\t$_->[2]\0" }
 578                         @$new)
 579                 or die "unable to write to git-update-index: $!";
 580         close $fh
 581                 or die "unable to write to git-update-index: $!";
 582         $? and die "git-update-index reported error: $?";
 583 }
 584
 585 sub write_tree () {
 586         open(my $fh, '-|', qw(git-write-tree))
 587                 or die "unable to open git-write-tree: $!";
 588         chomp(my $tree = <$fh>);
 589         is_sha1($tree)
 590                 or die "Cannot get tree id ($tree): $!";
 591         close($fh)
 592                 or die "Error running git-write-tree: $?\n";
 593         print "Tree ID $tree\n" if $opt_v;
 594         return $tree;
 595 }
 596
 597 my($patchset,$date,$author_name,$author_email,$branch,$ancestor,$tag,$logmsg);
 598 my(@old,@new,@skipped,%ignorebranch);
 599
 600 # commits that cvsps cannot place anywhere...
 601 $ignorebranch{'#CVSPS_NO_BRANCH'} = 1;
 602
 603 sub commit {
 604         update_index(@old, @new);
 605         @old = @new = ();
 606         my $tree = write_tree();
 607         my $parent = get_headref($last_branch, $git_dir);
 608         print "Parent ID " . ($parent ? $parent : "(empty)") . "\n" if $opt_v;
 609
 610         my @commit_args;
 611         push @commit_args, ("-p", $parent) if $parent;
 612
 613         # loose detection of merges
 614         # based on the commit msg
 615         foreach my $rx (@mergerx) {
 616                 next unless $logmsg =~ $rx && $1;
 617                 my $mparent = $1 eq 'HEAD' ? $opt_o : $1;
 618                 if(my $sha1 = get_headref($mparent, $git_dir)) {
 619                         push @commit_args, '-p', $mparent;
 620                         print "Merge parent branch: $mparent\n" if $opt_v;
 621                 }
 622         }
 623
 624         my $commit_date = strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date));
 625         $ENV{GIT_AUTHOR_NAME} = $author_name;
 626         $ENV{GIT_AUTHOR_EMAIL} = $author_email;
 627         $ENV{GIT_AUTHOR_DATE} = $commit_date;
 628         $ENV{GIT_COMMITTER_NAME} = $author_name;
 629         $ENV{GIT_COMMITTER_EMAIL} = $author_email;
 630         $ENV{GIT_COMMITTER_DATE} = $commit_date;
 631         my $pid = open2(my $commit_read, my $commit_write,
 632                 'git-commit-tree', $tree, @commit_args);
 633
 634         # compatibility with git2cvs
 635         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 636         $logmsg =~ s/[\s\n]+\z//;
 637
 638         if (@skipped) {
 639             $logmsg .= "\n\n\nSKIPPED:\n\t";
 640             $logmsg .= join("\n\t", @skipped) . "\n";
 641             @skipped = ();
 642         }
 643
 644         print($commit_write "$logmsg\n") && close($commit_write)
 645                 or die "Error writing to git-commit-tree: $!\n";
 646
 647         print "Committed patch $patchset ($branch $commit_date)\n" if $opt_v;
 648         chomp(my $cid = <$commit_read>);
 649         is_sha1($cid) or die "Cannot get commit id ($cid): $!\n";
 650         print "Commit ID $cid\n" if $opt_v;
 651         close($commit_read);
 652
 653         waitpid($pid,0);
 654         die "Error running git-commit-tree: $?\n" if $?;
 655
 656         system("git-update-ref refs/heads/$branch $cid") == 0
 657                 or die "Cannot write branch $branch for update: $!\n";
 658
 659         if($tag) {
 660                 my($in, $out) = ('','');
 661                 my($xtag) = $tag;
 662                 $xtag =~ s/\s+\*\*.*$//; # Remove stuff like ** INVALID ** and ** FUNKY **
 663                 $xtag =~ tr/_/\./ if ( $opt_u );
 664                 $xtag =~ s/[\/]/$opt_s/g;
 665
 666                 my $pid = open2($in, $out, 'git-mktag');
 667                 print $out "object $cid\n".
 668                     "type commit\n".
 669                     "tag $xtag\n".
 670                     "tagger $author_name <$author_email>\n"
 671                     or die "Cannot create tag object $xtag: $!\n";
 672                 close($out)
 673                     or die "Cannot create tag object $xtag: $!\n";
 674
 675                 my $tagobj = <$in>;
 676                 chomp $tagobj;
 677
 678                 if ( !close($in) or waitpid($pid, 0) != $pid or
 679                      $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 680                     die "Cannot create tag object $xtag: $!\n";
 681                 }
 682
 683
 684                 open(C,">$git_dir/refs/tags/$xtag")
 685                         or die "Cannot create tag $xtag: $!\n";
 686                 print C "$tagobj\n"
 687                         or die "Cannot write tag $xtag: $!\n";
 688                 close(C)
 689                         or die "Cannot write tag $xtag: $!\n";
 690
 691                 print "Created tag '$xtag' on '$branch'\n" if $opt_v;
 692         }
 693 };
 694
 695 my $commitcount = 1;
 696 while(<CVS>) {
 697         chomp;
 698         if($state == 0 and /^-+$/) {
 699                 $state = 1;
 700         } elsif($state == 0) {
 701                 $state = 1;
 702                 redo;
 703         } elsif(($state==0 or $state==1) and s/^PatchSet\s+//) {
 704                 $patchset = 0+$_;
 705                 $state=2;
 706         } elsif($state == 2 and s/^Date:\s+//) {
 707                 $date = pdate($_);
 708                 unless($date) {
 709                         print STDERR "Could not parse date: $_\n";
 710                         $state=0;
 711                         next;
 712                 }
 713                 $state=3;
 714         } elsif($state == 3 and s/^Author:\s+//) {
 715                 s/\s+$//;
 716                 if (/^(.*?)\s+<(.*)>/) {
 717                     ($author_name, $author_email) = ($1, $2);
 718                 } elsif ($conv_author_name{$_}) {
 719                         $author_name = $conv_author_name{$_};
 720                         $author_email = $conv_author_email{$_};
 721                 } else {
 722                     $author_name = $author_email = $_;
 723                 }
 724                 $state = 4;
 725         } elsif($state == 4 and s/^Branch:\s+//) {
 726                 s/\s+$//;
 727                 s/[\/]/$opt_s/g;
 728                 $branch = $_;
 729                 $state = 5;
 730         } elsif($state == 5 and s/^Ancestor branch:\s+//) {
 731                 s/\s+$//;
 732                 $ancestor = $_;
 733                 $ancestor = $opt_o if $ancestor eq "HEAD";
 734                 $state = 6;
 735         } elsif($state == 5) {
 736                 $ancestor = undef;
 737                 $state = 6;
 738                 redo;
 739         } elsif($state == 6 and s/^Tag:\s+//) {
 740                 s/\s+$//;
 741                 if($_ eq "(none)") {
 742                         $tag = undef;
 743                 } else {
 744                         $tag = $_;
 745                 }
 746                 $state = 7;
 747         } elsif($state == 7 and /^Log:/) {
 748                 $logmsg = "";
 749                 $state = 8;
 750         } elsif($state == 8 and /^Members:/) {
 751                 $branch = $opt_o if $branch eq "HEAD";
 752                 if(defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 753                         # skip
 754                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 755                         $state = 11;
 756                         next;
 757                 }
 758                 if (exists $ignorebranch{$branch}) {
 759                         print STDERR "Skipping $branch\n";
 760                         $state = 11;
 761                         next;
 762                 }
 763                 if($ancestor) {
 764                         if($ancestor eq $branch) {
 765                                 print STDERR "Branch $branch erroneously stems from itself -- changed ancestor to $opt_o\n";
 766                                 $ancestor = $opt_o;
 767                         }
 768                         if(-f "$git_dir/refs/heads/$branch") {
 769                                 print STDERR "Branch $branch already exists!\n";
 770                                 $state=11;
 771                                 next;
 772                         }
 773                         unless(open(H,"$git_dir/refs/heads/$ancestor")) {
 774                                 print STDERR "Branch $ancestor does not exist!\n";
 775                                 $ignorebranch{$branch} = 1;
 776                                 $state=11;
 777                                 next;
 778                         }
 779                         chomp(my $id = <H>);
 780                         close(H);
 781                         unless(open(H,"> $git_dir/refs/heads/$branch")) {
 782                                 print STDERR "Could not create branch $branch: $!\n";
 783                                 $ignorebranch{$branch} = 1;
 784                                 $state=11;
 785                                 next;
 786                         }
 787                         print H "$id\n"
 788                                 or die "Could not write branch $branch: $!";
 789                         close(H)
 790                                 or die "Could not write branch $branch: $!";
 791                 }
 792                 if(($ancestor || $branch) ne $last_branch) {
 793                         print "Switching from $last_branch to $branch\n" if $opt_v;
 794                         system("git-read-tree", $branch);
 795                         die "read-tree failed: $?\n" if $?;
 796                 }
 797                 $last_branch = $branch if $branch ne $last_branch;
 798                 $state = 9;
 799         } elsif($state == 8) {
 800                 $logmsg .= "$_\n";
 801         } elsif($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 802 #       VERSION:1.96->1.96.2.1
 803                 my $init = ($2 eq "INITIAL");
 804                 my $fn = $1;
 805                 my $rev = $3;
 806                 $fn =~ s#^/+##;
 807                 if ($opt_S && $fn =~ m/$opt_S/) {
 808                     print "SKIPPING $fn v $rev\n";
 809                     push(@skipped, $fn);
 810                     next;
 811                 }
 812                 print "Fetching $fn   v $rev\n" if $opt_v;
 813                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 814                 if($size == -1) {
 815                         push(@old,$fn);
 816                         print "Drop $fn\n" if $opt_v;
 817                 } else {
 818                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 819                         my $pid = open(my $F, '-|');
 820                         die $! unless defined $pid;
 821                         if (!$pid) {
 822                             exec("git-hash-object", "-w", $tmpname)
 823                                 or die "Cannot create object: $!\n";
 824                         }
 825                         my $sha = <$F>;
 826                         chomp $sha;
 827                         close $F;
 828                         my $mode = pmode($cvs->{'mode'});
 829                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 830                 }
 831                 unlink($tmpname);
 832         } elsif($state == 9 and /^\s+(.+?):\d+(?:\.\d+)+->(\d+(?:\.\d+)+)\(DEAD\)\s*$/) {
 833                 my $fn = $1;
 834                 $fn =~ s#^/+##;
 835                 push(@old,$fn);
 836                 print "Delete $fn\n" if $opt_v;
 837         } elsif($state == 9 and /^\s*$/) {
 838                 $state = 10;
 839         } elsif(($state == 9 or $state == 10) and /^-+$/) {
 840                 $commitcount++;
 841                 if ($opt_L && $commitcount > $opt_L) {
 842                         last;
 843                 }
 844                 commit();
 845                 if (($commitcount & 1023) == 0) {
 846                         system("git repack -a -d");
 847                 }
 848                 $state = 1;
 849         } elsif($state == 11 and /^-+$/) {
 850                 $state = 1;
 851         } elsif(/^-+$/) { # end of unknown-line processing
 852                 $state = 1;
 853         } elsif($state != 11) { # ignore stuff when skipping
 854                 print "* UNKNOWN LINE * $_\n";
 855         }
 856 }
 857 commit() if $branch and $state != 11;
 858
 859 unlink($git_index);
 860
 861 if (defined $orig_git_index) {
 862         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 863 } else {
 864         delete $ENV{GIT_INDEX_FILE};
 865 }
 866
 867 # Now switch back to the branch we were in before all of this happened
 868 if($orig_branch) {
 869         print "DONE.\n" if $opt_v;
 870         if ($opt_i) {
 871                 exit 0;
 872         }
 873         my $tip_at_end = `git-rev-parse --verify HEAD`;
 874         if ($tip_at_start ne $tip_at_end) {
 875                 for ($tip_at_start, $tip_at_end) { chomp; }
 876                 print "Fetched into the current branch.\n" if $opt_v;
 877                 system(qw(git-read-tree -u -m),
 878                        $tip_at_start, $tip_at_end);
 879                 die "Fast-forward update failed: $?\n" if $?;
 880         }
 881         else {
 882                 system(qw(git-merge cvsimport HEAD), "refs/heads/$opt_o");
 883                 die "Could not merge $opt_o into the current branch.\n" if $?;
 884         }
 885 } else {
 886         $orig_branch = "master";
 887         print "DONE; creating $orig_branch branch\n" if $opt_v;
 888         system("git-update-ref", "refs/heads/master", "refs/heads/$opt_o")
 889                 unless -f "$git_dir/refs/heads/master";
 890         system('git-update-ref', 'HEAD', "$orig_branch");
 891         unless ($opt_i) {
 892                 system('git checkout');
 893                 die "checkout failed: $?\n" if $?;
 894         }
 895 }