configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3.1])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.3001
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which version the library is compatible with
  23 dnl we must keep a separate library version cout of the format c:r:a if any
  24 dnl if only implementation changed but all interfaces are kept, do r++
  25 dnl when only functionality was added do c++,r=0,a++
  26 dnl if any functionality was removed do c++,r=0,a=0.
  27 dnl
  28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  29 dnl
  30 LIBVERS=4:0:0
  31 AC_SUBST(LIBVERS)
  32
  33 AC_CANONICAL_TARGET
  34 AM_INIT_AUTOMAKE
  35 AM_MAINTAINER_MODE
  36
  37 AC_CONFIG_HEADERS([rrd_config.h])
  38
  39 dnl all our local stuff like install scripts and include files
  40 dnl is in there
  41
  42
  43 dnl determine the type of system we are running on
  44
  45 AC_SUBST(VERSION)
  46
  47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  48
  49 dnl Minimum Autoconf version required.
  50 AC_PREREQ(2.59)
  51
  52 dnl At the TOP of the HEADER
  53
  54 AH_TOP([
  55
  56 #ifndef RRD_CONFIG_H
  57 #define RRD_CONFIG_H
  58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  59 #undef MUST_DISABLE_FPMASK
  60
  61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  62
  63 #undef MUST_DISABLE_SIGFPE
  64
  65 /* realloc does not support NULL as argument */
  66 #undef NO_NULL_REALLOC
  67
  68 /* lets enable madvise defines in NetBSD */
  69 #if defined(__NetBSD__)
  70 # if !defined(_NETBSD_SOURCE)
  71 #  define _NETBSD_SOURCE
  72 # endif
  73 #endif
  74
  75  ])
  76
  77 AH_BOTTOM([
  78 /* make sure that we pickup the correct stuff from all headers */
  79 #ifdef HAVE_FEATURES_H
  80 #undef _XOPEN_SOURCE /* keep unmodified */
  81 #undef _BSD_SOURCE /* keep unmodified */
  82 #define _XOPEN_SOURCE 600
  83 #define _BSD_SOURCE 1
  84 # include <features.h>
  85 #endif
  86
  87 /* FreeBSD 4.8 wants this included BEFORE sys/types.h */
  88 #ifdef HAVE_SYS_MMAN_H
  89 # include <sys/mman.h>
  90 #endif
  91
  92 #ifdef HAVE_SYS_TYPES_H
  93 # include <sys/types.h>
  94 #endif
  95
  96 #ifdef HAVE_SYS_PARAM_H
  97 # include <sys/param.h>
  98 #endif
  99 #ifndef MAXPATH
 100 # ifdef PATH_MAX
 101 #  define MAXPATH PATH_MAX
 102 # endif
 103 #endif
 104 #ifndef MAXPATH
 105 /* else try the BSD variant */
 106 # ifdef MAXPATHLEN
 107 #  define MAXPATH MAXPATHLEN
 108 # endif
 109 #endif
 110
 111 #ifdef HAVE_ERRNO_H
 112 # include <errno.h>
 113 #endif
 114
 115 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
 116 /* use posix_madvise family */
 117 # define madvise posix_madvise
 118 # define MADV_NORMAL POSIX_MADV_NORMAL
 119 # define MADV_RANDOM POSIX_MADV_RANDOM
 120 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
 121 # define MADV_WILLNEED POSIX_MADV_WILLNEED
 122 # define MADV_DONTNEED POSIX_MADV_DONTNEED
 123 #endif
 124 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
 125 # define USE_MADVISE 1
 126 #endif
 127
 128 #ifdef HAVE_SYS_STAT_H
 129 # include <sys/stat.h>
 130 #endif
 131
 132 #ifdef HAVE_FCNTL_H
 133 #include <fcntl.h>
 134 #endif
 135
 136 #ifdef HAVE_UNISTD_H
 137 # include <unistd.h>
 138 #endif
 139
 140 #ifdef TIME_WITH_SYS_TIME
 141 # include <sys/time.h>
 142 # include <time.h>
 143 #else
 144 # ifdef HAVE_SYS_TIME_H
 145 #  include <sys/time.h>
 146 # else
 147 #  include <time.h>
 148 # endif
 149 #endif
 150
 151 #ifdef HAVE_SYS_TIMES_H
 152 # include <sys/times.h>
 153 #endif
 154
 155 #ifdef HAVE_SYS_RESOURCE_H
 156 # include <sys/resource.h>
 157 #if (defined(__svr4__) && defined(__sun__))
 158 /* Solaris headers (pre 2.6) do not have a getrusage prototype.
 159    Use this instead. */
 160 extern int getrusage(int, struct rusage *);
 161 #endif /* __svr4__ && __sun__ */
 162 #endif
 163
 164
 165 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 166    make sure you are NOT using bcopy, index or rindex in the code */
 167
 168 #ifdef STDC_HEADERS
 169 # include <string.h>
 170 #else
 171 # ifndef HAVE_STRCHR
 172 #  define strchr index
 173 #  define strrchr rindex
 174 # endif
 175 char *strchr (), *strrchr ();
 176 # ifndef HAVE_MEMMOVE
 177 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 178 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 179 # endif
 180 #endif
 181
 182 #ifdef NO_NULL_REALLOC
 183 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 184 #else
 185 # define rrd_realloc(a,b) realloc((a), (b))
 186 #endif
 187
 188 #ifdef NEED_MALLOC_MALLOC_H
 189 #  include <malloc/malloc.h>
 190 #endif
 191
 192 #ifdef HAVE_STDIO_H
 193 # include <stdio.h>
 194 #endif
 195
 196 #ifdef HAVE_STDLIB_H
 197 # include <stdlib.h>
 198 #endif
 199
 200 #ifdef HAVE_CTYPE_H
 201 # include <ctype.h>
 202 #endif
 203
 204 #ifdef HAVE_DIRENT_H
 205 # include <dirent.h>
 206 # define NAMLEN(dirent) strlen((dirent)->d_name)
 207 #else
 208 # define dirent direct
 209 # define NAMLEN(dirent) (dirent)->d_namlen
 210 # ifdef HAVE_SYS_NDIR_H
 211 #  include <sys/ndir.h>
 212 # endif
 213 # ifdef HAVE_SYS_DIR_H
 214 #  include <sys/dir.h>
 215 # endif
 216 # ifdef HAVE_NDIR_H
 217 #  include <ndir.h>
 218 # endif
 219 #endif
 220
 221 #ifdef MUST_DISABLE_SIGFPE
 222 # include <signal.h>
 223 #endif
 224
 225 #ifdef MUST_DISABLE_FPMASK
 226 # include <floatingpoint.h>
 227 #endif
 228
 229
 230 #ifdef HAVE_MATH_H
 231 # include <math.h>
 232 #endif
 233
 234 #ifdef HAVE_FLOAT_H
 235 # include <float.h>
 236 #endif
 237
 238 #ifdef HAVE_IEEEFP_H
 239 # include <ieeefp.h>
 240 #endif
 241
 242 #ifdef HAVE_FP_CLASS_H
 243 # include <fp_class.h>
 244 #endif
 245
 246 /* for Solaris */
 247 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 248 #  define HAVE_ISINF 1
 249 #  ifdef isinf
 250 #  undef isinf /* confuse autoconf */
 251 #  endif
 252 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 253 #endif
 254
 255 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 256 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 257 #  undef isnan /* confuse autoconf to NOT remove this */
 258 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 259 #endif
 260
 261 /* for OSF1 Digital Unix */
 262 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 263 #  define HAVE_ISINF 1
 264 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 265 #endif
 266
 267 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 268 #  define HAVE_ISINF 1
 269 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 270 #endif
 271
 272 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 273 #  define HAVE_ISINF 1
 274 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 275 #endif
 276
 277 /* for AIX */
 278 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 279 #  define HAVE_ISINF 1
 280 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 281 #endif
 282
 283 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 284 #  define HAVE_FINITE 1
 285 #  define finite(a) isfinite(a)
 286 #endif
 287
 288 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 289 #  define HAVE_FINITE 1
 290 #  define finite(a) (! isnan(a) && ! isinf(a))
 291 #endif
 292
 293 #ifndef HAVE_FINITE
 294 #error "Can't compile without finite function"
 295 #endif
 296
 297 #ifndef HAVE_ISINF
 298 #error "Can't compile without isinf function"
 299 #endif
 300
 301 #if (! defined(HAVE_FDATASYNC) && defined(HAVE_FSYNC))
 302 #define fdatasync fsync
 303 #endif
 304
 305 #if (!defined(HAVE_FDATASYNC) && !defined(HAVE_FSYNC))
 306 #error "Can't compile with without fsync and fdatasync"
 307 #endif
 308
 309 #endif /* RRD_CONFIG_H */
 310 ])
 311
 312 dnl Process Special Options
 313 dnl -----------------------------------
 314
 315 dnl How the vertical axis label is printed
 316 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 317  [Vertical label angle: -90.0 (default) or 90.0])
 318 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 319  [Vertical label angle: -90.0 (default) or 90.0])
 320
 321 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 322 [],[enable_rrdcgi=yes])
 323
 324 dnl Check if we run on a system that has fonts
 325 AC_ARG_WITH(rrd-default-font,
 326 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 327 [RRD_DEFAULT_FONT=$withval],[
 328   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 329         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 330   else
 331         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 332   fi
 333 ])
 334
 335 dnl Use mmap in rrd_update instead of seek+write
 336 AC_ARG_ENABLE([mmap],
 337 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 338 [],
 339 [enable_mmap=yes])
 340
 341 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 342 [],[enable_pthread=yes])
 343
 344 AC_ARG_ENABLE(static-programs,
 345      [  --enable-static-programs  Build static programs],
 346      [case "${enableval}" in
 347        yes) staticprogs=yes ;;
 348        no)  staticprogs=no ;;
 349        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 350      esac],[staticprogs=no])
 351 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 352
 353
 354 CONFIGURE_PART(Audit Compilation Environment)
 355
 356
 357 dnl Check for the compiler and static/shared library creation.
 358 AC_PROG_CPP
 359 AC_PROG_CC
 360 AM_PROG_CC_C_O
 361 AC_PROG_LIBTOOL
 362
 363 dnl Try to detect/use GNU features
 364 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 365
 366 dnl which flags does the compiler support?
 367 if test "x$GCC" = "xyes"; then
 368   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 369     oCFLAGS="$CFLAGS"
 370     CFLAGS="$CFLAGS $flag"
 371     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 372     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 373        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 374     if eval test \$$cachename = no; then
 375          CFLAGS="$oCFLAGS"
 376     fi
 377   done
 378 fi
 379
 380
 381
 382 AC_SUBST(RRD_DEFAULT_FONT)
 383
 384 CONFIGURE_PART(Checking for Header Files)
 385
 386 dnl Checks for header files.
 387 AC_HEADER_STDC
 388 AC_HEADER_DIRENT
 389 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 390
 391 dnl Checks for typedefs, structures, and compiler characteristics.
 392 AC_C_CONST
 393 AC_HEADER_TIME
 394 AC_STRUCT_TM
 395
 396 CONFIGURE_PART(Test Library Functions)
 397
 398 dnl Checks for libraries.
 399 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 400
 401
 402
 403 dnl add pic flag in any case this makes sure all our code is relocatable
 404 eval `./libtool --config | grep pic_flag`
 405 CFLAGS="$CFLAGS $pic_flag"
 406
 407
 408 dnl Checks for library functions.
 409 AC_FUNC_STRFTIME
 410 AC_FUNC_VPRINTF
 411
 412 AC_C_BIGENDIAN
 413
 414 dnl for each function found we get a definition in config.h
 415 dnl of the form HAVE_FUNCTION
 416
 417 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 418
 419 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 420
 421 dnl Could use these to know if we need to provide a prototype
 422 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 423
 424 dnl check for fdatasync. Solaris has fdatasync in the librt
 425
 426 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 427 dnl if there is no fdatasync we may get lucky with fsync
 428 AC_CHECK_FUNCS(fsync)
 429
 430
 431 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 432 if test "x$enable_mmap" = "xyes"; then
 433   case "$host" in
 434   *cygwin*)
 435     # the normal mmap test does not work in cygwin
 436     AC_CHECK_FUNCS(mmap)
 437     if test "x$ac_cv_func_mmap" = "xyes"; then
 438       ac_cv_func_mmap_fixed_mapped=yes
 439     fi
 440   ;;
 441   *)
 442     AC_CHECK_HEADERS(sys/mman.h)
 443     AC_FUNC_MMAP
 444     AC_CHECK_FUNCS(mmap munmap msync)
 445     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 446                                      # include <sys/mman.h>
 447                                      #endif])
 448     if test "x$ac_cv_have_decl_madvise" = "xyes";
 449     then
 450       AC_CHECK_FUNCS(madvise)
 451     else
 452       AC_CHECK_FUNCS(posix_madvise)
 453       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 454         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 455       fi
 456     fi
 457   ;;
 458   esac
 459   if test "x$ac_cv_func_mmap" != "xyes";
 460   then
 461     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 462 dnl enable_mmap="no"
 463   fi
 464 fi
 465
 466 dnl can we use posix_fadvise
 467 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 468 #include <fcntl.h>])
 469 AC_CHECK_FUNCS(posix_fadvise)
 470
 471 CONFIGURE_PART(Libintl Processing)
 472
 473
 474 dnl gettext
 475 GETTEXT_PACKAGE=rrdtool
 476 AC_SUBST(GETTEXT_PACKAGE)
 477 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 478
 479 AM_GLIB_GNU_GETTEXT()
 480
 481 AC_ARG_ENABLE(libintl,[  --disable-libintl        i18n support (libintl)],
 482 [],[enable_libintl=yes])
 483
 484 if test x$enable_libintl = xyes; then
 485   IT_PROG_INTLTOOL([0.35.0],[no-xml])
 486 fi
 487
 488 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
 489   AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
 490   enable_libintl=no
 491 fi
 492
 493 if test x$enable_libintl = xyes; then
 494   AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
 495 fi
 496
 497 if test x$enable_libintl = xyes ; then
 498   dnl it seems bsd synstems need to link against libintl
 499   dnl when compiling rrdupdate. lets check
 500   AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
 501 fi
 502
 503 dnl use for linking rrdupdate
 504 AC_SUBST(LIB_LIBINTL)
 505
 506 dnl do not touch the po stuff if we are not going to build intl
 507 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
 508
 509 if test x$enable_libintl = xyes; then
 510    AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
 511 fi
 512
 513 CONFIGURE_PART(IEEE Math Checks)
 514
 515
 516 dnl actual code to check if this works
 517 AC_CHECK_FUNCS(fpclassify, ,
 518   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 519     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 520 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 521       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 522
 523 AC_CHECK_FUNCS(isinf, ,
 524   [AC_MSG_CHECKING(for isinf with <math.h>)
 525     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 526 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 527       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 528
 529 dnl finite is BSD, isfinite is C99, so prefer the latter
 530 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 531 AC_TRY_RUN([
 532 #ifdef HAVE_MATH_H
 533 #include <math.h>
 534 #endif
 535 #ifdef HAVE_FLOAT_H
 536 #include <float.h>
 537 #endif
 538 int main ()
 539 {
 540 #ifdef isfinite
 541 #ifdef LDBL_MAX
 542   if (!isfinite(LDBL_MAX)) return 1;
 543 #endif
 544 #ifdef DBL_MAX
 545   if (!isfinite(DBL_MAX)) return 1;
 546 #endif
 547 #endif
 548 return 0;
 549 }],[
 550 have_broken_isfinite=no],have_broken_isfinite=yes,[
 551 case "${target}" in
 552   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 553   sparc-sun-solaris2.8) have_broken_isfinite=yes ;;
 554   *) have_broken_isfinite=no ;;
 555 esac])
 556 ])
 557 if test "x$have_broken_isfinite" = "xno"; then
 558   AC_DEFINE(HAVE_ISFINITE)
 559 else
 560 AC_CHECK_FUNCS(finite,[],
 561   [AC_CHECK_FUNCS(isfinite,[],
 562       [AC_MSG_CHECKING(for isfinite with <math.h>)
 563        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 564 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 565                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 566 fi
 567
 568 AC_FULL_IEEE
 569
 570 CONFIGURE_PART(Resolve Portability Issues)
 571
 572 dnl what does realloc do if it gets called with a NULL pointer
 573
 574 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 575 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 576               int main(void){
 577               char *x = NULL;
 578               x = realloc (x,10);
 579               if (x==NULL) return 1;
 580               return 0;
 581              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 582
 583 if test x"$rd_cv_null_realloc" = xnope; then
 584 AC_DEFINE(NO_NULL_REALLOC)
 585 fi
 586
 587 AC_LANG_PUSH(C)
 588 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 589 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 590 AC_LINK_IFELSE(
 591     AC_LANG_PROGRAM(
 592            [[#include <time.h>]],
 593            [[ctime_r(NULL,NULL,0)]]
 594                    ),
 595     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 596       AC_LINK_IFELSE(
 597           AC_LANG_PROGRAM(
 598                 [[#include <time.h>]],
 599                 [[ctime_r(NULL,NULL)]]
 600                          ),
 601           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 602           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 603       )
 604     ],
 605     [ AC_LINK_IFELSE(
 606           AC_LANG_PROGRAM(
 607                 [[#include <time.h>]],
 608                 [[ctime_r(NULL,NULL)]]
 609                          ),
 610           [AC_MSG_RESULT(no)],
 611           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 612       )
 613     ]
 614 )
 615 AC_LANG_POP(C)
 616
 617 dnl Check for pthreads
 618 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 619
 620 AC_SUBST(MULTITHREAD_CFLAGS)
 621 AC_SUBST(MULTITHREAD_LDFLAGS)
 622
 623 if test $enable_pthread != no; then
 624  ACX_PTHREAD([
 625     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 626     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 627              ],
 628              [])
 629 fi
 630
 631 dnl since we use lots of *_r functions all over the code we better
 632 dnl make sure they are known
 633
 634 if test  "x$x_rflag" != "xno"; then
 635    CPPFLAGS="$CPPFLAGS $x_rflag"
 636 fi
 637
 638 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 639
 640 AC_LANG_PUSH(C)
 641 dnl see if we have to include malloc/malloc.h
 642 AC_MSG_CHECKING([do we need malloc/malloc.h])
 643 AC_LINK_IFELSE(
 644     AC_LANG_PROGRAM(
 645            [[#include <stdlib.h>]],
 646            [[malloc(1)]]
 647                    ),
 648     [ AC_MSG_RESULT([nope, works out of the box]) ],
 649     [ AC_LINK_IFELSE(
 650           AC_LANG_PROGRAM(
 651                 [[#include <stdlib.h>
 652                   #include <malloc/malloc.h>]],
 653                 [[malloc(1)]]
 654                          ),
 655           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 656            AC_MSG_RESULT([yes we do])],
 657           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 658       )
 659     ]
 660 )
 661 AC_LANG_POP(C)
 662
 663 CONFIGURE_PART(Find 3rd-Party Libraries)
 664
 665
 666 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 667
 668
 669 CORE_LIBS="$LIBS"
 670
 671 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 672 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 673 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 674 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 675 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 676 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 677 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 678 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 679 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 680 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 681 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 682
 683 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 684   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 685 fi
 686
 687 ALL_LIBS="$LIBS"
 688 LIBS=
 689
 690 AC_SUBST(CORE_LIBS)
 691 AC_SUBST(ALL_LIBS)
 692
 693 CONFIGURE_PART(Prep for Building Language Bindings)
 694
 695 dnl Check for Perl and friends
 696 PATH=$PATH:/usr/perl5/bin
 697 export PATH
 698 AC_PATH_PROG(PERL, perl, no)
 699 AC_PATH_PROG(POD2MAN, pod2man, no)
 700 AC_PATH_PROG(POD2HTML, pod2html, no)
 701
 702
 703 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 704 [],[enable_perl=yes])
 705
 706
 707 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 708 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 709 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 710 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 711
 712 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 713         COMP_PERL=
 714 else
 715         COMP_PERL="perl_piped perl_shared"
 716         AC_MSG_CHECKING(for the perl version you are running)
 717         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 718         AC_MSG_RESULT($PERL_VERSION)
 719         if test -z "$PERLCC"; then
 720             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 721             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 722             AC_MSG_RESULT($perlcc)
 723             if test ! -x "$perlcc"; then
 724                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 725                 if test "$PERL_CC" = "no"; then
 726                     AC_MSG_WARN([
 727 I would not find the Compiler ($perlcc) that was originally used to compile
 728 your perl binary. You should either make sure that this compiler is
 729 available on your system, pick an other compiler and set PERLCC
 730 appropriately, or use a different perl setup that was compiled locally.
 731
 732 I will disable the compilation of the RRDs perl module for now.
 733 ])
 734                     COMP_PERL="perl_piped"
 735                 fi
 736             fi
 737         fi
 738 fi
 739
 740 AC_MSG_CHECKING(Perl Modules to build)
 741 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 742
 743 # Options to pass when configuring perl module
 744 ppref=$prefix
 745 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 746
 747 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 748
 749 dnl pass additional perl options when generating Makefile from Makefile.PL
 750 AC_ARG_ENABLE(perl-site-install,
 751 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 752                           together with rrdtool in $prefix/lib/perl. You have to
 753                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 754                           when you want to use them. When you set this option
 755                           the perl modules will get installed wherever
 756                           your perl setup thinks it is best.],
 757 [PERL_MAKE_OPTIONS=],[])
 758
 759 if test ! -z "$PERLCC"; then
 760    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 761
 762    if test ! -z "$PERLCCFLAGS"; then
 763        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 764    fi
 765
 766    if test -z "$PERLLD"; then
 767        PERLLD=$PERLCC
 768    fi
 769    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 770
 771    if test ! -z "$PERLLDFLAGS"; then
 772        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 773    fi
 774 fi
 775
 776 AC_ARG_WITH(perl-options,
 777 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 778                           generating Makefile from Makefile.PL. If you set this
 779                           option, interesting things may happen unless you know
 780                           what you are doing!],
 781 [PERL_MAKE_OPTIONS=$withval])
 782
 783 AC_SUBST(PERL_MAKE_OPTIONS)
 784 AC_SUBST(PERL)
 785 AC_SUBST(COMP_PERL)
 786 AC_SUBST(PERL_VERSION)
 787
 788 dnl Check for Ruby.
 789 AC_PATH_PROG(RUBY, ruby, no)
 790
 791 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 792 [],[enable_ruby=yes])
 793
 794 AC_MSG_CHECKING(if ruby modules can be built)
 795
 796 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 797         COMP_RUBY=
 798         AC_MSG_RESULT(No .. Ruby not found or disabled)
 799 else
 800         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 801                 COMP_RUBY="ruby"
 802                 AC_MSG_RESULT(YES)
 803         else
 804                 COMP_RUBY=
 805                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 806         fi
 807 fi
 808
 809
 810 dnl pass additional ruby options when generating Makefile from Makefile.PL
 811 AC_ARG_ENABLE(ruby-site-install,
 812 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 813                           together with rrdtool in $prefix/lib/ruby. You have to
 814                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 815                           for ruby to find the RRD.so file.],
 816 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$prefix/lib/ruby"])
 817
 818
 819 AC_ARG_WITH(ruby-options,
 820 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 821                           generating Makefile from extconf.rb. If you set this
 822                           option, interesting things may happen unless you know
 823                           what you are doing!],
 824 [RUBY_MAKE_OPTIONS=$withval])
 825
 826 AC_SUBST(RUBY_MAKE_OPTIONS)
 827 AC_SUBST(RUBY)
 828 AC_SUBST(COMP_RUBY)
 829
 830
 831 enable_tcl_site=no
 832
 833 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 834 [],[enable_tcl=yes])
 835
 836 if test  "$enable_tcl" = "yes"; then
 837   dnl Check for Tcl.
 838   withval=""
 839   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 840   enable_tcl=no
 841   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 842     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 843     if test -f "$dir/tclConfig.sh" ; then
 844         tcl_config=$dir/tclConfig.sh
 845         enable_tcl=yes
 846         AC_MSG_RESULT(yes)
 847         break
 848     else
 849         AC_MSG_RESULT(no)
 850     fi
 851   done
 852
 853   if test "$enable_tcl" = "no"; then
 854         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 855   else
 856         . $tcl_config
 857         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 858         if test -n "$TCL_INC_DIR"; then
 859           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 860         fi
 861   fi
 862   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 863   [],[enable_tcl_site=yes])
 864
 865 fi
 866
 867 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 868 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 869
 870
 871 AC_SUBST(TCL_PREFIX)
 872 AC_SUBST(TCL_SHLIB_CFLAGS)
 873 AC_SUBST(TCL_SHLIB_LD)
 874 AC_SUBST(TCL_SHLIB_SUFFIX)
 875 AC_SUBST(TCL_PACKAGE_PATH)
 876 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 877 AC_SUBST(TCL_STUB_LIB_SPEC)
 878 AC_SUBST(TCL_VERSION)
 879 AC_SUBST(TCL_PACKAGE_DIR)
 880 AC_SUBST(TCL_INCLUDE_SPEC)
 881
 882 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 883 [],[enable_python=yes])
 884
 885 if test  "$enable_python" = "yes"; then
 886 dnl Check for python
 887 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 888 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 889 fi
 890
 891 if test  x$enable_python = xno; then
 892         COMP_PYTHON=
 893 else
 894         COMP_PYTHON="python"
 895 fi
 896
 897 AC_SUBST(COMP_PYTHON)
 898
 899 dnl Check for nroff
 900 AC_PATH_PROGS(NROFF, gnroff nroff)
 901 AC_PATH_PROGS(TROFF, groff troff)
 902
 903 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 904 if test -z "$RRDDOCDIR"; then
 905    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 906
 907
 908 CONFIGURE_PART(Apply Configuration Information)
 909
 910 AC_CONFIG_FILES([examples/shared-demo.pl])
 911 AC_CONFIG_FILES([examples/piped-demo.pl])
 912 AC_CONFIG_FILES([examples/stripes.pl])
 913 AC_CONFIG_FILES([examples/bigtops.pl])
 914 AC_CONFIG_FILES([examples/minmax.pl])
 915 AC_CONFIG_FILES([examples/4charts.pl])
 916 AC_CONFIG_FILES([examples/perftest.pl])
 917 AC_CONFIG_FILES([examples/Makefile])
 918 AC_CONFIG_FILES([doc/Makefile])
 919 AC_CONFIG_FILES([po/Makefile.in])
 920 AC_CONFIG_FILES([src/Makefile])
 921 AC_CONFIG_FILES([bindings/Makefile])
 922 AC_CONFIG_FILES([bindings/tcl/Makefile])
 923 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 924 AC_CONFIG_FILES([Makefile])
 925
 926 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 927 AC_OUTPUT
 928
 929 AC_MSG_CHECKING(in)
 930 AC_MSG_RESULT(and out again)
 931
 932 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 933 sleep 1
 934 echo $ECHO_N ".$ECHO_C" 1>&6
 935 sleep 1
 936 echo $ECHO_N ".$ECHO_C" 1>&6
 937 sleep 1
 938 echo $ECHO_N ".$ECHO_C" 1>&6
 939 sleep 1
 940 echo $ECHO_N ".$ECHO_C" 1>&6
 941 sleep 1
 942 AC_MSG_RESULT([ just kidding ;-)])
 943 echo
 944 echo "----------------------------------------------------------------"
 945 echo "Config is DONE!"
 946 echo
 947 echo "          With MMAP IO: $enable_mmap"
 948 echo "       Static programs: $staticprogs"
 949 echo "          Perl Modules: $COMP_PERL"
 950 echo "           Perl Binary: $PERL"
 951 echo "          Perl Version: $PERL_VERSION"
 952 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 953 echo "          Ruby Modules: $COMP_RUBY"
 954 echo "           Ruby Binary: $RUBY"
 955 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 956 echo "    Build Tcl Bindings: $enable_tcl"
 957 echo " Build Python Bindings: $enable_python"
 958 echo "          Build rrdcgi: $enable_rrdcgi"
 959 echo "       Build librrd MT: $enable_pthread"
 960 echo "     Link with libintl: $enable_libintl"
 961 echo
 962 echo "             Libraries: $ALL_LIBS"
 963 echo
 964 echo "Type 'make' to compile the software and use 'make install' to "
 965 echo "install everything to: $prefix."
 966 echo
 967 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 968 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 969 echo "place an order."
 970 echo
 971 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 972 echo "----------------------------------------------------------------"