configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.11])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devl versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.2011
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29
  30 AC_SUBST(VERSION)
  31
  32 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  33
  34 dnl Minimum Autoconf version required.
  35 AC_PREREQ(2.59)
  36
  37 dnl At the TOP of the HEADER
  38
  39 AH_TOP([
  40
  41 #ifndef CONFIG_H
  42 #define CONFIG_H
  43 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  44 #undef MUST_DISABLE_FPMASK
  45
  46 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  47
  48 #undef MUST_DISABLE_SIGFPE
  49
  50 /* realloc does not support NULL as argument */
  51 #undef NO_NULL_REALLOC
  52
  53  ])
  54
  55 AH_BOTTOM([
  56
  57 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  58    make sure you are NOT using bcopy, index or rindex in the code */
  59
  60 #if STDC_HEADERS
  61 # include <string.h>
  62 #else
  63 # ifndef HAVE_STRCHR
  64 #  define strchr index
  65 #  define strrchr rindex
  66 # endif
  67 char *strchr (), *strrchr ();
  68 # ifndef HAVE_MEMMOVE
  69 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  70 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  71 # endif
  72 #endif
  73
  74
  75 #if NO_NULL_REALLOC
  76 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  77 #else
  78 # define rrd_realloc(a,b) realloc((a), (b))
  79 #endif
  80
  81 #if NEED_MALLOC_MALLOC_H
  82 #  include <malloc/malloc.h>
  83 #endif
  84
  85 #if HAVE_MATH_H
  86 #  include <math.h>
  87 #endif
  88
  89 #if HAVE_FLOAT_H
  90 #  include <float.h>
  91 #endif
  92
  93 #if HAVE_IEEEFP_H
  94 #  include <ieeefp.h>
  95 #endif
  96
  97 #if HAVE_FP_CLASS_H
  98 #  include <fp_class.h>
  99 #endif
 100
 101 /* for Solaris */
 102 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 103 #  define HAVE_ISINF 1
 104 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 105 #endif
 106
 107 /* for OSF1 Digital Unix */
 108 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 109 #  define HAVE_ISINF 1
 110 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 111 #endif
 112
 113 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 114 #  define HAVE_ISINF 1
 115 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 116 #endif
 117
 118 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 119 #  define HAVE_ISINF 1
 120 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 121 #endif
 122
 123 /* for AIX */
 124 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 125 #  define HAVE_ISINF 1
 126 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 127 #endif
 128
 129 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 130 #  define HAVE_FINITE 1
 131 #  define finite(a) isfinite(a)
 132 #endif
 133
 134 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 135 #  define HAVE_FINITE 1
 136 #  define finite(a) (! isnan(a) && ! isinf(a))
 137 #endif
 138
 139 #ifndef HAVE_FINITE
 140 #error "Can't compile without finite function"
 141 #endif
 142
 143 #ifndef HAVE_ISINF
 144 #error "Can't compile without isinf function"
 145 #endif
 146
 147 #endif /* CONFIG_H */
 148 ])
 149
 150 dnl Process Special Options
 151 dnl -----------------------------------
 152
 153 dnl How the vertical axis label is printed
 154 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 155  [Vertical label angle: 90.0 (default) or 270.0])
 156 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 157  [Vertical label angle: 90.0 (default) or 270.0])
 158
 159 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 160 [],[enable_rrdcgi=yes])
 161
 162 dnl Check if we run on a system that has fonts
 163 AC_ARG_WITH(rrd-default-font,
 164 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 165 [RRD_DEFAULT_FONT=$withval],[
 166   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 167         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 168   else
 169         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 170   fi
 171 ])
 172
 173 dnl Use mmap in rrd_update instead of seek+write
 174 AC_ARG_ENABLE([mmap],
 175 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 176 [],
 177 [enable_mmap=yes])
 178
 179
 180  AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 181 [],[enable_pthread=yes])
 182
 183
 184
 185 CONFIGURE_PART(Audit Compilation Environment)
 186
 187
 188 dnl Check for the compiler and static/shared library creation.
 189 AC_PROG_CC
 190 AC_PROG_CPP
 191 AC_PROG_LIBTOOL
 192
 193
 194 AC_SUBST(RRD_DEFAULT_FONT)
 195
 196 CONFIGURE_PART(Checking for Header Files)
 197
 198 dnl Checks for header files.
 199 AC_HEADER_STDC
 200 AC_HEADER_DIRENT
 201 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 202
 203 dnl Checks for typedefs, structures, and compiler characteristics.
 204 AC_C_CONST
 205 AC_HEADER_TIME
 206 AC_STRUCT_TM
 207
 208 dnl Checks for libraries.
 209 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 210
 211 dnl add pic flag in any case this makes sure all our code is relocatable
 212 eval `./libtool --config | grep pic_flag`
 213 CFLAGS="$CFLAGS $pic_flag"
 214
 215 CONFIGURE_PART(Test Library Functions)
 216
 217 dnl Checks for library functions.
 218 AC_FUNC_STRFTIME
 219 AC_FUNC_VPRINTF
 220
 221 AC_C_BIGENDIAN
 222
 223 dnl for each function found we get a definition in config.h
 224 dnl of the form HAVE_FUNCTION
 225
 226 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 227
 228
 229 if test "x$enable_mmap" = xyes; then
 230   AC_FUNC_MMAP
 231 fi
 232
 233
 234 CONFIGURE_PART(IEEE Math Checks)
 235
 236 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 237 dnl actual code to check if this works
 238 AC_CHECK_FUNCS(fpclassify, ,
 239   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 240     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 241 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 242       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 243 AC_CHECK_FUNCS(finite, ,
 244   [AC_CHECK_FUNCS(isfinite, ,
 245     [AC_MSG_CHECKING(for isfinite with <math.h>)
 246     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 247 volatile int x;volatile float f;  ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 248       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 249 AC_CHECK_FUNCS(isinf, ,
 250   [AC_MSG_CHECKING(for isinf with <math.h>)
 251     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 252 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 253       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 254
 255 AC_FULL_IEEE
 256
 257 CONFIGURE_PART(Resolve Portability Issues)
 258
 259 dnl what does realloc do if it gets called with a NULL pointer
 260
 261 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 262 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 263               int main(void){
 264               char *x = NULL;
 265               x = realloc (x,10);
 266               if (x==NULL) return 1;
 267               return 0;
 268              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 269
 270 if test x"$rd_cv_null_realloc" = xnope; then
 271 AC_DEFINE(NO_NULL_REALLOC)
 272 fi
 273
 274 AC_LANG_PUSH(C)
 275 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 276 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 277 AC_LINK_IFELSE(
 278     AC_LANG_PROGRAM(
 279            [[#include <time.h>]],
 280            [[ctime_r(NULL,NULL,0)]]
 281                    ),
 282     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 283       AC_LINK_IFELSE(
 284           AC_LANG_PROGRAM(
 285                 [[#include <time.h>]],
 286                 [[ctime_r(NULL,NULL)]]
 287                          ),
 288           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 289           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 290       )
 291     ],
 292     [ AC_LINK_IFELSE(
 293           AC_LANG_PROGRAM(
 294                 [[#include <time.h>]],
 295                 [[ctime_r(NULL,NULL)]]
 296                          ),
 297           [AC_MSG_RESULT(no)],
 298           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 299       )
 300     ]
 301 )
 302 AC_LANG_POP(C)
 303
 304 dnl Check for pthreads
 305 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 306
 307 AC_SUBST(MULTITHREAD_CFLAGS)
 308 AC_SUBST(MULTITHREAD_LDFLAGS)
 309
 310 if test $enable_pthread != no; then
 311  ACX_PTHREAD([
 312     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 313     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 314              ],
 315              [])
 316 fi
 317
 318 dnl since we use lots of *_r functions all over the code we better
 319 dnl make sure they are known
 320
 321 if test  "x$x_rflag" != "xno"; then
 322    CPPFLAGS="$CPPFLAGS $x_rflag"
 323 fi
 324
 325 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 326
 327 AC_LANG_PUSH(C)
 328 dnl see if we have to include malloc/malloc.h
 329 AC_MSG_CHECKING([do we need malloc/malloc.h])
 330 AC_LINK_IFELSE(
 331     AC_LANG_PROGRAM(
 332            [[#include <stdlib.h>]],
 333            [[malloc(1)]]
 334                    ),
 335     [ AC_MSG_RESULT([nope, works out of the box]) ],
 336     [ AC_LINK_IFELSE(
 337           AC_LANG_PROGRAM(
 338                 [[#include <stdlib.h>
 339                   #include <malloc/malloc.h>]],
 340                 [[malloc(1)]]
 341                          ),
 342           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 343            AC_MSG_RESULT([yes we do])],
 344           [AC_MSG_ERROR([Can't figure how to compile malloc])]
 345       )
 346     ]
 347 )
 348 AC_LANG_POP(C)
 349
 350 CONFIGURE_PART(Findr 3rd-Party Libraries)
 351
 352
 353 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 354
 355 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 356 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.2,  http://www.gzip.org/zlib/, "")
 357 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 358 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 359
 360 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 361   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 362 fi
 363
 364
 365 CONFIGURE_PART(Prep for Building Language Bindings)
 366
 367 dnl Check for Perl.
 368 AC_PATH_PROG(PERL, perl, no)
 369
 370 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 371 [],[enable_perl=yes])
 372
 373
 374 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 375 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 376 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 377 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 378
 379 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 380         COMP_PERL=
 381 else
 382         COMP_PERL="perl_piped perl_shared"
 383         AC_MSG_CHECKING(for the perl version you are running)
 384         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 385         AC_MSG_RESULT($PERL_VERSION)
 386         if test -z "$PERLCC"; then
 387             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 388             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 389             AC_MSG_RESULT($perlcc)
 390             if test ! -x "$perlcc"; then
 391                 AC_PATH_PROG(PERL_CC, "${perlcc}", no)
 392                 if test "$PERL_CC" = "no"; then
 393                     AC_MSG_WARN([
 394 I would not find the Compiler ($perlcc) that was originally used to compile
 395 your perl binary. You should either make sure that this compiler is
 396 available on your system, pick an other compiler and set PERLCC
 397 appropriately, or use a different perl setup that was compiled locally.
 398
 399 I will disable the compilation of the RRDs perl module for now.
 400 ])
 401                     COMP_PERL="perl_piped"
 402                 fi
 403             fi
 404         fi
 405 fi
 406
 407 AC_MSG_CHECKING(Perl Modules to build)
 408 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 409
 410 # Options to pass when configuring perl module
 411 ppref=$prefix
 412 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 413
 414 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 415
 416 dnl pass additional perl options when generating Makefile from Makefile.PL
 417 AC_ARG_ENABLE(perl-site-install,
 418 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 419                           together with rrdtool in $prefix/lib/perl. You have to
 420                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 421                           when you want to use them. When you set this option
 422                           the perl modules will get installed wherever
 423                           your perl setup thinks it is best.],
 424 [PERL_MAKE_OPTIONS=],[])
 425
 426 if test ! -z "$PERLCC"; then
 427    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 428
 429    if test ! -z "$PERLCCFLAGS"; then
 430        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 431    fi
 432
 433    if test -z "$PERLLD"; then
 434        PERLLD=$PERLCC
 435    fi
 436    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 437
 438    if test ! -z "$PERLLDFLAGS"; then
 439        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 440    fi
 441 fi
 442
 443 AC_ARG_WITH(perl-options,
 444 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 445                           generating Makefile from Makefile.PL. If you set this
 446                           option, interesting things may happen unless you know
 447                           what you are doing!],
 448 [PERL_MAKE_OPTIONS=$withval])
 449
 450 AC_SUBST(PERL_MAKE_OPTIONS)
 451 AC_SUBST(PERL)
 452 AC_SUBST(COMP_PERL)
 453 AC_SUBST(PERL_VERSION)
 454
 455 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 456 [],[enable_tcl=yes])
 457
 458 if test  "$enable_tcl" = "yes"; then
 459   dnl Check for Tcl.
 460   withval=""
 461   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 462   enable_tcl=no
 463   for dir in $withval /usr/lib /usr/local/lib; do
 464     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 465     if test -f "$dir/tclConfig.sh" ; then
 466         tcl_config=$dir/tclConfig.sh
 467         enable_tcl=yes
 468         AC_MSG_RESULT(yes)
 469         break
 470     else
 471         AC_MSG_RESULT(no)
 472     fi
 473   done
 474
 475   if test "$enable_tcl" = "no"; then
 476         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 477   else
 478         . $tcl_config
 479         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 480   fi
 481 fi
 482
 483 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 484
 485 AC_SUBST(TCL_PREFIX)
 486 AC_SUBST(TCL_SHLIB_CFLAGS)
 487 AC_SUBST(TCL_SHLIB_LD)
 488 AC_SUBST(TCL_SHLIB_SUFFIX)
 489 AC_SUBST(TCL_PACKAGE_PATH)
 490 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 491 AC_SUBST(TCL_STUB_LIB_SPEC)
 492 AC_SUBST(TCL_VERSION)
 493 AC_SUBST(TCL_PACKAGE_DIR)
 494
 495 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 496 [],[enable_python=yes])
 497
 498 if test  "$enable_python" = "yes"; then
 499 dnl Check for python
 500 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 501 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 502 fi
 503
 504 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
 505
 506 dnl Check for nroff
 507 AC_PATH_PROGS(NROFF, gnroff nroff)
 508 AC_PATH_PROGS(TROFF, groff troff)
 509
 510 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 511 if test -z "$RRDDOCDIR"; then
 512    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 513
 514 dnl Does the compiler like -Wall and -pedantic?
 515 if test "$GCC" = "yes"; then
 516   oCFLAGS=$CFLAGS
 517   CFLAGS="$CFLAGS -fno-strict-aliasing -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 518   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 519                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 520                ]
 521         )
 522   if test $rd_cv_gcc_opt = no; then
 523          CFLAGS=$oCFLAGS
 524   fi
 525 fi
 526
 527
 528 CONFIGURE_PART(Apply Configuration Information)
 529
 530 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 531           examples/piped-demo.pl                        \
 532           examples/stripes.pl                           \
 533           examples/bigtops.pl                           \
 534           examples/minmax.pl                            \
 535           examples/cgi-demo.cgi                         \
 536           examples/4charts.pl                           \
 537           examples/Makefile                             \
 538           doc/Makefile                                  \
 539           src/Makefile                                  \
 540           bindings/Makefile                             \
 541           bindings/tcl/Makefile                         \
 542           bindings/tcl/ifOctets.tcl                     \
 543           bindings/python/Makefile                      \
 544           Makefile])
 545 AC_CONFIG_COMMANDS([default],[[\
 546           chmod +x examples/*.cgi examples/*.pl]],[[]])
 547 AC_OUTPUT
 548
 549 AC_MSG_CHECKING(in)
 550 AC_MSG_RESULT(and out again)
 551
 552 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 553 sleep 1
 554 echo $ECHO_N ".$ECHO_C" 1>&6
 555 sleep 1
 556 echo $ECHO_N ".$ECHO_C" 1>&6
 557 sleep 1
 558 echo $ECHO_N ".$ECHO_C" 1>&6
 559 sleep 1
 560 echo $ECHO_N ".$ECHO_C" 1>&6
 561 sleep 1
 562 AC_MSG_RESULT([ just kidding ;-)])
 563 echo
 564 echo "----------------------------------------------------------------"
 565 echo "Config is DONE!"
 566 echo
 567 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 568 echo "          Perl Modules: $COMP_PERL"
 569 echo "           Perl Binary: $PERL"
 570 echo "          Perl Version: $PERL_VERSION"
 571 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 572 echo "    Build Tcl Bindings: $enable_tcl"
 573 echo " Build Python Bindings: $enable_python"
 574 echo "          Build rrdcgi: $enable_rrdcgi"
 575 echo "       Build librrd MT: $enable_pthread"
 576 echo
 577 echo
 578 echo "Type 'make' to compile the software and use 'make install' to "
 579 echo "install everything to: $prefix."
 580 echo
 581 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 582 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 583 echo "place an order."
 584 echo
 585 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 586 echo "----------------------------------------------------------------"