configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl $Id$
   4 dnl
   5 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   6 dnl
   7 dnl Inspiration from http://autoconf-archive.cryp.to
   8
   9 dnl tell automake the this script is for rrdtool
  10
  11 dnl Minimum Autoconf version required.
  12 AC_PREREQ(2.59)
  13
  14 dnl the official version number is
  15 dnl a.b.c
  16 AC_INIT([rrdtool],[1.4.999])
  17
  18 dnl for testing a numberical version number comes handy
  19 dnl the released version are
  20 dnl a.bccc
  21 dnl the devel versions will be something like
  22 dnl a.b999yymmddhh
  23 NUMVERS=1.4999
  24 AC_SUBST(NUMVERS)
  25
  26 dnl for the linker to understand which versions the library are compatible with
  27 dnl each other we must keep a separate library version cout of the format c:r:a.
  28 dnl - if only implementation changed but all interfaces are kept, do r++
  29 dnl - if only functionality was added do c++,r=0,a++
  30 dnl - if any functionality was removed do c++,r=0,a=0.
  31 dnl
  32 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  33 dnl
  34 LIBVERS=5:3:1
  35 AC_SUBST(LIBVERS)
  36
  37 AC_CANONICAL_TARGET
  38 m4_version_prereq(2.60, [AC_USE_SYSTEM_EXTENSIONS], [#])
  39 AM_INIT_AUTOMAKE
  40 AM_MAINTAINER_MODE
  41 # Enable silent build rules by default, requires at least
  42 # Automake-1.11. Disable by either passing --disable-silent-rules to
  43 # configure or passing V=1 to make
  44 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  45 AC_CONFIG_HEADERS([rrd_config.h])
  46 AC_CONFIG_MACRO_DIR([m4])
  47
  48 dnl all our local stuff like install scripts and include files
  49 dnl is in there
  50
  51
  52 dnl determine the type of system we are running on
  53
  54 AC_SUBST(VERSION)
  55
  56 AC_PREFIX_DEFAULT( /opt/rrdtool-$PACKAGE_VERSION )
  57
  58 dnl At the TOP of the HEADER
  59
  60 AH_TOP([
  61 #ifndef RRD_CONFIG_H
  62 #define RRD_CONFIG_H
  63
  64 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  65 #undef MUST_DISABLE_FPMASK
  66
  67 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  68 #undef MUST_DISABLE_SIGFPE
  69
  70 /* realloc does not support NULL as argument */
  71 #undef NO_NULL_REALLOC
  72
  73 /* lets enable madvise defines in NetBSD */
  74 #if defined(__NetBSD__)
  75 # if !defined(_NETBSD_SOURCE)
  76 #  define _NETBSD_SOURCE
  77 # endif
  78 #endif
  79
  80 ])
  81
  82 AH_BOTTOM([
  83
  84 #ifdef MUST_HAVE_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #include "src/rrd_config_bottom.h"
  89
  90 #endif
  91 ])
  92
  93 dnl Process Special Options
  94 dnl -----------------------------------
  95
  96 dnl How the vertical axis label is printed
  97 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
  98  [Vertical label angle: -90.0 (default) or 90.0])
  99 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 100  [Vertical label angle: -90.0 (default) or 90.0])
 101
 102 AC_ARG_ENABLE(rrdcgi,AS_HELP_STRING([--disable-rrdcgi],[disable building of rrdcgi]),
 103 [],[enable_rrdcgi=yes])
 104
 105 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 106
 107 AC_ARG_ENABLE(rrd_graph,AS_HELP_STRING([--disable-rrd_graph],[disable all rrd_graph functions]),
 108 [enable_rrdcgi=no],[enable_rrd_graph=yes])
 109
 110 if test $enable_rrd_graph != no; then
 111  AC_DEFINE([HAVE_RRD_GRAPH], [], [is rrd_graph supported by this install])
 112 fi
 113
 114 dnl Check if we run on a system that has fonts
 115 AC_ARG_WITH(rrd-default-font,
 116 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 117 [RRD_DEFAULT_FONT=$withval],[
 118   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 119         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 120   else
 121         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 122   fi
 123 ])
 124
 125 dnl Use mmap in rrd_update instead of seek+write
 126 AC_ARG_ENABLE([mmap],
 127 AS_HELP_STRING([--disable-mmap],[disable mmap in rrd_update, use seek+write instead]),
 128 [],
 129 [enable_mmap=yes])
 130
 131 AC_ARG_ENABLE(pthread,AS_HELP_STRING([--disable-pthread],[disable multithread support]),
 132 [],[enable_pthread=yes])
 133
 134 AC_ARG_ENABLE(static-programs,
 135      AS_HELP_STRING([--enable-static-programs],[Build static programs]),
 136      [case "${enableval}" in
 137        yes) staticprogs=yes ;;
 138        no)  staticprogs=no ;;
 139        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 140      esac],[staticprogs=no])
 141 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 142
 143
 144 CONFIGURE_PART(Audit Compilation Environment)
 145
 146
 147 dnl Check for the compiler and static/shared library creation.
 148 AC_PROG_CPP
 149 AC_PROG_CC
 150 AM_PROG_CC_C_O
 151 AC_PROG_LIBTOOL
 152
 153 dnl Try to detect/use GNU features
 154 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 155
 156 dnl check for -Werror separatly
 157 dnl (quite a few autotool checks do not work with -Werror; also, the
 158 dnl check for -Werror fails after checking and adding the other flags)
 159 AC_CACHE_CHECK([if gcc likes the -Werror flag], rd_cv_gcc_flag__Werror,
 160   [AC_COMPILE_IFELSE(
 161     [AC_LANG_PROGRAM([[]], [[return 0 ]])],
 162     [rd_cv_gcc_flag__Werror="yes"],
 163     [rd_cv_gcc_flag__Werror="no"])])
 164 if test "x$rd_cv_gcc_flag__Werror" = "xyes"; then
 165   WERROR="-Werror"
 166 else
 167   WERROR=""
 168 fi
 169 AC_SUBST(WERROR)
 170
 171 dnl which flags does the compiler support?
 172 if test "x$GCC" = "xyes"; then
 173   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 174     oCFLAGS="$CFLAGS"
 175     CFLAGS="$CFLAGS $flag"
 176     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 177     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 178        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 179     if eval test \$$cachename = no; then
 180          CFLAGS="$oCFLAGS"
 181     fi
 182   done
 183 fi
 184
 185
 186
 187 AC_SUBST(RRD_DEFAULT_FONT)
 188
 189 CONFIGURE_PART(Checking for Header Files)
 190
 191 dnl Checks for header files.
 192 AC_HEADER_STDC
 193 AC_HEADER_DIRENT
 194 AC_CHECK_HEADERS(langinfo.h stdint.h inttypes.h libgen.h features.h sys/stat.h sys/types.h fcntl.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 195
 196 dnl Checks for typedefs, structures, and compiler characteristics.
 197 AC_C_CONST
 198 AC_HEADER_TIME
 199 AC_STRUCT_TM
 200
 201 CONFIGURE_PART(Test Library Functions)
 202
 203 dnl Checks for libraries.
 204 AC_CHECK_FUNC(acos,  , AC_CHECK_LIB(m, acos))
 205 AC_CHECK_FUNC(round, , AC_CHECK_LIB(m, round))
 206
 207
 208 dnl add pic flag in any case this makes sure all our code is relocatable
 209 eval `./libtool --config | grep pic_flag=`
 210 CFLAGS="$CFLAGS $pic_flag"
 211
 212
 213 dnl Checks for library functions.
 214 AC_FUNC_STRFTIME
 215 AC_FUNC_VPRINTF
 216
 217 AC_C_BIGENDIAN
 218
 219 dnl for each function found we get a definition in config.h
 220 dnl of the form HAVE_FUNCTION
 221
 222 AC_CHECK_FUNCS(nl_langinfo tzset fsync mbstowcs opendir readdir chdir chroot getuid strerror snprintf vsnprintf vasprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 223
 224 AC_FUNC_STRERROR_R
 225
 226 CONFIGURE_PART(Map/Fadvis/Madvise checking)
 227
 228 dnl Could use these to know if we need to provide a prototype
 229 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 230
 231 dnl check for fdatasync. Solaris has fdatasync in the librt
 232
 233 AC_CHECK_FUNCS(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
 234 dnl if there is no fdatasync we may get lucky with fsync
 235 AC_CHECK_FUNCS(fsync)
 236
 237 dnl check for socket and nsl solaris again ... we need this for the new rrd_daemon stuff
 238
 239 AC_CHECK_FUNCS(socket, [],  AC_CHECK_LIB(socket, socket, [LIBS="${LIBS} -lsocket"; AC_DEFINE(HAVE_SOCKET)],[]))
 240 AC_CHECK_FUNCS(getaddrinfo, [],  AC_CHECK_LIB(nsl, getaddrinfo, [LIBS="${LIBS} -lnsl"; AC_DEFINE(HAVE_GETADDRINFO)],[]))
 241
 242
 243
 244 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 245 if test "x$enable_mmap" = "xyes"; then
 246   case "$host" in
 247   *cygwin*)
 248     # the normal mmap test does not work in cygwin
 249     AC_CHECK_FUNCS(mmap)
 250     if test "x$ac_cv_func_mmap" = "xyes"; then
 251       ac_cv_func_mmap_fixed_mapped=yes
 252     fi
 253   ;;
 254   *)
 255     AC_CHECK_HEADERS(sys/mman.h)
 256     AC_FUNC_MMAP
 257     AC_CHECK_FUNCS(mmap munmap msync)
 258     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 259                                      # include <sys/mman.h>
 260                                      #endif])
 261     if test "x$ac_cv_have_decl_madvise" = "xyes";
 262     then
 263       AC_CHECK_FUNCS(madvise)
 264     else
 265       AC_CHECK_FUNCS(posix_madvise)
 266       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 267         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 268       fi
 269     fi
 270   ;;
 271   esac
 272   if test "x$ac_cv_func_mmap" != "xyes";
 273   then
 274     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 275 dnl enable_mmap="no"
 276   fi
 277 fi
 278
 279 dnl can we use posix_fadvise
 280 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 281 #include <fcntl.h>])
 282 AC_CHECK_FUNCS(posix_fadvise)
 283
 284 CONFIGURE_PART(Libintl Processing)
 285
 286 AM_GNU_GETTEXT_VERSION(0.17)
 287 AM_GNU_GETTEXT(external)
 288
 289 CONFIGURE_PART(IEEE Math Checks)
 290
 291
 292 dnl actual code to check if this works
 293 AC_CHECK_FUNCS(fpclassify, ,
 294   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 295     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 296 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 297       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 298
 299 AC_CHECK_FUNCS(isinf, ,
 300   [AC_MSG_CHECKING(for isinf with <math.h>)
 301     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 302 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 303       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 304
 305 dnl finite is BSD, isfinite is C99, so prefer the latter
 306 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
 307 AC_TRY_RUN([
 308 #ifdef HAVE_MATH_H
 309 #include <math.h>
 310 #endif
 311 #ifdef HAVE_FLOAT_H
 312 #include <float.h>
 313 #endif
 314 int main ()
 315 {
 316 #ifdef isfinite
 317 #ifdef LDBL_MAX
 318   if (!isfinite(LDBL_MAX)) return 1;
 319 #endif
 320 #ifdef DBL_MAX
 321   if (!isfinite(DBL_MAX)) return 1;
 322 #endif
 323 #endif
 324 return 0;
 325 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
 326 case "${target}" in
 327   hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
 328   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 329   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 330   *) ac_cv_have_broken_isfinite=no ;;
 331 esac])
 332 ])
 333
 334 dnl the test does not seem to work on solaris 2.8
 335 dnl so lets fix this by hand
 336 case "${target}" in
 337   *-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
 338   *-solaris2.9) ac_cv_have_broken_isfinite=yes ;;
 339 esac
 340
 341 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
 342   AC_DEFINE(HAVE_ISFINITE)
 343 else
 344   AC_CHECK_FUNCS(finite,[],
 345       [AC_CHECK_FUNCS(isfinite,[],
 346          [AC_MSG_CHECKING(for isfinite with <math.h>)
 347           AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 348 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 349                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 350 fi
 351
 352 AC_FULL_IEEE
 353
 354 CONFIGURE_PART(Resolve Portability Issues)
 355
 356 CHECK_FOR_WORKING_MS_ASYNC
 357
 358 dnl do we have nl_langinfo(_NL_TIME_WEEK_1STDAY)
 359 AC_CHECK_FUNCS(_NL_TIME_WEEK_1STDAY, ,
 360   [AC_MSG_CHECKING([for nl_langinfo(_NL_TIME_WEEK_1STDAY) with langinfo.h])
 361     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]], [[nl_langinfo(_NL_TIME_WEEK_1STDAY)]])],[AC_MSG_RESULT(yes)
 362       AC_DEFINE(HAVE__NL_TIME_WEEK_1STDAY)],[AC_MSG_RESULT(no)])])
 363
 364 dnl Do we need getopt_long
 365
 366 dnl even when including our own getopt implementation
 367 dnl we may want to make sure we use the external
 368 dnl defined by libc to not run into linker resolve trouble
 369
 370 AC_CACHE_CHECK([for opterr], rd_cv_var_int_opterr,
 371 [AC_TRY_LINK([#include <unistd.h>],
 372   [extern int opterr; opterr = 1;],
 373   [rd_cv_var_int_opterr=yes],
 374   [rd_cv_var_int_opterr=no])])
 375 if test x"$rd_cv_var_int_opterr" = x"yes"; then
 376   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
 377 fi
 378
 379 build_getopt=no
 380 RRD_GETOPT_LONG="LIBC_HAS_GETOPT_LONG"
 381 AC_CHECK_FUNC(getopt_long,[],[
 382 RRD_GETOPT_LONG="getopt_long"
 383 build_getopt=yes
 384 ])
 385 AC_SUBST(RRD_GETOPT_LONG)
 386 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
 387
 388 dnl what does realloc do if it gets called with a NULL pointer
 389
 390 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 391 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 392               int main(void){
 393               char *x = NULL;
 394               x = realloc (x,10);
 395               if (x==NULL) return 1;
 396               return 0;
 397              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 398
 399 if test x"$rd_cv_null_realloc" = xnope; then
 400 AC_DEFINE(NO_NULL_REALLOC)
 401 fi
 402
 403 AC_LANG_PUSH(C)
 404 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 405 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 406 AC_LINK_IFELSE(
 407     AC_LANG_PROGRAM(
 408            [[#include <time.h>]],
 409            [[ctime_r(NULL,NULL,0)]]
 410                    ),
 411     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 412       AC_LINK_IFELSE(
 413           AC_LANG_PROGRAM(
 414                 [[#include <time.h>]],
 415                 [[ctime_r(NULL,NULL)]]
 416                          ),
 417           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 418           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 419       )
 420     ],
 421     [ AC_LINK_IFELSE(
 422           AC_LANG_PROGRAM(
 423                 [[#include <time.h>]],
 424                 [[ctime_r(NULL,NULL)]]
 425                          ),
 426           [AC_MSG_RESULT(no)],
 427           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 428       )
 429     ]
 430 )
 431 AC_LANG_POP(C)
 432
 433 dnl Check for pthreads
 434 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 435
 436 AC_SUBST(MULTITHREAD_CFLAGS)
 437 AC_SUBST(MULTITHREAD_LDFLAGS)
 438
 439 if test $enable_pthread != no; then
 440  ACX_PTHREAD([
 441     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 442     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 443              ],
 444              [])
 445 fi
 446
 447 dnl since we use lots of *_r functions all over the code we better
 448 dnl make sure they are known
 449
 450 if test  "x$x_rflag" != "xno"; then
 451    CPPFLAGS="$CPPFLAGS $x_rflag"
 452 fi
 453
 454 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 455
 456 AC_LANG_PUSH(C)
 457 dnl see if we have to include malloc/malloc.h
 458 AC_MSG_CHECKING([do we need malloc/malloc.h])
 459 AC_LINK_IFELSE(
 460     AC_LANG_PROGRAM(
 461            [[#include <stdlib.h>]],
 462            [[malloc(1)]]
 463                    ),
 464     [ AC_MSG_RESULT([nope, works out of the box]) ],
 465     [ AC_LINK_IFELSE(
 466           AC_LANG_PROGRAM(
 467                 [[#include <stdlib.h>
 468                   #include <malloc/malloc.h>]],
 469                 [[malloc(1)]]
 470                          ),[
 471            AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
 472            AC_MSG_RESULT([yes we do])],
 473           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 474       )
 475     ]
 476 )
 477
 478 dnl is time_t 32 of 64 bit ?
 479 AC_DEFINE([TIME_T_IS_32BIT], [], [time_t is 32bit])
 480 AC_DEFINE([TIME_T_IS_64BIT], [], [time_t is 64bit])
 481 AC_MSG_CHECKING([the type of time_t])
 482 AC_CHECK_SIZEOF([time_t])
 483 if test "x$ac_cv_sizeof_time_t" = "x4"; then
 484   AC_MSG_RESULT([time_t is 32 bit])
 485   AC_DEFINE([TIME_T_IS_32BIT])
 486 elif test "x$ac_cv_sizeof_time_t" = "x8"; then
 487   AC_MSG_RESULT([time_t is 64 bit])
 488   AC_DEFINE([TIME_T_IS_64BIT])
 489 else
 490   AC_MSG_ERROR([can not figure type of time_t])
 491 fi
 492
 493 AC_LANG_POP(C)
 494
 495 CONFIGURE_PART(Find 3rd-Party Libraries)
 496
 497 have_libdbi=no
 498
 499 AC_ARG_ENABLE(libdbi,AS_HELP_STRING([--disable-libdbi],[do not build in support for libdbi]),[],[
 500     AC_CHECK_HEADER(dbi/dbi.h, [
 501        AC_CHECK_LIB(dbi, dbi_initialize, [
 502            AC_DEFINE(HAVE_LIBDBI,[1],[have got libdbi installed])
 503            LIBS="${LIBS} -ldbi -ldl"
 504            have_libdbi=yes
 505        ])
 506     ])
 507 ])
 508
 509 AM_CONDITIONAL(BUILD_LIBDBI,[test $have_libdbi != no])
 510
 511 have_libwrap=no
 512
 513 AC_ARG_ENABLE(libwrap, AS_HELP_STRING([--disable-libwrap], [do not build in support for libwrap (tcp wrapper)]),[],[
 514     AC_CHECK_HEADER(tcpd.h,[
 515         AC_CHECK_FUNCS(hosts_access, [
 516             AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 517             have_libwrap=yes
 518         ],
 519         [
 520             AC_CHECK_LIB(wrap, hosts_access, [
 521                AC_DEFINE(HAVE_LIBWRAP,[1],[have got libwrap installed])
 522                LIBS="${LIBS} -lwrap"
 523                have_libwrap=yes
 524             ])
 525         ])
 526     ])
 527 ])
 528
 529
 530 AM_CONDITIONAL(BUILD_LIBWRAP,[test $have_libwrap != no])
 531
 532 AM_CONDITIONAL(BUILD_RRDGRAPH,[test $enable_rrd_graph != no])
 533
 534
 535 CORE_LIBS="$LIBS"
 536
 537 if test $enable_rrd_graph != no; then
 538 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.5,  http://zlib.net/, "")
 539 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.4.8,  ftp://ftp.simplesystems.org/pub/libpng/png/src/, "")
 540 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.4.6,  http://download.savannah.gnu.org/releases/freetype/, /usr/include/freetype2)
 541 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.8.0,  http://www.freedesktop.org/software/fontconfig/release/, /usr/include)
 542 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.10.2,  http://cairographics.org/releases/, "")
 543 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.10.2,  http://cairographics.org/releases/, "")
 544 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.10.2,  http://cairographics.org/releases/, "")
 545 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.10.2,  http://cairographics.org/releases/, "")
 546 EX_CHECK_ALL(pangocairo-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.28.4,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.28, "")
 547
 548 fi
 549 EX_CHECK_ALL(glib-2.0,   glib_check_version,            glib.h,                 glib-2.0,    2.28.7, ftp://ftp.gtk.org/pub/glib/2.28/, "")
 550 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.7.8,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 551
 552 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 553   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 554 fi
 555
 556 ALL_LIBS="$LIBS"
 557 LIBS=
 558
 559 AC_SUBST(CORE_LIBS)
 560 AC_SUBST(ALL_LIBS)
 561
 562 CONFIGURE_PART(Prep for Building Language Bindings)
 563
 564 dnl Check for Perl and friends
 565 PATH=$PATH:/usr/perl5/bin
 566 export PATH
 567 AC_PATH_PROG(PERL, perl, no)
 568 AC_PATH_PROG(POD2MAN, pod2man, no)
 569 AC_PATH_PROG(POD2HTML, pod2html, no)
 570
 571
 572 AC_ARG_ENABLE(perl,AS_HELP_STRING([--disable-perl],[do not build the perl modules]),
 573 [],[enable_perl=yes])
 574
 575
 576 AC_ARG_VAR(PERLCC, [C compiler for Perl modules])
 577 AC_ARG_VAR(PERLCCFLAGS, [CC flags for Perl modules])
 578 AC_ARG_VAR(PERLLD, [Linker for Perl modules])
 579 AC_ARG_VAR(PERLLDFLAGS, [LD flags for Perl modules])
 580
 581 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 582         COMP_PERL=
 583 else
 584         COMP_PERL="perl_piped perl_shared"
 585         AC_MSG_CHECKING(for the perl version you are running)
 586         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 587         AC_MSG_RESULT($PERL_VERSION)
 588         if test -z "$PERLCC"; then
 589             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 590             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 591             AC_MSG_RESULT($perlcc)
 592             if test ! -x "$perlcc"; then
 593                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 594                 if test "$PERL_CC" = "no"; then
 595                     AC_MSG_WARN([
 596 I would not find the Compiler ($perlcc) that was originally used to compile
 597 your perl binary. You should either make sure that this compiler is
 598 available on your system, pick an other compiler and set PERLCC
 599 appropriately, or use a different perl setup that was compiled locally.
 600
 601 I will disable the compilation of the RRDs perl module for now.
 602 ])
 603                     COMP_PERL="perl_piped"
 604                 fi
 605             fi
 606         fi
 607 fi
 608
 609 AC_MSG_CHECKING(Perl Modules to build)
 610 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 611
 612 # Options to pass when configuring perl module
 613 langpref=$prefix
 614 test "$langpref" = '$(DESTDIR)NONE' && langpref='$(DESTDIR)'$ac_default_prefix
 615 test "$langpref" = "NONE" && langpref=$ac_default_prefix
 616
 617 PERL_MAKE_OPTIONS="PREFIX=$langpref LIB=$langpref/lib/perl/$PERL_VERSION"
 618
 619 dnl pass additional perl options when generating Makefile from Makefile.PL
 620 AC_ARG_ENABLE(perl-site-install,
 621 AS_HELP_STRING([--enable-perl-site-install],[by default the rrdtool perl modules are installed together with rrdtool in $prefix/lib/perl. You have to put a 'use lib qw($prefix/lib/perl)' into your scripts when you want to use them. When you set this option the perl modules will get installed wherever your perl setup thinks it is best.]),
 622 [PERL_MAKE_OPTIONS=],[])
 623
 624 if test ! -z "$PERLCC"; then
 625    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 626
 627    if test ! -z "$PERLCCFLAGS"; then
 628        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 629    fi
 630
 631    if test -z "$PERLLD"; then
 632        PERLLD=$PERLCC
 633    fi
 634    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 635
 636    if test ! -z "$PERLLDFLAGS"; then
 637        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 638    fi
 639 fi
 640
 641 AC_ARG_WITH(perl-options,
 642 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 643                           generating Makefile from Makefile.PL. If you set this
 644                           option, interesting things may happen unless you know
 645                           what you are doing!],
 646 [PERL_MAKE_OPTIONS=$withval])
 647
 648 AC_SUBST(PERL_MAKE_OPTIONS)
 649 AC_SUBST(PERL)
 650 AC_SUBST(COMP_PERL)
 651 AC_SUBST(PERL_VERSION)
 652
 653 dnl Check for Ruby.
 654 AC_PATH_PROG(RUBY, ruby, no)
 655
 656 AC_ARG_ENABLE(ruby,AS_HELP_STRING([--disable-ruby],[do not build the ruby modules]),
 657 [],[enable_ruby=yes])
 658
 659 AC_MSG_CHECKING(if ruby modules can be built)
 660
 661 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 662         COMP_RUBY=
 663         AC_MSG_RESULT(No .. Ruby not found or disabled)
 664 else
 665         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 666                 COMP_RUBY="ruby"
 667                 AC_MSG_RESULT(YES)
 668         else
 669                 COMP_RUBY=
 670                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 671         fi
 672 fi
 673
 674 dnl pass additional ruby options when generating Makefile from Makefile.PL
 675 AC_ARG_ENABLE(ruby-site-install,
 676 AS_HELP_STRING([--enable-ruby-site-install],[by default the rrdtool ruby modules are installed together with rrdtool in $prefix/lib/ruby. You have to add $prefix/lib/ruby/$ruby_version/$sitearch to your $: variable for ruby to find the RRD.so file.]),
 677 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$langpref/lib/ruby"])
 678
 679
 680 AC_ARG_WITH(ruby-options,
 681 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 682                           generating Makefile from extconf.rb. If you set this
 683                           option, interesting things may happen unless you know
 684                           what you are doing!],
 685 [RUBY_MAKE_OPTIONS=$withval])
 686
 687 AC_SUBST(RUBY_MAKE_OPTIONS)
 688 AC_SUBST(RUBY)
 689 AC_SUBST(COMP_RUBY)
 690
 691 dnl Check for Lua.
 692 AC_PATH_PROG(LUA, lua, no)
 693
 694 AC_ARG_ENABLE(lua,AS_HELP_STRING([--disable-lua],[do not build the lua modules]),
 695 [],[enable_lua=yes])
 696
 697 COMP_LUA=
 698 if test "$LUA" = "no" -o "$enable_lua" = "no"; then
 699   enable_lua=no
 700 else
 701   AC_MSG_CHECKING(for lua >= 5.0)
 702   read LUA_MAJOR LUA_MINOR LUA_POINT <<LUA_EOF
 703     $($LUA -v 2>&1 | cut -f2 -d' ' | sed -e 's/\./ /g')
 704 LUA_EOF
 705   if test 0$LUA_MAJOR -lt 5; then
 706     AC_MSG_RESULT([no, version found is $LUA_MAJOR.$LUA_MINOR])
 707   else
 708     AC_MSG_RESULT([$LUA_MAJOR.$LUA_MINOR found])
 709     lua_vdot=$LUA_MAJOR.$LUA_MINOR
 710     lua_vndot=$LUA_MAJOR$LUA_MINOR
 711     lua_version=$LUA_MAJOR.$LUA_MINOR.$LUA_POINT
 712     AC_CHECK_HEADERS(lua$lua_vndot/lua.h,
 713       [AC_CHECK_HEADERS(lua$lua_vndot/lualib.h,
 714         [AC_CHECK_HEADER(lua$lua_vndot/lauxlib.h,
 715           [lua_headerdir=lua$lua_vndot],
 716           [])],
 717         [])],
 718       [AC_CHECK_HEADERS(lua$lua_vdot/lua.h,
 719         [AC_CHECK_HEADERS(lua$lua_vdot/lualib.h,
 720           [AC_CHECK_HEADER(lua$lua_vdot/lauxlib.h,
 721             [lua_headerdir=lua$lua_vdot],
 722             [])],
 723           [])],
 724         [AC_CHECK_HEADERS(lua.h,
 725           [AC_CHECK_HEADERS(lualib.h,
 726             [AC_CHECK_HEADER(lauxlib.h,
 727               [lua_headerdir=""],
 728               [lua_headerdir="no"])],
 729             [])],
 730           [])])])
 731
 732     if test "$lua_headerdir" = "no"; then
 733       enable_lua=no
 734     else
 735       COMP_LUA=lua
 736     fi
 737
 738     if test "$COMP_LUA" != "lua"; then
 739       enable_lua=no
 740       AC_MSG_WARN([Lua $lua_vdot found but not lua.h, lualib.h and lauxlib.h! Please install the -dev packages for Lua $lua_vdot])
 741     else
 742       # OK, headers found, let's check the libraries (LIBS is not used)
 743       LIBS=
 744       lua_havelib=no
 745       LUA_HAVE_COMPAT51=DONT_HAVE_COMPAT51
 746       AC_SEARCH_LIBS(lua_call, lua$lua_vdot lua$lua_vndot lua,
 747         [AC_SEARCH_LIBS(luaL_register, lua$lua_vdot lua$lua_vndot lua,
 748           [lua_havelib=LUA$lua_vndot],
 749           [AC_SEARCH_LIBS(luaL_module, lualib$lua_vndot lualib$lua_vdot lualib,
 750             [lua_havelib=$lua_vndot; $LUA -l compat-5.1 2>/dev/null;
 751              test "$?" = "0" && LUA_HAVE_COMPAT51=HAVE_COMPAT51],
 752             [AC_SEARCH_LIBS(luaL_openlib, lualib$lua_vdot lualib$lua_vndot lualib,
 753               [lua_havelib=$lua_vndot],
 754               [COMP_LUA=], [-lm])], [-lm])], [-lm])],
 755         [COMP_LUA=], [-lm])
 756       lua_libs=$LIBS
 757       LIBS=
 758
 759       # Options to pass when configuring Lua module
 760       if test  "$lua_havelib" != "no"; then
 761         # OK, headers and libs found. Try to set lua flags
 762         # and modules installation dirs with pkg-config
 763         if test "$PKGCONFIG" != "no"; then
 764           if test "$lua_vndot" = "50"; then
 765             lua_pkg_prefix=lualib
 766           else
 767             lua_pkg_prefix=lua
 768           fi
 769           # try with dot, without dot and finally without version
 770           for f in $lua_pkg_prefix$lua_vdot $lua_pkg_prefix$lua_vndot $lua_pkg_prefix; do
 771             lua_exec_prefix=`$PKGCONFIG --variable=prefix $f 2>/dev/null`
 772             # same binaries?
 773             if test "$lua_exec_prefix/bin/lua" = "$LUA"; then
 774                 # OK, found CFLAGS. Get Lua LFLAGS and modules install dir
 775                 LUA_CFLAGS=`$PKGCONFIG --cflags $f 2>/dev/null`
 776                 LUA_LFLAGS=`$PKGCONFIG --libs $f 2>/dev/null`
 777                 LUA_INSTALL_CMOD=`$PKGCONFIG --variable=INSTALL_CMOD $f 2>/dev/null`
 778                 LUA_INSTALL_LMOD=`$PKGCONFIG --variable=INSTALL_LMOD $f 2>/dev/null`
 779                 break
 780             fi
 781           done
 782         fi
 783
 784         LUA_RRD_LIBDIR="$langpref/lib/lua/$lua_vdot"
 785         # if lua 5.0 can't find compat-5.1, force installation of
 786         # compat-5.1.lua together with RRDtool.
 787         if test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"; then
 788           lua_need_compat51=1
 789           LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"
 790         fi
 791
 792         # if not set with pkg-config, use default values in src packages compat-5.1, lua 5.1
 793         if test "$LUA_CFLAGS" = ""; then
 794           AC_MSG_WARN(Setting Lua include and lib flags to defaults in compat-5.1 and lua 5.1 sources)
 795           LUA_CFLAGS="-I/usr/local/include -I/usr/local/include/lua -I/usr/local/include/lua/$lua_vdot"
 796           LUA_LFLAGS="-L/usr/local/lib -L/usr/local/lib/lua -L/usr/local/lib/lua/$lua_vdot $lua_libs"
 797           LUA_INSTALL_CMOD="/usr/local/lib/lua/$lua_vdot"
 798         fi
 799
 800         dnl pass additional lua options
 801         dnl if lua-site-install is not set, overwrite LUA_INSTALL_CMOD already
 802         dnl found and install together with RRDtool, under $langpref.
 803         AC_ARG_ENABLE(lua-site-install,
 804         AS_HELP_STRING([--enable-lua-site-install],[by default the lua module is installed together with rrdtool in $prefix/lib/lua/$lua_version. You have to add $prefix/lib/lua/$lua_version/?.so to package.cpath for lua to find 'rrd.so'. For lua 5.0 you may also need to change LUA_PATH to the same dir, to require 'compat-5.1'. When you set this option the lua modules will get installed wherever your Lua setup thinks it is best. WARNING: if you set this option, system lua modules compat-5.1.lua and rrd.so, if any, may be overwritten.]),
 805         [],
 806         [LUA_INSTALL_CMOD="$LUA_RRD_LIBDIR"; LUA_INSTALL_LMOD="$LUA_RRD_LIBDIR"])
 807
 808         LUA_DEFINES="-DLUA$lua_vndot -D$LUA_HAVE_COMPAT51"
 809         AC_SUBST(LUA)
 810         AC_SUBST(COMP_LUA)
 811         AC_SUBST(LUA_INSTALL_CMOD)
 812         AC_SUBST(LUA_INSTALL_LMOD)
 813         AC_SUBST(LUA_CFLAGS)
 814         AC_SUBST(LUA_LFLAGS)
 815         AC_SUBST(LUA_DEFINES)
 816       else
 817         enable_lua=no
 818         AC_MSG_RESULT([Lua headers found but not the libraries! Please reinstall the dev packages for Lua $LUA_MAJOR.$LUA_MINOR])
 819       fi
 820     fi
 821   fi
 822 fi
 823 dnl If Lua 5.0, we need compat-5.1. Add ours unless already
 824 dnl integrated as in Debian/Ubuntu 5.0 -dev packages.
 825 AM_CONDITIONAL(LUA_NEED_OUR_COMPAT51,
 826       [test "$lua_vdot" = "5.0" -a "$LUA_HAVE_COMPAT51" != "HAVE_COMPAT51"])
 827 AM_CONDITIONAL(LUA_SITE_CINSTALL, [test "$LUA_INSTALL_CMOD" != "$LUA_RRD_LIBDIR"])
 828 AM_CONDITIONAL(LUA_SITE_LINSTALL, [test "$LUA_INSTALL_LMOD" != "$LUA_RRD_LIBDIR"])
 829 AM_CONDITIONAL(LUA50, [test "$lua_vndot" = "50"])
 830 AM_CONDITIONAL(BUILD_LUA, [test "$enable_lua" = "yes"])
 831
 832 enable_tcl_site=no
 833
 834 AC_ARG_ENABLE(tcl,AS_HELP_STRING([--disable-tcl],[do not build the tcl modules]),
 835 [],[enable_tcl=yes])
 836
 837 if test  "$enable_tcl" = "yes"; then
 838   dnl Check for Tcl.
 839   withval=""
 840   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 841   enable_tcl=no
 842   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 843     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 844     if test -f "$dir/tclConfig.sh" ; then
 845         tcl_config=$dir/tclConfig.sh
 846         enable_tcl=yes
 847         AC_MSG_RESULT(yes)
 848         break
 849     else
 850         AC_MSG_RESULT(no)
 851     fi
 852   done
 853
 854   if test "$enable_tcl" = "no"; then
 855         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 856   else
 857         . $tcl_config
 858         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 859         if test -n "$TCL_INC_DIR"; then
 860           TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
 861         fi
 862   fi
 863   AC_ARG_ENABLE(tcl-site,AS_HELP_STRING([--enable-tcl-site],[install the tcl extension in the tcl tree]),
 864   [],[enable_tcl_site=yes])
 865
 866 fi
 867
 868 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 869 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 870
 871
 872 AC_SUBST(TCL_PREFIX)
 873 AC_SUBST(TCL_SHLIB_CFLAGS)
 874 AC_SUBST(TCL_SHLIB_LD)
 875 AC_SUBST(TCL_SHLIB_SUFFIX)
 876 AC_SUBST(TCL_PACKAGE_PATH)
 877 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 878 AC_SUBST(TCL_STUB_LIB_SPEC)
 879 AC_SUBST(TCL_VERSION)
 880 AC_SUBST(TCL_PACKAGE_DIR)
 881 AC_SUBST(TCL_INCLUDE_SPEC)
 882
 883 AC_ARG_ENABLE(python,AS_HELP_STRING([--disable-python],[do not build the python modules]),
 884 [],[enable_python=yes])
 885
 886 if test  "$enable_python" = "yes"; then
 887 dnl Check for python
 888 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 889 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 890 fi
 891
 892 if test  x$enable_python = xno; then
 893         COMP_PYTHON=
 894 else
 895         COMP_PYTHON="python"
 896 fi
 897
 898 AC_SUBST(COMP_PYTHON)
 899
 900 dnl Check for nroff
 901 AC_ARG_VAR(NROFF, [path to the local nroff version])
 902 AC_PATH_PROGS(NROFF, [gnroff nroff])
 903 if test x$NROFF = x; then
 904   AC_MSG_ERROR([I need a copy of *nroff to format the documentation])
 905 fi
 906 AC_ARG_VAR(TROFF, [path to the local troff version])
 907 AC_PATH_PROGS(TROFF, [groff troff])
 908 if test x$TROFF = x; then
 909   AC_MSG_ERROR([I need a copy of *troff to format the documentation])
 910 fi
 911
 912 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 913 if test -z "$RRDDOCDIR"; then
 914    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 915
 916
 917 CONFIGURE_PART(Apply Configuration Information)
 918
 919 AC_CONFIG_FILES([examples/shared-demo.pl])
 920 AC_CONFIG_FILES([examples/piped-demo.pl])
 921 AC_CONFIG_FILES([examples/stripes.pl])
 922 AC_CONFIG_FILES([examples/bigtops.pl])
 923 AC_CONFIG_FILES([examples/minmax.pl])
 924 AC_CONFIG_FILES([examples/4charts.pl])
 925 AC_CONFIG_FILES([examples/perftest.pl])
 926 AC_CONFIG_FILES([examples/Makefile])
 927 AC_CONFIG_FILES([examples/rrdcached/Makefile])
 928 AC_CONFIG_FILES([doc/Makefile])
 929 AC_CONFIG_FILES([po/Makefile.in])
 930 AC_CONFIG_FILES([src/Makefile])
 931 AC_CONFIG_FILES([src/librrd.sym.in])
 932 AC_CONFIG_FILES([src/librrd.pc])
 933 AC_CONFIG_FILES([bindings/Makefile])
 934 AC_CONFIG_FILES([bindings/tcl/Makefile])
 935 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 936 AC_CONFIG_FILES([Makefile])
 937 AC_CONFIG_FILES([bindings/lua/Makefile])
 938
 939 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 940
 941 dnl intl requires our config to be called config.h. indulge it.
 942 AC_CONFIG_COMMANDS_POST([ test -f config.h || ln -s rrd_config.h config.h ])
 943
 944 AC_OUTPUT
 945
 946 AC_MSG_CHECKING(in)
 947 AC_MSG_RESULT(and out again)
 948
 949 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 950 sleep 1
 951 echo $ECHO_N ".$ECHO_C" 1>&6
 952 sleep 1
 953 echo $ECHO_N ".$ECHO_C" 1>&6
 954 sleep 1
 955 echo $ECHO_N ".$ECHO_C" 1>&6
 956 sleep 1
 957 echo $ECHO_N ".$ECHO_C" 1>&6
 958 sleep 1
 959 AC_MSG_RESULT([ just kidding ;-)])
 960 echo
 961 echo "----------------------------------------------------------------"
 962 echo "Config is DONE!"
 963 echo
 964 echo "          With MMAP IO: $enable_mmap"
 965 echo "      Build rrd_getopt: $build_getopt"
 966 echo "       Build rrd_graph: $enable_rrd_graph"
 967 echo "       Static programs: $staticprogs"
 968 echo "          Perl Modules: $COMP_PERL"
 969 echo "           Perl Binary: $PERL"
 970 echo "          Perl Version: $PERL_VERSION"
 971 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 972 echo "          Ruby Modules: $COMP_RUBY"
 973 echo "           Ruby Binary: $RUBY"
 974 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 975 echo "    Build Lua Bindings: $enable_lua"
 976 if test "$enable_lua" = "yes"; then
 977 echo "            Lua Binary: $LUA"
 978 echo "           Lua Version: $lua_version"
 979 echo "     Lua C-modules dir: $LUA_INSTALL_CMOD"
 980 if test "$lua_need_compat51" = "1"; then
 981 echo "   Lua Lua-modules dir: $LUA_INSTALL_LMOD"
 982 fi
 983 fi
 984 echo "    Build Tcl Bindings: $enable_tcl"
 985 echo " Build Python Bindings: $enable_python"
 986 echo "          Build rrdcgi: $enable_rrdcgi"
 987 echo "       Build librrd MT: $enable_pthread"
 988 echo "           Use gettext: $USE_NLS"
 989 echo "           With libDBI: $have_libdbi"
 990 echo "          With libwrap: $have_libwrap"
 991 echo
 992 echo "             Libraries: $ALL_LIBS"
 993 echo
 994 echo "Type 'make' to compile the software and use 'make install' to "
 995 echo "install everything to: $prefix."
 996 echo
 997 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 998 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 999 echo "place an order."
1000 echo
1001 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
1002 echo "----------------------------------------------------------------"