configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.23])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devl versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.2023
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52  ])
  53
  54 AH_BOTTOM([
  55
  56 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  57    make sure you are NOT using bcopy, index or rindex in the code */
  58
  59 #ifdef STDC_HEADERS
  60 # include <string.h>
  61 #else
  62 # ifndef HAVE_STRCHR
  63 #  define strchr index
  64 #  define strrchr rindex
  65 # endif
  66 char *strchr (), *strrchr ();
  67 # ifndef HAVE_MEMMOVE
  68 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  69 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  70 # endif
  71 #endif
  72
  73 /* enable posix_fadvise on linux */
  74 #ifdef HAVE_POSIX_FADVISE
  75 #define __USE_XOPEN2K 1
  76 #endif
  77
  78 #ifdef NO_NULL_REALLOC
  79 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  80 #else
  81 # define rrd_realloc(a,b) realloc((a), (b))
  82 #endif
  83
  84 #ifdef NEED_MALLOC_MALLOC_H
  85 #  include <malloc/malloc.h>
  86 #endif
  87
  88 #ifdef HAVE_MATH_H
  89 #  include <math.h>
  90 #endif
  91
  92 #ifdef HAVE_FLOAT_H
  93 #  include <float.h>
  94 #endif
  95
  96 #ifdef HAVE_IEEEFP_H
  97 #  include <ieeefp.h>
  98 #endif
  99
 100 #ifdef HAVE_FP_CLASS_H
 101 #  include <fp_class.h>
 102 #endif
 103
 104 /* for Solaris */
 105 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 106 #  define HAVE_ISINF 1
 107 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 108 #endif
 109
 110 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 111 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 112 #  undef isnan
 113 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 114 #endif
 115
 116 /* for OSF1 Digital Unix */
 117 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 118 #  define HAVE_ISINF 1
 119 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 120 #endif
 121
 122 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 123 #  define HAVE_ISINF 1
 124 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 125 #endif
 126
 127 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 128 #  define HAVE_ISINF 1
 129 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 130 #endif
 131
 132 /* for AIX */
 133 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 134 #  define HAVE_ISINF 1
 135 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 136 #endif
 137
 138 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 139 #  define HAVE_FINITE 1
 140 #  define finite(a) isfinite(a)
 141 #endif
 142
 143 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 144 #  define HAVE_FINITE 1
 145 #  define finite(a) (! isnan(a) && ! isinf(a))
 146 #endif
 147
 148 #ifndef HAVE_FINITE
 149 #error "Can't compile without finite function"
 150 #endif
 151
 152 #ifndef HAVE_ISINF
 153 #error "Can't compile without isinf function"
 154 #endif
 155
 156 #endif /* RRD_CONFIG_H */
 157 ])
 158
 159 dnl Process Special Options
 160 dnl -----------------------------------
 161
 162 dnl How the vertical axis label is printed
 163 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 164  [Vertical label angle: 90.0 (default) or 270.0])
 165 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 166  [Vertical label angle: 90.0 (default) or 270.0])
 167
 168 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 169 [],[enable_rrdcgi=yes])
 170
 171 dnl Check if we run on a system that has fonts
 172 AC_ARG_WITH(rrd-default-font,
 173 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 174 [RRD_DEFAULT_FONT=$withval],[
 175   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 176         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 177   else
 178         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 179   fi
 180 ])
 181
 182 dnl Use mmap in rrd_update instead of seek+write
 183 AC_ARG_ENABLE([mmap],
 184 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 185 [],
 186 [enable_mmap=yes])
 187
 188
 189  AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 190 [],[enable_pthread=yes])
 191
 192
 193
 194 CONFIGURE_PART(Audit Compilation Environment)
 195
 196
 197 dnl Check for the compiler and static/shared library creation.
 198 AC_PROG_CC
 199 AC_PROG_CPP
 200 AC_PROG_LIBTOOL
 201
 202 dnl which flags does the compile support?
 203 if test "$GCC" = "yes"; then
 204   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W; do
 205     oCFLAGS=$CFLAGS
 206     CFLAGS="$CFLAGS $flag"
 207     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 208     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 209        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 210     if eval test \$$cachename = no; then
 211          CFLAGS=$oCFLAGS
 212     fi
 213   done
 214 fi
 215
 216
 217
 218 AC_SUBST(RRD_DEFAULT_FONT)
 219
 220 CONFIGURE_PART(Checking for Header Files)
 221
 222 dnl Checks for header files.
 223 AC_HEADER_STDC
 224 AC_HEADER_DIRENT
 225 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 226
 227 dnl Checks for typedefs, structures, and compiler characteristics.
 228 AC_C_CONST
 229 AC_HEADER_TIME
 230 AC_STRUCT_TM
 231
 232 dnl Checks for libraries.
 233 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 234
 235 dnl add pic flag in any case this makes sure all our code is relocatable
 236 eval `./libtool --config | grep pic_flag`
 237 CFLAGS="$CFLAGS $pic_flag"
 238
 239 CONFIGURE_PART(Test Library Functions)
 240
 241 dnl Checks for library functions.
 242 AC_FUNC_STRFTIME
 243 AC_FUNC_VPRINTF
 244
 245 AC_C_BIGENDIAN
 246
 247 dnl for each function found we get a definition in config.h
 248 dnl of the form HAVE_FUNCTION
 249
 250 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday posix_fadvise)
 251
 252
 253 if test "x$enable_mmap" = xyes; then
 254   case "$host" in
 255     *cygwin*)
 256        # the normal mmap test does not work in cygwin
 257        AC_CHECK_FUNCS(mmap)
 258        if [ "x${ac_cv_func_mmap}" = xyes ]; then
 259          ac_cv_func_mmap_fixed_mapped=yes
 260        fi
 261     ;;
 262     *)
 263        AC_FUNC_MMAP
 264     ;;
 265   esac
 266 fi
 267
 268
 269 CONFIGURE_PART(IEEE Math Checks)
 270
 271 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 272 dnl actual code to check if this works
 273 AC_CHECK_FUNCS(fpclassify, ,
 274   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 275     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 276 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 277       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 278 AC_CHECK_FUNCS(finite, ,
 279   [AC_CHECK_FUNCS(isfinite, ,
 280     [AC_MSG_CHECKING(for isfinite with <math.h>)
 281     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 282 volatile int x;volatile float f;  ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 283       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 284 AC_CHECK_FUNCS(isinf, ,
 285   [AC_MSG_CHECKING(for isinf with <math.h>)
 286     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 287 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 288       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 289
 290 AC_FULL_IEEE
 291
 292 CONFIGURE_PART(Resolve Portability Issues)
 293
 294 dnl what does realloc do if it gets called with a NULL pointer
 295
 296 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 297 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 298               int main(void){
 299               char *x = NULL;
 300               x = realloc (x,10);
 301               if (x==NULL) return 1;
 302               return 0;
 303              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 304
 305 if test x"$rd_cv_null_realloc" = xnope; then
 306 AC_DEFINE(NO_NULL_REALLOC)
 307 fi
 308
 309 AC_LANG_PUSH(C)
 310 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 311 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 312 AC_LINK_IFELSE(
 313     AC_LANG_PROGRAM(
 314            [[#include <time.h>]],
 315            [[ctime_r(NULL,NULL,0)]]
 316                    ),
 317     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 318       AC_LINK_IFELSE(
 319           AC_LANG_PROGRAM(
 320                 [[#include <time.h>]],
 321                 [[ctime_r(NULL,NULL)]]
 322                          ),
 323           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 324           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 325       )
 326     ],
 327     [ AC_LINK_IFELSE(
 328           AC_LANG_PROGRAM(
 329                 [[#include <time.h>]],
 330                 [[ctime_r(NULL,NULL)]]
 331                          ),
 332           [AC_MSG_RESULT(no)],
 333           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 334       )
 335     ]
 336 )
 337 AC_LANG_POP(C)
 338
 339 dnl Check for pthreads
 340 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 341
 342 AC_SUBST(MULTITHREAD_CFLAGS)
 343 AC_SUBST(MULTITHREAD_LDFLAGS)
 344
 345 if test $enable_pthread != no; then
 346  ACX_PTHREAD([
 347     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 348     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 349              ],
 350              [])
 351 fi
 352
 353 dnl since we use lots of *_r functions all over the code we better
 354 dnl make sure they are known
 355
 356 if test  "x$x_rflag" != "xno"; then
 357    CPPFLAGS="$CPPFLAGS $x_rflag"
 358 fi
 359
 360 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 361
 362 AC_LANG_PUSH(C)
 363 dnl see if we have to include malloc/malloc.h
 364 AC_MSG_CHECKING([do we need malloc/malloc.h])
 365 AC_LINK_IFELSE(
 366     AC_LANG_PROGRAM(
 367            [[#include <stdlib.h>]],
 368            [[malloc(1)]]
 369                    ),
 370     [ AC_MSG_RESULT([nope, works out of the box]) ],
 371     [ AC_LINK_IFELSE(
 372           AC_LANG_PROGRAM(
 373                 [[#include <stdlib.h>
 374                   #include <malloc/malloc.h>]],
 375                 [[malloc(1)]]
 376                          ),
 377           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 378            AC_MSG_RESULT([yes we do])],
 379           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 380       )
 381     ]
 382 )
 383 AC_LANG_POP(C)
 384
 385 CONFIGURE_PART(Findr 3rd-Party Libraries)
 386
 387
 388 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 389
 390 CORE_LIBS="$LIBS"
 391
 392 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 393 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 394 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 395 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 396
 397 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 398   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 399 fi
 400
 401 ALL_LIBS="$LIBS"
 402 LIBS=
 403
 404 AC_SUBST(CORE_LIBS)
 405 AC_SUBST(ALL_LIBS)
 406
 407 CONFIGURE_PART(Prep for Building Language Bindings)
 408
 409 dnl Check for Perl.
 410 AC_PATH_PROG(PERL, perl, no)
 411
 412 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 413 [],[enable_perl=yes])
 414
 415
 416 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 417 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 418 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 419 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 420
 421 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 422         COMP_PERL=
 423 else
 424         COMP_PERL="perl_piped perl_shared"
 425         AC_MSG_CHECKING(for the perl version you are running)
 426         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 427         AC_MSG_RESULT($PERL_VERSION)
 428         if test -z "$PERLCC"; then
 429             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 430             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 431             AC_MSG_RESULT($perlcc)
 432             if test ! -x "$perlcc"; then
 433                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 434                 if test "$PERL_CC" = "no"; then
 435                     AC_MSG_WARN([
 436 I would not find the Compiler ($perlcc) that was originally used to compile
 437 your perl binary. You should either make sure that this compiler is
 438 available on your system, pick an other compiler and set PERLCC
 439 appropriately, or use a different perl setup that was compiled locally.
 440
 441 I will disable the compilation of the RRDs perl module for now.
 442 ])
 443                     COMP_PERL="perl_piped"
 444                 fi
 445             fi
 446         fi
 447 fi
 448
 449 AC_MSG_CHECKING(Perl Modules to build)
 450 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 451
 452 # Options to pass when configuring perl module
 453 ppref=$prefix
 454 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 455
 456 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 457
 458 dnl pass additional perl options when generating Makefile from Makefile.PL
 459 AC_ARG_ENABLE(perl-site-install,
 460 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 461                           together with rrdtool in $prefix/lib/perl. You have to
 462                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 463                           when you want to use them. When you set this option
 464                           the perl modules will get installed wherever
 465                           your perl setup thinks it is best.],
 466 [PERL_MAKE_OPTIONS=],[])
 467
 468 if test ! -z "$PERLCC"; then
 469    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 470
 471    if test ! -z "$PERLCCFLAGS"; then
 472        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 473    fi
 474
 475    if test -z "$PERLLD"; then
 476        PERLLD=$PERLCC
 477    fi
 478    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 479
 480    if test ! -z "$PERLLDFLAGS"; then
 481        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 482    fi
 483 fi
 484
 485 AC_ARG_WITH(perl-options,
 486 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 487                           generating Makefile from Makefile.PL. If you set this
 488                           option, interesting things may happen unless you know
 489                           what you are doing!],
 490 [PERL_MAKE_OPTIONS=$withval])
 491
 492 AC_SUBST(PERL_MAKE_OPTIONS)
 493 AC_SUBST(PERL)
 494 AC_SUBST(COMP_PERL)
 495 AC_SUBST(PERL_VERSION)
 496
 497 dnl Check for Ruby.
 498 AC_PATH_PROG(RUBY, ruby, no)
 499
 500 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 501 [],[enable_ruby=yes])
 502
 503 AC_MSG_CHECKING(if ruby modules can be built)
 504
 505 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 506         COMP_RUBY=
 507         AC_MSG_RESULT(No .. Ruby not found or disabled)
 508 else
 509         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 510                 COMP_RUBY="ruby"
 511                 AC_MSG_RESULT(YES)
 512         else
 513                 COMP_RUBY=
 514                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 515         fi
 516 fi
 517
 518
 519 dnl pass additional ruby options when generating Makefile from Makefile.PL
 520 AC_ARG_ENABLE(ruby-site-install,
 521 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 522                           together with rrdtool in $prefix/lib/ruby. You have to
 523                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 524                           for ruby to find the RRD.so file.],
 525 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 526
 527
 528 AC_ARG_WITH(ruby-options,
 529 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 530                           generating Makefile from extconf.rb. If you set this
 531                           option, interesting things may happen unless you know
 532                           what you are doing!],
 533 [RUBY_MAKE_OPTIONS=$withval])
 534
 535 AC_SUBST(RUBY_MAKE_OPTIONS)
 536 AC_SUBST(RUBY)
 537 AC_SUBST(COMP_RUBY)
 538
 539
 540 enable_tcl_site=no
 541
 542 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 543 [],[enable_tcl=yes])
 544
 545 if test  "$enable_tcl" = "yes"; then
 546   dnl Check for Tcl.
 547   withval=""
 548   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 549   enable_tcl=no
 550   for dir in $withval /usr/lib /usr/local/lib; do
 551     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 552     if test -f "$dir/tclConfig.sh" ; then
 553         tcl_config=$dir/tclConfig.sh
 554         enable_tcl=yes
 555         AC_MSG_RESULT(yes)
 556         break
 557     else
 558         AC_MSG_RESULT(no)
 559     fi
 560   done
 561
 562   if test "$enable_tcl" = "no"; then
 563         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 564   else
 565         . $tcl_config
 566         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 567   fi
 568   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 569   [],[enable_tcl_site=yes])
 570
 571 fi
 572
 573 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 574 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 575
 576 AC_SUBST(TCL_PREFIX)
 577 AC_SUBST(TCL_SHLIB_CFLAGS)
 578 AC_SUBST(TCL_SHLIB_LD)
 579 AC_SUBST(TCL_SHLIB_SUFFIX)
 580 AC_SUBST(TCL_PACKAGE_PATH)
 581 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 582 AC_SUBST(TCL_STUB_LIB_SPEC)
 583 AC_SUBST(TCL_VERSION)
 584 AC_SUBST(TCL_PACKAGE_DIR)
 585
 586 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 587 [],[enable_python=yes])
 588
 589 if test  "$enable_python" = "yes"; then
 590 dnl Check for python
 591 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 592 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 593 fi
 594
 595 if test  x$enable_python = xno; then
 596         COMP_PYTHON=
 597 else
 598         COMP_PYTHON="python"
 599 fi
 600
 601 AC_SUBST(COMP_PYTHON)
 602
 603 dnl Check for nroff
 604 AC_PATH_PROGS(NROFF, gnroff nroff)
 605 AC_PATH_PROGS(TROFF, groff troff)
 606
 607 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 608 if test -z "$RRDDOCDIR"; then
 609    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 610
 611
 612 CONFIGURE_PART(Apply Configuration Information)
 613
 614 AC_CONFIG_FILES([examples/shared-demo.pl])
 615 AC_CONFIG_FILES([examples/piped-demo.pl])
 616 AC_CONFIG_FILES([examples/stripes.pl])
 617 AC_CONFIG_FILES([examples/bigtops.pl])
 618 AC_CONFIG_FILES([examples/minmax.pl])
 619 AC_CONFIG_FILES([examples/4charts.pl])
 620 AC_CONFIG_FILES([examples/perftest.pl])
 621 AC_CONFIG_FILES([examples/Makefile])
 622 AC_CONFIG_FILES([doc/Makefile])
 623 AC_CONFIG_FILES([src/Makefile])
 624 AC_CONFIG_FILES([bindings/Makefile])
 625 AC_CONFIG_FILES([bindings/tcl/Makefile])
 626 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 627 AC_CONFIG_FILES([Makefile])
 628
 629 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 630 AC_OUTPUT
 631
 632 AC_MSG_CHECKING(in)
 633 AC_MSG_RESULT(and out again)
 634
 635 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 636 sleep 1
 637 echo $ECHO_N ".$ECHO_C" 1>&6
 638 sleep 1
 639 echo $ECHO_N ".$ECHO_C" 1>&6
 640 sleep 1
 641 echo $ECHO_N ".$ECHO_C" 1>&6
 642 sleep 1
 643 echo $ECHO_N ".$ECHO_C" 1>&6
 644 sleep 1
 645 AC_MSG_RESULT([ just kidding ;-)])
 646 echo
 647 echo "----------------------------------------------------------------"
 648 echo "Config is DONE!"
 649 echo
 650 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 651 echo "          Perl Modules: $COMP_PERL"
 652 echo "           Perl Binary: $PERL"
 653 echo "          Perl Version: $PERL_VERSION"
 654 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 655 echo "          Ruby Modules: $COMP_RUBY"
 656 echo "           Ruby Binary: $RUBY"
 657 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 658 echo "    Build Tcl Bindings: $enable_tcl"
 659 echo " Build Python Bindings: $enable_python"
 660 echo "          Build rrdcgi: $enable_rrdcgi"
 661 echo "       Build librrd MT: $enable_pthread"
 662 echo
 663 echo
 664 echo "Type 'make' to compile the software and use 'make install' to "
 665 echo "install everything to: $prefix."
 666 echo
 667 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 668 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 669 echo "place an order."
 670 echo
 671 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 672 echo "----------------------------------------------------------------"