configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.99907052400])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devel versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.299907052400
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52  ])
  53
  54 AH_BOTTOM([
  55 /* make sure that we pickup the correct stuff from all headers */
  56 #define _XOPEN_SOURCE 600
  57 #ifdef HAVE_FEATURES_H
  58 # include <features.h>
  59 #endif
  60
  61 #ifdef HAVE_SYS_TYPES_H
  62 # include <sys/types.h>
  63 #endif
  64
  65 #ifdef HAVE_SYS_PARAM_H
  66 # include <sys/param.h>
  67 #endif
  68 #ifndef MAXPATH
  69 # ifdef PATH_MAX
  70 #  define MAXPATH PATH_MAX
  71 # endif
  72 #endif
  73 #ifndef MAXPATH
  74 /* else try the BSD variant */
  75 # ifdef MAXPATHLEN
  76 #  define MAXPATH MAXPATHLEN
  77 # endif
  78 #endif
  79
  80 #ifdef HAVE_ERRNO_H
  81 # include <errno.h>
  82 #endif
  83
  84 #ifdef HAVE_SYS_MMAN_H
  85 # include <sys/mman.h>
  86 #endif
  87 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
  88 /* use posix_madvise family */
  89 # define madvise posix_madvise
  90 # define MADV_NORMAL POSIX_MADV_NORMAL
  91 # define MADV_RANDOM POSIX_MADV_RANDOM
  92 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
  93 # define MADV_WILLNEED POSIX_MADV_WILLNEED
  94 # define MADV_DONTNEED POSIX_MADV_DONTNEED
  95 #endif
  96 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
  97 # define USE_MADVISE 1
  98 #endif
  99
 100 #ifdef HAVE_SYS_STAT_H
 101 # include <sys/stat.h>
 102 #endif
 103
 104 /* enable posix_fadvise on linux */
 105 #if defined(HAVE_POSIX_FADVISE) && defined(HAVE_FCNTL_H)
 106 #include <fcntl.h>
 107 #endif
 108
 109 #ifdef HAVE_UNISTD_H
 110 # include <unistd.h>
 111 #endif
 112
 113 #ifdef TIME_WITH_SYS_TIME
 114 # include <sys/time.h>
 115 # include <time.h>
 116 #else
 117 # ifdef HAVE_SYS_TIME_H
 118 #  include <sys/time.h>
 119 # else
 120 #  include <time.h>
 121 # endif
 122 #endif
 123
 124 #ifdef HAVE_SYS_TIMES_H
 125 # include <sys/times.h>
 126 #endif
 127
 128 #ifdef HAVE_SYS_RESOURCE_H
 129 # include <sys/resource.h>
 130 #if (defined(__svr4__) && defined(__sun__))
 131 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
 132    Use this instead. */
 133 extern int getrusage(int, struct rusage *);
 134 #endif /* __svr4__ && __sun__ */
 135 #endif
 136
 137
 138 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 139    make sure you are NOT using bcopy, index or rindex in the code */
 140
 141 #ifdef STDC_HEADERS
 142 # include <string.h>
 143 #else
 144 # ifndef HAVE_STRCHR
 145 #  define strchr index
 146 #  define strrchr rindex
 147 # endif
 148 char *strchr (), *strrchr ();
 149 # ifndef HAVE_MEMMOVE
 150 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 151 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 152 # endif
 153 #endif
 154
 155 #ifdef NO_NULL_REALLOC
 156 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 157 #else
 158 # define rrd_realloc(a,b) realloc((a), (b))
 159 #endif
 160
 161 #ifdef NEED_MALLOC_MALLOC_H
 162 #  include <malloc/malloc.h>
 163 #endif
 164
 165 #ifdef HAVE_STDIO_H
 166 # include <stdio.h>
 167 #endif
 168
 169 #ifdef HAVE_STDLIB_H
 170 # include <stdlib.h>
 171 #endif
 172
 173 #ifdef HAVE_CTYPE_H
 174 # include <ctype.h>
 175 #endif
 176
 177 #ifdef HAVE_DIRENT_H
 178 # include <dirent.h>
 179 # define NAMLEN(dirent) strlen((dirent)->d_name)
 180 #else
 181 # define dirent direct
 182 # define NAMLEN(dirent) (dirent)->d_namlen
 183 # ifdef HAVE_SYS_NDIR_H
 184 #  include <sys/ndir.h>
 185 # endif
 186 # ifdef HAVE_SYS_DIR_H
 187 #  include <sys/dir.h>
 188 # endif
 189 # ifdef HAVE_NDIR_H
 190 #  include <ndir.h>
 191 # endif
 192 #endif
 193
 194 #ifdef MUST_DISABLE_SIGFPE
 195 # include <signal.h>
 196 #endif
 197
 198 #ifdef MUST_DISABLE_FPMASK
 199 # include <floatingpoint.h>
 200 #endif
 201
 202
 203 #ifdef HAVE_MATH_H
 204 # include <math.h>
 205 #endif
 206
 207 #ifdef HAVE_FLOAT_H
 208 # include <float.h>
 209 #endif
 210
 211 #ifdef HAVE_IEEEFP_H
 212 # include <ieeefp.h>
 213 #endif
 214
 215 #ifdef HAVE_FP_CLASS_H
 216 # include <fp_class.h>
 217 #endif
 218
 219 /* for Solaris */
 220 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 221 #  define HAVE_ISINF 1
 222 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 223 #endif
 224
 225 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 226 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 227 #  undef isnan
 228 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 229 #endif
 230
 231 /* for OSF1 Digital Unix */
 232 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 233 #  define HAVE_ISINF 1
 234 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 235 #endif
 236
 237 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 238 #  define HAVE_ISINF 1
 239 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 240 #endif
 241
 242 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 243 #  define HAVE_ISINF 1
 244 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 245 #endif
 246
 247 /* for AIX */
 248 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 249 #  define HAVE_ISINF 1
 250 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 251 #endif
 252
 253 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 254 #  define HAVE_FINITE 1
 255 #  define finite(a) isfinite(a)
 256 #endif
 257
 258 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 259 #  define HAVE_FINITE 1
 260 #  define finite(a) (! isnan(a) && ! isinf(a))
 261 #endif
 262
 263 #ifndef HAVE_FINITE
 264 #error "Can't compile without finite function"
 265 #endif
 266
 267 #ifndef HAVE_ISINF
 268 #error "Can't compile without isinf function"
 269 #endif
 270
 271 #endif /* RRD_CONFIG_H */
 272 ])
 273
 274 dnl Process Special Options
 275 dnl -----------------------------------
 276
 277 dnl How the vertical axis label is printed
 278 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 279  [Vertical label angle: 90.0 (default) or 270.0])
 280 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 281  [Vertical label angle: 90.0 (default) or 270.0])
 282
 283 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 284 [],[enable_rrdcgi=yes])
 285
 286 dnl Check if we run on a system that has fonts
 287 AC_ARG_WITH(rrd-default-font,
 288 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 289 [RRD_DEFAULT_FONT=$withval],[
 290   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 291         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 292   else
 293         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 294   fi
 295 ])
 296
 297 dnl Use mmap in rrd_update instead of seek+write
 298 AC_ARG_ENABLE([mmap],
 299 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 300 [],
 301 [enable_mmap=yes])
 302 AC_ARG_ENABLE([direct-io],
 303 [  --enable-direct-io      enable O_DIRECT],
 304 [],
 305 [enable_direct_io=yes])
 306
 307  AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 308 [],[enable_pthread=yes])
 309
 310
 311
 312 CONFIGURE_PART(Audit Compilation Environment)
 313
 314
 315 dnl Check for the compiler and static/shared library creation.
 316 AC_PROG_CC
 317 AC_PROG_CPP
 318 AC_PROG_LIBTOOL
 319
 320 dnl which flags does the compiler support?
 321 if test "x$GCC" = "xyes"; then
 322   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W; do
 323     oCFLAGS="$CFLAGS"
 324     CFLAGS="$CFLAGS $flag"
 325     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 326     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 327        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 328     if eval test \$$cachename = no; then
 329          CFLAGS="$oCFLAGS"
 330     fi
 331   done
 332 fi
 333
 334
 335
 336 AC_SUBST(RRD_DEFAULT_FONT)
 337
 338 CONFIGURE_PART(Checking for Header Files)
 339
 340 dnl Checks for header files.
 341 AC_HEADER_STDC
 342 AC_HEADER_DIRENT
 343 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 344
 345 dnl Checks for typedefs, structures, and compiler characteristics.
 346 AC_C_CONST
 347 AC_HEADER_TIME
 348 AC_STRUCT_TM
 349
 350 dnl Checks for libraries.
 351 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 352
 353 dnl add pic flag in any case this makes sure all our code is relocatable
 354 eval `./libtool --config | grep pic_flag`
 355 CFLAGS="$CFLAGS $pic_flag"
 356
 357 CONFIGURE_PART(Test Library Functions)
 358
 359 dnl Checks for library functions.
 360 AC_FUNC_STRFTIME
 361 AC_FUNC_VPRINTF
 362
 363 AC_C_BIGENDIAN
 364
 365 dnl for each function found we get a definition in config.h
 366 dnl of the form HAVE_FUNCTION
 367
 368 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday posix_fadvise)
 369
 370 dnl Could use these to know if we need to provide a prototype
 371 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 372 dnl AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 373 dnl #include <fcntl.h>])
 374
 375 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 376 if test "x$enable_mmap" = "xyes"; then
 377   case "$host" in
 378   *cygwin*)
 379     # the normal mmap test does not work in cygwin
 380     AC_CHECK_FUNCS(mmap)
 381     if test "x$ac_cv_func_mmap" = "xyes"; then
 382       ac_cv_func_mmap_fixed_mapped=yes
 383     fi
 384   ;;
 385   *)
 386     AC_CHECK_HEADERS(sys/mman.h)
 387     AC_FUNC_MMAP
 388     AC_CHECK_FUNCS(mmap munmap)
 389     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 390                                      # include <sys/mman.h>
 391                                      #endif])
 392     if test "x$ac_cv_have_decl_madvise" = "xyes";
 393     then
 394       AC_CHECK_FUNCS(madvise)
 395     else
 396       AC_CHECK_FUNCS(posix_madvise)
 397       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 398         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 399       fi
 400     fi
 401   ;;
 402   esac
 403   if test "x$ac_cv_func_mmap" != "xyes";
 404   then
 405     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 406   fi
 407 fi
 408
 409
 410 dnl if test "x$enable_direct_io" = "xyes"; then
 411 dnl check for working O_DIRECT
 412 dnl fi
 413 AC_SUBST([USE_DIRECT_IO])
 414
 415 CONFIGURE_PART(IEEE Math Checks)
 416
 417
 418 dnl actual code to check if this works
 419 AC_CHECK_FUNCS(fpclassify, ,
 420   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 421     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 422 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 423       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 424
 425 AC_CHECK_FUNCS(isinf, ,
 426   [AC_MSG_CHECKING(for isinf with <math.h>)
 427     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 428 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 429       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 430
 431 dnl finite is BSD, isfinite is C99, so prefer the latter
 432 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 433 AC_TRY_RUN([
 434 #ifdef HAVE_MATH_H
 435 #include <math.h>
 436 #endif
 437 #ifdef HAVE_FLOAT_H
 438 #include <float.h>
 439 #endif
 440 int main ()
 441 {
 442 #ifdef isfinite
 443 #ifdef LDBL_MAX
 444   if (!isfinite(LDBL_MAX)) return 1;
 445 #endif
 446 #ifdef DBL_MAX
 447   if (!isfinite(DBL_MAX)) return 1;
 448 #endif
 449 #endif
 450 return 0;
 451 }],[
 452 have_broken_isfinite=no],have_broken_isfinite=yes,[
 453 case "${target}" in
 454   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 455   *) have_broken_isfinite=no ;;
 456 esac])
 457 ])
 458 if test "x$have_broken_isfinite" = "xno"; then
 459   AC_DEFINE(HAVE_ISFINITE)
 460 else
 461 AC_CHECK_FUNCS(finite,[],
 462   [AC_CHECK_FUNCS(isfinite,[],
 463       [AC_MSG_CHECKING(for isfinite with <math.h>)
 464        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 465 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 466                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 467 fi
 468
 469 AC_FULL_IEEE
 470
 471 CONFIGURE_PART(Resolve Portability Issues)
 472
 473 dnl what does realloc do if it gets called with a NULL pointer
 474
 475 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 476 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 477               int main(void){
 478               char *x = NULL;
 479               x = realloc (x,10);
 480               if (x==NULL) return 1;
 481               return 0;
 482              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 483
 484 if test x"$rd_cv_null_realloc" = xnope; then
 485 AC_DEFINE(NO_NULL_REALLOC)
 486 fi
 487
 488 AC_LANG_PUSH(C)
 489 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 490 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 491 AC_LINK_IFELSE(
 492     AC_LANG_PROGRAM(
 493            [[#include <time.h>]],
 494            [[ctime_r(NULL,NULL,0)]]
 495                    ),
 496     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 497       AC_LINK_IFELSE(
 498           AC_LANG_PROGRAM(
 499                 [[#include <time.h>]],
 500                 [[ctime_r(NULL,NULL)]]
 501                          ),
 502           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 503           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 504       )
 505     ],
 506     [ AC_LINK_IFELSE(
 507           AC_LANG_PROGRAM(
 508                 [[#include <time.h>]],
 509                 [[ctime_r(NULL,NULL)]]
 510                          ),
 511           [AC_MSG_RESULT(no)],
 512           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 513       )
 514     ]
 515 )
 516 AC_LANG_POP(C)
 517
 518 dnl Check for pthreads
 519 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 520
 521 AC_SUBST(MULTITHREAD_CFLAGS)
 522 AC_SUBST(MULTITHREAD_LDFLAGS)
 523
 524 if test $enable_pthread != no; then
 525  ACX_PTHREAD([
 526     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 527     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 528              ],
 529              [])
 530 fi
 531
 532 dnl since we use lots of *_r functions all over the code we better
 533 dnl make sure they are known
 534
 535 if test  "x$x_rflag" != "xno"; then
 536    CPPFLAGS="$CPPFLAGS $x_rflag"
 537 fi
 538
 539 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 540
 541 AC_LANG_PUSH(C)
 542 dnl see if we have to include malloc/malloc.h
 543 AC_MSG_CHECKING([do we need malloc/malloc.h])
 544 AC_LINK_IFELSE(
 545     AC_LANG_PROGRAM(
 546            [[#include <stdlib.h>]],
 547            [[malloc(1)]]
 548                    ),
 549     [ AC_MSG_RESULT([nope, works out of the box]) ],
 550     [ AC_LINK_IFELSE(
 551           AC_LANG_PROGRAM(
 552                 [[#include <stdlib.h>
 553                   #include <malloc/malloc.h>]],
 554                 [[malloc(1)]]
 555                          ),
 556           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 557            AC_MSG_RESULT([yes we do])],
 558           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 559       )
 560     ]
 561 )
 562 AC_LANG_POP(C)
 563
 564 CONFIGURE_PART(Find 3rd-Party Libraries)
 565
 566
 567 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 568
 569 CORE_LIBS="$LIBS"
 570
 571 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 572 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 573 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 574 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 575
 576 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 577   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 578 fi
 579
 580 ALL_LIBS="$LIBS"
 581 LIBS=
 582
 583 AC_SUBST(CORE_LIBS)
 584 AC_SUBST(ALL_LIBS)
 585
 586 CONFIGURE_PART(Prep for Building Language Bindings)
 587
 588 dnl Check for Perl.
 589 AC_PATH_PROG(PERL, perl, no)
 590
 591 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 592 [],[enable_perl=yes])
 593
 594
 595 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 596 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 597 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 598 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 599
 600 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 601         COMP_PERL=
 602 else
 603         COMP_PERL="perl_piped perl_shared"
 604         AC_MSG_CHECKING(for the perl version you are running)
 605         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 606         AC_MSG_RESULT($PERL_VERSION)
 607         if test -z "$PERLCC"; then
 608             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 609             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 610             AC_MSG_RESULT($perlcc)
 611             if test ! -x "$perlcc"; then
 612                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 613                 if test "$PERL_CC" = "no"; then
 614                     AC_MSG_WARN([
 615 I would not find the Compiler ($perlcc) that was originally used to compile
 616 your perl binary. You should either make sure that this compiler is
 617 available on your system, pick an other compiler and set PERLCC
 618 appropriately, or use a different perl setup that was compiled locally.
 619
 620 I will disable the compilation of the RRDs perl module for now.
 621 ])
 622                     COMP_PERL="perl_piped"
 623                 fi
 624             fi
 625         fi
 626 fi
 627
 628 AC_MSG_CHECKING(Perl Modules to build)
 629 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 630
 631 # Options to pass when configuring perl module
 632 ppref=$prefix
 633 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 634
 635 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 636
 637 dnl pass additional perl options when generating Makefile from Makefile.PL
 638 AC_ARG_ENABLE(perl-site-install,
 639 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 640                           together with rrdtool in $prefix/lib/perl. You have to
 641                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 642                           when you want to use them. When you set this option
 643                           the perl modules will get installed wherever
 644                           your perl setup thinks it is best.],
 645 [PERL_MAKE_OPTIONS=],[])
 646
 647 if test ! -z "$PERLCC"; then
 648    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 649
 650    if test ! -z "$PERLCCFLAGS"; then
 651        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 652    fi
 653
 654    if test -z "$PERLLD"; then
 655        PERLLD=$PERLCC
 656    fi
 657    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 658
 659    if test ! -z "$PERLLDFLAGS"; then
 660        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 661    fi
 662 fi
 663
 664 AC_ARG_WITH(perl-options,
 665 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 666                           generating Makefile from Makefile.PL. If you set this
 667                           option, interesting things may happen unless you know
 668                           what you are doing!],
 669 [PERL_MAKE_OPTIONS=$withval])
 670
 671 AC_SUBST(PERL_MAKE_OPTIONS)
 672 AC_SUBST(PERL)
 673 AC_SUBST(COMP_PERL)
 674 AC_SUBST(PERL_VERSION)
 675
 676 dnl Check for Ruby.
 677 AC_PATH_PROG(RUBY, ruby, no)
 678
 679 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 680 [],[enable_ruby=yes])
 681
 682 AC_MSG_CHECKING(if ruby modules can be built)
 683
 684 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 685         COMP_RUBY=
 686         AC_MSG_RESULT(No .. Ruby not found or disabled)
 687 else
 688         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 689                 COMP_RUBY="ruby"
 690                 AC_MSG_RESULT(YES)
 691         else
 692                 COMP_RUBY=
 693                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 694         fi
 695 fi
 696
 697
 698 dnl pass additional ruby options when generating Makefile from Makefile.PL
 699 AC_ARG_ENABLE(ruby-site-install,
 700 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 701                           together with rrdtool in $prefix/lib/ruby. You have to
 702                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 703                           for ruby to find the RRD.so file.],
 704 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 705
 706
 707 AC_ARG_WITH(ruby-options,
 708 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 709                           generating Makefile from extconf.rb. If you set this
 710                           option, interesting things may happen unless you know
 711                           what you are doing!],
 712 [RUBY_MAKE_OPTIONS=$withval])
 713
 714 AC_SUBST(RUBY_MAKE_OPTIONS)
 715 AC_SUBST(RUBY)
 716 AC_SUBST(COMP_RUBY)
 717
 718
 719 enable_tcl_site=no
 720
 721 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 722 [],[enable_tcl=yes])
 723
 724 if test  "$enable_tcl" = "yes"; then
 725   dnl Check for Tcl.
 726   withval=""
 727   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 728   enable_tcl=no
 729   for dir in $withval /usr/lib /usr/local/lib; do
 730     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 731     if test -f "$dir/tclConfig.sh" ; then
 732         tcl_config=$dir/tclConfig.sh
 733         enable_tcl=yes
 734         AC_MSG_RESULT(yes)
 735         break
 736     else
 737         AC_MSG_RESULT(no)
 738     fi
 739   done
 740
 741   if test "$enable_tcl" = "no"; then
 742         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 743   else
 744         . $tcl_config
 745         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 746   fi
 747   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 748   [],[enable_tcl_site=yes])
 749
 750 fi
 751
 752 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 753 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 754
 755 AC_SUBST(TCL_PREFIX)
 756 AC_SUBST(TCL_SHLIB_CFLAGS)
 757 AC_SUBST(TCL_SHLIB_LD)
 758 AC_SUBST(TCL_SHLIB_SUFFIX)
 759 AC_SUBST(TCL_PACKAGE_PATH)
 760 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 761 AC_SUBST(TCL_STUB_LIB_SPEC)
 762 AC_SUBST(TCL_VERSION)
 763 AC_SUBST(TCL_PACKAGE_DIR)
 764
 765 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 766 [],[enable_python=yes])
 767
 768 if test  "$enable_python" = "yes"; then
 769 dnl Check for python
 770 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 771 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 772 fi
 773
 774 if test  x$enable_python = xno; then
 775         COMP_PYTHON=
 776 else
 777         COMP_PYTHON="python"
 778 fi
 779
 780 AC_SUBST(COMP_PYTHON)
 781
 782 dnl Check for nroff
 783 AC_PATH_PROGS(NROFF, gnroff nroff)
 784 AC_PATH_PROGS(TROFF, groff troff)
 785
 786 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 787 if test -z "$RRDDOCDIR"; then
 788    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 789
 790
 791 CONFIGURE_PART(Apply Configuration Information)
 792
 793 AC_CONFIG_FILES([examples/shared-demo.pl])
 794 AC_CONFIG_FILES([examples/piped-demo.pl])
 795 AC_CONFIG_FILES([examples/stripes.pl])
 796 AC_CONFIG_FILES([examples/bigtops.pl])
 797 AC_CONFIG_FILES([examples/minmax.pl])
 798 AC_CONFIG_FILES([examples/4charts.pl])
 799 AC_CONFIG_FILES([examples/perftest.pl])
 800 AC_CONFIG_FILES([examples/Makefile])
 801 AC_CONFIG_FILES([doc/Makefile])
 802 AC_CONFIG_FILES([src/Makefile])
 803 AC_CONFIG_FILES([bindings/Makefile])
 804 AC_CONFIG_FILES([bindings/tcl/Makefile])
 805 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 806 AC_CONFIG_FILES([Makefile])
 807
 808 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 809 AC_OUTPUT
 810
 811 AC_MSG_CHECKING(in)
 812 AC_MSG_RESULT(and out again)
 813
 814 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 815 sleep 1
 816 echo $ECHO_N ".$ECHO_C" 1>&6
 817 sleep 1
 818 echo $ECHO_N ".$ECHO_C" 1>&6
 819 sleep 1
 820 echo $ECHO_N ".$ECHO_C" 1>&6
 821 sleep 1
 822 echo $ECHO_N ".$ECHO_C" 1>&6
 823 sleep 1
 824 AC_MSG_RESULT([ just kidding ;-)])
 825 echo
 826 echo "----------------------------------------------------------------"
 827 echo "Config is DONE!"
 828 echo
 829 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 830 echo "          Perl Modules: $COMP_PERL"
 831 echo "           Perl Binary: $PERL"
 832 echo "          Perl Version: $PERL_VERSION"
 833 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 834 echo "          Ruby Modules: $COMP_RUBY"
 835 echo "           Ruby Binary: $RUBY"
 836 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 837 echo "    Build Tcl Bindings: $enable_tcl"
 838 echo " Build Python Bindings: $enable_python"
 839 echo "          Build rrdcgi: $enable_rrdcgi"
 840 echo "       Build librrd MT: $enable_pthread"
 841 echo
 842 echo
 843 echo "Type 'make' to compile the software and use 'make install' to "
 844 echo "install everything to: $prefix."
 845 echo
 846 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 847 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 848 echo "place an order."
 849 echo
 850 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 851 echo "----------------------------------------------------------------"