configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.99908020600])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devel versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.299908020600
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52 /* lets enable madvise defines in NetBSD */
  53 #if defined(__NetBSD__)
  54 # if !defined(_NETBSD_SOURCE)
  55 #  define _NETBSD_SOURCE
  56 # endif
  57 #endif
  58
  59  ])
  60
  61 AH_BOTTOM([
  62 /* make sure that we pickup the correct stuff from all headers */
  63 #ifdef HAVE_FEATURES_H
  64 #undef _XOPEN_SOURCE /* keep unmodified */
  65 #undef _BSD_SOURCE /* keep unmodified */
  66 #define _XOPEN_SOURCE 600
  67 #define _BSD_SOURCE 1
  68 # include <features.h>
  69 #endif
  70
  71 /* FreeBSD 4.8 wants this included BEFORE sys/types.h */
  72 #ifdef HAVE_SYS_MMAN_H
  73 # include <sys/mman.h>
  74 #endif
  75
  76 #ifdef HAVE_SYS_TYPES_H
  77 # include <sys/types.h>
  78 #endif
  79
  80 #ifdef HAVE_SYS_PARAM_H
  81 # include <sys/param.h>
  82 #endif
  83 #ifndef MAXPATH
  84 # ifdef PATH_MAX
  85 #  define MAXPATH PATH_MAX
  86 # endif
  87 #endif
  88 #ifndef MAXPATH
  89 /* else try the BSD variant */
  90 # ifdef MAXPATHLEN
  91 #  define MAXPATH MAXPATHLEN
  92 # endif
  93 #endif
  94
  95 #ifdef HAVE_ERRNO_H
  96 # include <errno.h>
  97 #endif
  98
  99 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
 100 /* use posix_madvise family */
 101 # define madvise posix_madvise
 102 # define MADV_NORMAL POSIX_MADV_NORMAL
 103 # define MADV_RANDOM POSIX_MADV_RANDOM
 104 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
 105 # define MADV_WILLNEED POSIX_MADV_WILLNEED
 106 # define MADV_DONTNEED POSIX_MADV_DONTNEED
 107 #endif
 108 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
 109 # define USE_MADVISE 1
 110 #endif
 111
 112 #ifdef HAVE_SYS_STAT_H
 113 # include <sys/stat.h>
 114 #endif
 115
 116 #ifdef HAVE_FCNTL_H
 117 #include <fcntl.h>
 118 #endif
 119
 120 #ifdef HAVE_UNISTD_H
 121 # include <unistd.h>
 122 #endif
 123
 124 #ifdef TIME_WITH_SYS_TIME
 125 # include <sys/time.h>
 126 # include <time.h>
 127 #else
 128 # ifdef HAVE_SYS_TIME_H
 129 #  include <sys/time.h>
 130 # else
 131 #  include <time.h>
 132 # endif
 133 #endif
 134
 135 #ifdef HAVE_SYS_TIMES_H
 136 # include <sys/times.h>
 137 #endif
 138
 139 #ifdef HAVE_SYS_RESOURCE_H
 140 # include <sys/resource.h>
 141 #if (defined(__svr4__) && defined(__sun__))
 142 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
 143    Use this instead. */
 144 extern int getrusage(int, struct rusage *);
 145 #endif /* __svr4__ && __sun__ */
 146 #endif
 147
 148
 149 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 150    make sure you are NOT using bcopy, index or rindex in the code */
 151
 152 #ifdef STDC_HEADERS
 153 # include <string.h>
 154 #else
 155 # ifndef HAVE_STRCHR
 156 #  define strchr index
 157 #  define strrchr rindex
 158 # endif
 159 char *strchr (), *strrchr ();
 160 # ifndef HAVE_MEMMOVE
 161 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 162 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 163 # endif
 164 #endif
 165
 166 #ifdef NO_NULL_REALLOC
 167 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 168 #else
 169 # define rrd_realloc(a,b) realloc((a), (b))
 170 #endif
 171
 172 #ifdef NEED_MALLOC_MALLOC_H
 173 #  include <malloc/malloc.h>
 174 #endif
 175
 176 #ifdef HAVE_STDIO_H
 177 # include <stdio.h>
 178 #endif
 179
 180 #ifdef HAVE_STDLIB_H
 181 # include <stdlib.h>
 182 #endif
 183
 184 #ifdef HAVE_CTYPE_H
 185 # include <ctype.h>
 186 #endif
 187
 188 #ifdef HAVE_DIRENT_H
 189 # include <dirent.h>
 190 # define NAMLEN(dirent) strlen((dirent)->d_name)
 191 #else
 192 # define dirent direct
 193 # define NAMLEN(dirent) (dirent)->d_namlen
 194 # ifdef HAVE_SYS_NDIR_H
 195 #  include <sys/ndir.h>
 196 # endif
 197 # ifdef HAVE_SYS_DIR_H
 198 #  include <sys/dir.h>
 199 # endif
 200 # ifdef HAVE_NDIR_H
 201 #  include <ndir.h>
 202 # endif
 203 #endif
 204
 205 #ifdef MUST_DISABLE_SIGFPE
 206 # include <signal.h>
 207 #endif
 208
 209 #ifdef MUST_DISABLE_FPMASK
 210 # include <floatingpoint.h>
 211 #endif
 212
 213
 214 #ifdef HAVE_MATH_H
 215 # include <math.h>
 216 #endif
 217
 218 #ifdef HAVE_FLOAT_H
 219 # include <float.h>
 220 #endif
 221
 222 #ifdef HAVE_IEEEFP_H
 223 # include <ieeefp.h>
 224 #endif
 225
 226 #ifdef HAVE_FP_CLASS_H
 227 # include <fp_class.h>
 228 #endif
 229
 230 /* for Solaris */
 231 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 232 #  define HAVE_ISINF 1
 233 #  ifdef isinf
 234 #  undef isinf /* confuse autoconf */
 235 #  endif
 236 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 237 #endif
 238
 239 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 240 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 241 #  undef isnan /* confuse autoconf to NOT remove this */
 242 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 243 #endif
 244
 245 /* for OSF1 Digital Unix */
 246 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 247 #  define HAVE_ISINF 1
 248 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 249 #endif
 250
 251 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 252 #  define HAVE_ISINF 1
 253 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 254 #endif
 255
 256 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 257 #  define HAVE_ISINF 1
 258 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 259 #endif
 260
 261 /* for AIX */
 262 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 263 #  define HAVE_ISINF 1
 264 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 265 #endif
 266
 267 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 268 #  define HAVE_FINITE 1
 269 #  define finite(a) isfinite(a)
 270 #endif
 271
 272 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 273 #  define HAVE_FINITE 1
 274 #  define finite(a) (! isnan(a) && ! isinf(a))
 275 #endif
 276
 277 #ifndef HAVE_FINITE
 278 #error "Can't compile without finite function"
 279 #endif
 280
 281 #ifndef HAVE_ISINF
 282 #error "Can't compile without isinf function"
 283 #endif
 284
 285 #endif /* RRD_CONFIG_H */
 286 ])
 287
 288 dnl Process Special Options
 289 dnl -----------------------------------
 290
 291 dnl gettext
 292 GETTEXT_PACKAGE=rrdtool
 293 AC_SUBST(GETTEXT_PACKAGE)
 294 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 295 IT_PROG_INTLTOOL([0.35.0],[no-xml])
 296 AM_GLIB_GNU_GETTEXT
 297
 298 dnl How the vertical axis label is printed
 299 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 300  [Vertical label angle: -90.0 (default) or 90.0])
 301 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 302  [Vertical label angle: -90.0 (default) or 90.0])
 303
 304 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 305 [],[enable_rrdcgi=yes])
 306
 307 dnl Check if we run on a system that has fonts
 308 AC_ARG_WITH(rrd-default-font,
 309 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 310 [RRD_DEFAULT_FONT=$withval],[
 311   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 312         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 313   else
 314         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 315   fi
 316 ])
 317
 318 dnl Use mmap in rrd_update instead of seek+write
 319 AC_ARG_ENABLE([mmap],
 320 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 321 [],
 322 [enable_mmap=yes])
 323
 324 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 325 [],[enable_pthread=yes])
 326
 327 AC_ARG_ENABLE(static-programs,
 328      [  --enable-static-programs  Build static programs],
 329      [case "${enableval}" in
 330        yes) staticprogs=yes ;;
 331        no)  staticprogs=no ;;
 332        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 333      esac],[staticprogs=no])
 334 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 335
 336
 337 CONFIGURE_PART(Audit Compilation Environment)
 338
 339
 340 dnl Check for the compiler and static/shared library creation.
 341 AC_PROG_CC
 342 AC_PROG_CPP
 343 AC_PROG_LIBTOOL
 344
 345 dnl Try to detect/use GNU features
 346 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 347
 348 dnl which flags does the compiler support?
 349 if test "x$GCC" = "xyes"; then
 350   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 351     oCFLAGS="$CFLAGS"
 352     CFLAGS="$CFLAGS $flag"
 353     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 354     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 355        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 356     if eval test \$$cachename = no; then
 357          CFLAGS="$oCFLAGS"
 358     fi
 359   done
 360 fi
 361
 362
 363
 364 AC_SUBST(RRD_DEFAULT_FONT)
 365
 366 CONFIGURE_PART(Checking for Header Files)
 367
 368 dnl Checks for header files.
 369 AC_HEADER_STDC
 370 AC_HEADER_DIRENT
 371 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h libintl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 372
 373 dnl Checks for typedefs, structures, and compiler characteristics.
 374 AC_C_CONST
 375 AC_HEADER_TIME
 376 AC_STRUCT_TM
 377
 378 dnl Checks for libraries.
 379 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 380
 381
 382 dnl add pic flag in any case this makes sure all our code is relocatable
 383 eval `./libtool --config | grep pic_flag`
 384 CFLAGS="$CFLAGS $pic_flag"
 385
 386 CONFIGURE_PART(Test Library Functions)
 387
 388 dnl Checks for library functions.
 389 AC_FUNC_STRFTIME
 390 AC_FUNC_VPRINTF
 391
 392 AC_C_BIGENDIAN
 393
 394 dnl for each function found we get a definition in config.h
 395 dnl of the form HAVE_FUNCTION
 396
 397 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 398
 399
 400 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 401 if test "x$enable_mmap" = "xyes"; then
 402   case "$host" in
 403   *cygwin*)
 404     # the normal mmap test does not work in cygwin
 405     AC_CHECK_FUNCS(mmap)
 406     if test "x$ac_cv_func_mmap" = "xyes"; then
 407       ac_cv_func_mmap_fixed_mapped=yes
 408     fi
 409   ;;
 410   *)
 411     AC_CHECK_HEADERS(sys/mman.h)
 412     AC_FUNC_MMAP
 413     AC_CHECK_FUNCS(mmap munmap msync)
 414     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 415                                      # include <sys/mman.h>
 416                                      #endif])
 417     if test "x$ac_cv_have_decl_madvise" = "xyes";
 418     then
 419       AC_CHECK_FUNCS(madvise)
 420     else
 421       AC_CHECK_FUNCS(posix_madvise)
 422       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 423         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 424       fi
 425     fi
 426   ;;
 427   esac
 428   if test "x$ac_cv_func_mmap" != "xyes";
 429   then
 430     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 431 dnl enable_mmap="no"
 432   fi
 433 fi
 434
 435 dnl can we use posix_fadvise
 436 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 437 #include <fcntl.h>])
 438 AC_CHECK_FUNCS(posix_fadvise)
 439
 440
 441
 442 CONFIGURE_PART(IEEE Math Checks)
 443
 444
 445 dnl actual code to check if this works
 446 AC_CHECK_FUNCS(fpclassify, ,
 447   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 448     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 449 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 450       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 451
 452 AC_CHECK_FUNCS(isinf, ,
 453   [AC_MSG_CHECKING(for isinf with <math.h>)
 454     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 455 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 456       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 457
 458 dnl finite is BSD, isfinite is C99, so prefer the latter
 459 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 460 AC_TRY_RUN([
 461 #ifdef HAVE_MATH_H
 462 #include <math.h>
 463 #endif
 464 #ifdef HAVE_FLOAT_H
 465 #include <float.h>
 466 #endif
 467 int main ()
 468 {
 469 #ifdef isfinite
 470 #ifdef LDBL_MAX
 471   if (!isfinite(LDBL_MAX)) return 1;
 472 #endif
 473 #ifdef DBL_MAX
 474   if (!isfinite(DBL_MAX)) return 1;
 475 #endif
 476 #endif
 477 return 0;
 478 }],[
 479 have_broken_isfinite=no],have_broken_isfinite=yes,[
 480 case "${target}" in
 481   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 482   *) have_broken_isfinite=no ;;
 483 esac])
 484 ])
 485 if test "x$have_broken_isfinite" = "xno"; then
 486   AC_DEFINE(HAVE_ISFINITE)
 487 else
 488 AC_CHECK_FUNCS(finite,[],
 489   [AC_CHECK_FUNCS(isfinite,[],
 490       [AC_MSG_CHECKING(for isfinite with <math.h>)
 491        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 492 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 493                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 494 fi
 495
 496 AC_FULL_IEEE
 497
 498 CONFIGURE_PART(Resolve Portability Issues)
 499
 500 dnl what does realloc do if it gets called with a NULL pointer
 501
 502 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 503 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 504               int main(void){
 505               char *x = NULL;
 506               x = realloc (x,10);
 507               if (x==NULL) return 1;
 508               return 0;
 509              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 510
 511 if test x"$rd_cv_null_realloc" = xnope; then
 512 AC_DEFINE(NO_NULL_REALLOC)
 513 fi
 514
 515 AC_LANG_PUSH(C)
 516 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 517 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 518 AC_LINK_IFELSE(
 519     AC_LANG_PROGRAM(
 520            [[#include <time.h>]],
 521            [[ctime_r(NULL,NULL,0)]]
 522                    ),
 523     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 524       AC_LINK_IFELSE(
 525           AC_LANG_PROGRAM(
 526                 [[#include <time.h>]],
 527                 [[ctime_r(NULL,NULL)]]
 528                          ),
 529           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 530           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 531       )
 532     ],
 533     [ AC_LINK_IFELSE(
 534           AC_LANG_PROGRAM(
 535                 [[#include <time.h>]],
 536                 [[ctime_r(NULL,NULL)]]
 537                          ),
 538           [AC_MSG_RESULT(no)],
 539           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 540       )
 541     ]
 542 )
 543 AC_LANG_POP(C)
 544
 545 dnl Check for pthreads
 546 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 547
 548 AC_SUBST(MULTITHREAD_CFLAGS)
 549 AC_SUBST(MULTITHREAD_LDFLAGS)
 550
 551 if test $enable_pthread != no; then
 552  ACX_PTHREAD([
 553     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 554     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 555              ],
 556              [])
 557 fi
 558
 559 dnl since we use lots of *_r functions all over the code we better
 560 dnl make sure they are known
 561
 562 if test  "x$x_rflag" != "xno"; then
 563    CPPFLAGS="$CPPFLAGS $x_rflag"
 564 fi
 565
 566 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 567
 568 AC_LANG_PUSH(C)
 569 dnl see if we have to include malloc/malloc.h
 570 AC_MSG_CHECKING([do we need malloc/malloc.h])
 571 AC_LINK_IFELSE(
 572     AC_LANG_PROGRAM(
 573            [[#include <stdlib.h>]],
 574            [[malloc(1)]]
 575                    ),
 576     [ AC_MSG_RESULT([nope, works out of the box]) ],
 577     [ AC_LINK_IFELSE(
 578           AC_LANG_PROGRAM(
 579                 [[#include <stdlib.h>
 580                   #include <malloc/malloc.h>]],
 581                 [[malloc(1)]]
 582                          ),
 583           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 584            AC_MSG_RESULT([yes we do])],
 585           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 586       )
 587     ]
 588 )
 589 AC_LANG_POP(C)
 590
 591 dnl Could use these to know if we need to provide a prototype
 592 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 593
 594 dnl solaris has fdatasync in the librt
 595
 596 AC_CHECK_FUNC(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"],[]))
 597
 598
 599 CONFIGURE_PART(Find 3rd-Party Libraries)
 600
 601
 602 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 603
 604 CORE_LIBS="$LIBS"
 605
 606 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 607 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 608 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 609 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 610 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 611 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 612 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 613 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 614 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 615 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 616 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 617
 618 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 619   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 620 fi
 621
 622 ALL_LIBS="$LIBS"
 623 LIBS=
 624
 625 AC_SUBST(CORE_LIBS)
 626 AC_SUBST(ALL_LIBS)
 627
 628 CONFIGURE_PART(Prep for Building Language Bindings)
 629
 630 dnl Check for Perl.
 631 AC_PATH_PROG(PERL, perl, no)
 632
 633 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 634 [],[enable_perl=yes])
 635
 636
 637 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 638 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 639 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 640 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 641
 642 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 643         COMP_PERL=
 644 else
 645         COMP_PERL="perl_piped perl_shared"
 646         AC_MSG_CHECKING(for the perl version you are running)
 647         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 648         AC_MSG_RESULT($PERL_VERSION)
 649         if test -z "$PERLCC"; then
 650             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 651             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 652             AC_MSG_RESULT($perlcc)
 653             if test ! -x "$perlcc"; then
 654                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 655                 if test "$PERL_CC" = "no"; then
 656                     AC_MSG_WARN([
 657 I would not find the Compiler ($perlcc) that was originally used to compile
 658 your perl binary. You should either make sure that this compiler is
 659 available on your system, pick an other compiler and set PERLCC
 660 appropriately, or use a different perl setup that was compiled locally.
 661
 662 I will disable the compilation of the RRDs perl module for now.
 663 ])
 664                     COMP_PERL="perl_piped"
 665                 fi
 666             fi
 667         fi
 668 fi
 669
 670 AC_MSG_CHECKING(Perl Modules to build)
 671 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 672
 673 # Options to pass when configuring perl module
 674 ppref=$prefix
 675 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 676
 677 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 678
 679 dnl pass additional perl options when generating Makefile from Makefile.PL
 680 AC_ARG_ENABLE(perl-site-install,
 681 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 682                           together with rrdtool in $prefix/lib/perl. You have to
 683                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 684                           when you want to use them. When you set this option
 685                           the perl modules will get installed wherever
 686                           your perl setup thinks it is best.],
 687 [PERL_MAKE_OPTIONS=],[])
 688
 689 if test ! -z "$PERLCC"; then
 690    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 691
 692    if test ! -z "$PERLCCFLAGS"; then
 693        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 694    fi
 695
 696    if test -z "$PERLLD"; then
 697        PERLLD=$PERLCC
 698    fi
 699    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 700
 701    if test ! -z "$PERLLDFLAGS"; then
 702        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 703    fi
 704 fi
 705
 706 AC_ARG_WITH(perl-options,
 707 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 708                           generating Makefile from Makefile.PL. If you set this
 709                           option, interesting things may happen unless you know
 710                           what you are doing!],
 711 [PERL_MAKE_OPTIONS=$withval])
 712
 713 AC_SUBST(PERL_MAKE_OPTIONS)
 714 AC_SUBST(PERL)
 715 AC_SUBST(COMP_PERL)
 716 AC_SUBST(PERL_VERSION)
 717
 718 dnl Check for Ruby.
 719 AC_PATH_PROG(RUBY, ruby, no)
 720
 721 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 722 [],[enable_ruby=yes])
 723
 724 AC_MSG_CHECKING(if ruby modules can be built)
 725
 726 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 727         COMP_RUBY=
 728         AC_MSG_RESULT(No .. Ruby not found or disabled)
 729 else
 730         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 731                 COMP_RUBY="ruby"
 732                 AC_MSG_RESULT(YES)
 733         else
 734                 COMP_RUBY=
 735                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 736         fi
 737 fi
 738
 739
 740 dnl pass additional ruby options when generating Makefile from Makefile.PL
 741 AC_ARG_ENABLE(ruby-site-install,
 742 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 743                           together with rrdtool in $prefix/lib/ruby. You have to
 744                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 745                           for ruby to find the RRD.so file.],
 746 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$prefix/lib/ruby"])
 747
 748
 749 AC_ARG_WITH(ruby-options,
 750 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 751                           generating Makefile from extconf.rb. If you set this
 752                           option, interesting things may happen unless you know
 753                           what you are doing!],
 754 [RUBY_MAKE_OPTIONS=$withval])
 755
 756 AC_SUBST(RUBY_MAKE_OPTIONS)
 757 AC_SUBST(RUBY)
 758 AC_SUBST(COMP_RUBY)
 759
 760
 761 enable_tcl_site=no
 762
 763 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 764 [],[enable_tcl=yes])
 765
 766 if test  "$enable_tcl" = "yes"; then
 767   dnl Check for Tcl.
 768   withval=""
 769   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 770   enable_tcl=no
 771   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 772     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 773     if test -f "$dir/tclConfig.sh" ; then
 774         tcl_config=$dir/tclConfig.sh
 775         enable_tcl=yes
 776         AC_MSG_RESULT(yes)
 777         break
 778     else
 779         AC_MSG_RESULT(no)
 780     fi
 781   done
 782
 783   if test "$enable_tcl" = "no"; then
 784         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 785   else
 786         . $tcl_config
 787         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 788   fi
 789   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 790   [],[enable_tcl_site=yes])
 791
 792 fi
 793
 794 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 795 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 796
 797 AC_SUBST(TCL_PREFIX)
 798 AC_SUBST(TCL_SHLIB_CFLAGS)
 799 AC_SUBST(TCL_SHLIB_LD)
 800 AC_SUBST(TCL_SHLIB_SUFFIX)
 801 AC_SUBST(TCL_PACKAGE_PATH)
 802 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 803 AC_SUBST(TCL_STUB_LIB_SPEC)
 804 AC_SUBST(TCL_VERSION)
 805 AC_SUBST(TCL_PACKAGE_DIR)
 806 AC_SUBST(TCL_INC_DIR)
 807
 808 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 809 [],[enable_python=yes])
 810
 811 if test  "$enable_python" = "yes"; then
 812 dnl Check for python
 813 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 814 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 815 fi
 816
 817 if test  x$enable_python = xno; then
 818         COMP_PYTHON=
 819 else
 820         COMP_PYTHON="python"
 821 fi
 822
 823 AC_SUBST(COMP_PYTHON)
 824
 825 dnl Check for nroff
 826 AC_PATH_PROGS(NROFF, gnroff nroff)
 827 AC_PATH_PROGS(TROFF, groff troff)
 828
 829 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 830 if test -z "$RRDDOCDIR"; then
 831    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 832
 833
 834 CONFIGURE_PART(Apply Configuration Information)
 835
 836 AC_CONFIG_FILES([examples/shared-demo.pl])
 837 AC_CONFIG_FILES([examples/piped-demo.pl])
 838 AC_CONFIG_FILES([examples/stripes.pl])
 839 AC_CONFIG_FILES([examples/bigtops.pl])
 840 AC_CONFIG_FILES([examples/minmax.pl])
 841 AC_CONFIG_FILES([examples/4charts.pl])
 842 AC_CONFIG_FILES([examples/perftest.pl])
 843 AC_CONFIG_FILES([examples/Makefile])
 844 AC_CONFIG_FILES([doc/Makefile])
 845 AC_CONFIG_FILES([po/Makefile.in])
 846 AC_CONFIG_FILES([src/Makefile])
 847 AC_CONFIG_FILES([bindings/Makefile])
 848 AC_CONFIG_FILES([bindings/tcl/Makefile])
 849 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 850 AC_CONFIG_FILES([Makefile])
 851
 852 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 853 AC_OUTPUT
 854
 855 AC_MSG_CHECKING(in)
 856 AC_MSG_RESULT(and out again)
 857
 858 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 859 sleep 1
 860 echo $ECHO_N ".$ECHO_C" 1>&6
 861 sleep 1
 862 echo $ECHO_N ".$ECHO_C" 1>&6
 863 sleep 1
 864 echo $ECHO_N ".$ECHO_C" 1>&6
 865 sleep 1
 866 echo $ECHO_N ".$ECHO_C" 1>&6
 867 sleep 1
 868 AC_MSG_RESULT([ just kidding ;-)])
 869 echo
 870 echo "----------------------------------------------------------------"
 871 echo "Config is DONE!"
 872 echo
 873 echo "          With MMAP IO: $enable_mmap"
 874 echo "       Static programs: $staticprogs"
 875 echo "          Perl Modules: $COMP_PERL"
 876 echo "           Perl Binary: $PERL"
 877 echo "          Perl Version: $PERL_VERSION"
 878 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 879 echo "          Ruby Modules: $COMP_RUBY"
 880 echo "           Ruby Binary: $RUBY"
 881 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 882 echo "    Build Tcl Bindings: $enable_tcl"
 883 echo " Build Python Bindings: $enable_python"
 884 echo "          Build rrdcgi: $enable_rrdcgi"
 885 echo "       Build librrd MT: $enable_pthread"
 886 echo
 887 echo
 888 echo "Type 'make' to compile the software and use 'make install' to "
 889 echo "install everything to: $prefix."
 890 echo
 891 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 892 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 893 echo "place an order."
 894 echo
 895 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 896 echo "----------------------------------------------------------------"