configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.99907052400])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devel versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.299907052400
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52  ])
  53
  54 AH_BOTTOM([
  55 /* make sure that we pickup the correct stuff from all headers */
  56 #define _XOPEN_SOURCE 600
  57 #ifdef HAVE_FEATURES_H
  58 # include <features.h>
  59 #endif
  60
  61 #ifdef HAVE_SYS_TYPES_H
  62 # include <sys/types.h>
  63 #endif
  64
  65 #ifdef HAVE_SYS_PARAM_H
  66 # include <sys/param.h>
  67 #endif
  68 #ifndef MAXPATH
  69 # ifdef PATH_MAX
  70 #  define MAXPATH PATH_MAX
  71 # endif
  72 #endif
  73 #ifndef MAXPATH
  74 /* else try the BSD variant */
  75 # ifdef MAXPATHLEN
  76 #  define MAXPATH MAXPATHLEN
  77 # endif
  78 #endif
  79
  80 #ifdef HAVE_ERRNO_H
  81 # include <errno.h>
  82 #endif
  83
  84 #ifdef HAVE_SYS_MMAN_H
  85 # include <sys/mman.h>
  86 #endif
  87 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
  88 /* use posix_madvise family */
  89 # define madvise posix_madvise
  90 # define MADV_NORMAL POSIX_MADV_NORMAL
  91 # define MADV_RANDOM POSIX_MADV_RANDOM
  92 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
  93 # define MADV_WILLNEED POSIX_MADV_WILLNEED
  94 # define MADV_DONTNEED POSIX_MADV_DONTNEED
  95 #endif
  96 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
  97 # define USE_MADVISE 1
  98 #endif
  99
 100 #ifdef HAVE_SYS_STAT_H
 101 # include <sys/stat.h>
 102 #endif
 103
 104 #ifdef HAVE_FCNTL_H
 105 #include <fcntl.h>
 106 #endif
 107
 108 #ifdef HAVE_UNISTD_H
 109 # include <unistd.h>
 110 #endif
 111
 112 #ifdef TIME_WITH_SYS_TIME
 113 # include <sys/time.h>
 114 # include <time.h>
 115 #else
 116 # ifdef HAVE_SYS_TIME_H
 117 #  include <sys/time.h>
 118 # else
 119 #  include <time.h>
 120 # endif
 121 #endif
 122
 123 #ifdef HAVE_SYS_TIMES_H
 124 # include <sys/times.h>
 125 #endif
 126
 127 #ifdef HAVE_SYS_RESOURCE_H
 128 # include <sys/resource.h>
 129 #if (defined(__svr4__) && defined(__sun__))
 130 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
 131    Use this instead. */
 132 extern int getrusage(int, struct rusage *);
 133 #endif /* __svr4__ && __sun__ */
 134 #endif
 135
 136
 137 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 138    make sure you are NOT using bcopy, index or rindex in the code */
 139
 140 #ifdef STDC_HEADERS
 141 # include <string.h>
 142 #else
 143 # ifndef HAVE_STRCHR
 144 #  define strchr index
 145 #  define strrchr rindex
 146 # endif
 147 char *strchr (), *strrchr ();
 148 # ifndef HAVE_MEMMOVE
 149 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 150 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 151 # endif
 152 #endif
 153
 154 #ifdef NO_NULL_REALLOC
 155 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 156 #else
 157 # define rrd_realloc(a,b) realloc((a), (b))
 158 #endif
 159
 160 #ifdef NEED_MALLOC_MALLOC_H
 161 #  include <malloc/malloc.h>
 162 #endif
 163
 164 #ifdef HAVE_STDIO_H
 165 # include <stdio.h>
 166 #endif
 167
 168 #ifdef HAVE_STDLIB_H
 169 # include <stdlib.h>
 170 #endif
 171
 172 #ifdef HAVE_CTYPE_H
 173 # include <ctype.h>
 174 #endif
 175
 176 #ifdef HAVE_DIRENT_H
 177 # include <dirent.h>
 178 # define NAMLEN(dirent) strlen((dirent)->d_name)
 179 #else
 180 # define dirent direct
 181 # define NAMLEN(dirent) (dirent)->d_namlen
 182 # ifdef HAVE_SYS_NDIR_H
 183 #  include <sys/ndir.h>
 184 # endif
 185 # ifdef HAVE_SYS_DIR_H
 186 #  include <sys/dir.h>
 187 # endif
 188 # ifdef HAVE_NDIR_H
 189 #  include <ndir.h>
 190 # endif
 191 #endif
 192
 193 #ifdef MUST_DISABLE_SIGFPE
 194 # include <signal.h>
 195 #endif
 196
 197 #ifdef MUST_DISABLE_FPMASK
 198 # include <floatingpoint.h>
 199 #endif
 200
 201
 202 #ifdef HAVE_MATH_H
 203 # include <math.h>
 204 #endif
 205
 206 #ifdef HAVE_FLOAT_H
 207 # include <float.h>
 208 #endif
 209
 210 #ifdef HAVE_IEEEFP_H
 211 # include <ieeefp.h>
 212 #endif
 213
 214 #ifdef HAVE_FP_CLASS_H
 215 # include <fp_class.h>
 216 #endif
 217
 218 /* for Solaris */
 219 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 220 #  define HAVE_ISINF 1
 221 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 222 #endif
 223
 224 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 225 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 226 #  undef isnan
 227 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 228 #endif
 229
 230 /* for OSF1 Digital Unix */
 231 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 232 #  define HAVE_ISINF 1
 233 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 234 #endif
 235
 236 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 237 #  define HAVE_ISINF 1
 238 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 239 #endif
 240
 241 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 242 #  define HAVE_ISINF 1
 243 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 244 #endif
 245
 246 /* for AIX */
 247 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 248 #  define HAVE_ISINF 1
 249 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 250 #endif
 251
 252 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 253 #  define HAVE_FINITE 1
 254 #  define finite(a) isfinite(a)
 255 #endif
 256
 257 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 258 #  define HAVE_FINITE 1
 259 #  define finite(a) (! isnan(a) && ! isinf(a))
 260 #endif
 261
 262 #ifndef HAVE_FINITE
 263 #error "Can't compile without finite function"
 264 #endif
 265
 266 #ifndef HAVE_ISINF
 267 #error "Can't compile without isinf function"
 268 #endif
 269
 270 #endif /* RRD_CONFIG_H */
 271 ])
 272
 273 dnl Process Special Options
 274 dnl -----------------------------------
 275
 276 dnl How the vertical axis label is printed
 277 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 278  [Vertical label angle: 90.0 (default) or 270.0])
 279 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 280  [Vertical label angle: 90.0 (default) or 270.0])
 281
 282 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 283 [],[enable_rrdcgi=yes])
 284
 285 dnl Check if we run on a system that has fonts
 286 AC_ARG_WITH(rrd-default-font,
 287 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 288 [RRD_DEFAULT_FONT=$withval],[
 289   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 290         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 291   else
 292         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 293   fi
 294 ])
 295
 296 dnl Use mmap in rrd_update instead of seek+write
 297 AC_ARG_ENABLE([mmap],
 298 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 299 [],
 300 [enable_mmap=yes])
 301
 302 dnl will most likely not work on compressed filesystems, i think.. *shrug*
 303 AC_ARG_ENABLE([direct-io],
 304 [  --enable-direct-io      enable O_DIRECT if available],
 305 [enable_direct_io=yes],
 306 [])
 307
 308  AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 309 [],[enable_pthread=yes])
 310
 311
 312
 313 CONFIGURE_PART(Audit Compilation Environment)
 314
 315
 316 dnl Check for the compiler and static/shared library creation.
 317 AC_PROG_CC
 318 AC_PROG_CPP
 319 AC_PROG_LIBTOOL
 320
 321 dnl Try to detect/use GNU features
 322 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 323
 324 dnl which flags does the compiler support?
 325 if test "x$GCC" = "xyes"; then
 326   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W; do
 327     oCFLAGS="$CFLAGS"
 328     CFLAGS="$CFLAGS $flag"
 329     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 330     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 331        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 332     if eval test \$$cachename = no; then
 333          CFLAGS="$oCFLAGS"
 334     fi
 335   done
 336 fi
 337
 338
 339
 340 AC_SUBST(RRD_DEFAULT_FONT)
 341
 342 CONFIGURE_PART(Checking for Header Files)
 343
 344 dnl Checks for header files.
 345 AC_HEADER_STDC
 346 AC_HEADER_DIRENT
 347 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 348
 349 if test "x$enable_direct_io" = "xyes"; then
 350 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],rrd_cv_HAVE_OPEN_O_DIRECT,[
 351 AC_TRY_COMPILE([
 352 #ifdef HAVE_UNISTD_H
 353 #include <unistd.h>
 354 #endif
 355 #ifdef HAVE_FCNTL_H
 356 #include <fcntl.h>
 357 #endif],
 358 [int fd = open("/dev/null", O_DIRECT);],
 359 rrd_cv_HAVE_OPEN_O_DIRECT=yes,rrd_cv_HAVE_OPEN_O_DIRECT=no)])
 360   if test "x$rrd_cv_HAVE_OPEN_O_DIRECT" = "xyes"; then
 361     AC_DEFINE(USE_DIRECT_IO,1,[Whether the open(2) accepts O_DIRECT])
 362   else
 363     enable_direct_io="no"
 364   fi
 365 else
 366   enable_direct_io="no"
 367 fi
 368
 369 dnl Checks for typedefs, structures, and compiler characteristics.
 370 AC_C_CONST
 371 AC_HEADER_TIME
 372 AC_STRUCT_TM
 373
 374 dnl Checks for libraries.
 375 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 376
 377 dnl add pic flag in any case this makes sure all our code is relocatable
 378 eval `./libtool --config | grep pic_flag`
 379 CFLAGS="$CFLAGS $pic_flag"
 380
 381 CONFIGURE_PART(Test Library Functions)
 382
 383 dnl Checks for library functions.
 384 AC_FUNC_STRFTIME
 385 AC_FUNC_VPRINTF
 386
 387 AC_C_BIGENDIAN
 388
 389 dnl for each function found we get a definition in config.h
 390 dnl of the form HAVE_FUNCTION
 391
 392 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 393
 394 dnl Could use these to know if we need to provide a prototype
 395 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 396
 397 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 398 if test "x$enable_mmap" = "xyes"; then
 399   case "$host" in
 400   *cygwin*)
 401     # the normal mmap test does not work in cygwin
 402     AC_CHECK_FUNCS(mmap)
 403     if test "x$ac_cv_func_mmap" = "xyes"; then
 404       ac_cv_func_mmap_fixed_mapped=yes
 405     fi
 406   ;;
 407   *)
 408     AC_CHECK_HEADERS(sys/mman.h)
 409     AC_FUNC_MMAP
 410     AC_CHECK_FUNCS(mmap munmap)
 411     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 412                                      # include <sys/mman.h>
 413                                      #endif])
 414     if test "x$ac_cv_have_decl_madvise" = "xyes";
 415     then
 416       AC_CHECK_FUNCS(madvise)
 417     else
 418       AC_CHECK_FUNCS(posix_madvise)
 419       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 420         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 421       fi
 422     fi
 423   ;;
 424   esac
 425   if test "x$ac_cv_func_mmap" != "xyes";
 426   then
 427     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 428 dnl enable_mmap="no"
 429   fi
 430 fi
 431
 432 dnl use FD based I/O ?
 433 if test "x$enable_mmap" = "xno";then
 434     AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 435 #include <fcntl.h>])
 436     AC_CHECK_FUNCS(posix_fadvise)
 437 fi
 438
 439
 440 CONFIGURE_PART(IEEE Math Checks)
 441
 442
 443 dnl actual code to check if this works
 444 AC_CHECK_FUNCS(fpclassify, ,
 445   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 446     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 447 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 448       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 449
 450 AC_CHECK_FUNCS(isinf, ,
 451   [AC_MSG_CHECKING(for isinf with <math.h>)
 452     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 453 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 454       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 455
 456 dnl finite is BSD, isfinite is C99, so prefer the latter
 457 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 458 AC_TRY_RUN([
 459 #ifdef HAVE_MATH_H
 460 #include <math.h>
 461 #endif
 462 #ifdef HAVE_FLOAT_H
 463 #include <float.h>
 464 #endif
 465 int main ()
 466 {
 467 #ifdef isfinite
 468 #ifdef LDBL_MAX
 469   if (!isfinite(LDBL_MAX)) return 1;
 470 #endif
 471 #ifdef DBL_MAX
 472   if (!isfinite(DBL_MAX)) return 1;
 473 #endif
 474 #endif
 475 return 0;
 476 }],[
 477 have_broken_isfinite=no],have_broken_isfinite=yes,[
 478 case "${target}" in
 479   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 480   *) have_broken_isfinite=no ;;
 481 esac])
 482 ])
 483 if test "x$have_broken_isfinite" = "xno"; then
 484   AC_DEFINE(HAVE_ISFINITE)
 485 else
 486 AC_CHECK_FUNCS(finite,[],
 487   [AC_CHECK_FUNCS(isfinite,[],
 488       [AC_MSG_CHECKING(for isfinite with <math.h>)
 489        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 490 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 491                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 492 fi
 493
 494 AC_FULL_IEEE
 495
 496 CONFIGURE_PART(Resolve Portability Issues)
 497
 498 dnl what does realloc do if it gets called with a NULL pointer
 499
 500 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 501 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 502               int main(void){
 503               char *x = NULL;
 504               x = realloc (x,10);
 505               if (x==NULL) return 1;
 506               return 0;
 507              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 508
 509 if test x"$rd_cv_null_realloc" = xnope; then
 510 AC_DEFINE(NO_NULL_REALLOC)
 511 fi
 512
 513 AC_LANG_PUSH(C)
 514 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 515 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 516 AC_LINK_IFELSE(
 517     AC_LANG_PROGRAM(
 518            [[#include <time.h>]],
 519            [[ctime_r(NULL,NULL,0)]]
 520                    ),
 521     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 522       AC_LINK_IFELSE(
 523           AC_LANG_PROGRAM(
 524                 [[#include <time.h>]],
 525                 [[ctime_r(NULL,NULL)]]
 526                          ),
 527           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 528           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 529       )
 530     ],
 531     [ AC_LINK_IFELSE(
 532           AC_LANG_PROGRAM(
 533                 [[#include <time.h>]],
 534                 [[ctime_r(NULL,NULL)]]
 535                          ),
 536           [AC_MSG_RESULT(no)],
 537           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 538       )
 539     ]
 540 )
 541 AC_LANG_POP(C)
 542
 543 dnl Check for pthreads
 544 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 545
 546 AC_SUBST(MULTITHREAD_CFLAGS)
 547 AC_SUBST(MULTITHREAD_LDFLAGS)
 548
 549 if test $enable_pthread != no; then
 550  ACX_PTHREAD([
 551     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 552     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 553              ],
 554              [])
 555 fi
 556
 557 dnl since we use lots of *_r functions all over the code we better
 558 dnl make sure they are known
 559
 560 if test  "x$x_rflag" != "xno"; then
 561    CPPFLAGS="$CPPFLAGS $x_rflag"
 562 fi
 563
 564 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 565
 566 AC_LANG_PUSH(C)
 567 dnl see if we have to include malloc/malloc.h
 568 AC_MSG_CHECKING([do we need malloc/malloc.h])
 569 AC_LINK_IFELSE(
 570     AC_LANG_PROGRAM(
 571            [[#include <stdlib.h>]],
 572            [[malloc(1)]]
 573                    ),
 574     [ AC_MSG_RESULT([nope, works out of the box]) ],
 575     [ AC_LINK_IFELSE(
 576           AC_LANG_PROGRAM(
 577                 [[#include <stdlib.h>
 578                   #include <malloc/malloc.h>]],
 579                 [[malloc(1)]]
 580                          ),
 581           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 582            AC_MSG_RESULT([yes we do])],
 583           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 584       )
 585     ]
 586 )
 587 AC_LANG_POP(C)
 588
 589 CONFIGURE_PART(Find 3rd-Party Libraries)
 590
 591
 592 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 593
 594 CORE_LIBS="$LIBS"
 595
 596 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 597 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 598 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 599 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 600
 601 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 602   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 603 fi
 604
 605 ALL_LIBS="$LIBS"
 606 LIBS=
 607
 608 AC_SUBST(CORE_LIBS)
 609 AC_SUBST(ALL_LIBS)
 610
 611 CONFIGURE_PART(Prep for Building Language Bindings)
 612
 613 dnl Check for Perl.
 614 AC_PATH_PROG(PERL, perl, no)
 615
 616 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 617 [],[enable_perl=yes])
 618
 619
 620 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 621 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 622 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 623 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 624
 625 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 626         COMP_PERL=
 627 else
 628         COMP_PERL="perl_piped perl_shared"
 629         AC_MSG_CHECKING(for the perl version you are running)
 630         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 631         AC_MSG_RESULT($PERL_VERSION)
 632         if test -z "$PERLCC"; then
 633             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 634             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 635             AC_MSG_RESULT($perlcc)
 636             if test ! -x "$perlcc"; then
 637                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 638                 if test "$PERL_CC" = "no"; then
 639                     AC_MSG_WARN([
 640 I would not find the Compiler ($perlcc) that was originally used to compile
 641 your perl binary. You should either make sure that this compiler is
 642 available on your system, pick an other compiler and set PERLCC
 643 appropriately, or use a different perl setup that was compiled locally.
 644
 645 I will disable the compilation of the RRDs perl module for now.
 646 ])
 647                     COMP_PERL="perl_piped"
 648                 fi
 649             fi
 650         fi
 651 fi
 652
 653 AC_MSG_CHECKING(Perl Modules to build)
 654 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 655
 656 # Options to pass when configuring perl module
 657 ppref=$prefix
 658 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 659
 660 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 661
 662 dnl pass additional perl options when generating Makefile from Makefile.PL
 663 AC_ARG_ENABLE(perl-site-install,
 664 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 665                           together with rrdtool in $prefix/lib/perl. You have to
 666                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 667                           when you want to use them. When you set this option
 668                           the perl modules will get installed wherever
 669                           your perl setup thinks it is best.],
 670 [PERL_MAKE_OPTIONS=],[])
 671
 672 if test ! -z "$PERLCC"; then
 673    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 674
 675    if test ! -z "$PERLCCFLAGS"; then
 676        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 677    fi
 678
 679    if test -z "$PERLLD"; then
 680        PERLLD=$PERLCC
 681    fi
 682    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 683
 684    if test ! -z "$PERLLDFLAGS"; then
 685        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 686    fi
 687 fi
 688
 689 AC_ARG_WITH(perl-options,
 690 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 691                           generating Makefile from Makefile.PL. If you set this
 692                           option, interesting things may happen unless you know
 693                           what you are doing!],
 694 [PERL_MAKE_OPTIONS=$withval])
 695
 696 AC_SUBST(PERL_MAKE_OPTIONS)
 697 AC_SUBST(PERL)
 698 AC_SUBST(COMP_PERL)
 699 AC_SUBST(PERL_VERSION)
 700
 701 dnl Check for Ruby.
 702 AC_PATH_PROG(RUBY, ruby, no)
 703
 704 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 705 [],[enable_ruby=yes])
 706
 707 AC_MSG_CHECKING(if ruby modules can be built)
 708
 709 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 710         COMP_RUBY=
 711         AC_MSG_RESULT(No .. Ruby not found or disabled)
 712 else
 713         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 714                 COMP_RUBY="ruby"
 715                 AC_MSG_RESULT(YES)
 716         else
 717                 COMP_RUBY=
 718                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 719         fi
 720 fi
 721
 722
 723 dnl pass additional ruby options when generating Makefile from Makefile.PL
 724 AC_ARG_ENABLE(ruby-site-install,
 725 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 726                           together with rrdtool in $prefix/lib/ruby. You have to
 727                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 728                           for ruby to find the RRD.so file.],
 729 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 730
 731
 732 AC_ARG_WITH(ruby-options,
 733 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 734                           generating Makefile from extconf.rb. If you set this
 735                           option, interesting things may happen unless you know
 736                           what you are doing!],
 737 [RUBY_MAKE_OPTIONS=$withval])
 738
 739 AC_SUBST(RUBY_MAKE_OPTIONS)
 740 AC_SUBST(RUBY)
 741 AC_SUBST(COMP_RUBY)
 742
 743
 744 enable_tcl_site=no
 745
 746 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 747 [],[enable_tcl=yes])
 748
 749 if test  "$enable_tcl" = "yes"; then
 750   dnl Check for Tcl.
 751   withval=""
 752   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 753   enable_tcl=no
 754   for dir in $withval /usr/lib /usr/local/lib; do
 755     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 756     if test -f "$dir/tclConfig.sh" ; then
 757         tcl_config=$dir/tclConfig.sh
 758         enable_tcl=yes
 759         AC_MSG_RESULT(yes)
 760         break
 761     else
 762         AC_MSG_RESULT(no)
 763     fi
 764   done
 765
 766   if test "$enable_tcl" = "no"; then
 767         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 768   else
 769         . $tcl_config
 770         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 771   fi
 772   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 773   [],[enable_tcl_site=yes])
 774
 775 fi
 776
 777 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 778 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 779
 780 AC_SUBST(TCL_PREFIX)
 781 AC_SUBST(TCL_SHLIB_CFLAGS)
 782 AC_SUBST(TCL_SHLIB_LD)
 783 AC_SUBST(TCL_SHLIB_SUFFIX)
 784 AC_SUBST(TCL_PACKAGE_PATH)
 785 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 786 AC_SUBST(TCL_STUB_LIB_SPEC)
 787 AC_SUBST(TCL_VERSION)
 788 AC_SUBST(TCL_PACKAGE_DIR)
 789
 790 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 791 [],[enable_python=yes])
 792
 793 if test  "$enable_python" = "yes"; then
 794 dnl Check for python
 795 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 796 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 797 fi
 798
 799 if test  x$enable_python = xno; then
 800         COMP_PYTHON=
 801 else
 802         COMP_PYTHON="python"
 803 fi
 804
 805 AC_SUBST(COMP_PYTHON)
 806
 807 dnl Check for nroff
 808 AC_PATH_PROGS(NROFF, gnroff nroff)
 809 AC_PATH_PROGS(TROFF, groff troff)
 810
 811 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 812 if test -z "$RRDDOCDIR"; then
 813    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 814
 815
 816 CONFIGURE_PART(Apply Configuration Information)
 817
 818 AC_CONFIG_FILES([examples/shared-demo.pl])
 819 AC_CONFIG_FILES([examples/piped-demo.pl])
 820 AC_CONFIG_FILES([examples/stripes.pl])
 821 AC_CONFIG_FILES([examples/bigtops.pl])
 822 AC_CONFIG_FILES([examples/minmax.pl])
 823 AC_CONFIG_FILES([examples/4charts.pl])
 824 AC_CONFIG_FILES([examples/perftest.pl])
 825 AC_CONFIG_FILES([examples/Makefile])
 826 AC_CONFIG_FILES([doc/Makefile])
 827 AC_CONFIG_FILES([src/Makefile])
 828 AC_CONFIG_FILES([bindings/Makefile])
 829 AC_CONFIG_FILES([bindings/tcl/Makefile])
 830 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 831 AC_CONFIG_FILES([Makefile])
 832
 833 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 834 AC_OUTPUT
 835
 836 AC_MSG_CHECKING(in)
 837 AC_MSG_RESULT(and out again)
 838
 839 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 840 sleep 1
 841 echo $ECHO_N ".$ECHO_C" 1>&6
 842 sleep 1
 843 echo $ECHO_N ".$ECHO_C" 1>&6
 844 sleep 1
 845 echo $ECHO_N ".$ECHO_C" 1>&6
 846 sleep 1
 847 echo $ECHO_N ".$ECHO_C" 1>&6
 848 sleep 1
 849 AC_MSG_RESULT([ just kidding ;-)])
 850 echo
 851 echo "----------------------------------------------------------------"
 852 echo "Config is DONE!"
 853 echo
 854 echo "          With MMAP IO: $enable_mmap"
 855 echo "          Use O_DIRECT: $enable_direct_io"
 856 echo "          Perl Modules: $COMP_PERL"
 857 echo "           Perl Binary: $PERL"
 858 echo "          Perl Version: $PERL_VERSION"
 859 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 860 echo "          Ruby Modules: $COMP_RUBY"
 861 echo "           Ruby Binary: $RUBY"
 862 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 863 echo "    Build Tcl Bindings: $enable_tcl"
 864 echo " Build Python Bindings: $enable_python"
 865 echo "          Build rrdcgi: $enable_rrdcgi"
 866 echo "       Build librrd MT: $enable_pthread"
 867 echo
 868 echo
 869 echo "Type 'make' to compile the software and use 'make install' to "
 870 echo "install everything to: $prefix."
 871 echo
 872 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 873 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 874 echo "place an order."
 875 echo
 876 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 877 echo "----------------------------------------------------------------"