configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.99907080300])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devel versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.299907080300
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52 /* lets enable madvise defines in NetBSD */
  53 #if defined(__NetBSD__)
  54 # if !defined(_NETBSD_SOURCE)
  55 #  define _NETBSD_SOURCE
  56 # endif
  57 #endif
  58
  59  ])
  60
  61 AH_BOTTOM([
  62 /* make sure that we pickup the correct stuff from all headers */
  63 #ifdef HAVE_FEATURES_H
  64 #define _XOPEN_SOURCE 600
  65 #define _BSD_SOURCE 1
  66 # include <features.h>
  67 #endif
  68
  69 #ifdef HAVE_SYS_TYPES_H
  70 # include <sys/types.h>
  71 #endif
  72
  73 #ifdef HAVE_SYS_PARAM_H
  74 # include <sys/param.h>
  75 #endif
  76 #ifndef MAXPATH
  77 # ifdef PATH_MAX
  78 #  define MAXPATH PATH_MAX
  79 # endif
  80 #endif
  81 #ifndef MAXPATH
  82 /* else try the BSD variant */
  83 # ifdef MAXPATHLEN
  84 #  define MAXPATH MAXPATHLEN
  85 # endif
  86 #endif
  87
  88 #ifdef HAVE_ERRNO_H
  89 # include <errno.h>
  90 #endif
  91
  92 #ifdef HAVE_SYS_MMAN_H
  93 # include <sys/mman.h>
  94 #endif
  95
  96 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
  97 /* use posix_madvise family */
  98 # define madvise posix_madvise
  99 # define MADV_NORMAL POSIX_MADV_NORMAL
 100 # define MADV_RANDOM POSIX_MADV_RANDOM
 101 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
 102 # define MADV_WILLNEED POSIX_MADV_WILLNEED
 103 # define MADV_DONTNEED POSIX_MADV_DONTNEED
 104 #endif
 105 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
 106 # define USE_MADVISE 1
 107 #endif
 108
 109 #ifdef HAVE_SYS_STAT_H
 110 # include <sys/stat.h>
 111 #endif
 112
 113 #ifdef HAVE_FCNTL_H
 114 #include <fcntl.h>
 115 #endif
 116
 117 #ifdef HAVE_UNISTD_H
 118 # include <unistd.h>
 119 #endif
 120
 121 #ifdef TIME_WITH_SYS_TIME
 122 # include <sys/time.h>
 123 # include <time.h>
 124 #else
 125 # ifdef HAVE_SYS_TIME_H
 126 #  include <sys/time.h>
 127 # else
 128 #  include <time.h>
 129 # endif
 130 #endif
 131
 132 #ifdef HAVE_SYS_TIMES_H
 133 # include <sys/times.h>
 134 #endif
 135
 136 #ifdef HAVE_SYS_RESOURCE_H
 137 # include <sys/resource.h>
 138 #if (defined(__svr4__) && defined(__sun__))
 139 /* Solaris headers (pre 2.6) don't have a getrusage prototype.
 140    Use this instead. */
 141 extern int getrusage(int, struct rusage *);
 142 #endif /* __svr4__ && __sun__ */
 143 #endif
 144
 145
 146 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 147    make sure you are NOT using bcopy, index or rindex in the code */
 148
 149 #ifdef STDC_HEADERS
 150 # include <string.h>
 151 #else
 152 # ifndef HAVE_STRCHR
 153 #  define strchr index
 154 #  define strrchr rindex
 155 # endif
 156 char *strchr (), *strrchr ();
 157 # ifndef HAVE_MEMMOVE
 158 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 159 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 160 # endif
 161 #endif
 162
 163 #ifdef NO_NULL_REALLOC
 164 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 165 #else
 166 # define rrd_realloc(a,b) realloc((a), (b))
 167 #endif
 168
 169 #ifdef NEED_MALLOC_MALLOC_H
 170 #  include <malloc/malloc.h>
 171 #endif
 172
 173 #ifdef HAVE_STDIO_H
 174 # include <stdio.h>
 175 #endif
 176
 177 #ifdef HAVE_STDLIB_H
 178 # include <stdlib.h>
 179 #endif
 180
 181 #ifdef HAVE_CTYPE_H
 182 # include <ctype.h>
 183 #endif
 184
 185 #ifdef HAVE_DIRENT_H
 186 # include <dirent.h>
 187 # define NAMLEN(dirent) strlen((dirent)->d_name)
 188 #else
 189 # define dirent direct
 190 # define NAMLEN(dirent) (dirent)->d_namlen
 191 # ifdef HAVE_SYS_NDIR_H
 192 #  include <sys/ndir.h>
 193 # endif
 194 # ifdef HAVE_SYS_DIR_H
 195 #  include <sys/dir.h>
 196 # endif
 197 # ifdef HAVE_NDIR_H
 198 #  include <ndir.h>
 199 # endif
 200 #endif
 201
 202 #ifdef MUST_DISABLE_SIGFPE
 203 # include <signal.h>
 204 #endif
 205
 206 #ifdef MUST_DISABLE_FPMASK
 207 # include <floatingpoint.h>
 208 #endif
 209
 210
 211 #ifdef HAVE_MATH_H
 212 # include <math.h>
 213 #endif
 214
 215 #ifdef HAVE_FLOAT_H
 216 # include <float.h>
 217 #endif
 218
 219 #ifdef HAVE_IEEEFP_H
 220 # include <ieeefp.h>
 221 #endif
 222
 223 #ifdef HAVE_FP_CLASS_H
 224 # include <fp_class.h>
 225 #endif
 226
 227 /* for Solaris */
 228 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 229 #  define HAVE_ISINF 1
 230 #  ifdef isinf
 231 #  undef isinf /* confuse autoconf */
 232 #  endif
 233 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 234 #endif
 235
 236 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 237 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 238 #  undef isnan /* confuse autoconf to NOT remove this */
 239 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 240 #endif
 241
 242 /* for OSF1 Digital Unix */
 243 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 244 #  define HAVE_ISINF 1
 245 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 246 #endif
 247
 248 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 249 #  define HAVE_ISINF 1
 250 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 251 #endif
 252
 253 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 254 #  define HAVE_ISINF 1
 255 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 256 #endif
 257
 258 /* for AIX */
 259 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 260 #  define HAVE_ISINF 1
 261 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 262 #endif
 263
 264 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 265 #  define HAVE_FINITE 1
 266 #  define finite(a) isfinite(a)
 267 #endif
 268
 269 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 270 #  define HAVE_FINITE 1
 271 #  define finite(a) (! isnan(a) && ! isinf(a))
 272 #endif
 273
 274 #ifndef HAVE_FINITE
 275 #error "Can't compile without finite function"
 276 #endif
 277
 278 #ifndef HAVE_ISINF
 279 #error "Can't compile without isinf function"
 280 #endif
 281
 282 #endif /* RRD_CONFIG_H */
 283 ])
 284
 285 dnl Process Special Options
 286 dnl -----------------------------------
 287
 288 dnl How the vertical axis label is printed
 289 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 290  [Vertical label angle: -90.0 (default) or 90.0])
 291 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 292  [Vertical label angle: -90.0 (default) or 90.0])
 293
 294 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 295 [],[enable_rrdcgi=yes])
 296
 297 dnl Check if we run on a system that has fonts
 298 AC_ARG_WITH(rrd-default-font,
 299 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 300 [RRD_DEFAULT_FONT=$withval],[
 301   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 302         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 303   else
 304         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 305   fi
 306 ])
 307
 308 dnl Use mmap in rrd_update instead of seek+write
 309 AC_ARG_ENABLE([mmap],
 310 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 311 [],
 312 [enable_mmap=yes])
 313
 314 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 315 [],[enable_pthread=yes])
 316
 317 AC_ARG_ENABLE(static-programs,
 318      [  --enable-static-programs  Build static programs],
 319      [case "${enableval}" in
 320        yes) staticprogs=yes ;;
 321        no)  staticprogs=no ;;
 322        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 323      esac],[staticprogs=no])
 324 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 325
 326
 327 CONFIGURE_PART(Audit Compilation Environment)
 328
 329
 330 dnl Check for the compiler and static/shared library creation.
 331 AC_PROG_CC
 332 AC_PROG_CPP
 333 AC_PROG_LIBTOOL
 334
 335 dnl Try to detect/use GNU features
 336 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 337
 338 dnl which flags does the compiler support?
 339 if test "x$GCC" = "xyes"; then
 340   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wc++-compat -Wold-style-definition -W; do
 341     oCFLAGS="$CFLAGS"
 342     CFLAGS="$CFLAGS $flag"
 343     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 344     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 345        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 346     if eval test \$$cachename = no; then
 347          CFLAGS="$oCFLAGS"
 348     fi
 349   done
 350 fi
 351
 352
 353
 354 AC_SUBST(RRD_DEFAULT_FONT)
 355
 356 CONFIGURE_PART(Checking for Header Files)
 357
 358 dnl Checks for header files.
 359 AC_HEADER_STDC
 360 AC_HEADER_DIRENT
 361 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 362
 363 dnl Checks for typedefs, structures, and compiler characteristics.
 364 AC_C_CONST
 365 AC_HEADER_TIME
 366 AC_STRUCT_TM
 367
 368 dnl Checks for libraries.
 369 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 370
 371
 372 dnl add pic flag in any case this makes sure all our code is relocatable
 373 eval `./libtool --config | grep pic_flag`
 374 CFLAGS="$CFLAGS $pic_flag"
 375
 376 CONFIGURE_PART(Test Library Functions)
 377
 378 dnl Checks for library functions.
 379 AC_FUNC_STRFTIME
 380 AC_FUNC_VPRINTF
 381
 382 AC_C_BIGENDIAN
 383
 384 dnl for each function found we get a definition in config.h
 385 dnl of the form HAVE_FUNCTION
 386
 387 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 388
 389
 390 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 391 if test "x$enable_mmap" = "xyes"; then
 392   case "$host" in
 393   *cygwin*)
 394     # the normal mmap test does not work in cygwin
 395     AC_CHECK_FUNCS(mmap)
 396     if test "x$ac_cv_func_mmap" = "xyes"; then
 397       ac_cv_func_mmap_fixed_mapped=yes
 398     fi
 399   ;;
 400   *)
 401     AC_CHECK_HEADERS(sys/mman.h)
 402     AC_FUNC_MMAP
 403     AC_CHECK_FUNCS(mmap munmap msync)
 404     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 405                                      # include <sys/mman.h>
 406                                      #endif])
 407     if test "x$ac_cv_have_decl_madvise" = "xyes";
 408     then
 409       AC_CHECK_FUNCS(madvise)
 410     else
 411       AC_CHECK_FUNCS(posix_madvise)
 412       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 413         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 414       fi
 415     fi
 416   ;;
 417   esac
 418   if test "x$ac_cv_func_mmap" != "xyes";
 419   then
 420     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 421 dnl enable_mmap="no"
 422   fi
 423 fi
 424
 425 dnl can we use posix_fadvise
 426 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 427 #include <fcntl.h>])
 428 AC_CHECK_FUNCS(posix_fadvise)
 429
 430
 431
 432 CONFIGURE_PART(IEEE Math Checks)
 433
 434
 435 dnl actual code to check if this works
 436 AC_CHECK_FUNCS(fpclassify, ,
 437   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 438     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 439 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 440       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 441
 442 AC_CHECK_FUNCS(isinf, ,
 443   [AC_MSG_CHECKING(for isinf with <math.h>)
 444     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 445 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 446       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 447
 448 dnl finite is BSD, isfinite is C99, so prefer the latter
 449 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 450 AC_TRY_RUN([
 451 #ifdef HAVE_MATH_H
 452 #include <math.h>
 453 #endif
 454 #ifdef HAVE_FLOAT_H
 455 #include <float.h>
 456 #endif
 457 int main ()
 458 {
 459 #ifdef isfinite
 460 #ifdef LDBL_MAX
 461   if (!isfinite(LDBL_MAX)) return 1;
 462 #endif
 463 #ifdef DBL_MAX
 464   if (!isfinite(DBL_MAX)) return 1;
 465 #endif
 466 #endif
 467 return 0;
 468 }],[
 469 have_broken_isfinite=no],have_broken_isfinite=yes,[
 470 case "${target}" in
 471   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 472   *) have_broken_isfinite=no ;;
 473 esac])
 474 ])
 475 if test "x$have_broken_isfinite" = "xno"; then
 476   AC_DEFINE(HAVE_ISFINITE)
 477 else
 478 AC_CHECK_FUNCS(finite,[],
 479   [AC_CHECK_FUNCS(isfinite,[],
 480       [AC_MSG_CHECKING(for isfinite with <math.h>)
 481        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 482 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 483                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 484 fi
 485
 486 AC_FULL_IEEE
 487
 488 CONFIGURE_PART(Resolve Portability Issues)
 489
 490 dnl what does realloc do if it gets called with a NULL pointer
 491
 492 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 493 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 494               int main(void){
 495               char *x = NULL;
 496               x = realloc (x,10);
 497               if (x==NULL) return 1;
 498               return 0;
 499              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 500
 501 if test x"$rd_cv_null_realloc" = xnope; then
 502 AC_DEFINE(NO_NULL_REALLOC)
 503 fi
 504
 505 AC_LANG_PUSH(C)
 506 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 507 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 508 AC_LINK_IFELSE(
 509     AC_LANG_PROGRAM(
 510            [[#include <time.h>]],
 511            [[ctime_r(NULL,NULL,0)]]
 512                    ),
 513     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 514       AC_LINK_IFELSE(
 515           AC_LANG_PROGRAM(
 516                 [[#include <time.h>]],
 517                 [[ctime_r(NULL,NULL)]]
 518                          ),
 519           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 520           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 521       )
 522     ],
 523     [ AC_LINK_IFELSE(
 524           AC_LANG_PROGRAM(
 525                 [[#include <time.h>]],
 526                 [[ctime_r(NULL,NULL)]]
 527                          ),
 528           [AC_MSG_RESULT(no)],
 529           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 530       )
 531     ]
 532 )
 533 AC_LANG_POP(C)
 534
 535 dnl Check for pthreads
 536 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 537
 538 AC_SUBST(MULTITHREAD_CFLAGS)
 539 AC_SUBST(MULTITHREAD_LDFLAGS)
 540
 541 if test $enable_pthread != no; then
 542  ACX_PTHREAD([
 543     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 544     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 545              ],
 546              [])
 547 fi
 548
 549 dnl since we use lots of *_r functions all over the code we better
 550 dnl make sure they are known
 551
 552 if test  "x$x_rflag" != "xno"; then
 553    CPPFLAGS="$CPPFLAGS $x_rflag"
 554 fi
 555
 556 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 557
 558 AC_LANG_PUSH(C)
 559 dnl see if we have to include malloc/malloc.h
 560 AC_MSG_CHECKING([do we need malloc/malloc.h])
 561 AC_LINK_IFELSE(
 562     AC_LANG_PROGRAM(
 563            [[#include <stdlib.h>]],
 564            [[malloc(1)]]
 565                    ),
 566     [ AC_MSG_RESULT([nope, works out of the box]) ],
 567     [ AC_LINK_IFELSE(
 568           AC_LANG_PROGRAM(
 569                 [[#include <stdlib.h>
 570                   #include <malloc/malloc.h>]],
 571                 [[malloc(1)]]
 572                          ),
 573           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 574            AC_MSG_RESULT([yes we do])],
 575           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 576       )
 577     ]
 578 )
 579 AC_LANG_POP(C)
 580
 581 dnl Could use these to know if we need to provide a prototype
 582 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 583
 584 dnl solaris has fdatasync in the librt
 585
 586 AC_CHECK_FUNC(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"],[]))
 587
 588
 589 CONFIGURE_PART(Find 3rd-Party Libraries)
 590
 591
 592 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 593
 594 CORE_LIBS="$LIBS"
 595
 596 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 597 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 598 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,                     freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 599 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,               fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 600 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 601 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 602 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 603
 604 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 605   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 606 fi
 607
 608 ALL_LIBS="$LIBS"
 609 LIBS=
 610
 611 AC_SUBST(CORE_LIBS)
 612 AC_SUBST(ALL_LIBS)
 613
 614 CONFIGURE_PART(Prep for Building Language Bindings)
 615
 616 dnl Check for Perl.
 617 AC_PATH_PROG(PERL, perl, no)
 618
 619 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 620 [],[enable_perl=yes])
 621
 622
 623 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 624 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 625 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 626 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 627
 628 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 629         COMP_PERL=
 630 else
 631         COMP_PERL="perl_piped perl_shared"
 632         AC_MSG_CHECKING(for the perl version you are running)
 633         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 634         AC_MSG_RESULT($PERL_VERSION)
 635         if test -z "$PERLCC"; then
 636             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 637             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 638             AC_MSG_RESULT($perlcc)
 639             if test ! -x "$perlcc"; then
 640                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 641                 if test "$PERL_CC" = "no"; then
 642                     AC_MSG_WARN([
 643 I would not find the Compiler ($perlcc) that was originally used to compile
 644 your perl binary. You should either make sure that this compiler is
 645 available on your system, pick an other compiler and set PERLCC
 646 appropriately, or use a different perl setup that was compiled locally.
 647
 648 I will disable the compilation of the RRDs perl module for now.
 649 ])
 650                     COMP_PERL="perl_piped"
 651                 fi
 652             fi
 653         fi
 654 fi
 655
 656 AC_MSG_CHECKING(Perl Modules to build)
 657 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 658
 659 # Options to pass when configuring perl module
 660 ppref=$prefix
 661 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 662
 663 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 664
 665 dnl pass additional perl options when generating Makefile from Makefile.PL
 666 AC_ARG_ENABLE(perl-site-install,
 667 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 668                           together with rrdtool in $prefix/lib/perl. You have to
 669                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 670                           when you want to use them. When you set this option
 671                           the perl modules will get installed wherever
 672                           your perl setup thinks it is best.],
 673 [PERL_MAKE_OPTIONS=],[])
 674
 675 if test ! -z "$PERLCC"; then
 676    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 677
 678    if test ! -z "$PERLCCFLAGS"; then
 679        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 680    fi
 681
 682    if test -z "$PERLLD"; then
 683        PERLLD=$PERLCC
 684    fi
 685    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 686
 687    if test ! -z "$PERLLDFLAGS"; then
 688        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 689    fi
 690 fi
 691
 692 AC_ARG_WITH(perl-options,
 693 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 694                           generating Makefile from Makefile.PL. If you set this
 695                           option, interesting things may happen unless you know
 696                           what you are doing!],
 697 [PERL_MAKE_OPTIONS=$withval])
 698
 699 AC_SUBST(PERL_MAKE_OPTIONS)
 700 AC_SUBST(PERL)
 701 AC_SUBST(COMP_PERL)
 702 AC_SUBST(PERL_VERSION)
 703
 704 dnl Check for Ruby.
 705 AC_PATH_PROG(RUBY, ruby, no)
 706
 707 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 708 [],[enable_ruby=yes])
 709
 710 AC_MSG_CHECKING(if ruby modules can be built)
 711
 712 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 713         COMP_RUBY=
 714         AC_MSG_RESULT(No .. Ruby not found or disabled)
 715 else
 716         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 717                 COMP_RUBY="ruby"
 718                 AC_MSG_RESULT(YES)
 719         else
 720                 COMP_RUBY=
 721                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 722         fi
 723 fi
 724
 725
 726 dnl pass additional ruby options when generating Makefile from Makefile.PL
 727 AC_ARG_ENABLE(ruby-site-install,
 728 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 729                           together with rrdtool in $prefix/lib/ruby. You have to
 730                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 731                           for ruby to find the RRD.so file.],
 732 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 733
 734
 735 AC_ARG_WITH(ruby-options,
 736 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 737                           generating Makefile from extconf.rb. If you set this
 738                           option, interesting things may happen unless you know
 739                           what you are doing!],
 740 [RUBY_MAKE_OPTIONS=$withval])
 741
 742 AC_SUBST(RUBY_MAKE_OPTIONS)
 743 AC_SUBST(RUBY)
 744 AC_SUBST(COMP_RUBY)
 745
 746
 747 enable_tcl_site=no
 748
 749 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 750 [],[enable_tcl=yes])
 751
 752 if test  "$enable_tcl" = "yes"; then
 753   dnl Check for Tcl.
 754   withval=""
 755   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 756   enable_tcl=no
 757   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 758     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 759     if test -f "$dir/tclConfig.sh" ; then
 760         tcl_config=$dir/tclConfig.sh
 761         enable_tcl=yes
 762         AC_MSG_RESULT(yes)
 763         break
 764     else
 765         AC_MSG_RESULT(no)
 766     fi
 767   done
 768
 769   if test "$enable_tcl" = "no"; then
 770         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 771   else
 772         . $tcl_config
 773         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 774   fi
 775   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 776   [],[enable_tcl_site=yes])
 777
 778 fi
 779
 780 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 781 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 782
 783 AC_SUBST(TCL_PREFIX)
 784 AC_SUBST(TCL_SHLIB_CFLAGS)
 785 AC_SUBST(TCL_SHLIB_LD)
 786 AC_SUBST(TCL_SHLIB_SUFFIX)
 787 AC_SUBST(TCL_PACKAGE_PATH)
 788 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 789 AC_SUBST(TCL_STUB_LIB_SPEC)
 790 AC_SUBST(TCL_VERSION)
 791 AC_SUBST(TCL_PACKAGE_DIR)
 792 AC_SUBST(TCL_INC_DIR)
 793
 794 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 795 [],[enable_python=yes])
 796
 797 if test  "$enable_python" = "yes"; then
 798 dnl Check for python
 799 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 800 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 801 fi
 802
 803 if test  x$enable_python = xno; then
 804         COMP_PYTHON=
 805 else
 806         COMP_PYTHON="python"
 807 fi
 808
 809 AC_SUBST(COMP_PYTHON)
 810
 811 dnl Check for nroff
 812 AC_PATH_PROGS(NROFF, gnroff nroff)
 813 AC_PATH_PROGS(TROFF, groff troff)
 814
 815 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 816 if test -z "$RRDDOCDIR"; then
 817    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 818
 819
 820 CONFIGURE_PART(Apply Configuration Information)
 821
 822 AC_CONFIG_FILES([examples/shared-demo.pl])
 823 AC_CONFIG_FILES([examples/piped-demo.pl])
 824 AC_CONFIG_FILES([examples/stripes.pl])
 825 AC_CONFIG_FILES([examples/bigtops.pl])
 826 AC_CONFIG_FILES([examples/minmax.pl])
 827 AC_CONFIG_FILES([examples/4charts.pl])
 828 AC_CONFIG_FILES([examples/perftest.pl])
 829 AC_CONFIG_FILES([examples/Makefile])
 830 AC_CONFIG_FILES([doc/Makefile])
 831 AC_CONFIG_FILES([src/Makefile])
 832 AC_CONFIG_FILES([bindings/Makefile])
 833 AC_CONFIG_FILES([bindings/tcl/Makefile])
 834 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 835 AC_CONFIG_FILES([Makefile])
 836
 837 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 838 AC_OUTPUT
 839
 840 AC_MSG_CHECKING(in)
 841 AC_MSG_RESULT(and out again)
 842
 843 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 844 sleep 1
 845 echo $ECHO_N ".$ECHO_C" 1>&6
 846 sleep 1
 847 echo $ECHO_N ".$ECHO_C" 1>&6
 848 sleep 1
 849 echo $ECHO_N ".$ECHO_C" 1>&6
 850 sleep 1
 851 echo $ECHO_N ".$ECHO_C" 1>&6
 852 sleep 1
 853 AC_MSG_RESULT([ just kidding ;-)])
 854 echo
 855 echo "----------------------------------------------------------------"
 856 echo "Config is DONE!"
 857 echo
 858 echo "          With MMAP IO: $enable_mmap"
 859 echo "       Static programs: $staticprogs"
 860 echo "          Perl Modules: $COMP_PERL"
 861 echo "           Perl Binary: $PERL"
 862 echo "          Perl Version: $PERL_VERSION"
 863 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 864 echo "          Ruby Modules: $COMP_RUBY"
 865 echo "           Ruby Binary: $RUBY"
 866 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 867 echo "    Build Tcl Bindings: $enable_tcl"
 868 echo " Build Python Bindings: $enable_python"
 869 echo "          Build rrdcgi: $enable_rrdcgi"
 870 echo "       Build librrd MT: $enable_pthread"
 871 echo
 872 echo
 873 echo "Type 'make' to compile the software and use 'make install' to "
 874 echo "install everything to: $prefix."
 875 echo
 876 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 877 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 878 echo "place an order."
 879 echo
 880 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 881 echo "----------------------------------------------------------------"