configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3rc1])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.299908051200
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which version the library is compatible with
  23 dnl we must keep a separate library version cout of the format c:r:a if any
  24 dnl functionality is changed do c++ prior to release
  25 dnl if only implementation changed but all interfaces are kept, do r++
  26 dnl when only functionality was added, do a++ if any functionality was
  27 dnl removed to a=0.
  28 dnl
  29 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  30 dnl
  31 LIBVERS=3:0:1
  32 AC_SUBST(LIBVERS)
  33
  34 AC_CANONICAL_TARGET
  35 AM_INIT_AUTOMAKE
  36 AC_CONFIG_HEADERS([rrd_config.h])
  37
  38 dnl all our local stuff like install scripts and include files
  39 dnl is in there
  40
  41
  42 dnl determine the type of system we are running on
  43
  44 AC_SUBST(VERSION)
  45
  46 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  47
  48 dnl Minimum Autoconf version required.
  49 AC_PREREQ(2.59)
  50
  51 dnl At the TOP of the HEADER
  52
  53 AH_TOP([
  54
  55 #ifndef RRD_CONFIG_H
  56 #define RRD_CONFIG_H
  57 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  58 #undef MUST_DISABLE_FPMASK
  59
  60 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  61
  62 #undef MUST_DISABLE_SIGFPE
  63
  64 /* realloc does not support NULL as argument */
  65 #undef NO_NULL_REALLOC
  66
  67 /* lets enable madvise defines in NetBSD */
  68 #if defined(__NetBSD__)
  69 # if !defined(_NETBSD_SOURCE)
  70 #  define _NETBSD_SOURCE
  71 # endif
  72 #endif
  73
  74  ])
  75
  76 AH_BOTTOM([
  77 /* make sure that we pickup the correct stuff from all headers */
  78 #ifdef HAVE_FEATURES_H
  79 #undef _XOPEN_SOURCE /* keep unmodified */
  80 #undef _BSD_SOURCE /* keep unmodified */
  81 #define _XOPEN_SOURCE 600
  82 #define _BSD_SOURCE 1
  83 # include <features.h>
  84 #endif
  85
  86 /* FreeBSD 4.8 wants this included BEFORE sys/types.h */
  87 #ifdef HAVE_SYS_MMAN_H
  88 # include <sys/mman.h>
  89 #endif
  90
  91 #ifdef HAVE_SYS_TYPES_H
  92 # include <sys/types.h>
  93 #endif
  94
  95 #ifdef HAVE_SYS_PARAM_H
  96 # include <sys/param.h>
  97 #endif
  98 #ifndef MAXPATH
  99 # ifdef PATH_MAX
 100 #  define MAXPATH PATH_MAX
 101 # endif
 102 #endif
 103 #ifndef MAXPATH
 104 /* else try the BSD variant */
 105 # ifdef MAXPATHLEN
 106 #  define MAXPATH MAXPATHLEN
 107 # endif
 108 #endif
 109
 110 #ifdef HAVE_ERRNO_H
 111 # include <errno.h>
 112 #endif
 113
 114 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
 115 /* use posix_madvise family */
 116 # define madvise posix_madvise
 117 # define MADV_NORMAL POSIX_MADV_NORMAL
 118 # define MADV_RANDOM POSIX_MADV_RANDOM
 119 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
 120 # define MADV_WILLNEED POSIX_MADV_WILLNEED
 121 # define MADV_DONTNEED POSIX_MADV_DONTNEED
 122 #endif
 123 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
 124 # define USE_MADVISE 1
 125 #endif
 126
 127 #ifdef HAVE_SYS_STAT_H
 128 # include <sys/stat.h>
 129 #endif
 130
 131 #ifdef HAVE_FCNTL_H
 132 #include <fcntl.h>
 133 #endif
 134
 135 #ifdef HAVE_UNISTD_H
 136 # include <unistd.h>
 137 #endif
 138
 139 #ifdef TIME_WITH_SYS_TIME
 140 # include <sys/time.h>
 141 # include <time.h>
 142 #else
 143 # ifdef HAVE_SYS_TIME_H
 144 #  include <sys/time.h>
 145 # else
 146 #  include <time.h>
 147 # endif
 148 #endif
 149
 150 #ifdef HAVE_SYS_TIMES_H
 151 # include <sys/times.h>
 152 #endif
 153
 154 #ifdef HAVE_SYS_RESOURCE_H
 155 # include <sys/resource.h>
 156 #if (defined(__svr4__) && defined(__sun__))
 157 /* Solaris headers (pre 2.6) do not have a getrusage prototype.
 158    Use this instead. */
 159 extern int getrusage(int, struct rusage *);
 160 #endif /* __svr4__ && __sun__ */
 161 #endif
 162
 163
 164 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 165    make sure you are NOT using bcopy, index or rindex in the code */
 166
 167 #ifdef STDC_HEADERS
 168 # include <string.h>
 169 #else
 170 # ifndef HAVE_STRCHR
 171 #  define strchr index
 172 #  define strrchr rindex
 173 # endif
 174 char *strchr (), *strrchr ();
 175 # ifndef HAVE_MEMMOVE
 176 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 177 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 178 # endif
 179 #endif
 180
 181 #ifdef NO_NULL_REALLOC
 182 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 183 #else
 184 # define rrd_realloc(a,b) realloc((a), (b))
 185 #endif
 186
 187 #ifdef NEED_MALLOC_MALLOC_H
 188 #  include <malloc/malloc.h>
 189 #endif
 190
 191 #ifdef HAVE_STDIO_H
 192 # include <stdio.h>
 193 #endif
 194
 195 #ifdef HAVE_STDLIB_H
 196 # include <stdlib.h>
 197 #endif
 198
 199 #ifdef HAVE_CTYPE_H
 200 # include <ctype.h>
 201 #endif
 202
 203 #ifdef HAVE_DIRENT_H
 204 # include <dirent.h>
 205 # define NAMLEN(dirent) strlen((dirent)->d_name)
 206 #else
 207 # define dirent direct
 208 # define NAMLEN(dirent) (dirent)->d_namlen
 209 # ifdef HAVE_SYS_NDIR_H
 210 #  include <sys/ndir.h>
 211 # endif
 212 # ifdef HAVE_SYS_DIR_H
 213 #  include <sys/dir.h>
 214 # endif
 215 # ifdef HAVE_NDIR_H
 216 #  include <ndir.h>
 217 # endif
 218 #endif
 219
 220 #ifdef MUST_DISABLE_SIGFPE
 221 # include <signal.h>
 222 #endif
 223
 224 #ifdef MUST_DISABLE_FPMASK
 225 # include <floatingpoint.h>
 226 #endif
 227
 228
 229 #ifdef HAVE_MATH_H
 230 # include <math.h>
 231 #endif
 232
 233 #ifdef HAVE_FLOAT_H
 234 # include <float.h>
 235 #endif
 236
 237 #ifdef HAVE_IEEEFP_H
 238 # include <ieeefp.h>
 239 #endif
 240
 241 #ifdef HAVE_FP_CLASS_H
 242 # include <fp_class.h>
 243 #endif
 244
 245 /* for Solaris */
 246 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 247 #  define HAVE_ISINF 1
 248 #  ifdef isinf
 249 #  undef isinf /* confuse autoconf */
 250 #  endif
 251 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 252 #endif
 253
 254 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 255 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 256 #  undef isnan /* confuse autoconf to NOT remove this */
 257 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 258 #endif
 259
 260 /* for OSF1 Digital Unix */
 261 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 262 #  define HAVE_ISINF 1
 263 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 264 #endif
 265
 266 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 267 #  define HAVE_ISINF 1
 268 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 269 #endif
 270
 271 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 272 #  define HAVE_ISINF 1
 273 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 274 #endif
 275
 276 /* for AIX */
 277 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 278 #  define HAVE_ISINF 1
 279 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 280 #endif
 281
 282 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 283 #  define HAVE_FINITE 1
 284 #  define finite(a) isfinite(a)
 285 #endif
 286
 287 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 288 #  define HAVE_FINITE 1
 289 #  define finite(a) (! isnan(a) && ! isinf(a))
 290 #endif
 291
 292 #ifndef HAVE_FINITE
 293 #error "Can't compile without finite function"
 294 #endif
 295
 296 #ifndef HAVE_ISINF
 297 #error "Can't compile without isinf function"
 298 #endif
 299
 300 #endif /* RRD_CONFIG_H */
 301 ])
 302
 303 dnl Process Special Options
 304 dnl -----------------------------------
 305
 306 dnl gettext
 307 GETTEXT_PACKAGE=rrdtool
 308 AC_SUBST(GETTEXT_PACKAGE)
 309 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 310 AM_GLIB_GNU_GETTEXT()
 311 IT_PROG_INTLTOOL([0.35.0],[no-xml])
 312
 313 AM_MAINTAINER_MODE
 314
 315 dnl How the vertical axis label is printed
 316 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 317  [Vertical label angle: -90.0 (default) or 90.0])
 318 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 319  [Vertical label angle: -90.0 (default) or 90.0])
 320
 321 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 322 [],[enable_rrdcgi=yes])
 323
 324 dnl Check if we run on a system that has fonts
 325 AC_ARG_WITH(rrd-default-font,
 326 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 327 [RRD_DEFAULT_FONT=$withval],[
 328   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 329         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 330   else
 331         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 332   fi
 333 ])
 334
 335 dnl Use mmap in rrd_update instead of seek+write
 336 AC_ARG_ENABLE([mmap],
 337 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 338 [],
 339 [enable_mmap=yes])
 340
 341 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 342 [],[enable_pthread=yes])
 343
 344 AC_ARG_ENABLE(static-programs,
 345      [  --enable-static-programs  Build static programs],
 346      [case "${enableval}" in
 347        yes) staticprogs=yes ;;
 348        no)  staticprogs=no ;;
 349        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 350      esac],[staticprogs=no])
 351 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 352
 353
 354 CONFIGURE_PART(Audit Compilation Environment)
 355
 356
 357 dnl Check for the compiler and static/shared library creation.
 358 AC_PROG_CC
 359 AC_PROG_CPP
 360 AC_PROG_LIBTOOL
 361
 362 dnl Try to detect/use GNU features
 363 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 364
 365 dnl which flags does the compiler support?
 366 if test "x$GCC" = "xyes"; then
 367   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 368     oCFLAGS="$CFLAGS"
 369     CFLAGS="$CFLAGS $flag"
 370     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 371     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 372        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 373     if eval test \$$cachename = no; then
 374          CFLAGS="$oCFLAGS"
 375     fi
 376   done
 377 fi
 378
 379
 380
 381 AC_SUBST(RRD_DEFAULT_FONT)
 382
 383 CONFIGURE_PART(Checking for Header Files)
 384
 385 dnl Checks for header files.
 386 AC_HEADER_STDC
 387 AC_HEADER_DIRENT
 388 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h libintl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 389
 390 dnl Checks for typedefs, structures, and compiler characteristics.
 391 AC_C_CONST
 392 AC_HEADER_TIME
 393 AC_STRUCT_TM
 394
 395 dnl Checks for libraries.
 396 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 397
 398
 399 dnl add pic flag in any case this makes sure all our code is relocatable
 400 eval `./libtool --config | grep pic_flag`
 401 CFLAGS="$CFLAGS $pic_flag"
 402
 403 CONFIGURE_PART(Test Library Functions)
 404
 405 dnl Checks for library functions.
 406 AC_FUNC_STRFTIME
 407 AC_FUNC_VPRINTF
 408
 409 AC_C_BIGENDIAN
 410
 411 dnl for each function found we get a definition in config.h
 412 dnl of the form HAVE_FUNCTION
 413
 414 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 415
 416
 417 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 418 if test "x$enable_mmap" = "xyes"; then
 419   case "$host" in
 420   *cygwin*)
 421     # the normal mmap test does not work in cygwin
 422     AC_CHECK_FUNCS(mmap)
 423     if test "x$ac_cv_func_mmap" = "xyes"; then
 424       ac_cv_func_mmap_fixed_mapped=yes
 425     fi
 426   ;;
 427   *)
 428     AC_CHECK_HEADERS(sys/mman.h)
 429     AC_FUNC_MMAP
 430     AC_CHECK_FUNCS(mmap munmap msync)
 431     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 432                                      # include <sys/mman.h>
 433                                      #endif])
 434     if test "x$ac_cv_have_decl_madvise" = "xyes";
 435     then
 436       AC_CHECK_FUNCS(madvise)
 437     else
 438       AC_CHECK_FUNCS(posix_madvise)
 439       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 440         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 441       fi
 442     fi
 443   ;;
 444   esac
 445   if test "x$ac_cv_func_mmap" != "xyes";
 446   then
 447     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 448 dnl enable_mmap="no"
 449   fi
 450 fi
 451
 452 dnl can we use posix_fadvise
 453 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 454 #include <fcntl.h>])
 455 AC_CHECK_FUNCS(posix_fadvise)
 456
 457
 458
 459 CONFIGURE_PART(IEEE Math Checks)
 460
 461
 462 dnl actual code to check if this works
 463 AC_CHECK_FUNCS(fpclassify, ,
 464   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 465     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 466 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 467       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 468
 469 AC_CHECK_FUNCS(isinf, ,
 470   [AC_MSG_CHECKING(for isinf with <math.h>)
 471     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 472 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 473       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 474
 475 dnl finite is BSD, isfinite is C99, so prefer the latter
 476 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 477 AC_TRY_RUN([
 478 #ifdef HAVE_MATH_H
 479 #include <math.h>
 480 #endif
 481 #ifdef HAVE_FLOAT_H
 482 #include <float.h>
 483 #endif
 484 int main ()
 485 {
 486 #ifdef isfinite
 487 #ifdef LDBL_MAX
 488   if (!isfinite(LDBL_MAX)) return 1;
 489 #endif
 490 #ifdef DBL_MAX
 491   if (!isfinite(DBL_MAX)) return 1;
 492 #endif
 493 #endif
 494 return 0;
 495 }],[
 496 have_broken_isfinite=no],have_broken_isfinite=yes,[
 497 case "${target}" in
 498   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 499   *) have_broken_isfinite=no ;;
 500 esac])
 501 ])
 502 if test "x$have_broken_isfinite" = "xno"; then
 503   AC_DEFINE(HAVE_ISFINITE)
 504 else
 505 AC_CHECK_FUNCS(finite,[],
 506   [AC_CHECK_FUNCS(isfinite,[],
 507       [AC_MSG_CHECKING(for isfinite with <math.h>)
 508        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 509 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 510                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 511 fi
 512
 513 AC_FULL_IEEE
 514
 515 CONFIGURE_PART(Resolve Portability Issues)
 516
 517 dnl what does realloc do if it gets called with a NULL pointer
 518
 519 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 520 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 521               int main(void){
 522               char *x = NULL;
 523               x = realloc (x,10);
 524               if (x==NULL) return 1;
 525               return 0;
 526              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 527
 528 if test x"$rd_cv_null_realloc" = xnope; then
 529 AC_DEFINE(NO_NULL_REALLOC)
 530 fi
 531
 532 AC_LANG_PUSH(C)
 533 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 534 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 535 AC_LINK_IFELSE(
 536     AC_LANG_PROGRAM(
 537            [[#include <time.h>]],
 538            [[ctime_r(NULL,NULL,0)]]
 539                    ),
 540     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 541       AC_LINK_IFELSE(
 542           AC_LANG_PROGRAM(
 543                 [[#include <time.h>]],
 544                 [[ctime_r(NULL,NULL)]]
 545                          ),
 546           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 547           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 548       )
 549     ],
 550     [ AC_LINK_IFELSE(
 551           AC_LANG_PROGRAM(
 552                 [[#include <time.h>]],
 553                 [[ctime_r(NULL,NULL)]]
 554                          ),
 555           [AC_MSG_RESULT(no)],
 556           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 557       )
 558     ]
 559 )
 560 AC_LANG_POP(C)
 561
 562 dnl Check for pthreads
 563 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 564
 565 AC_SUBST(MULTITHREAD_CFLAGS)
 566 AC_SUBST(MULTITHREAD_LDFLAGS)
 567
 568 if test $enable_pthread != no; then
 569  ACX_PTHREAD([
 570     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 571     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 572              ],
 573              [])
 574 fi
 575
 576 dnl since we use lots of *_r functions all over the code we better
 577 dnl make sure they are known
 578
 579 if test  "x$x_rflag" != "xno"; then
 580    CPPFLAGS="$CPPFLAGS $x_rflag"
 581 fi
 582
 583 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 584
 585 AC_LANG_PUSH(C)
 586 dnl see if we have to include malloc/malloc.h
 587 AC_MSG_CHECKING([do we need malloc/malloc.h])
 588 AC_LINK_IFELSE(
 589     AC_LANG_PROGRAM(
 590            [[#include <stdlib.h>]],
 591            [[malloc(1)]]
 592                    ),
 593     [ AC_MSG_RESULT([nope, works out of the box]) ],
 594     [ AC_LINK_IFELSE(
 595           AC_LANG_PROGRAM(
 596                 [[#include <stdlib.h>
 597                   #include <malloc/malloc.h>]],
 598                 [[malloc(1)]]
 599                          ),
 600           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 601            AC_MSG_RESULT([yes we do])],
 602           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 603       )
 604     ]
 605 )
 606 AC_LANG_POP(C)
 607
 608 dnl Could use these to know if we need to provide a prototype
 609 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 610
 611 dnl solaris has fdatasync in the librt
 612
 613 AC_CHECK_FUNC(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"],[]))
 614
 615
 616 CONFIGURE_PART(Find 3rd-Party Libraries)
 617
 618
 619 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 620
 621 CORE_LIBS="$LIBS"
 622
 623 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 624 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 625 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 626 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 627 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 628 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 629 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 630 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 631 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 632 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 633 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 634
 635 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 636   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 637 fi
 638
 639 ALL_LIBS="$LIBS"
 640 LIBS=
 641
 642 AC_SUBST(CORE_LIBS)
 643 AC_SUBST(ALL_LIBS)
 644
 645 CONFIGURE_PART(Prep for Building Language Bindings)
 646
 647 dnl Check for Perl and friends
 648 PATH=/usr/perl5/bin:$PATH
 649 export PATH
 650 AC_PATH_PROG(PERL, perl, no)
 651 AC_PATH_PROG(POD2MAN, pod2man, no)
 652 AC_PATH_PROG(POD2HTML, pod2html, no)
 653
 654
 655 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 656 [],[enable_perl=yes])
 657
 658
 659 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 660 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 661 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 662 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 663
 664 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 665         COMP_PERL=
 666 else
 667         COMP_PERL="perl_piped perl_shared"
 668         AC_MSG_CHECKING(for the perl version you are running)
 669         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 670         AC_MSG_RESULT($PERL_VERSION)
 671         if test -z "$PERLCC"; then
 672             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 673             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 674             AC_MSG_RESULT($perlcc)
 675             if test ! -x "$perlcc"; then
 676                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 677                 if test "$PERL_CC" = "no"; then
 678                     AC_MSG_WARN([
 679 I would not find the Compiler ($perlcc) that was originally used to compile
 680 your perl binary. You should either make sure that this compiler is
 681 available on your system, pick an other compiler and set PERLCC
 682 appropriately, or use a different perl setup that was compiled locally.
 683
 684 I will disable the compilation of the RRDs perl module for now.
 685 ])
 686                     COMP_PERL="perl_piped"
 687                 fi
 688             fi
 689         fi
 690 fi
 691
 692 AC_MSG_CHECKING(Perl Modules to build)
 693 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 694
 695 # Options to pass when configuring perl module
 696 ppref=$prefix
 697 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 698
 699 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 700
 701 dnl pass additional perl options when generating Makefile from Makefile.PL
 702 AC_ARG_ENABLE(perl-site-install,
 703 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 704                           together with rrdtool in $prefix/lib/perl. You have to
 705                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 706                           when you want to use them. When you set this option
 707                           the perl modules will get installed wherever
 708                           your perl setup thinks it is best.],
 709 [PERL_MAKE_OPTIONS=],[])
 710
 711 if test ! -z "$PERLCC"; then
 712    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 713
 714    if test ! -z "$PERLCCFLAGS"; then
 715        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 716    fi
 717
 718    if test -z "$PERLLD"; then
 719        PERLLD=$PERLCC
 720    fi
 721    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 722
 723    if test ! -z "$PERLLDFLAGS"; then
 724        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 725    fi
 726 fi
 727
 728 AC_ARG_WITH(perl-options,
 729 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 730                           generating Makefile from Makefile.PL. If you set this
 731                           option, interesting things may happen unless you know
 732                           what you are doing!],
 733 [PERL_MAKE_OPTIONS=$withval])
 734
 735 AC_SUBST(PERL_MAKE_OPTIONS)
 736 AC_SUBST(PERL)
 737 AC_SUBST(COMP_PERL)
 738 AC_SUBST(PERL_VERSION)
 739
 740 dnl Check for Ruby.
 741 AC_PATH_PROG(RUBY, ruby, no)
 742
 743 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 744 [],[enable_ruby=yes])
 745
 746 AC_MSG_CHECKING(if ruby modules can be built)
 747
 748 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 749         COMP_RUBY=
 750         AC_MSG_RESULT(No .. Ruby not found or disabled)
 751 else
 752         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 753                 COMP_RUBY="ruby"
 754                 AC_MSG_RESULT(YES)
 755         else
 756                 COMP_RUBY=
 757                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 758         fi
 759 fi
 760
 761
 762 dnl pass additional ruby options when generating Makefile from Makefile.PL
 763 AC_ARG_ENABLE(ruby-site-install,
 764 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 765                           together with rrdtool in $prefix/lib/ruby. You have to
 766                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 767                           for ruby to find the RRD.so file.],
 768 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$prefix/lib/ruby"])
 769
 770
 771 AC_ARG_WITH(ruby-options,
 772 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 773                           generating Makefile from extconf.rb. If you set this
 774                           option, interesting things may happen unless you know
 775                           what you are doing!],
 776 [RUBY_MAKE_OPTIONS=$withval])
 777
 778 AC_SUBST(RUBY_MAKE_OPTIONS)
 779 AC_SUBST(RUBY)
 780 AC_SUBST(COMP_RUBY)
 781
 782
 783 enable_tcl_site=no
 784
 785 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 786 [],[enable_tcl=yes])
 787
 788 if test  "$enable_tcl" = "yes"; then
 789   dnl Check for Tcl.
 790   withval=""
 791   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 792   enable_tcl=no
 793   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 794     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 795     if test -f "$dir/tclConfig.sh" ; then
 796         tcl_config=$dir/tclConfig.sh
 797         enable_tcl=yes
 798         AC_MSG_RESULT(yes)
 799         break
 800     else
 801         AC_MSG_RESULT(no)
 802     fi
 803   done
 804
 805   if test "$enable_tcl" = "no"; then
 806         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 807   else
 808         . $tcl_config
 809         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 810   fi
 811   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 812   [],[enable_tcl_site=yes])
 813
 814 fi
 815
 816 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 817 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 818
 819 AC_SUBST(TCL_PREFIX)
 820 AC_SUBST(TCL_SHLIB_CFLAGS)
 821 AC_SUBST(TCL_SHLIB_LD)
 822 AC_SUBST(TCL_SHLIB_SUFFIX)
 823 AC_SUBST(TCL_PACKAGE_PATH)
 824 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 825 AC_SUBST(TCL_STUB_LIB_SPEC)
 826 AC_SUBST(TCL_VERSION)
 827 AC_SUBST(TCL_PACKAGE_DIR)
 828 AC_SUBST(TCL_INC_DIR)
 829
 830 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 831 [],[enable_python=yes])
 832
 833 if test  "$enable_python" = "yes"; then
 834 dnl Check for python
 835 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 836 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 837 fi
 838
 839 if test  x$enable_python = xno; then
 840         COMP_PYTHON=
 841 else
 842         COMP_PYTHON="python"
 843 fi
 844
 845 AC_SUBST(COMP_PYTHON)
 846
 847 dnl Check for nroff
 848 AC_PATH_PROGS(NROFF, gnroff nroff)
 849 AC_PATH_PROGS(TROFF, groff troff)
 850
 851 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 852 if test -z "$RRDDOCDIR"; then
 853    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 854
 855
 856 CONFIGURE_PART(Apply Configuration Information)
 857
 858 AC_CONFIG_FILES([examples/shared-demo.pl])
 859 AC_CONFIG_FILES([examples/piped-demo.pl])
 860 AC_CONFIG_FILES([examples/stripes.pl])
 861 AC_CONFIG_FILES([examples/bigtops.pl])
 862 AC_CONFIG_FILES([examples/minmax.pl])
 863 AC_CONFIG_FILES([examples/4charts.pl])
 864 AC_CONFIG_FILES([examples/perftest.pl])
 865 AC_CONFIG_FILES([examples/Makefile])
 866 AC_CONFIG_FILES([doc/Makefile])
 867 AC_CONFIG_FILES([po/Makefile.in])
 868 AC_CONFIG_FILES([src/Makefile])
 869 AC_CONFIG_FILES([bindings/Makefile])
 870 AC_CONFIG_FILES([bindings/tcl/Makefile])
 871 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 872 AC_CONFIG_FILES([Makefile])
 873
 874 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 875 AC_OUTPUT
 876
 877 AC_MSG_CHECKING(in)
 878 AC_MSG_RESULT(and out again)
 879
 880 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 881 sleep 1
 882 echo $ECHO_N ".$ECHO_C" 1>&6
 883 sleep 1
 884 echo $ECHO_N ".$ECHO_C" 1>&6
 885 sleep 1
 886 echo $ECHO_N ".$ECHO_C" 1>&6
 887 sleep 1
 888 echo $ECHO_N ".$ECHO_C" 1>&6
 889 sleep 1
 890 AC_MSG_RESULT([ just kidding ;-)])
 891 echo
 892 echo "----------------------------------------------------------------"
 893 echo "Config is DONE!"
 894 echo
 895 echo "          With MMAP IO: $enable_mmap"
 896 echo "       Static programs: $staticprogs"
 897 echo "          Perl Modules: $COMP_PERL"
 898 echo "           Perl Binary: $PERL"
 899 echo "          Perl Version: $PERL_VERSION"
 900 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 901 echo "          Ruby Modules: $COMP_RUBY"
 902 echo "           Ruby Binary: $RUBY"
 903 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 904 echo "    Build Tcl Bindings: $enable_tcl"
 905 echo " Build Python Bindings: $enable_python"
 906 echo "          Build rrdcgi: $enable_rrdcgi"
 907 echo "       Build librrd MT: $enable_pthread"
 908 echo
 909 echo
 910 echo "Type 'make' to compile the software and use 'make install' to "
 911 echo "install everything to: $prefix."
 912 echo
 913 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 914 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 915 echo "place an order."
 916 echo
 917 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 918 echo "----------------------------------------------------------------"