configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9
  10 dnl the official version number is
  11 dnl a.b.c
  12 AC_INIT([rrdtool],[1.3rc1])
  13
  14 dnl for testing a numberical version number comes handy
  15 dnl the released version are
  16 dnl a.bccc
  17 dnl the devel versions will be something like
  18 dnl a.b999yymmddhh
  19 NUMVERS=1.299908051200
  20 AC_SUBST(NUMVERS)
  21
  22 dnl for the linker to understand which version the library is compatible with
  23 dnl we must keep a separate library version cout of the format c:r:a if any
  24 dnl functionality is changed do c++ prior to release
  25 dnl if only implementation changed but all interfaces are kept, do r++
  26 dnl when only functionality was added, do a++ if any functionality was
  27 dnl removed to a=0.
  28 dnl
  29 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
  30 dnl
  31 LIBVERS=3:0:1
  32 AC_SUBST(LIBVERS)
  33
  34 AC_CANONICAL_TARGET
  35 AM_INIT_AUTOMAKE
  36 AC_CONFIG_HEADERS([rrd_config.h])
  37
  38 dnl all our local stuff like install scripts and include files
  39 dnl is in there
  40
  41
  42 dnl determine the type of system we are running on
  43
  44 AC_SUBST(VERSION)
  45
  46 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  47
  48 dnl Minimum Autoconf version required.
  49 AC_PREREQ(2.59)
  50
  51 dnl At the TOP of the HEADER
  52
  53 AH_TOP([
  54
  55 #ifndef RRD_CONFIG_H
  56 #define RRD_CONFIG_H
  57 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  58 #undef MUST_DISABLE_FPMASK
  59
  60 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  61
  62 #undef MUST_DISABLE_SIGFPE
  63
  64 /* realloc does not support NULL as argument */
  65 #undef NO_NULL_REALLOC
  66
  67 /* lets enable madvise defines in NetBSD */
  68 #if defined(__NetBSD__)
  69 # if !defined(_NETBSD_SOURCE)
  70 #  define _NETBSD_SOURCE
  71 # endif
  72 #endif
  73
  74  ])
  75
  76 AH_BOTTOM([
  77 /* make sure that we pickup the correct stuff from all headers */
  78 #ifdef HAVE_FEATURES_H
  79 #undef _XOPEN_SOURCE /* keep unmodified */
  80 #undef _BSD_SOURCE /* keep unmodified */
  81 #define _XOPEN_SOURCE 600
  82 #define _BSD_SOURCE 1
  83 # include <features.h>
  84 #endif
  85
  86 /* FreeBSD 4.8 wants this included BEFORE sys/types.h */
  87 #ifdef HAVE_SYS_MMAN_H
  88 # include <sys/mman.h>
  89 #endif
  90
  91 #ifdef HAVE_SYS_TYPES_H
  92 # include <sys/types.h>
  93 #endif
  94
  95 #ifdef HAVE_SYS_PARAM_H
  96 # include <sys/param.h>
  97 #endif
  98 #ifndef MAXPATH
  99 # ifdef PATH_MAX
 100 #  define MAXPATH PATH_MAX
 101 # endif
 102 #endif
 103 #ifndef MAXPATH
 104 /* else try the BSD variant */
 105 # ifdef MAXPATHLEN
 106 #  define MAXPATH MAXPATHLEN
 107 # endif
 108 #endif
 109
 110 #ifdef HAVE_ERRNO_H
 111 # include <errno.h>
 112 #endif
 113
 114 #if !defined HAVE_MADVISE && defined HAVE_POSIX_MADVISE
 115 /* use posix_madvise family */
 116 # define madvise posix_madvise
 117 # define MADV_NORMAL POSIX_MADV_NORMAL
 118 # define MADV_RANDOM POSIX_MADV_RANDOM
 119 # define MADV_SEQUENTIAL POSIX_MADV_SEQUENTIAL
 120 # define MADV_WILLNEED POSIX_MADV_WILLNEED
 121 # define MADV_DONTNEED POSIX_MADV_DONTNEED
 122 #endif
 123 #if defined HAVE_MADVISE || defined HAVE_POSIX_MADVISE
 124 # define USE_MADVISE 1
 125 #endif
 126
 127 #ifdef HAVE_SYS_STAT_H
 128 # include <sys/stat.h>
 129 #endif
 130
 131 #ifdef HAVE_FCNTL_H
 132 #include <fcntl.h>
 133 #endif
 134
 135 #ifdef HAVE_UNISTD_H
 136 # include <unistd.h>
 137 #endif
 138
 139 #ifdef TIME_WITH_SYS_TIME
 140 # include <sys/time.h>
 141 # include <time.h>
 142 #else
 143 # ifdef HAVE_SYS_TIME_H
 144 #  include <sys/time.h>
 145 # else
 146 #  include <time.h>
 147 # endif
 148 #endif
 149
 150 #ifdef HAVE_SYS_TIMES_H
 151 # include <sys/times.h>
 152 #endif
 153
 154 #ifdef HAVE_SYS_RESOURCE_H
 155 # include <sys/resource.h>
 156 #if (defined(__svr4__) && defined(__sun__))
 157 /* Solaris headers (pre 2.6) do not have a getrusage prototype.
 158    Use this instead. */
 159 extern int getrusage(int, struct rusage *);
 160 #endif /* __svr4__ && __sun__ */
 161 #endif
 162
 163
 164 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
 165    make sure you are NOT using bcopy, index or rindex in the code */
 166
 167 #ifdef STDC_HEADERS
 168 # include <string.h>
 169 #else
 170 # ifndef HAVE_STRCHR
 171 #  define strchr index
 172 #  define strrchr rindex
 173 # endif
 174 char *strchr (), *strrchr ();
 175 # ifndef HAVE_MEMMOVE
 176 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
 177 #  define memmove(d, s, n) bcopy ((s), (d), (n))
 178 # endif
 179 #endif
 180
 181 #ifdef NO_NULL_REALLOC
 182 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
 183 #else
 184 # define rrd_realloc(a,b) realloc((a), (b))
 185 #endif
 186
 187 #ifdef NEED_MALLOC_MALLOC_H
 188 #  include <malloc/malloc.h>
 189 #endif
 190
 191 #ifdef HAVE_STDIO_H
 192 # include <stdio.h>
 193 #endif
 194
 195 #ifdef HAVE_STDLIB_H
 196 # include <stdlib.h>
 197 #endif
 198
 199 #ifdef HAVE_CTYPE_H
 200 # include <ctype.h>
 201 #endif
 202
 203 #ifdef HAVE_DIRENT_H
 204 # include <dirent.h>
 205 # define NAMLEN(dirent) strlen((dirent)->d_name)
 206 #else
 207 # define dirent direct
 208 # define NAMLEN(dirent) (dirent)->d_namlen
 209 # ifdef HAVE_SYS_NDIR_H
 210 #  include <sys/ndir.h>
 211 # endif
 212 # ifdef HAVE_SYS_DIR_H
 213 #  include <sys/dir.h>
 214 # endif
 215 # ifdef HAVE_NDIR_H
 216 #  include <ndir.h>
 217 # endif
 218 #endif
 219
 220 #ifdef MUST_DISABLE_SIGFPE
 221 # include <signal.h>
 222 #endif
 223
 224 #ifdef MUST_DISABLE_FPMASK
 225 # include <floatingpoint.h>
 226 #endif
 227
 228
 229 #ifdef HAVE_MATH_H
 230 # include <math.h>
 231 #endif
 232
 233 #ifdef HAVE_FLOAT_H
 234 # include <float.h>
 235 #endif
 236
 237 #ifdef HAVE_IEEEFP_H
 238 # include <ieeefp.h>
 239 #endif
 240
 241 #ifdef HAVE_FP_CLASS_H
 242 # include <fp_class.h>
 243 #endif
 244
 245 /* for Solaris */
 246 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 247 #  define HAVE_ISINF 1
 248 #  ifdef isinf
 249 #  undef isinf /* confuse autoconf */
 250 #  endif
 251 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 252 #endif
 253
 254 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 255 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 256 #  undef isnan /* confuse autoconf to NOT remove this */
 257 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 258 #endif
 259
 260 /* for OSF1 Digital Unix */
 261 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 262 #  define HAVE_ISINF 1
 263 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 264 #endif
 265
 266 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 267 #  define HAVE_ISINF 1
 268 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 269 #endif
 270
 271 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 272 #  define HAVE_ISINF 1
 273 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 274 #endif
 275
 276 /* for AIX */
 277 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 278 #  define HAVE_ISINF 1
 279 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 280 #endif
 281
 282 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 283 #  define HAVE_FINITE 1
 284 #  define finite(a) isfinite(a)
 285 #endif
 286
 287 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 288 #  define HAVE_FINITE 1
 289 #  define finite(a) (! isnan(a) && ! isinf(a))
 290 #endif
 291
 292 #ifndef HAVE_FINITE
 293 #error "Can't compile without finite function"
 294 #endif
 295
 296 #ifndef HAVE_ISINF
 297 #error "Can't compile without isinf function"
 298 #endif
 299
 300 #endif /* RRD_CONFIG_H */
 301 ])
 302
 303 dnl Process Special Options
 304 dnl -----------------------------------
 305
 306 dnl gettext
 307 GETTEXT_PACKAGE=rrdtool
 308 AC_SUBST(GETTEXT_PACKAGE)
 309 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
 310 IT_PROG_INTLTOOL([0.35.0],[no-xml])
 311 AM_GLIB_GNU_GETTEXT
 312
 313 dnl How the vertical axis label is printed
 314 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 315  [Vertical label angle: -90.0 (default) or 90.0])
 316 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 317  [Vertical label angle: -90.0 (default) or 90.0])
 318
 319 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 320 [],[enable_rrdcgi=yes])
 321
 322 dnl Check if we run on a system that has fonts
 323 AC_ARG_WITH(rrd-default-font,
 324 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 325 [RRD_DEFAULT_FONT=$withval],[
 326   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 327         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 328   else
 329         RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
 330   fi
 331 ])
 332
 333 dnl Use mmap in rrd_update instead of seek+write
 334 AC_ARG_ENABLE([mmap],
 335 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 336 [],
 337 [enable_mmap=yes])
 338
 339 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 340 [],[enable_pthread=yes])
 341
 342 AC_ARG_ENABLE(static-programs,
 343      [  --enable-static-programs  Build static programs],
 344      [case "${enableval}" in
 345        yes) staticprogs=yes ;;
 346        no)  staticprogs=no ;;
 347        *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
 348      esac],[staticprogs=no])
 349 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
 350
 351
 352 CONFIGURE_PART(Audit Compilation Environment)
 353
 354
 355 dnl Check for the compiler and static/shared library creation.
 356 AC_PROG_CC
 357 AC_PROG_CPP
 358 AC_PROG_LIBTOOL
 359
 360 dnl Try to detect/use GNU features
 361 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 362
 363 dnl which flags does the compiler support?
 364 if test "x$GCC" = "xyes"; then
 365   for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
 366     oCFLAGS="$CFLAGS"
 367     CFLAGS="$CFLAGS $flag"
 368     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 369     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 370        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 371     if eval test \$$cachename = no; then
 372          CFLAGS="$oCFLAGS"
 373     fi
 374   done
 375 fi
 376
 377
 378
 379 AC_SUBST(RRD_DEFAULT_FONT)
 380
 381 CONFIGURE_PART(Checking for Header Files)
 382
 383 dnl Checks for header files.
 384 AC_HEADER_STDC
 385 AC_HEADER_DIRENT
 386 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h libintl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
 387
 388 dnl Checks for typedefs, structures, and compiler characteristics.
 389 AC_C_CONST
 390 AC_HEADER_TIME
 391 AC_STRUCT_TM
 392
 393 dnl Checks for libraries.
 394 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 395
 396
 397 dnl add pic flag in any case this makes sure all our code is relocatable
 398 eval `./libtool --config | grep pic_flag`
 399 CFLAGS="$CFLAGS $pic_flag"
 400
 401 CONFIGURE_PART(Test Library Functions)
 402
 403 dnl Checks for library functions.
 404 AC_FUNC_STRFTIME
 405 AC_FUNC_VPRINTF
 406
 407 AC_C_BIGENDIAN
 408
 409 dnl for each function found we get a definition in config.h
 410 dnl of the form HAVE_FUNCTION
 411
 412 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 413
 414
 415 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
 416 if test "x$enable_mmap" = "xyes"; then
 417   case "$host" in
 418   *cygwin*)
 419     # the normal mmap test does not work in cygwin
 420     AC_CHECK_FUNCS(mmap)
 421     if test "x$ac_cv_func_mmap" = "xyes"; then
 422       ac_cv_func_mmap_fixed_mapped=yes
 423     fi
 424   ;;
 425   *)
 426     AC_CHECK_HEADERS(sys/mman.h)
 427     AC_FUNC_MMAP
 428     AC_CHECK_FUNCS(mmap munmap msync)
 429     AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
 430                                      # include <sys/mman.h>
 431                                      #endif])
 432     if test "x$ac_cv_have_decl_madvise" = "xyes";
 433     then
 434       AC_CHECK_FUNCS(madvise)
 435     else
 436       AC_CHECK_FUNCS(posix_madvise)
 437       if test "x$ac_cv_func_posix_madvise" != "xyes"; then
 438         AC_MSG_WARN([madvise() nor posix_madvise() found.])
 439       fi
 440     fi
 441   ;;
 442   esac
 443   if test "x$ac_cv_func_mmap" != "xyes";
 444   then
 445     AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
 446 dnl enable_mmap="no"
 447   fi
 448 fi
 449
 450 dnl can we use posix_fadvise
 451 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
 452 #include <fcntl.h>])
 453 AC_CHECK_FUNCS(posix_fadvise)
 454
 455
 456
 457 CONFIGURE_PART(IEEE Math Checks)
 458
 459
 460 dnl actual code to check if this works
 461 AC_CHECK_FUNCS(fpclassify, ,
 462   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 463     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 464 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 465       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 466
 467 AC_CHECK_FUNCS(isinf, ,
 468   [AC_MSG_CHECKING(for isinf with <math.h>)
 469     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 470 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 471       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 472
 473 dnl finite is BSD, isfinite is C99, so prefer the latter
 474 AC_CACHE_CHECK([whether isfinite is broken],[have_broken_isfinite],[
 475 AC_TRY_RUN([
 476 #ifdef HAVE_MATH_H
 477 #include <math.h>
 478 #endif
 479 #ifdef HAVE_FLOAT_H
 480 #include <float.h>
 481 #endif
 482 int main ()
 483 {
 484 #ifdef isfinite
 485 #ifdef LDBL_MAX
 486   if (!isfinite(LDBL_MAX)) return 1;
 487 #endif
 488 #ifdef DBL_MAX
 489   if (!isfinite(DBL_MAX)) return 1;
 490 #endif
 491 #endif
 492 return 0;
 493 }],[
 494 have_broken_isfinite=no],have_broken_isfinite=yes,[
 495 case "${target}" in
 496   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 497   *) have_broken_isfinite=no ;;
 498 esac])
 499 ])
 500 if test "x$have_broken_isfinite" = "xno"; then
 501   AC_DEFINE(HAVE_ISFINITE)
 502 else
 503 AC_CHECK_FUNCS(finite,[],
 504   [AC_CHECK_FUNCS(isfinite,[],
 505       [AC_MSG_CHECKING(for isfinite with <math.h>)
 506        AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 507 volatile int x;volatile float f;  ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 508                 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 509 fi
 510
 511 AC_FULL_IEEE
 512
 513 CONFIGURE_PART(Resolve Portability Issues)
 514
 515 dnl what does realloc do if it gets called with a NULL pointer
 516
 517 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 518 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 519               int main(void){
 520               char *x = NULL;
 521               x = realloc (x,10);
 522               if (x==NULL) return 1;
 523               return 0;
 524              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 525
 526 if test x"$rd_cv_null_realloc" = xnope; then
 527 AC_DEFINE(NO_NULL_REALLOC)
 528 fi
 529
 530 AC_LANG_PUSH(C)
 531 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 532 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 533 AC_LINK_IFELSE(
 534     AC_LANG_PROGRAM(
 535            [[#include <time.h>]],
 536            [[ctime_r(NULL,NULL,0)]]
 537                    ),
 538     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 539       AC_LINK_IFELSE(
 540           AC_LANG_PROGRAM(
 541                 [[#include <time.h>]],
 542                 [[ctime_r(NULL,NULL)]]
 543                          ),
 544           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 545           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 546       )
 547     ],
 548     [ AC_LINK_IFELSE(
 549           AC_LANG_PROGRAM(
 550                 [[#include <time.h>]],
 551                 [[ctime_r(NULL,NULL)]]
 552                          ),
 553           [AC_MSG_RESULT(no)],
 554           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 555       )
 556     ]
 557 )
 558 AC_LANG_POP(C)
 559
 560 dnl Check for pthreads
 561 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 562
 563 AC_SUBST(MULTITHREAD_CFLAGS)
 564 AC_SUBST(MULTITHREAD_LDFLAGS)
 565
 566 if test $enable_pthread != no; then
 567  ACX_PTHREAD([
 568     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 569     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 570              ],
 571              [])
 572 fi
 573
 574 dnl since we use lots of *_r functions all over the code we better
 575 dnl make sure they are known
 576
 577 if test  "x$x_rflag" != "xno"; then
 578    CPPFLAGS="$CPPFLAGS $x_rflag"
 579 fi
 580
 581 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 582
 583 AC_LANG_PUSH(C)
 584 dnl see if we have to include malloc/malloc.h
 585 AC_MSG_CHECKING([do we need malloc/malloc.h])
 586 AC_LINK_IFELSE(
 587     AC_LANG_PROGRAM(
 588            [[#include <stdlib.h>]],
 589            [[malloc(1)]]
 590                    ),
 591     [ AC_MSG_RESULT([nope, works out of the box]) ],
 592     [ AC_LINK_IFELSE(
 593           AC_LANG_PROGRAM(
 594                 [[#include <stdlib.h>
 595                   #include <malloc/malloc.h>]],
 596                 [[malloc(1)]]
 597                          ),
 598           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 599            AC_MSG_RESULT([yes we do])],
 600           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 601       )
 602     ]
 603 )
 604 AC_LANG_POP(C)
 605
 606 dnl Could use these to know if we need to provide a prototype
 607 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 608
 609 dnl solaris has fdatasync in the librt
 610
 611 AC_CHECK_FUNC(fdatasync, [],  AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"],[]))
 612
 613
 614 CONFIGURE_PART(Find 3rd-Party Libraries)
 615
 616
 617 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 618
 619 CORE_LIBS="$LIBS"
 620
 621 dnl EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 622 dnl EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 623 dnl EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 624 dnl EX_CHECK_ALL(fontconfig, FcInit,                    fontconfig.h,           fontconfig,  2.3.1,  http://fontconfig.org/release/, /usr/include)
 625 EX_CHECK_ALL(cairo,      cairo_font_options_create,     cairo.h,                cairo-png,   1.4.6,  http://cairographics.org/releases/, "")
 626 EX_CHECK_ALL(cairo,      cairo_svg_surface_create,      cairo-svg.h,            cairo-svg,   1.4.6,  http://cairographics.org/releases/, "")
 627 EX_CHECK_ALL(cairo,      cairo_pdf_surface_create,      cairo-pdf.h,            cairo-pdf,   1.4.6,  http://cairographics.org/releases/, "")
 628 EX_CHECK_ALL(cairo,      cairo_ps_surface_create,       cairo-ps.h,             cairo-ps,    1.4.6,  http://cairographics.org/releases/, "")
 629 dnl EX_CHECK_ALL(glib-2.0,   glib_check_version,        glib.h,                 glib-2.0,    2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
 630 EX_CHECK_ALL(pango-1.0,  pango_cairo_context_set_font_options,  pango/pango.h,  pangocairo,  1.17,    http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
 631 EX_CHECK_ALL(xml2,       xmlParseFile,                  libxml/parser.h,        libxml-2.0,        2.6.31,  http://xmlsoft.org/downloads.html, /usr/include/libxml2)
 632
 633 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 634   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 635 fi
 636
 637 ALL_LIBS="$LIBS"
 638 LIBS=
 639
 640 AC_SUBST(CORE_LIBS)
 641 AC_SUBST(ALL_LIBS)
 642
 643 CONFIGURE_PART(Prep for Building Language Bindings)
 644
 645 dnl Check for Perl.
 646 AC_PATH_PROG(PERL, perl, no)
 647
 648 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 649 [],[enable_perl=yes])
 650
 651
 652 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 653 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 654 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 655 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 656
 657 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 658         COMP_PERL=
 659 else
 660         COMP_PERL="perl_piped perl_shared"
 661         AC_MSG_CHECKING(for the perl version you are running)
 662         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 663         AC_MSG_RESULT($PERL_VERSION)
 664         if test -z "$PERLCC"; then
 665             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 666             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 667             AC_MSG_RESULT($perlcc)
 668             if test ! -x "$perlcc"; then
 669                 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
 670                 if test "$PERL_CC" = "no"; then
 671                     AC_MSG_WARN([
 672 I would not find the Compiler ($perlcc) that was originally used to compile
 673 your perl binary. You should either make sure that this compiler is
 674 available on your system, pick an other compiler and set PERLCC
 675 appropriately, or use a different perl setup that was compiled locally.
 676
 677 I will disable the compilation of the RRDs perl module for now.
 678 ])
 679                     COMP_PERL="perl_piped"
 680                 fi
 681             fi
 682         fi
 683 fi
 684
 685 AC_MSG_CHECKING(Perl Modules to build)
 686 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 687
 688 # Options to pass when configuring perl module
 689 ppref=$prefix
 690 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 691
 692 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 693
 694 dnl pass additional perl options when generating Makefile from Makefile.PL
 695 AC_ARG_ENABLE(perl-site-install,
 696 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 697                           together with rrdtool in $prefix/lib/perl. You have to
 698                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 699                           when you want to use them. When you set this option
 700                           the perl modules will get installed wherever
 701                           your perl setup thinks it is best.],
 702 [PERL_MAKE_OPTIONS=],[])
 703
 704 if test ! -z "$PERLCC"; then
 705    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 706
 707    if test ! -z "$PERLCCFLAGS"; then
 708        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 709    fi
 710
 711    if test -z "$PERLLD"; then
 712        PERLLD=$PERLCC
 713    fi
 714    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 715
 716    if test ! -z "$PERLLDFLAGS"; then
 717        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 718    fi
 719 fi
 720
 721 AC_ARG_WITH(perl-options,
 722 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 723                           generating Makefile from Makefile.PL. If you set this
 724                           option, interesting things may happen unless you know
 725                           what you are doing!],
 726 [PERL_MAKE_OPTIONS=$withval])
 727
 728 AC_SUBST(PERL_MAKE_OPTIONS)
 729 AC_SUBST(PERL)
 730 AC_SUBST(COMP_PERL)
 731 AC_SUBST(PERL_VERSION)
 732
 733 dnl Check for Ruby.
 734 AC_PATH_PROG(RUBY, ruby, no)
 735
 736 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 737 [],[enable_ruby=yes])
 738
 739 AC_MSG_CHECKING(if ruby modules can be built)
 740
 741 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 742         COMP_RUBY=
 743         AC_MSG_RESULT(No .. Ruby not found or disabled)
 744 else
 745         if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
 746                 COMP_RUBY="ruby"
 747                 AC_MSG_RESULT(YES)
 748         else
 749                 COMP_RUBY=
 750                 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
 751         fi
 752 fi
 753
 754
 755 dnl pass additional ruby options when generating Makefile from Makefile.PL
 756 AC_ARG_ENABLE(ruby-site-install,
 757 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 758                           together with rrdtool in $prefix/lib/ruby. You have to
 759                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 760                           for ruby to find the RRD.so file.],
 761 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$prefix/lib/ruby"])
 762
 763
 764 AC_ARG_WITH(ruby-options,
 765 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 766                           generating Makefile from extconf.rb. If you set this
 767                           option, interesting things may happen unless you know
 768                           what you are doing!],
 769 [RUBY_MAKE_OPTIONS=$withval])
 770
 771 AC_SUBST(RUBY_MAKE_OPTIONS)
 772 AC_SUBST(RUBY)
 773 AC_SUBST(COMP_RUBY)
 774
 775
 776 enable_tcl_site=no
 777
 778 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 779 [],[enable_tcl=yes])
 780
 781 if test  "$enable_tcl" = "yes"; then
 782   dnl Check for Tcl.
 783   withval=""
 784   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 785   enable_tcl=no
 786   for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
 787     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 788     if test -f "$dir/tclConfig.sh" ; then
 789         tcl_config=$dir/tclConfig.sh
 790         enable_tcl=yes
 791         AC_MSG_RESULT(yes)
 792         break
 793     else
 794         AC_MSG_RESULT(no)
 795     fi
 796   done
 797
 798   if test "$enable_tcl" = "no"; then
 799         AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
 800   else
 801         . $tcl_config
 802         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 803   fi
 804   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 805   [],[enable_tcl_site=yes])
 806
 807 fi
 808
 809 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 810 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 811
 812 AC_SUBST(TCL_PREFIX)
 813 AC_SUBST(TCL_SHLIB_CFLAGS)
 814 AC_SUBST(TCL_SHLIB_LD)
 815 AC_SUBST(TCL_SHLIB_SUFFIX)
 816 AC_SUBST(TCL_PACKAGE_PATH)
 817 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 818 AC_SUBST(TCL_STUB_LIB_SPEC)
 819 AC_SUBST(TCL_VERSION)
 820 AC_SUBST(TCL_PACKAGE_DIR)
 821 AC_SUBST(TCL_INC_DIR)
 822
 823 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 824 [],[enable_python=yes])
 825
 826 if test  "$enable_python" = "yes"; then
 827 dnl Check for python
 828 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 829 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 830 fi
 831
 832 if test  x$enable_python = xno; then
 833         COMP_PYTHON=
 834 else
 835         COMP_PYTHON="python"
 836 fi
 837
 838 AC_SUBST(COMP_PYTHON)
 839
 840 dnl Check for nroff
 841 AC_PATH_PROGS(NROFF, gnroff nroff)
 842 AC_PATH_PROGS(TROFF, groff troff)
 843
 844 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 845 if test -z "$RRDDOCDIR"; then
 846    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 847
 848
 849 CONFIGURE_PART(Apply Configuration Information)
 850
 851 AC_CONFIG_FILES([examples/shared-demo.pl])
 852 AC_CONFIG_FILES([examples/piped-demo.pl])
 853 AC_CONFIG_FILES([examples/stripes.pl])
 854 AC_CONFIG_FILES([examples/bigtops.pl])
 855 AC_CONFIG_FILES([examples/minmax.pl])
 856 AC_CONFIG_FILES([examples/4charts.pl])
 857 AC_CONFIG_FILES([examples/perftest.pl])
 858 AC_CONFIG_FILES([examples/Makefile])
 859 AC_CONFIG_FILES([doc/Makefile])
 860 AC_CONFIG_FILES([po/Makefile.in])
 861 AC_CONFIG_FILES([src/Makefile])
 862 AC_CONFIG_FILES([bindings/Makefile])
 863 AC_CONFIG_FILES([bindings/tcl/Makefile])
 864 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 865 AC_CONFIG_FILES([Makefile])
 866
 867 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 868 AC_OUTPUT
 869
 870 AC_MSG_CHECKING(in)
 871 AC_MSG_RESULT(and out again)
 872
 873 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 874 sleep 1
 875 echo $ECHO_N ".$ECHO_C" 1>&6
 876 sleep 1
 877 echo $ECHO_N ".$ECHO_C" 1>&6
 878 sleep 1
 879 echo $ECHO_N ".$ECHO_C" 1>&6
 880 sleep 1
 881 echo $ECHO_N ".$ECHO_C" 1>&6
 882 sleep 1
 883 AC_MSG_RESULT([ just kidding ;-)])
 884 echo
 885 echo "----------------------------------------------------------------"
 886 echo "Config is DONE!"
 887 echo
 888 echo "          With MMAP IO: $enable_mmap"
 889 echo "       Static programs: $staticprogs"
 890 echo "          Perl Modules: $COMP_PERL"
 891 echo "           Perl Binary: $PERL"
 892 echo "          Perl Version: $PERL_VERSION"
 893 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 894 echo "          Ruby Modules: $COMP_RUBY"
 895 echo "           Ruby Binary: $RUBY"
 896 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 897 echo "    Build Tcl Bindings: $enable_tcl"
 898 echo " Build Python Bindings: $enable_python"
 899 echo "          Build rrdcgi: $enable_rrdcgi"
 900 echo "       Build librrd MT: $enable_pthread"
 901 echo
 902 echo
 903 echo "Type 'make' to compile the software and use 'make install' to "
 904 echo "install everything to: $prefix."
 905 echo
 906 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 907 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 908 echo "place an order."
 909 echo
 910 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 911 echo "----------------------------------------------------------------"