CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 #
  36 # Open Issues:
  37 #  - none?
  38 #
  39
  40
  41 ## Project name to use as command prefix
  42
  43 PROJECT(SUPERTUX)
  44
  45
  46 ### CMake configuration
  47
  48 # allow building with old CMake. Use some bundled modules as a fallback
  49 CMAKE_MINIMUM_REQUIRED(VERSION 2.4)
  50 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${SUPERTUX_SOURCE_DIR}/mk/cmake)
  51
  52 # move some config clutter to the advanced section
  53 MARK_AS_ADVANCED(
  54         CMAKE_BACKWARDS_COMPATIBILITY
  55         CMAKE_BUILD_TYPE
  56         CMAKE_INSTALL_PREFIX
  57         EXECUTABLE_OUTPUT_PATH
  58         LIBRARY_OUTPUT_PATH
  59 )
  60
  61 ## For autopackage
  62 MARK_AS_ADVANCED(
  63         ENABLE_BINRELOC
  64         APPDATADIR
  65 )
  66 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  67 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share" CACHE STRING "APPDATADIR for autopackage's BINRELOC features")
  68
  69 ## Check endianess
  70
  71 INCLUDE(TestBigEndian)
  72 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  73
  74 ## Add lots of dependencies to compiler switches
  75
  76 FIND_PACKAGE(SDL REQUIRED)
  77 MARK_AS_ADVANCED(
  78         SDLMAIN_LIBRARY
  79         SDL_INCLUDE_DIR
  80         SDL_LIBRARY
  81 )
  82 INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR})
  83 LINK_LIBRARIES(${SDL_LIBRARY})
  84
  85 FIND_PACKAGE(SDL_image REQUIRED)
  86 MARK_AS_ADVANCED(
  87         SDLIMAGE_INCLUDE_DIR
  88         SDLIMAGE_LIBRARY
  89 )
  90 INCLUDE_DIRECTORIES(${SDLIMAGE_INCLUDE_DIR})
  91 LINK_LIBRARIES(${SDLIMAGE_LIBRARY})
  92
  93 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  94 IF(ENABLE_OPENGL)
  95   FIND_PACKAGE(OpenGL)
  96   IF(${OPENGL_FOUND} STREQUAL "YES")
  97     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  98     LINK_LIBRARIES(${OPENGL_LIBRARY})
  99     SET(HAVE_OPENGL TRUE)
 100   ENDIF(${OPENGL_FOUND} STREQUAL "YES")
 101 ENDIF(ENABLE_OPENGL)
 102
 103 FIND_PACKAGE(OpenAL REQUIRED)
 104 MARK_AS_ADVANCED(
 105         OPENAL_INCLUDE_DIR
 106         OPENAL_LIBRARY
 107 )
 108 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
 109 LINK_LIBRARIES(${OPENAL_LIBRARY})
 110
 111 FIND_PACKAGE(OggVorbis REQUIRED)
 112 MARK_AS_ADVANCED(
 113         OGG_LIBRARY
 114         VORBISENC_LIBRARY
 115         VORBISFILE_LIBRARY
 116         VORBIS_INCLUDE_DIR
 117         VORBIS_LIBRARY
 118 )
 119 INCLUDE_DIRECTORIES(${OGGVORBIS_INCLUDE_DIR})
 120 LINK_LIBRARIES(${OGGVORBIS_LIBRARIES})
 121
 122 FIND_PACKAGE(PhysFS REQUIRED)
 123 MARK_AS_ADVANCED(
 124         PHYSFS_INCLUDE_DIR
 125         PHYSFS_LIBRARY
 126 )
 127 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
 128 LINK_LIBRARIES(${PHYSFS_LIBRARY})
 129
 130 FIND_PACKAGE(CURL)
 131 IF(${CURL_FOUND})
 132   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
 133   LINK_LIBRARIES(${CURL_LIBRARY})
 134   SET(HAVE_LIBCURL TRUE)
 135 ENDIF(${CURL_FOUND})
 136
 137 #FIND_PACKAGE(ICONV REQUIRED)
 138 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 139 #LINK_LIBRARIES(${ICONV_LIBRARY})
 140
 141 ## Check platform-dependent build options
 142
 143 INCLUDE(ConfigureChecks)
 144
 145 ## Create config.h
 146
 147 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 148 include_directories (${CMAKE_BINARY_DIR}/)
 149
 150 ## Also execute instructions in src/squirrel/CMakeLists.txt
 151
 152 ADD_SUBDIRECTORY(src/squirrel)
 153
 154 ## Add squirrel lib dir to search path
 155
 156 LINK_DIRECTORIES(src/squirrel)
 157
 158 ## Some additional include paths
 159
 160 include_directories (${SUPERTUX_SOURCE_DIR}/src/)
 161 include_directories (${SUPERTUX_SOURCE_DIR}/src/squirrel/include/)
 162
 163 ## Build list of sources for supertux binary
 164
 165 FILE(GLOB SUPERTUX_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} src/*.cpp src/audio/*.cpp src/badguy/*.cpp src/binreloc/*.cpp src/control/*.cpp src/gui/*.cpp src/lisp/*.cpp src/math/*.cpp src/object/*.cpp src/physfs/*.cpp src/sprite/*.cpp src/tinygettext/*.cpp src/trigger/*.cpp src/video/*.cpp src/worldmap/*.cpp src/scripting/*.cpp src/obstack/*.c)
 166
 167 ## Debug options
 168
 169 OPTION(DEBUG "Build with debugging options" OFF)
 170 OPTION(PROFILE "Build with profiling information" OFF)
 171 IF(CMAKE_COMPILER_IS_GNUCC)
 172   IF (DEBUG)
 173     REMOVE_DEFINITIONS(-O2)
 174     ADD_DEFINITIONS(-O0 -g -Wall -Werror)
 175   ELSE (DEBUG)
 176     ADD_DEFINITIONS(-O2)
 177     REMOVE_DEFINITIONS(-O0 -g -Wall -Werror)
 178   ENDIF (DEBUG)
 179   IF (PROFILE)
 180     ADD_DEFINITIONS(-pg)
 181   ELSE (PROFILE)
 182     REMOVE_DEFINITIONS(-pg)
 183   ENDIF (PROFILE)
 184 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 185
 186 ## Add in squirrel debug stuff
 187
 188 OPTION(ENABLE_SQDBG "Build squirrel script interpreter with debugging options" OFF)
 189 IF(ENABLE_SQDBG)
 190   include_directories (${SUPERTUX_SOURCE_DIR}/src/squirrel/)
 191   FILE(GLOB SQDBG_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} src/squirrel/sqdbg/*.cpp)
 192   SET(SUPERTUX_SOURCES ${SQDBG_SOURCES} ${SUPERTUX_SOURCES})
 193 ENDIF(ENABLE_SQDBG)
 194
 195 ## Build miniswig and generate miniswig wrapper
 196
 197 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" ${DEBUG})
 198 IF(GENERATE_WRAPPER)
 199   ADD_SUBDIRECTORY(tools/miniswig)
 200   ADD_CUSTOM_COMMAND(
 201     OUTPUT ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp
 202     COMMAND cd ${SUPERTUX_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 203     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${SUPERTUX_BINARY_DIR}/miniswig.tmp
 204     COMMAND tools/miniswig/miniswig
 205     ARGS --input miniswig.tmp --output-cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace Scripting
 206     DEPENDS src/scripting/wrapper.interface.hpp tools/miniswig/miniswig
 207   )
 208 ENDIF(GENERATE_WRAPPER)
 209
 210 IF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 211   SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 212 ENDIF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 213
 214 ## If xgettext is available, generate messages.pot for sources
 215
 216 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" ${DEBUG})
 217 IF(GENERATE_MESSAGESPOT)
 218   MARK_AS_ADVANCED(
 219     XGETTEXT
 220   )
 221   FIND_PROGRAM(
 222     XGETTEXT
 223     NAMES "xgettext"
 224     PATHS "/usr/bin"
 225   )
 226   IF(${XGETTEXT} STREQUAL "XGETTEXT-NOTFOUND")
 227     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 228   ELSE(${XGETTEXT} STREQUAL "XGETTEXT-NOTFOUND")
 229     MESSAGE(STATUS "Found xgettext: ${XGETTEXT}")
 230
 231     SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/data/locale/messages.pot)
 232     ADD_CUSTOM_COMMAND(
 233       OUTPUT ${MESSAGES_POT_FILE}
 234       COMMAND "/usr/bin/xgettext" --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES}
 235       DEPENDS ${SUPERTUX_SOURCES}
 236       WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 237       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 238     )
 239     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 240
 241     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${SUPERTUX_SOURCE_DIR} data/levels/*)
 242     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 243     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 244       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${SUPERTUX_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 245
 246       SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 247       ADD_CUSTOM_COMMAND(
 248         OUTPUT ${MESSAGES_POT_FILE}
 249         COMMAND "/usr/bin/xgettext" --keyword="_:1" --language=Lisp --sort-by-file --output=${MESSAGES_POT_FILE} ${SUPERTUX_LEVELS}
 250         DEPENDS ${SUPERTUX_LEVELS}
 251         WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 252         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 253       )
 254       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 255
 256     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 257
 258     ADD_CUSTOM_TARGET(
 259       supertux2-messages ALL
 260       DEPENDS ${MESSAGES_POT_FILES}
 261     )
 262
 263   ENDIF(${XGETTEXT} STREQUAL "XGETTEXT-NOTFOUND")
 264 ENDIF(GENERATE_MESSAGESPOT)
 265
 266 ## Some additional compiler switches
 267 IF(CMAKE_COMPILER_IS_GNUCC)
 268   ADD_DEFINITIONS(-fno-strict-aliasing)
 269 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 270
 271
 272 ## On Windows, add an icon
 273
 274 IF(WIN32)
 275   SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 276   IF(MINGW)
 277     ADD_CUSTOM_COMMAND(
 278     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 279     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 280     SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 281   ELSE(MINGW)
 282     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 283   ENDIF(MINGW)
 284 ENDIF(WIN32)
 285
 286
 287 ## Generate supertux executable in the right place
 288
 289 SET(EXECUTABLE_OUTPUT_PATH ${SUPERTUX_SOURCE_DIR})
 290
 291 ## Add target for supertux binary
 292
 293 ADD_EXECUTABLE(supertux2 ${SUPERTUX_SOURCES})
 294
 295 ## Link supertux binary with squirrel
 296
 297 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 298
 299
 300 ## Install stuff
 301
 302 IF(WIN32 AND NOT UNIX)
 303
 304   SET(INSTALL_SUBDIR_BIN ".")
 305   SET(INSTALL_SUBDIR_SHARE "data/")
 306   SET(INSTALL_SUBDIR_DOC ".")
 307   SET(INSTALL_SUBDIR_ICONS ".")
 308
 309   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/SDL.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 310   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/SDL_image.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 311   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/iconv.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 312   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/libogg-0.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 313   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/libphysfs-1-0-0.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 314   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/OpenAl32.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 315   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/wrap_oal.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 316   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/libcurl-4.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 317
 318 ELSE(WIN32 AND NOT UNIX)
 319
 320   SET(INSTALL_SUBDIR_BIN "games/")
 321   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2/")
 322   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2/")
 323   SET(INSTALL_SUBDIR_ICONS "share/pixmaps/")
 324
 325   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/supertux2.desktop DESTINATION share/applications)
 326
 327 ENDIF(WIN32 AND NOT UNIX)
 328
 329 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 330 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION ${INSTALL_SUBDIR_ICONS})
 331 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/INSTALL ${SUPERTUX_SOURCE_DIR}/README ${SUPERTUX_SOURCE_DIR}/COPYING ${SUPERTUX_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 332 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/credits.txt ${SUPERTUX_SOURCE_DIR}/data/camera.cfg DESTINATION ${INSTALL_SUBDIR_SHARE})
 333 INSTALL(DIRECTORY data/images DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 334 INSTALL(DIRECTORY data/levels DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 335 INSTALL(DIRECTORY data/music DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 336 INSTALL(DIRECTORY data/scripts DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 337 INSTALL(DIRECTORY data/speech DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 338 INSTALL(DIRECTORY data/sounds DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 339 INSTALL(DIRECTORY data/locale DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 340
 341
 342 ## CPack/Installation-specific stuff
 343
 344 INCLUDE(InstallRequiredSystemLibraries)
 345 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "SuperTux")
 346 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 347 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${SUPERTUX_SOURCE_DIR}/README")
 348 SET(CPACK_RESOURCE_FILE_LICENSE "${SUPERTUX_SOURCE_DIR}/COPYING")
 349 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 350 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 351 SET(CPACK_PACKAGE_VERSION_PATCH "1-SVN")
 352 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 353 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 354 IF(WIN32 AND NOT UNIX)
 355   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 356   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 357 ELSE(WIN32 AND NOT UNIX)
 358 ENDIF(WIN32 AND NOT UNIX)
 359 INCLUDE(CPack)
 360