CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix
  36
  37 PROJECT(SUPERTUX)
  38
  39
  40 ### CMake configuration
  41
  42 # allow building with CMake 2.6. Set compatibility options. Use some bundled modules as a fallback
  43 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  44 IF(COMMAND cmake_policy)
  45         CMAKE_POLICY(SET CMP0003 NEW)
  46 ENDIF(COMMAND cmake_policy)
  47
  48 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${SUPERTUX_SOURCE_DIR}/mk/cmake)
  49
  50 # move some config clutter to the advanced section
  51 MARK_AS_ADVANCED(
  52         CMAKE_BACKWARDS_COMPATIBILITY
  53         CMAKE_BUILD_TYPE
  54         CMAKE_INSTALL_PREFIX
  55         EXECUTABLE_OUTPUT_PATH
  56         LIBRARY_OUTPUT_PATH
  57         CMAKE_OSX_ARCHITECTURES
  58         CMAKE_OSX_SYSROOT
  59 )
  60
  61 ## For autopackage
  62 MARK_AS_ADVANCED(
  63         ENABLE_BINRELOC
  64         APPDATADIR
  65 )
  66 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  67 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2")
  68
  69 ## Check endianess
  70
  71 INCLUDE(TestBigEndian)
  72 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  73
  74 ## Add lots of dependencies to compiler switches
  75
  76 FIND_PACKAGE(SDL REQUIRED)
  77 MARK_AS_ADVANCED(
  78         SDLMAIN_LIBRARY
  79         SDL_INCLUDE_DIR
  80         SDL_LIBRARY
  81 )
  82 INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR})
  83
  84 FIND_PACKAGE(SDL_image REQUIRED)
  85 MARK_AS_ADVANCED(
  86         SDLIMAGE_INCLUDE_DIR
  87         SDLIMAGE_LIBRARY
  88 )
  89 INCLUDE_DIRECTORIES(${SDLIMAGE_INCLUDE_DIR})
  90
  91 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  92 IF(ENABLE_OPENGL)
  93   FIND_PACKAGE(OpenGL)
  94   IF(${OPENGL_FOUND} STREQUAL "YES")
  95     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  96     SET(HAVE_OPENGL TRUE)
  97   ENDIF(${OPENGL_FOUND} STREQUAL "YES")
  98 ENDIF(ENABLE_OPENGL)
  99
 100 FIND_PACKAGE(OpenAL REQUIRED)
 101 MARK_AS_ADVANCED(
 102         OPENAL_INCLUDE_DIR
 103         OPENAL_LIBRARY
 104 )
 105 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
 106
 107 FIND_PACKAGE(OggVorbis REQUIRED)
 108 MARK_AS_ADVANCED(
 109         OGG_LIBRARY
 110         VORBISENC_LIBRARY
 111         VORBISFILE_LIBRARY
 112         VORBIS_INCLUDE_DIR
 113         VORBIS_LIBRARY
 114 )
 115 INCLUDE_DIRECTORIES(${OGGVORBIS_INCLUDE_DIR})
 116
 117 FIND_PACKAGE(PhysFS REQUIRED)
 118 MARK_AS_ADVANCED(
 119         PHYSFS_INCLUDE_DIR
 120         PHYSFS_LIBRARY
 121 )
 122 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
 123
 124 FIND_PACKAGE(CURL)
 125 IF(CURL_FOUND)
 126   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
 127   SET(HAVE_LIBCURL TRUE)
 128 ENDIF(CURL_FOUND)
 129
 130 #FIND_PACKAGE(ICONV REQUIRED)
 131 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 132 #LINK_LIBRARIES(${ICONV_LIBRARY})
 133
 134 ## Find revision of WC
 135 MARK_AS_ADVANCED(SVNVERSION_EXECUTABLE)
 136 FIND_PROGRAM(SVNVERSION_EXECUTABLE svnversion)
 137 IF(SVNVERSION_EXECUTABLE)
 138   EXECUTE_PROCESS(COMMAND svnversion -n ${SUPERTUX_SOURCE_DIR}
 139                   OUTPUT_VARIABLE SUPERTUX_WC_REVISION)
 140   SET(REVISION " r${SUPERTUX_WC_REVISION}")
 141 ENDIF(SVNVERSION_EXECUTABLE)
 142
 143 ## Check platform-dependent build options
 144
 145 INCLUDE(ConfigureChecks)
 146
 147 ## Create config.h and version.h
 148
 149 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 150 configure_file(version.h.cmake ${CMAKE_BINARY_DIR}/version.h )
 151 include_directories (${CMAKE_BINARY_DIR}/)
 152
 153 ## Also execute instructions in src/squirrel/CMakeLists.txt
 154
 155 ADD_SUBDIRECTORY(src/squirrel)
 156
 157 ## Add squirrel lib dir to search path
 158
 159 LINK_DIRECTORIES(src/squirrel)
 160
 161 ## Some additional include paths
 162
 163 include_directories (${SUPERTUX_SOURCE_DIR}/src/)
 164 include_directories (${SUPERTUX_SOURCE_DIR}/src/squirrel/include/)
 165
 166 ## Build list of sources for supertux binary
 167
 168 FILE(GLOB SUPERTUX_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} src/*.cpp src/*/*.cpp src/obstack/*.c)
 169
 170 ## Precompile "a few" headers in GCC
 171 OPTION(PRECOMPILE_HEADERS "Precompile headers (experimental)" OFF)
 172 IF(PRECOMPILE_HEADERS)
 173   FILE(GLOB PRECOMPILED_HEADERS RELATIVE ${SUPERTUX_SOURCE_DIR} src/badguy/badguy.hpp
 174            src/scripting/wrapper.hpp src/video/*.hpp src/math/*.hpp)
 175   FILE(WRITE ${SUPERTUX_BINARY_DIR}/precompile.hh "// Precompiled headers\n")
 176   FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#ifndef __SUPERTUX_PRECOMPILED_HEADER\n")
 177   FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#define __SUPERTUX_PRECOMPILED_HEADER\n")
 178   FOREACH(PRECOMPILED_HEADER ${PRECOMPILED_HEADERS})
 179     FILE(RELATIVE_PATH PRECOMPILED_HEADER ${SUPERTUX_SOURCE_DIR}/src "${SUPERTUX_SOURCE_DIR}/${PRECOMPILED_HEADER}")
 180     FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#include \"${PRECOMPILED_HEADER}\"\n")
 181   ENDFOREACH(PRECOMPILED_HEADER)
 182   FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#endif /*__SUPERTUX_PRECOMPILED_HEADER*/\n")
 183   ADD_CUSTOM_COMMAND(
 184     OUTPUT ${SUPERTUX_BINARY_DIR}/precompile.hh.gch
 185     COMMAND ${CMAKE_CXX_COMPILER} -x "c++-header" $(CXX_FLAGS) ${SUPERTUX_BINARY_DIR}/precompile.hh
 186     DEPENDS ${PRECOMPILED_HEADERS}
 187     COMMENT "Building precompiled header..."
 188   )
 189   ## Make certain it is built
 190   SET(SUPERTUX_SOURCES ${SUPERTUX_BINARY_DIR}/precompile.hh.gch ${SUPERTUX_SOURCES})
 191   SET(CMAKE_CXX_FLAGS "-include ${SUPERTUX_BINARY_DIR}/precompile.hh" ${CMAKE_CXX_FLAGS})
 192 ELSE(PRECOMPILE_HEADERS)
 193   IF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh)
 194     FILE(REMOVE ${SUPERTUX_BINARY_DIR}/precompile.hh)
 195   ENDIF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh)
 196   IF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh.gch)
 197     FILE(REMOVE ${SUPERTUX_BINARY_DIR}/precompile.hh.gch)
 198   ENDIF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh.gch)
 199 ENDIF(PRECOMPILE_HEADERS)
 200
 201
 202 ## Debug options
 203
 204 OPTION(DEBUG "Build with debugging options" ON)
 205 OPTION(WERROR "Stop on first compiler warning" ON)
 206 IF(CMAKE_COMPILER_IS_GNUCC)
 207   ADD_DEFINITIONS(-Wall -Wextra -W)
 208   IF (DEBUG)
 209     REMOVE_DEFINITIONS(-O2)
 210     ADD_DEFINITIONS(-O0 -g)
 211   ELSE (DEBUG)
 212     ADD_DEFINITIONS(-O2)
 213     REMOVE_DEFINITIONS(-O0 -g)
 214   ENDIF (DEBUG)
 215   SET(CMAKE_CXX_FLAGS_PROFILE "-pg")
 216   SET(CMAKE_C_FLAGS_PROFILE "-pg")
 217   SET(CMAKE_LD_FLAGS_PROFILE "-pg")
 218   IF(WERROR)
 219     ADD_DEFINITIONS(-Werror)
 220   ELSE(WERROR)
 221     REMOVE_DEFINITIONS(-Werror)
 222   ENDIF(WERROR)
 223 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 224
 225 ## Add in squirrel debug stuff
 226
 227 OPTION(ENABLE_SQDBG "Build squirrel script interpreter with debugging options" OFF)
 228 IF(ENABLE_SQDBG)
 229   include_directories (${SUPERTUX_SOURCE_DIR}/src/squirrel/)
 230   FILE(GLOB SQDBG_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} src/squirrel/sqdbg/*.cpp)
 231   SET(SUPERTUX_SOURCES ${SQDBG_SOURCES} ${SUPERTUX_SOURCES})
 232 ENDIF(ENABLE_SQDBG)
 233
 234 ## Build miniswig and generate miniswig wrapper
 235
 236 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" ${DEBUG})
 237 IF(GENERATE_WRAPPER)
 238   ADD_SUBDIRECTORY(tools/miniswig)
 239   ADD_CUSTOM_COMMAND(
 240     OUTPUT ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp
 241     COMMAND cd ${SUPERTUX_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 242     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${SUPERTUX_BINARY_DIR}/miniswig.tmp
 243     COMMAND tools/miniswig/miniswig
 244     ARGS --input miniswig.tmp --output-cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace Scripting
 245     DEPENDS tools/miniswig/miniswig
 246     IMPLICIT_DEPENDS CXX ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.interface.hpp
 247   )
 248 ENDIF(GENERATE_WRAPPER)
 249
 250 IF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 251   SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 252 ENDIF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 253
 254 ## If xgettext is available, generate messages.pot for sources
 255
 256 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" ${DEBUG})
 257 IF(GENERATE_MESSAGESPOT)
 258   MARK_AS_ADVANCED(
 259     XGETTEXT_EXECUTABLE
 260   )
 261   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 262   IF(NOT XGETTEXT_EXECUTABLE)
 263     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 264   ELSE(NOT XGETTEXT_EXECUTABLE)
 265     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 266
 267     SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/data/locale/messages.pot)
 268     ADD_CUSTOM_COMMAND(
 269       OUTPUT ${MESSAGES_POT_FILE}
 270       COMMAND ${XGETTEXT_EXECUTABLE}
 271       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES}
 272       DEPENDS ${SUPERTUX_SOURCES}
 273       WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 274       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 275     )
 276     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 277
 278     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${SUPERTUX_SOURCE_DIR} data/levels/*)
 279     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 280     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 281       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${SUPERTUX_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 282
 283       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 284       IF(SUPERTUX_LEVELS)
 285       SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 286       ADD_CUSTOM_COMMAND(
 287         OUTPUT ${MESSAGES_POT_FILE}
 288         COMMAND ${XGETTEXT_EXECUTABLE}
 289         ARGS --keyword="_:1" --language=Lisp --force-po --sort-by-file "--output=${MESSAGES_POT_FILE}" ${SUPERTUX_LEVELS}
 290         DEPENDS ${SUPERTUX_LEVELS}
 291         WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 292         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 293       )
 294       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 295       ENDIF(SUPERTUX_LEVELS)
 296
 297     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 298
 299     ADD_CUSTOM_TARGET(
 300       supertux2-messages ALL
 301       DEPENDS ${MESSAGES_POT_FILES}
 302     )
 303
 304   ENDIF(NOT XGETTEXT_EXECUTABLE)
 305 ENDIF(GENERATE_MESSAGESPOT)
 306
 307 ## Some additional compiler switches
 308 IF(CMAKE_COMPILER_IS_GNUCC)
 309   ADD_DEFINITIONS(-fno-strict-aliasing)
 310 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 311
 312 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 313   ADD_DEFINITIONS(-DMACOSX)
 314 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 315
 316
 317 ## On Windows, add an icon
 318
 319 IF(WIN32)
 320   SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 321   IF(MINGW)
 322     ADD_CUSTOM_COMMAND(
 323     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 324     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 325     SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 326   ELSE(MINGW)
 327     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 328   ENDIF(MINGW)
 329 ENDIF(WIN32)
 330
 331 ## Add binreloc.c if enabled
 332 IF(ENABLE_BINRELOC)
 333   SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${SUPERTUX_SOURCE_DIR}/src/binreloc/binreloc.c)
 334 ENDIF(ENABLE_BINRELOC)
 335
 336
 337 ## Generate supertux executable in the right place
 338
 339 SET(EXECUTABLE_OUTPUT_PATH ${SUPERTUX_SOURCE_DIR})
 340
 341 ## Add target for supertux binary
 342
 343 ADD_EXECUTABLE(supertux2 ${SUPERTUX_SOURCES})
 344
 345 ## Link supertux binary with squirrel and other libraries
 346
 347 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 348 TARGET_LINK_LIBRARIES(supertux2 ${SDL_LIBRARY})
 349 TARGET_LINK_LIBRARIES(supertux2 ${SDLIMAGE_LIBRARY})
 350 TARGET_LINK_LIBRARIES(supertux2 ${OPENAL_LIBRARY})
 351 TARGET_LINK_LIBRARIES(supertux2 ${OGGVORBIS_LIBRARIES})
 352 TARGET_LINK_LIBRARIES(supertux2 ${PHYSFS_LIBRARY})
 353 IF(HAVE_OPENGL)
 354     TARGET_LINK_LIBRARIES(supertux2 ${OPENGL_LIBRARY})
 355 ENDIF(HAVE_OPENGL)
 356 IF(HAVE_LIBCURL)
 357   TARGET_LINK_LIBRARIES(supertux2 ${CURL_LIBRARY})
 358 ENDIF(HAVE_LIBCURL)
 359
 360 ## Install stuff
 361
 362 IF(WIN32 AND NOT UNIX)
 363
 364   SET(INSTALL_SUBDIR_BIN ".")
 365   SET(INSTALL_SUBDIR_SHARE "data/")
 366   SET(INSTALL_SUBDIR_DOC ".")
 367
 368   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/SDL.dll
 369                 ${SUPERTUX_SOURCE_DIR}/SDL_image.dll
 370                 ${SUPERTUX_SOURCE_DIR}/iconv.dll
 371                 ${SUPERTUX_SOURCE_DIR}/libogg-0.dll
 372                 ${SUPERTUX_SOURCE_DIR}/libphysfs-1-0-0.dll
 373                 ${SUPERTUX_SOURCE_DIR}/OpenAl32.dll
 374                 ${SUPERTUX_SOURCE_DIR}/wrap_oal.dll
 375                 ${SUPERTUX_SOURCE_DIR}/libcurl-4.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 376
 377   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 378
 379 ELSE(WIN32 AND NOT UNIX)
 380 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 381
 382   SET(INSTALL_SUBDIR_BIN "SuperTux.app/Contents/MacOS/")
 383   SET(INSTALL_SUBDIR_SHARE "SuperTux.app/Contents/Resources/data/")
 384   SET(INSTALL_SUBDIR_DOC "SuperTux.app/Contents/Resources/")
 385
 386   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 387
 388   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 389
 390 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 391
 392   SET(INSTALL_SUBDIR_BIN "games/")
 393   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2/")
 394   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2/")
 395
 396   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 397
 398   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 399
 400 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 401 ENDIF(WIN32 AND NOT UNIX)
 402
 403 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 404
 405 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/INSTALL ${SUPERTUX_SOURCE_DIR}/README ${SUPERTUX_SOURCE_DIR}/COPYING ${SUPERTUX_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 406
 407 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/credits.txt DESTINATION ${INSTALL_SUBDIR_SHARE})
 408
 409 FILE(GLOB INSTALL_DATA_DIRS ${SUPERTUX_SOURCE_DIR}/data/*/)
 410 message(STATUS blah ${INSTALL_DATA_DIRS} blah)
 411
 412 INSTALL(DIRECTORY data/images
 413                   data/fonts
 414                   data/levels
 415                   data/music
 416                   data/scripts
 417                   data/speech
 418                   data/sounds
 419                   data/locale
 420                                DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 421
 422
 423 ## CPack/Installation-specific stuff
 424
 425 INCLUDE(InstallRequiredSystemLibraries)
 426 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 427 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 428 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 429 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 430 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 431 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 432 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 433 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 434 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 435 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 436 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 437 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 438   # The OS X PackageMaker doesn't seem to like files with no extension
 439 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 440   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${SUPERTUX_SOURCE_DIR}/README")
 441   SET(CPACK_RESOURCE_FILE_LICENSE "${SUPERTUX_SOURCE_DIR}/COPYING")
 442 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 443 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 444 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 445 SET(CPACK_PACKAGE_VERSION_PATCH "2-SVN")
 446 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 447 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 448 IF(WIN32 AND NOT UNIX)
 449   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 450   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 451 ELSE(WIN32 AND NOT UNIX)
 452 ENDIF(WIN32 AND NOT UNIX)
 453 INCLUDE(CPack)
 454