CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix.
  36
  37 PROJECT(SUPERTUX)
  38
  39 ## Version, for display in title bar.
  40 ## Will add r<revision number> to the end if svnversion is available.
  41 SET(SUPERTUX_VERSION "0.3.2-SVN")
  42
  43 ### CMake configuration
  44
  45 # allow building with CMake 2.6. Set compatibility options. Use some bundled modules as a fallback
  46 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  47 IF(COMMAND cmake_policy)
  48         CMAKE_POLICY(SET CMP0003 NEW)
  49 ENDIF(COMMAND cmake_policy)
  50
  51 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/mk/cmake)
  52
  53 ## For autopackage
  54 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  55 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2")
  56
  57 ## Check endianess
  58
  59 INCLUDE(TestBigEndian)
  60 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  61
  62 ## Add lots of dependencies to compiler switches
  63
  64 SET(Boost_ADDITIONAL_VERSIONS "1.41" "1.41.0")
  65 FIND_PACKAGE(Boost REQUIRED)
  66 INCLUDE_DIRECTORIES(SYSTEM ${Boost_INCLUDE_DIR})
  67 LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
  68
  69 FIND_PACKAGE(SDL REQUIRED)
  70 INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR})
  71 SET(HAVE_SDL TRUE)
  72
  73 FIND_PACKAGE(SDL_image REQUIRED)
  74 INCLUDE_DIRECTORIES(${SDLIMAGE_INCLUDE_DIR})
  75
  76 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  77 IF(ENABLE_OPENGL)
  78   FIND_PACKAGE(OpenGL)
  79   IF(OPENGL_FOUND)
  80     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  81     SET(HAVE_OPENGL TRUE)
  82   ENDIF(OPENGL_FOUND)
  83
  84   FIND_PACKAGE(GLEW)
  85   IF(GLEW_FOUND)
  86     INCLUDE_DIRECTORIES(${GLEW_INCLUDE_DIR})
  87   ENDIF(GLEW_FOUND)
  88 ENDIF(ENABLE_OPENGL)
  89
  90 FIND_PACKAGE(OpenAL REQUIRED)
  91 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
  92
  93 FIND_PACKAGE(OggVorbis REQUIRED)
  94 INCLUDE_DIRECTORIES(${OGGVORBIS_INCLUDE_DIR})
  95
  96 FIND_PACKAGE(PhysFS REQUIRED)
  97 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
  98
  99 FIND_PACKAGE(CURL)
 100 IF(CURL_FOUND)
 101   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
 102   SET(HAVE_LIBCURL TRUE)
 103 ENDIF(CURL_FOUND)
 104
 105 #FIND_PACKAGE(ICONV REQUIRED)
 106 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 107 #LINK_LIBRARIES(${ICONV_LIBRARY})
 108
 109 ## Find revision of WC
 110 MARK_AS_ADVANCED(SVNVERSION_EXECUTABLE)
 111 FIND_PROGRAM(SVNVERSION_EXECUTABLE svnversion)
 112 IF(SVNVERSION_EXECUTABLE)
 113   ADD_CUSTOM_TARGET(svnversion ALL
 114                     cmake -E echo "#ifndef VERSION_H" > "${CMAKE_BINARY_DIR}/version.h.tmp"
 115                     COMMAND cmake -E echo "#define VERSION_H" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 116                     COMMAND cmake -E echo_append "#define PACKAGE_VERSION \"${SUPERTUX_VERSION}r" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 117                     COMMAND svnversion -n ${CMAKE_CURRENT_SOURCE_DIR} >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 118                     COMMAND cmake -E echo "\"" >>  "${CMAKE_BINARY_DIR}/version.h.tmp"
 119                     COMMAND cmake -E echo "#endif" >>  "${CMAKE_BINARY_DIR}/version.h.tmp"
 120                     COMMAND cmake -E copy_if_different "${CMAKE_BINARY_DIR}/version.h.tmp" "${CMAKE_BINARY_DIR}/version.h"
 121                     COMMAND cmake -E remove "${CMAKE_BINARY_DIR}/version.h.tmp"
 122                     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
 123                     COMMENT "Updating ${CMAKE_BINARY_DIR}/version.h..."
 124                     VERBATIM)
 125 ELSE(SVNVERSION_EXECUTABLE)
 126   ADD_CUSTOM_TARGET(svnversion ALL
 127                     cmake -E echo "#ifndef VERSION_H" > "${CMAKE_BINARY_DIR}/version.h.tmp"
 128                     COMMAND cmake -E echo "#define VERSION_H" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 129                     COMMAND cmake -E echo "#define PACKAGE_VERSION \"${SUPERTUX_VERSION}\"" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 130                     COMMAND cmake -E echo "#endif" >>  "${CMAKE_BINARY_DIR}/version.h.tmp"
 131                     COMMAND cmake -E copy_if_different "${CMAKE_BINARY_DIR}/version.h.tmp" "${CMAKE_BINARY_DIR}/version.h"
 132                     COMMAND cmake -E remove "${CMAKE_BINARY_DIR}/version.h.tmp"
 133                     WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 134                     COMMENT "Updating ${CMAKE_BINARY_DIR}/version.h..."
 135                     VERBATIM)
 136 ENDIF(SVNVERSION_EXECUTABLE)
 137
 138 SET_SOURCE_FILES_PROPERTIES(${CMAKE_BINARY_DIR}/version.h
 139                             PROPERTIES GENERATED true)
 140 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/main.cpp
 141                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 142
 143 ## Check platform-dependent build options
 144
 145 INCLUDE(ConfigureChecks)
 146
 147 ## Create config.h and version.h
 148
 149 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 150 include_directories (${CMAKE_BINARY_DIR}/)
 151
 152 ## Also execute instructions in src/squirrel/CMakeLists.txt
 153
 154 ADD_SUBDIRECTORY(external/squirrel)
 155
 156 ## Add squirrel lib dir to search path
 157
 158 LINK_DIRECTORIES(external/squirrel)
 159
 160 ## Some additional include paths
 161
 162 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/src/)
 163 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel/include/)
 164 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/tinygettext/)
 165 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/findlocale/)
 166 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/obstack/)
 167 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/)
 168
 169 ## Build list of sources for supertux binary
 170
 171 FILE(GLOB SUPERTUX_SOURCES_C RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/obstack/*.c external/findlocale/findlocale.c)
 172
 173 FILE(GLOB SUPERTUX_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/main.cpp src/*/*.cpp src/supertux/menu/*.cpp src/video/sdl/*.cpp)
 174
 175 FILE(GLOB TINYGETTEXT_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/tinygettext/tinygettext/*.cpp)
 176 SET_SOURCE_FILES_PROPERTIES(${TINYGETTEXT_SOURCES_CXX} PROPERTIES COMPILE_DEFINITIONS HAVE_SDL)
 177
 178 IF(HAVE_OPENGL)
 179   FILE(GLOB SUPERTUX_OPENGL_SOURCES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/video/gl/*.cpp)
 180   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_OPENGL_SOURCES})
 181 ENDIF(HAVE_OPENGL)
 182
 183 ## Build miniswig and generate miniswig wrapper
 184
 185 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" ${DEBUG})
 186 IF(GENERATE_WRAPPER)
 187   ADD_SUBDIRECTORY(tools/miniswig)
 188   ADD_CUSTOM_COMMAND(
 189     OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp
 190     COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 191     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${CMAKE_CURRENT_BINARY_DIR}/miniswig.tmp -I${CMAKE_CURRENT_SOURCE_DIR}/src
 192     COMMAND tools/miniswig/miniswig
 193     ARGS --input miniswig.tmp --output-cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace scripting
 194     DEPENDS tools/miniswig/miniswig
 195     IMPLICIT_DEPENDS CXX ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.interface.hpp
 196   )
 197 ENDIF(GENERATE_WRAPPER)
 198
 199 IF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 200   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 201 ENDIF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 202
 203 ## Compile everything at once (roughly equivalent to cat *.cpp | gcc)
 204
 205 OPTION(COMPILE_AMALGATION "Compile all the files together at once (experimental)" OFF)
 206 IF(COMPILE_AMALGATION)
 207   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "// Includes all source files of the project\n")
 208   FOREACH(ST_FILE ${SUPERTUX_SOURCES_CXX})
 209     FILE(RELATIVE_PATH CXX_FILE ${CMAKE_CURRENT_SOURCE_DIR}/src "${CMAKE_CURRENT_SOURCE_DIR}/${ST_FILE}")
 210     FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "#include \"${CXX_FILE}\"\n")
 211   ENDFOREACH(ST_FILE)
 212   ## Build instead of CXX sources
 213   SET(SUPERTUX_SOURCES_CXX ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 214 ELSE(COMPILE_AMALGATION)
 215   IF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 216     FILE(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 217   ENDIF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 218 ENDIF(COMPILE_AMALGATION)
 219
 220 ## Debug options
 221
 222 OPTION(WERROR "Stop on first compiler warning" OFF)
 223 OPTION(WARNINGS "Enable long list of warnings for compiler to check" ${DEBUG})
 224 IF(CMAKE_COMPILER_IS_GNUCC)
 225   SET(CMAKE_CXX_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 226   SET(CMAKE_C_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 227   SET(CMAKE_CXX_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 228   SET(CMAKE_C_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 229   SET(CMAKE_LD_FLAGS_PROFILE "-lgmon" CACHE STRING "Profile flags")
 230   ADD_DEFINITIONS(-Wall -Wextra -funit-at-a-time)
 231   IF(WERROR)
 232     ADD_DEFINITIONS(-Werror)
 233   ELSE(WERROR)
 234     REMOVE_DEFINITIONS(-Werror)
 235   ENDIF(WERROR)
 236   IF(WARNINGS)
 237     ADD_DEFINITIONS(-fdiagnostics-show-option -pedantic -Wno-long-long -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wlogical-op -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector -Wconversion -Wundef -Wsign-conversion -Wshadow -Winline -Wunsafe-loop-optimizations -Wfloat-equal -Wswitch-default -Wswitch-enum -Wcast-qual -Wsign-promo -Woverloaded-virtual -Wmissing-format-attribute -Wstrict-overflow=5 -Wformat=2-Weffc++ -Wabi -Wctor-dtor-privacy -Wstrict-null-sentinel)
 238     # -ansi fails in MinGW
 239     # still left:  -Wold-style-cast -Wpadded
 240   ENDIF(WARNINGS)
 241 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 242
 243 ## If xgettext is available, generate messages.pot for sources
 244
 245 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" ${DEBUG})
 246 IF(GENERATE_MESSAGESPOT)
 247   MARK_AS_ADVANCED(
 248     XGETTEXT_EXECUTABLE
 249   )
 250   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 251   IF(NOT XGETTEXT_EXECUTABLE)
 252     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 253   ELSE(NOT XGETTEXT_EXECUTABLE)
 254     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 255
 256     SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/data/locale/messages.pot)
 257     ADD_CUSTOM_COMMAND(
 258       OUTPUT ${MESSAGES_POT_FILE}
 259       COMMAND ${XGETTEXT_EXECUTABLE}
 260       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES_CXX}
 261       DEPENDS ${SUPERTUX_SOURCES_CXX}
 262       WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 263       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 264     )
 265     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 266
 267     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} data/levels/*)
 268     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 269     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 270       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 271
 272       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 273       IF(SUPERTUX_LEVELS)
 274       SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 275       ADD_CUSTOM_COMMAND(
 276         OUTPUT ${MESSAGES_POT_FILE}
 277         COMMAND ${XGETTEXT_EXECUTABLE}
 278         ARGS --keyword="_:1" --language=Lisp --force-po --sort-by-file "--output=${MESSAGES_POT_FILE}" ${SUPERTUX_LEVELS}
 279         DEPENDS ${SUPERTUX_LEVELS}
 280         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 281         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 282       )
 283       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 284       ENDIF(SUPERTUX_LEVELS)
 285
 286     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 287
 288     ADD_CUSTOM_TARGET(
 289       supertux2-messages ALL
 290       DEPENDS ${MESSAGES_POT_FILES}
 291     )
 292
 293   ENDIF(NOT XGETTEXT_EXECUTABLE)
 294 ENDIF(GENERATE_MESSAGESPOT)
 295
 296 ## Some additional compiler switches
 297 IF(CMAKE_COMPILER_IS_GNUCC)
 298   ADD_DEFINITIONS(-fno-strict-aliasing)
 299 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 300
 301 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 302   ADD_DEFINITIONS(-DMACOSX)
 303 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 304
 305
 306 ## On Windows, add an icon
 307
 308 IF(WIN32)
 309   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 310   IF(MINGW)
 311     ADD_CUSTOM_COMMAND(
 312     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 313     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 314     SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 315   ELSE(MINGW)
 316     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 317   ENDIF(MINGW)
 318 ENDIF(WIN32)
 319
 320 ## Add binreloc.c if enabled
 321 IF(ENABLE_BINRELOC)
 322   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/binreloc.c)
 323 ENDIF(ENABLE_BINRELOC)
 324
 325
 326 ## Generate supertux executable in the right place
 327
 328 SET(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 329
 330 ## Add target for supertux binary
 331
 332 ADD_EXECUTABLE(supertux2 ${CMAKE_BINARY_DIR}/version.h ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCES_CXX} ${TINYGETTEXT_SOURCES_CXX})
 333 ADD_DEPENDENCIES(supertux2 svnversion)
 334
 335 ## Link supertux binary with squirrel and other libraries
 336
 337 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 338 TARGET_LINK_LIBRARIES(supertux2 ${SDL_LIBRARY})
 339 TARGET_LINK_LIBRARIES(supertux2 ${SDLIMAGE_LIBRARY})
 340 TARGET_LINK_LIBRARIES(supertux2 ${OPENAL_LIBRARY})
 341 TARGET_LINK_LIBRARIES(supertux2 ${OGGVORBIS_LIBRARIES})
 342 TARGET_LINK_LIBRARIES(supertux2 ${PHYSFS_LIBRARY})
 343 IF(HAVE_OPENGL)
 344     TARGET_LINK_LIBRARIES(supertux2 ${OPENGL_LIBRARY})
 345     TARGET_LINK_LIBRARIES(supertux2 ${GLEW_LIBRARY})
 346 ENDIF(HAVE_OPENGL)
 347 IF(HAVE_LIBCURL)
 348   TARGET_LINK_LIBRARIES(supertux2 ${CURL_LIBRARY})
 349 ENDIF(HAVE_LIBCURL)
 350
 351 ## Install stuff
 352
 353 IF(WIN32 AND NOT UNIX)
 354
 355   SET(INSTALL_SUBDIR_BIN "." CACHE STRING "Installation subdir for binaries")
 356   SET(INSTALL_SUBDIR_SHARE "data" CACHE STRING "Installation subdir for data")
 357   SET(INSTALL_SUBDIR_DOC "." CACHE STRING "Installation subdir for docs")
 358
 359   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/SDL.dll
 360                 ${CMAKE_CURRENT_SOURCE_DIR}/SDL_image.dll
 361                 ${CMAKE_CURRENT_SOURCE_DIR}/iconv.dll
 362                 ${CMAKE_CURRENT_SOURCE_DIR}/libogg-0.dll
 363                 ${CMAKE_CURRENT_SOURCE_DIR}/libphysfs-1-0-0.dll
 364                 ${CMAKE_CURRENT_SOURCE_DIR}/OpenAl32.dll
 365                 ${CMAKE_CURRENT_SOURCE_DIR}/wrap_oal.dll
 366                 ${CMAKE_CURRENT_SOURCE_DIR}/libcurl-4.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 367
 368   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 369
 370 ELSE(WIN32 AND NOT UNIX)
 371 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 372
 373   SET(INSTALL_SUBDIR_BIN "SuperTux.app/Contents/MacOS" CACHE STRING "Installation subdir for binaries")
 374   SET(INSTALL_SUBDIR_SHARE "SuperTux.app/Contents/Resources/data" CACHE STRING "Installation subdir for data")
 375   SET(INSTALL_SUBDIR_DOC "SuperTux.app/Contents/Resources" CACHE STRING "Installation subdir for docs")
 376
 377   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 378
 379   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 380
 381 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 382
 383   SET(INSTALL_SUBDIR_BIN "games" CACHE STRING "Installation subdir for binaries")
 384   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2" CACHE STRING "Installation subdir for data")
 385   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2" CACHE STRING "Installation subdir for docs")
 386
 387   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 388
 389   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 390
 391 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 392 ENDIF(WIN32 AND NOT UNIX)
 393
 394 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 395
 396 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/INSTALL ${CMAKE_CURRENT_SOURCE_DIR}/README ${CMAKE_CURRENT_SOURCE_DIR}/COPYING ${CMAKE_CURRENT_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 397
 398 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/credits.txt DESTINATION ${INSTALL_SUBDIR_SHARE})
 399
 400 INSTALL(DIRECTORY data/images
 401                   data/fonts
 402                   data/levels
 403                   data/music
 404                   data/scripts
 405                   data/speech
 406                   data/sounds
 407                   data/locale
 408                                DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 409
 410
 411 ## CPack/Installation-specific stuff
 412
 413 INCLUDE(InstallRequiredSystemLibraries)
 414 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 415 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 416 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 417 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 418 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 419 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 420 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 421 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 422 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 423 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 424 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 425 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 426   # The OS X PackageMaker doesn't seem to like files with no extension
 427 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 428   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README")
 429   SET(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 430 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 431 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 432 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 433 SET(CPACK_PACKAGE_VERSION_PATCH "2-SVN")
 434 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 435 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 436 IF(WIN32 AND NOT UNIX)
 437   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 438   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 439 ELSE(WIN32 AND NOT UNIX)
 440 ENDIF(WIN32 AND NOT UNIX)
 441 INCLUDE(CPack)
 442
 443 # move some config clutter to the advanced section
 444 MARK_AS_ADVANCED(
 445   INSTALL_SUBDIR_BIN
 446   INSTALL_SUBDIR_SHARE
 447   INSTALL_SUBDIR_DOC
 448 )
 449
 450 MARK_AS_ADVANCED(
 451         CMAKE_BACKWARDS_COMPATIBILITY
 452         CMAKE_BUILD_TYPE
 453         CMAKE_INSTALL_PREFIX
 454         EXECUTABLE_OUTPUT_PATH
 455         LIBRARY_OUTPUT_PATH
 456         CMAKE_OSX_ARCHITECTURES
 457         CMAKE_OSX_SYSROOT
 458 )
 459
 460 MARK_AS_ADVANCED(
 461         ENABLE_BINRELOC
 462         APPDATADIR
 463 )
 464
 465 MARK_AS_ADVANCED(
 466         Boost_INCLUDE_DIR
 467         Boost_LIBRARIES
 468 )
 469
 470 MARK_AS_ADVANCED(
 471         SDLMAIN_LIBRARY
 472         SDL_INCLUDE_DIR
 473         SDL_LIBRARY
 474 )
 475
 476 MARK_AS_ADVANCED(
 477         SDLIMAGE_INCLUDE_DIR
 478         SDLIMAGE_LIBRARY
 479 )
 480
 481 MARK_AS_ADVANCED(
 482         OPENAL_INCLUDE_DIR
 483         OPENAL_LIBRARY
 484 )
 485
 486 MARK_AS_ADVANCED(
 487         OGG_LIBRARY
 488         VORBISENC_LIBRARY
 489         VORBISFILE_LIBRARY
 490         VORBIS_INCLUDE_DIR
 491         VORBIS_LIBRARY
 492 )
 493
 494 MARK_AS_ADVANCED(
 495         PHYSFS_INCLUDE_DIR
 496         PHYSFS_LIBRARY
 497 )