CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix
  36
  37 PROJECT(SUPERTUX)
  38
  39
  40 ### CMake configuration
  41
  42 # allow building with old CMake. Use some bundled modules as a fallback
  43 CMAKE_MINIMUM_REQUIRED(VERSION 2.4)
  44 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${SUPERTUX_SOURCE_DIR}/mk/cmake)
  45
  46 # move some config clutter to the advanced section
  47 MARK_AS_ADVANCED(
  48         CMAKE_BACKWARDS_COMPATIBILITY
  49         CMAKE_BUILD_TYPE
  50         CMAKE_INSTALL_PREFIX
  51         EXECUTABLE_OUTPUT_PATH
  52         LIBRARY_OUTPUT_PATH
  53         CMAKE_OSX_ARCHITECTURES
  54         CMAKE_OSX_SYSROOT
  55 )
  56
  57 ## For autopackage
  58 MARK_AS_ADVANCED(
  59         ENABLE_BINRELOC
  60         APPDATADIR
  61 )
  62 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  63 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2" CACHE STRING "APPDATADIR where data files reside")
  64
  65 ## Check endianess
  66
  67 INCLUDE(TestBigEndian)
  68 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  69
  70 ## Add lots of dependencies to compiler switches
  71
  72 FIND_PACKAGE(SDL REQUIRED)
  73 MARK_AS_ADVANCED(
  74         SDLMAIN_LIBRARY
  75         SDL_INCLUDE_DIR
  76         SDL_LIBRARY
  77 )
  78 INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR})
  79 LINK_LIBRARIES(${SDL_LIBRARY})
  80
  81 FIND_PACKAGE(SDL_image REQUIRED)
  82 MARK_AS_ADVANCED(
  83         SDLIMAGE_INCLUDE_DIR
  84         SDLIMAGE_LIBRARY
  85 )
  86 INCLUDE_DIRECTORIES(${SDLIMAGE_INCLUDE_DIR})
  87 LINK_LIBRARIES(${SDLIMAGE_LIBRARY})
  88
  89 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  90 IF(ENABLE_OPENGL)
  91   FIND_PACKAGE(OpenGL)
  92   IF(${OPENGL_FOUND} STREQUAL "YES")
  93     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  94     LINK_LIBRARIES(${OPENGL_LIBRARY})
  95     SET(HAVE_OPENGL TRUE)
  96   ENDIF(${OPENGL_FOUND} STREQUAL "YES")
  97 ENDIF(ENABLE_OPENGL)
  98
  99 FIND_PACKAGE(OpenAL REQUIRED)
 100 MARK_AS_ADVANCED(
 101         OPENAL_INCLUDE_DIR
 102         OPENAL_LIBRARY
 103 )
 104 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
 105 LINK_LIBRARIES(${OPENAL_LIBRARY})
 106
 107 FIND_PACKAGE(OggVorbis REQUIRED)
 108 MARK_AS_ADVANCED(
 109         OGG_LIBRARY
 110         VORBISENC_LIBRARY
 111         VORBISFILE_LIBRARY
 112         VORBIS_INCLUDE_DIR
 113         VORBIS_LIBRARY
 114 )
 115 INCLUDE_DIRECTORIES(${OGGVORBIS_INCLUDE_DIR})
 116 LINK_LIBRARIES(${OGGVORBIS_LIBRARIES})
 117
 118 FIND_PACKAGE(PhysFS REQUIRED)
 119 MARK_AS_ADVANCED(
 120         PHYSFS_INCLUDE_DIR
 121         PHYSFS_LIBRARY
 122 )
 123 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
 124 LINK_LIBRARIES(${PHYSFS_LIBRARY})
 125
 126 FIND_PACKAGE(CURL)
 127 IF(CURL_FOUND)
 128   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
 129   LINK_LIBRARIES(${CURL_LIBRARY})
 130   SET(HAVE_LIBCURL TRUE)
 131 ENDIF(CURL_FOUND)
 132
 133 #FIND_PACKAGE(ICONV REQUIRED)
 134 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 135 #LINK_LIBRARIES(${ICONV_LIBRARY})
 136
 137 ## Check platform-dependent build options
 138
 139 INCLUDE(ConfigureChecks)
 140
 141 ## Create config.h
 142
 143 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 144 include_directories (${CMAKE_BINARY_DIR}/)
 145
 146 ## Also execute instructions in src/squirrel/CMakeLists.txt
 147
 148 ADD_SUBDIRECTORY(src/squirrel)
 149
 150 ## Add squirrel lib dir to search path
 151
 152 LINK_DIRECTORIES(src/squirrel)
 153
 154 ## Some additional include paths
 155
 156 include_directories (${SUPERTUX_SOURCE_DIR}/src/)
 157 include_directories (${SUPERTUX_SOURCE_DIR}/src/squirrel/include/)
 158
 159 ## Build list of sources for supertux binary
 160
 161 FILE(GLOB SUPERTUX_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} src/*.cpp src/audio/*.cpp src/badguy/*.cpp src/binreloc/*.cpp src/control/*.cpp src/gui/*.cpp src/lisp/*.cpp src/math/*.cpp src/object/*.cpp src/physfs/*.cpp src/sprite/*.cpp src/tinygettext/*.cpp src/trigger/*.cpp src/video/*.cpp src/worldmap/*.cpp src/scripting/*.cpp src/obstack/*.c)
 162
 163 ## Debug options
 164
 165 OPTION(DEBUG "Build with debugging options" OFF)
 166 OPTION(PROFILE "Build with profiling information" OFF)
 167 OPTION(WERROR "Build stops on first compiler warning" OFF)
 168 IF(CMAKE_COMPILER_IS_GNUCC)
 169   IF (DEBUG)
 170     REMOVE_DEFINITIONS(-O2)
 171     ADD_DEFINITIONS(-O0 -g)
 172   ELSE (DEBUG)
 173     ADD_DEFINITIONS(-O2)
 174     REMOVE_DEFINITIONS(-O0 -g)
 175   ENDIF (DEBUG)
 176   IF (PROFILE)
 177     ADD_DEFINITIONS(-pg)
 178   ELSE (PROFILE)
 179     REMOVE_DEFINITIONS(-pg)
 180   ENDIF (PROFILE)
 181   IF (WERROR)
 182     ADD_DEFINITIONS(-Wall -Werror)
 183   ELSE (WERROR)
 184     REMOVE_DEFINITIONS(-Wall -Werror)
 185   ENDIF (WERROR)
 186 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 187
 188 ## Add in squirrel debug stuff
 189
 190 OPTION(ENABLE_SQDBG "Build squirrel script interpreter with debugging options" OFF)
 191 IF(ENABLE_SQDBG)
 192   include_directories (${SUPERTUX_SOURCE_DIR}/src/squirrel/)
 193   FILE(GLOB SQDBG_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} src/squirrel/sqdbg/*.cpp)
 194   SET(SUPERTUX_SOURCES ${SQDBG_SOURCES} ${SUPERTUX_SOURCES})
 195 ENDIF(ENABLE_SQDBG)
 196
 197 ## Build miniswig and generate miniswig wrapper
 198
 199 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" ${DEBUG})
 200 IF(GENERATE_WRAPPER)
 201   ADD_SUBDIRECTORY(tools/miniswig)
 202   FILE(GLOB GENERATE_WRAPPER_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} src/scripting/*.?pp)
 203   LIST(REMOVE_ITEM GENERATE_WRAPPER_SOURCES "src/scripting/wrapper.cpp" "src/scripting/wrapper.hpp")
 204   ADD_CUSTOM_COMMAND(
 205     OUTPUT ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp
 206     COMMAND cd ${SUPERTUX_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 207     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${SUPERTUX_BINARY_DIR}/miniswig.tmp
 208     COMMAND tools/miniswig/miniswig
 209     ARGS --input miniswig.tmp --output-cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace Scripting
 210     DEPENDS ${GENERATE_WRAPPER_SOURCES} tools/miniswig/miniswig
 211   )
 212 ENDIF(GENERATE_WRAPPER)
 213
 214 IF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 215   SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 216 ENDIF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 217
 218 ## If xgettext is available, generate messages.pot for sources
 219
 220 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" ${DEBUG})
 221 IF(GENERATE_MESSAGESPOT)
 222   MARK_AS_ADVANCED(
 223     XGETTEXT_EXECUTABLE
 224   )
 225   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 226   IF(NOT XGETTEXT_EXECUTABLE)
 227     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 228   ELSE(NOT XGETTEXT_EXECUTABLE)
 229     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 230
 231     SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/data/locale/messages.pot)
 232     ADD_CUSTOM_COMMAND(
 233       OUTPUT ${MESSAGES_POT_FILE}
 234       COMMAND ${XGETTEXT_EXECUTABLE}
 235       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES}
 236       DEPENDS ${SUPERTUX_SOURCES}
 237       WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 238       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 239     )
 240     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 241
 242     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${SUPERTUX_SOURCE_DIR} data/levels/*)
 243     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 244     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 245       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${SUPERTUX_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 246
 247       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 248       IF(SUPERTUX_LEVELS)
 249       SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 250       ADD_CUSTOM_COMMAND(
 251         OUTPUT ${MESSAGES_POT_FILE}
 252         COMMAND ${XGETTEXT_EXECUTABLE}
 253         ARGS --keyword="_:1" --language=Lisp --sort-by-file --output=${MESSAGES_POT_FILE} ${SUPERTUX_LEVELS}
 254         DEPENDS ${SUPERTUX_LEVELS}
 255         WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 256         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 257       )
 258       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 259       ENDIF(SUPERTUX_LEVELS)
 260
 261     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 262
 263     ADD_CUSTOM_TARGET(
 264       supertux2-messages ALL
 265       DEPENDS ${MESSAGES_POT_FILES}
 266     )
 267
 268   ENDIF(NOT XGETTEXT_EXECUTABLE)
 269 ENDIF(GENERATE_MESSAGESPOT)
 270
 271 ## Some additional compiler switches
 272 IF(CMAKE_COMPILER_IS_GNUCC)
 273   ADD_DEFINITIONS(-fno-strict-aliasing)
 274 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 275
 276 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 277   ADD_DEFINITIONS(-DMACOSX)
 278 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 279
 280
 281 ## On Windows, add an icon
 282
 283 IF(WIN32)
 284   SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 285   IF(MINGW)
 286     ADD_CUSTOM_COMMAND(
 287     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 288     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 289     SET(SUPERTUX_SOURCES ${SUPERTUX_SOURCES} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 290   ELSE(MINGW)
 291     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 292   ENDIF(MINGW)
 293 ENDIF(WIN32)
 294
 295
 296 ## Generate supertux executable in the right place
 297
 298 SET(EXECUTABLE_OUTPUT_PATH ${SUPERTUX_SOURCE_DIR})
 299
 300 ## Add target for supertux binary
 301
 302 ADD_EXECUTABLE(supertux2 ${SUPERTUX_SOURCES})
 303
 304 ## Link supertux binary with squirrel
 305
 306 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 307
 308
 309 ## Install stuff
 310
 311 IF(WIN32 AND NOT UNIX)
 312
 313   SET(INSTALL_SUBDIR_BIN ".")
 314   SET(INSTALL_SUBDIR_SHARE "data/")
 315   SET(INSTALL_SUBDIR_DOC ".")
 316
 317   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/SDL.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 318   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/SDL_image.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 319   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/iconv.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 320   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/libogg-0.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 321   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/libphysfs-1-0-0.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 322   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/OpenAl32.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 323   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/wrap_oal.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 324   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/libcurl-4.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 325
 326   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 327
 328 ELSE(WIN32 AND NOT UNIX)
 329 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 330
 331   SET(INSTALL_SUBDIR_BIN "SuperTux.app/Contents/MacOS/")
 332   SET(INSTALL_SUBDIR_SHARE "SuperTux.app/Contents/Resources/data/")
 333   SET(INSTALL_SUBDIR_DOC "SuperTux.app/Contents/Resources/")
 334
 335   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 336
 337   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 338
 339 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 340
 341   SET(INSTALL_SUBDIR_BIN "games/")
 342   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2/")
 343   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2/")
 344
 345   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 346
 347   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 348
 349 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 350 ENDIF(WIN32 AND NOT UNIX)
 351
 352 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 353
 354 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/INSTALL ${SUPERTUX_SOURCE_DIR}/README ${SUPERTUX_SOURCE_DIR}/COPYING ${SUPERTUX_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 355
 356 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/credits.txt ${SUPERTUX_SOURCE_DIR}/data/camera.cfg DESTINATION ${INSTALL_SUBDIR_SHARE})
 357 INSTALL(DIRECTORY data/images DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 358 INSTALL(DIRECTORY data/levels DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 359 INSTALL(DIRECTORY data/music DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 360 INSTALL(DIRECTORY data/scripts DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 361 INSTALL(DIRECTORY data/speech DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 362 INSTALL(DIRECTORY data/sounds DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 363 INSTALL(DIRECTORY data/locale DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 364
 365
 366 ## CPack/Installation-specific stuff
 367
 368 INCLUDE(InstallRequiredSystemLibraries)
 369 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 370 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 371 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 372 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 373 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 374 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completly redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 375 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 376 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 377 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completly redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 378 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 379 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 380 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 381   # The OS X PackageMaker doesn't seem to like files with no extension
 382 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 383   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${SUPERTUX_SOURCE_DIR}/README")
 384   SET(CPACK_RESOURCE_FILE_LICENSE "${SUPERTUX_SOURCE_DIR}/COPYING")
 385 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 386 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 387 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 388 SET(CPACK_PACKAGE_VERSION_PATCH "2-SVN")
 389 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 390 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 391 IF(WIN32 AND NOT UNIX)
 392   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 393   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 394 ELSE(WIN32 AND NOT UNIX)
 395 ENDIF(WIN32 AND NOT UNIX)
 396 INCLUDE(CPack)
 397