configure.ac

   1 dnl ===========================================================================
   2 dnl    "configure.in"
   3 dnl
   4 dnl current contact:
   5 dnl          SuperTux development team
   6 dnl
   7 dnl original author:
   8 dnl          Duong-Khang NGUYEN
   9 dnl          neoneurone@users.sf.net
  10 dnl ===========================================================================
  11
  12 dnl Process this file with autoconf to produce a configure script.
  13 AC_PREREQ([2.54])
  14 AC_INIT(supertux, 0.2-svn)
  15 AC_CONFIG_SRCDIR([src/main.cpp])
  16 AC_CONFIG_AUX_DIR([mk/autoconf])
  17 AC_CANONICAL_TARGET
  18
  19 AC_CONFIG_HEADERS(config.h)
  20
  21 # we don't want the stupid autoconf default -g -O2
  22 test ".$CXXFLAGS" = "." && CXXFLAGS=" "
  23
  24 CXXFLAGS="$CXXFLAGS -ffast-math"
  25
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_PROG_INSTALL
  29 AC_PATH_PROG(AR, ar)
  30 if test "$AR" = "" ; then
  31   AC_MSG_ERROR([Couldn't find ar])
  32 fi
  33 AR="$AR ru"
  34
  35 AC_C_BIGENDIAN
  36
  37 AC_CHECK_PROGS(XGETTEXT, [xgettext xgettext.exe])
  38 if test -n "$XGETTEXT" ; then
  39     AC_MSG_CHECKING([if xgettext supports lisp])
  40     if echo '(gettext "test")' | xgettext -o - -L Lisp - >& /dev/null; then
  41         AC_MSG_RESULT(yes)
  42     else
  43         AC_MSG_RESULT(no)
  44         AC_MSG_WARN([It seems your gettext installation is too old, try updating it])
  45         XGETTEXT=""
  46     fi
  47 fi
  48
  49 AC_PROG_LEX
  50 LEX_LIBS=$LEXLIB
  51 AC_SUBST([LEX_LIBS])
  52 AC_CHECK_PROGS([BISON], [bison bison.exe])
  53 AC_SUBST([BISON])
  54
  55 dnl Checks for header files.
  56 AC_HEADER_DIRENT
  57 AC_HEADER_STDC
  58 AC_CHECK_HEADERS(unistd.h)
  59
  60 dnl Checks for typedefs, structures, and compiler characteristics.
  61 AC_C_CONST
  62 AC_C_BIGENDIAN
  63
  64 dnl ===========================================================================
  65 dnl Give advanced users some options to play with
  66
  67 VARIANT=optimize
  68 AC_MSG_CHECKING([for build variant])
  69
  70 AC_ARG_ENABLE(gprof,
  71               AC_HELP_STRING([--enable-gprof], [enable GNU profiling support]),
  72               [enable_gprof=$enableval], [enable_gprof=no])
  73 if test "$enable_gprof" = "yes"; then
  74     VARIANT=profile
  75 fi
  76
  77 AC_ARG_ENABLE(debug,
  78               AC_HELP_STRING([--enable-debug], [enable debugging mode]),
  79               [enable_debug=$enableval], [enable_debug=no])
  80 if test "$enable_debug" = "yes"; then
  81     AC_DEFINE([DEBUG], 1, [define to compile in debug checks])
  82     VARIANT=debug
  83 else
  84     VARIANT=optimize
  85 fi
  86 AC_SUBST([VARIANT])
  87 AC_MSG_RESULT([$VARIANT])
  88
  89 AC_ARG_ENABLE(sqdbg,
  90               AC_HELP_STRING([--enable-sqdbg], [enable squirrel remote debugger]),
  91               [enable_sqdbg=$enableval], [enable_sqdbg=no])
  92 if test "$enable_sqdbg" = "yes"; then
  93     AC_DEFINE([ENABLE_SQDBG], 1, [define if sqdbg should be enabled])
  94     AC_SUBST([enable_sqdbg])
  95 fi
  96
  97 AM_ICONV
  98 AC_SUBST([ICONV_LIBS], [$LIBICONV])
  99
 100 dnl ===========================================================================
 101 dnl Check for SDL
 102 SDL_VERSION=1.2.4
 103 AM_PATH_SDL($SDL_VERSION,
 104             :,
 105             AC_MSG_ERROR([*** SDL version $SDL_VERSION not found!]))
 106
 107 XIPH_PATH_VORBIS(, [AC_MSG_ERROR([Please install libvorbis])])
 108 XIPH_PATH_OGG(, [AC_MSG_ERROR([Please install libogg])])
 109
 110 NP_FINDLIB([SDLIMAGE], [SDL_image], [SDL_image >= 1.2],
 111         NP_LANG_PROGRAM([#include <SDL_image.h>], [IMG_Load("");]),
 112         [], [-lSDL_image],
 113         [],
 114         [AC_MSG_ERROR([Please install SDLImage >= 1.2.1])],
 115         [$SDL_CFLAGS], [$SDL_LIBS])
 116
 117 NP_FINDLIB([PHYSFS], [physfs], [physfs >= 1.0.0],
 118         NP_LANG_PROGRAM([
 119 #include <stdio.h>
 120 #include <physfs.h>
 121 #if PHYSFS_VER_MAJOR < 1
 122 # error PHYSFS is too old
 123 #endif]),
 124         [], [-lphysfs],
 125         [],
 126         [AC_MSG_ERROR([Please install physfs >= 1.0])])
 127
 128 NP_FINDLIB([OPENAL], [OpenAL], [OpenAL],
 129          NP_LANG_PROGRAM([#include <AL/al.h>],
 130            [alcOpenDevice(0);]),
 131          [], [-lopenal],
 132          [],
 133          [AC_MSG_ERROR([Please intall OpenAL])],
 134          [], [])
 135
 136 AX_CHECK_GL
 137 if test "$no_gl" = "yes"; then
 138   AC_MSG_ERROR([Please install opengl libraries and headers])
 139 fi
 140
 141 dnl Checks for library functions.
 142 AC_CHECK_FUNCS(mkdir strdup strstr)
 143
 144 AC_INIT_JAM
 145 AC_CONFIG_FILES([Jamconfig])
 146
 147 AC_OUTPUT
 148
 149 echo ""
 150 echo "       NOTE: This project uses jam (and not make) as build tool"
 151 echo ""
 152