src/scanner.l

   1 /**
   2  * oconfig - src/scanner.l
   3  * Copyright (C) 2007  Florian octo Forster <octo at verplant.org>
   4  * Copyright (C) 2008  Sebastian tokkee Harl <sh at tokkee.org>
   5  *
   6  * This program is free software; you can redistribute it and/or modify it
   7  * under the terms of the GNU General Public License as published by the
   8  * Free Software Foundation; only version 2 of the License is applicable.
   9  *
  10  * This program is distributed in the hope that it will be useful, but WITHOUT
  11  * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  12  * FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
  13  * more details.
  14  *
  15  * You should have received a copy of the GNU General Public License along with
  16  * this program; if not, write to the Free Software Foundation, Inc.,
  17  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  18  */
  19
  20 %{
  21 #include <stdlib.h>
  22 #include "oconfig.h"
  23 #include "aux_types.h"
  24 #include "parser.h"
  25
  26 /* multiline string buffer */
  27 static char *ml_buffer = NULL;
  28 static int   ml_pos    = 0;
  29 static int   ml_len    = 0;
  30
  31 #define ml_free (ml_len - ml_pos)
  32
  33 static void ml_append (char *);
  34
  35 #ifdef yyterminate
  36 # undef yyterminate
  37 #endif
  38 #define yyterminate() \
  39         do { free (ml_buffer); ml_buffer = NULL; ml_pos = 0; ml_len = 0; \
  40                 return YY_NULL; } while (0)
  41 %}
  42 %option yylineno
  43 %option noyywrap
  44 %x ML
  45 WHITE_SPACE [\ \t\b]
  46 NON_WHITE_SPACE [^\ \t\b]
  47 EOL (\r\n|\n)
  48 QUOTED_STRING ([^\\"]+|\\.)*
  49 UNQUOTED_STRING [0-9A-Za-z_]+
  50 HEX_NUMBER 0[xX][0-9a-fA-F]+
  51 OCT_NUMBER 0[0-7]+
  52 DEC_NUMBER [\+\-]?[0-9]+
  53 FLOAT_NUMBER [\+\-]?[0-9]*\.[0-9]+([eE][\+\-][0-9]+)?
  54 NUMBER ({FLOAT_NUMBER}|{HEX_NUMBER}|{OCT_NUMBER}|{DEC_NUMBER})
  55 BOOL_TRUE (true|yes|on)
  56 BOOL_FALSE (false|no|off)
  57 COMMENT #.*
  58 PORT (6(5(5(3[0-5]|[0-2][0-9])|[0-4][0-9][0-9])|[0-4][0-9][0-9][0-9])|[1-5][0-9][0-9][0-9][0-9]|[1-9][0-9]?[0-9]?[0-9]?)
  59 IP_BYTE (2(5[0-5]|[0-4][0-9])|1[0-9][0-9]|[1-9]?[0-9])
  60 IPV4_ADDR {IP_BYTE}\.{IP_BYTE}\.{IP_BYTE}\.{IP_BYTE}(:{PORT})?
  61
  62 %%
  63 {WHITE_SPACE}           |
  64 {COMMENT}               {/* ignore */}
  65
  66 \\{EOL}                 {/* continue line */}
  67
  68 {EOL}                   {return (EOL);}
  69 "/"                     {return (SLASH);}
  70 "<"                     {return (OPENBRAC);}
  71 ">"                     {return (CLOSEBRAC);}
  72 {BOOL_TRUE}             {yylval.boolean = 1; return (BTRUE);}
  73 {BOOL_FALSE}            {yylval.boolean = 0; return (BFALSE);}
  74
  75 {IPV4_ADDR}             {yylval.string = yytext; return (UNQUOTED_STRING);}
  76
  77 {NUMBER}                {yylval.number = strtod (yytext, NULL); return (NUMBER);}
  78
  79 \"{QUOTED_STRING}\"     {yylval.string = yytext; return (QUOTED_STRING);}
  80 {UNQUOTED_STRING}       {yylval.string = yytext; return (UNQUOTED_STRING);}
  81
  82 \"{QUOTED_STRING}\\{EOL} {
  83         int len = strlen (yytext);
  84
  85         ml_pos = 0;
  86
  87         /* remove "\\<EOL>" */
  88         if ('\r' == yytext[len - 2])
  89                 len -= 3;
  90         else
  91                 len -= 2;
  92         yytext[len] = '\0';
  93
  94         ml_append (yytext);
  95         BEGIN (ML);
  96 }
  97 <ML>^{WHITE_SPACE}+ {/* remove leading white-space */}
  98 <ML>{NON_WHITE_SPACE}{QUOTED_STRING}\\{EOL} {
  99         int len = strlen (yytext);
 100
 101         /* remove "\\<EOL>" */
 102         if ('\r' == yytext[len - 2])
 103                 len -= 3;
 104         else
 105                 len -= 2;
 106         yytext[len] = '\0';
 107
 108         ml_append(yytext);
 109 }
 110 <ML>{NON_WHITE_SPACE}{QUOTED_STRING}\" {
 111         ml_append(yytext);
 112         yylval.string = ml_buffer;
 113
 114         BEGIN (INITIAL);
 115         return (QUOTED_STRING);
 116 }
 117 %%
 118 static void ml_append (char *string)
 119 {
 120         int len = strlen (string);
 121         int s;
 122
 123         if (ml_free <= len) {
 124                 ml_len += len - ml_free + 1;
 125                 ml_buffer = (char *)realloc (ml_buffer, ml_len);
 126                 if (NULL == ml_buffer)
 127                         YY_FATAL_ERROR ("out of dynamic memory in ml_append");
 128         }
 129
 130         s = snprintf (ml_buffer + ml_pos, ml_free, "%s", string);
 131         if ((0 > s) || (ml_free <= s))
 132                 YY_FATAL_ERROR ("failed to write to multiline buffer");
 133
 134         ml_pos += s;
 135         return;
 136 } /* ml_append */
 137