configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(collectd, 3.11.2)
   3 AC_CONFIG_SRCDIR(src/collectd.c)
   4 AC_CONFIG_HEADERS(src/config.h)
   5 AM_INIT_AUTOMAKE(dist-bzip2)
   6 AC_LANG(C)
   7
   8 AC_PREFIX_DEFAULT("/opt/collectd")
   9
  10 #
  11 # Checks for programs.
  12 #
  13 AC_PROG_CC
  14 AC_PROG_CPP
  15 AC_PROG_INSTALL
  16 AC_PROG_LN_S
  17 AC_PROG_MAKE_SET
  18 AM_CONDITIONAL(COMPILER_IS_GCC, test "x$GCC" = "xyes")
  19
  20 dnl configure libtool
  21 AC_DISABLE_STATIC
  22 AC_LIBLTDL_CONVENIENCE
  23 AC_SUBST(LTDLINCL)
  24 AC_SUBST(LIBLTDL)
  25 AC_LIBTOOL_DLOPEN
  26 AC_PROG_LIBTOOL
  27 AC_PROG_LEX
  28 AC_PROG_YACC
  29 AC_CONFIG_SUBDIRS(libltdl)
  30
  31 #
  32 # Checks for header files.
  33 #
  34 AC_HEADER_STDC
  35 AC_HEADER_SYS_WAIT
  36 AC_HEADER_DIRENT
  37 AC_CHECK_HEADERS(stdint.h)
  38 AC_CHECK_HEADERS(stdio.h)
  39 AC_CHECK_HEADERS(errno.h)
  40 AC_CHECK_HEADERS(math.h)
  41 AC_CHECK_HEADERS(syslog.h)
  42 AC_CHECK_HEADERS(fcntl.h)
  43 AC_CHECK_HEADERS(signal.h)
  44 AC_CHECK_HEADERS(assert.h)
  45 AC_CHECK_HEADERS(sys/types.h)
  46 AC_CHECK_HEADERS(sys/socket.h)
  47 AC_CHECK_HEADERS(sys/select.h)
  48 AC_CHECK_HEADERS(poll.h)
  49 AC_CHECK_HEADERS(netdb.h)
  50 AC_CHECK_HEADERS(arpa/inet.h)
  51 AC_CHECK_HEADERS(sys/resource.h)
  52 AC_CHECK_HEADERS(sys/param.h)
  53
  54 # For ping library
  55 AC_CHECK_HEADERS(netinet/in_systm.h, [], [],
  56 [#if HAVE_STDINT_H
  57 # include <stdint.h>
  58 #endif
  59 #if HAVE_SYS_TYPES_H
  60 # include <sys/types.h>
  61 #endif
  62 ])
  63 AC_CHECK_HEADERS(netinet/in.h, [], [],
  64 [#if HAVE_STDINT_H
  65 # include <stdint.h>
  66 #endif
  67 #if HAVE_SYS_TYPES_H
  68 # include <sys/types.h>
  69 #endif
  70 #if HAVE_NETINET_IN_SYSTM_H
  71 # include <netinet/in_systm.h>
  72 #endif
  73 ])
  74 AC_CHECK_HEADERS(netinet/ip.h, [], [],
  75 [#if HAVE_STDINT_H
  76 # include <stdint.h>
  77 #endif
  78 #if HAVE_SYS_TYPES_H
  79 # include <sys/types.h>
  80 #endif
  81 #if HAVE_NETINET_IN_SYSTM_H
  82 # include <netinet/in_systm.h>
  83 #endif
  84 #if HAVE_NETINET_IN_H
  85 # include <netinet/in.h>
  86 #endif
  87 ])
  88 AC_CHECK_HEADERS(netinet/ip_icmp.h, [], [],
  89 [#if HAVE_STDINT_H
  90 # include <stdint.h>
  91 #endif
  92 #if HAVE_SYS_TYPES_H
  93 # include <sys/types.h>
  94 #endif
  95 #if HAVE_NETINET_IN_SYSTM_H
  96 # include <netinet/in_systm.h>
  97 #endif
  98 #if HAVE_NETINET_IN_H
  99 # include <netinet/in.h>
 100 #endif
 101 #if HAVE_NETINET_IP_H
 102 # include <netinet/ip.h>
 103 #endif
 104 ])
 105 AC_CHECK_HEADERS(netinet/ip_var.h, [], [],
 106 [#if HAVE_STDINT_H
 107 # include <stdint.h>
 108 #endif
 109 #if HAVE_SYS_TYPES_H
 110 # include <sys/types.h>
 111 #endif
 112 #if HAVE_NETINET_IN_SYSTM_H
 113 # include <netinet/in_systm.h>
 114 #endif
 115 #if HAVE_NETINET_IN_H
 116 # include <netinet/in.h>
 117 #endif
 118 #if HAVE_NETINET_IP_H
 119 # include <netinet/ip.h>
 120 #endif
 121 ])
 122 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
 123 [#if HAVE_STDINT_H
 124 # include <stdint.h>
 125 #endif
 126 #if HAVE_SYS_TYPES_H
 127 # include <sys/types.h>
 128 #endif
 129 #if HAVE_NETINET_IN_SYSTM_H
 130 # include <netinet/in_systm.h>
 131 #endif
 132 #if HAVE_NETINET_IN_H
 133 # include <netinet/in.h>
 134 #endif
 135 ])
 136 AC_CHECK_HEADERS(netinet/icmp6.h, [], [],
 137 [#if HAVE_STDINT_H
 138 # include <stdint.h>
 139 #endif
 140 #if HAVE_SYS_TYPES_H
 141 # include <sys/types.h>
 142 #endif
 143 #if HAVE_NETINET_IN_SYSTM_H
 144 # include <netinet/in_systm.h>
 145 #endif
 146 #if HAVE_NETINET_IN_H
 147 # include <netinet/in.h>
 148 #endif
 149 #if HAVE_NETINET_IP6_H
 150 # include <netinet/ip6.h>
 151 #endif
 152 ])
 153 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 154 [#if HAVE_STDINT_H
 155 # include <stdint.h>
 156 #endif
 157 #if HAVE_SYS_TYPES_H
 158 # include <sys/types.h>
 159 #endif
 160 #if HAVE_NETINET_IN_SYSTM_H
 161 # include <netinet/in_systm.h>
 162 #endif
 163 #if HAVE_NETINET_IN_H
 164 # include <netinet/in.h>
 165 #endif
 166 #if HAVE_NETINET_IP_H
 167 # include <netinet/ip.h>
 168 #endif
 169 ])
 170 AC_CHECK_HEADERS(netinet/udp.h, [], [],
 171 [#if HAVE_STDINT_H
 172 # include <stdint.h>
 173 #endif
 174 #if HAVE_SYS_TYPES_H
 175 # include <sys/types.h>
 176 #endif
 177 #if HAVE_NETINET_IN_SYSTM_H
 178 # include <netinet/in_systm.h>
 179 #endif
 180 #if HAVE_NETINET_IN_H
 181 # include <netinet/in.h>
 182 #endif
 183 #if HAVE_NETINET_IP_H
 184 # include <netinet/ip.h>
 185 #endif
 186 ])
 187
 188 # For cpu modules
 189 AC_CHECK_HEADERS(sys/sysctl.h sys/dkstat.h)
 190 AC_CHECK_HEADERS(mach/mach_init.h)
 191 AC_CHECK_HEADERS(mach/host_priv.h)
 192 AC_CHECK_HEADERS(mach/mach_error.h)
 193 AC_CHECK_HEADERS(mach/mach_host.h)
 194 AC_CHECK_HEADERS(mach/mach_port.h)
 195 AC_CHECK_HEADERS(mach/mach_types.h)
 196 AC_CHECK_HEADERS(mach/message.h)
 197 AC_CHECK_HEADERS(mach/processor_set.h)
 198 AC_CHECK_HEADERS(mach/processor.h)
 199 AC_CHECK_HEADERS(mach/processor_info.h)
 200 AC_CHECK_HEADERS(mach/task.h)
 201 AC_CHECK_HEADERS(mach/thread_act.h)
 202 AC_CHECK_HEADERS(mach/vm_region.h)
 203 AC_CHECK_HEADERS(mach/vm_map.h)
 204 AC_CHECK_HEADERS(mach/vm_prot.h)
 205 AC_CHECK_HEADERS(mach/vm_statistics.h)
 206 AC_CHECK_HEADERS(mach/kern_return.h)
 207
 208 # For hddtemp module
 209 AC_CHECK_HEADERS(linux/major.h)
 210
 211 # For the apple_sensors module
 212 AC_CHECK_HEADERS(CoreFoundation/CoreFoundation.h)
 213 AC_CHECK_HEADERS(IOKit/IOKitLib.h)
 214 AC_CHECK_HEADERS(IOKit/IOTypes.h)
 215
 216 # For the battery plugin
 217 AC_CHECK_HEADERS(IOKit/ps/IOPowerSources.h, [], [],
 218 [
 219 #if HAVE_IOKIT_IOKITLIB_H
 220 #  include <IOKit/IOKitLib.h>
 221 #endif
 222 #if HAVE_IOKIT_IOTYPES_H
 223 #  include <IOKit/IOTypes.h>
 224 #endif
 225 ])
 226 AC_CHECK_HEADERS(IOKit/ps/IOPSKeys.h)
 227
 228 # For the `disk' plugin
 229 AC_CHECK_HEADERS(IOKit/IOBSD.h)
 230 AC_CHECK_HEADERS(IOKit/storage/IOBlockStorageDriver.h)
 231
 232 # For load module
 233 AC_CHECK_HEADERS(sys/loadavg.h)
 234
 235 # For the processes plugin
 236 AC_CHECK_HEADERS(linux/config.h)
 237
 238 # For the swap module
 239 AC_CHECK_HEADERS(sys/swap.h)
 240
 241 # For users module
 242 AC_CHECK_HEADERS(utmp.h)
 243 AC_CHECK_HEADERS(utmpx.h)
 244
 245 # For traffic plugin
 246 AC_CHECK_HEADERS(ifaddrs.h)
 247 AC_CHECK_HEADERS(net/if.h, [], [],
 248 [
 249 #if HAVE_SYS_TYPES_H
 250 #  include <sys/types.h>
 251 #endif
 252 #if HAVE_SYS_SOCKET_H
 253 #  include <sys/socket.h>
 254 #endif
 255 ])
 256 AC_CHECK_HEADERS(linux/if.h, [], [],
 257 [
 258 #if HAVE_SYS_TYPES_H
 259 #  include <sys/types.h>
 260 #endif
 261 #if HAVE_SYS_SOCKET_H
 262 #  include <sys/socket.h>
 263 #endif
 264 ])
 265 AC_CHECK_HEADERS(linux/netdevice.h, [], [],
 266 [
 267 #if HAVE_SYS_TYPES_H
 268 #  include <sys/types.h>
 269 #endif
 270 #if HAVE_SYS_SOCKET_H
 271 #  include <sys/socket.h>
 272 #endif
 273 #if HAVE_LINUX_IF_H
 274 # include <linux/if.h>
 275 #endif
 276 ])
 277
 278 # For apache plugin
 279 AC_CHECK_HEADERS(curl/curl.h)
 280
 281 # For quota module
 282 AC_CHECK_HEADERS(grp.h pwd.h sys/ucred.h)
 283 AC_CHECK_HEADERS(ctype.h)
 284 AC_CHECK_HEADERS(limits.h)
 285 AC_CHECK_HEADERS(sys/quota.h)
 286 AC_CHECK_HEADERS(xfs/xqm.h)
 287
 288 # For mount interface
 289 AC_CHECK_HEADERS(fs_info.h)
 290 AC_CHECK_HEADERS(fshelp.h)
 291 AC_CHECK_HEADERS(paths.h)
 292 AC_CHECK_HEADERS(mntent.h)
 293 AC_CHECK_HEADERS(mnttab.h)
 294 AC_CHECK_HEADERS(sys/fstyp.h)
 295 AC_CHECK_HEADERS(sys/fs_types.h)
 296 AC_CHECK_HEADERS(sys/mntent.h)
 297 AC_CHECK_HEADERS(sys/mnttab.h)
 298 AC_CHECK_HEADERS(sys/mount.h)
 299 AC_CHECK_HEADERS(sys/statfs.h)
 300 AC_CHECK_HEADERS(sys/statvfs.h)
 301 AC_CHECK_HEADERS(sys/vfs.h)
 302 AC_CHECK_HEADERS(sys/vfstab.h)
 303
 304 # For the swap plugin, FreeBSD
 305 AC_CHECK_HEADERS(kvm.h)
 306
 307 # For the email plugin
 308 AC_CHECK_HEADERS(linux/un.h, [], [],
 309 [
 310 #if HAVE_SYS_SOCKET_H
 311 #       include <sys/socket.h>
 312 #endif
 313 ])
 314 AC_CHECK_HEADERS(sys/un.h)
 315 AC_CHECK_HEADERS(grp.h)
 316
 317 # For debugging interface (variable number of arguments)
 318 AC_CHECK_HEADERS(stdarg.h)
 319
 320 # Regular expressions for the ignorelist.
 321 AC_CHECK_HEADERS(regex.h)
 322
 323 # For the dns plugin
 324 AC_CHECK_HEADERS(arpa/nameser.h arpa/nameser_compat.h)
 325
 326 AC_CHECK_HEADERS(net/if_arp.h)
 327 AC_CHECK_HEADERS(net/if_ppp.h)
 328 AC_CHECK_HEADERS(netinet/if_ether.h)
 329
 330 # For the multimeter plugin
 331 AC_CHECK_HEADERS(termios.h)
 332 AC_CHECK_HEADERS(sys/ioctl.h)
 333
 334 dnl Checking for libraries
 335 AC_CHECK_LIB(m, ext)
 336
 337 #
 338 # Checks for typedefs, structures, and compiler characteristics.
 339 #
 340 AC_C_CONST
 341 AC_TYPE_PID_T
 342 AC_TYPE_SIZE_T
 343 AC_TYPE_UID_T
 344 AC_HEADER_TIME
 345
 346 #
 347 # Checks for library functions.
 348 #
 349 AC_PROG_GCC_TRADITIONAL
 350 AC_CHECK_FUNCS(gettimeofday select strdup strtol)
 351 AC_CHECK_FUNCS(getaddrinfo getnameinfo)
 352 AC_CHECK_FUNCS(strchr memcpy strstr strcmp strncmp strncpy strlen)
 353 AC_CHECK_FUNCS(strncasecmp strcasecmp)
 354 AC_CHECK_FUNCS(openlog syslog closelog)
 355
 356 socket_needs_socket="no"
 357 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [socket_needs_socket="yes"], AC_MSG_ERROR(cannot find socket)))
 358 AM_CONDITIONAL(BUILD_WITH_LIBSOCKET, test "x$socket_needs_socket" = "xyes")
 359
 360 nanosleep_needs_rt="no"
 361 AC_CHECK_FUNCS(nanosleep, [], AC_CHECK_LIB(rt, nanosleep, [nanosleep_needs_rt="yes"], AC_MSG_ERROR(cannot find nanosleep)))
 362 AM_CONDITIONAL(BUILD_WITH_LIBRT, test "x$nanosleep_needs_rt" = "xyes")
 363
 364 # Regular expressions for the ignorelist.
 365 AC_CHECK_FUNCS(regcomp regerror regexec regfree)
 366
 367 # For cpu module
 368 AC_CHECK_FUNCS(sysctlbyname, [have_sysctlbyname="yes"], [have_sysctlbyname="no"])
 369
 370 # For df module
 371 AC_CHECK_FUNCS(statfs statvfs)
 372
 373 # For load module
 374 AC_CHECK_FUNCS(getloadavg, [have_getloadavg="yes"], [have_getloadavg="no"])
 375
 376 # For the `processes' plugin
 377 AC_CHECK_FUNCS(thread_info)
 378
 379 # For users module
 380 AC_CHECK_FUNCS(getutent getutxent)
 381
 382 # For quota module
 383 AC_CHECK_FUNCS(quotactl)
 384 AC_CHECK_FUNCS(getgrgid getpwuid)
 385
 386 # For traffic module
 387 AC_CHECK_FUNCS(getifaddrs)
 388
 389 # Check for NAN
 390 nan_type="none"
 391 if test "x$nan_type" = "xnone"; then
 392   AC_CACHE_CHECK([whether NAN is defined by default],
 393     [have_nan_default],
 394     AC_COMPILE_IFELSE(
 395       AC_LANG_PROGRAM(
 396       [[
 397 #include <stdlib.h>
 398 #include <math.h>
 399 static float foo = NAN;
 400       ]],
 401       [[
 402        if (isnan (foo))
 403         return 0;
 404        else
 405         return 1;
 406       ]]),
 407       [have_nan_default="yes"],
 408       [have_nan_default="no"]
 409     )
 410   )
 411   if test "x$have_nan_default" = "xyes"
 412   then
 413    nan_type="default"
 414    AC_DEFINE(NAN_STATIC_DEFAULT, 1,
 415      [Define if NAN is defined by default and can initialize static variables.])
 416   fi
 417 fi
 418 if test "x$nan_type" = "xnone"; then
 419   AC_CACHE_CHECK([whether NAN is defined by __USE_ISOC99],
 420     [have_nan_isoc],
 421     AC_COMPILE_IFELSE(
 422       AC_LANG_PROGRAM(
 423       [[
 424 #include <stdlib.h>
 425 #define __USE_ISOC99 1
 426 #include <math.h>
 427 static float foo = NAN;
 428       ]],
 429       [[
 430        if (isnan (foo))
 431         return 0;
 432        else
 433         return 1;
 434       ]]),
 435       [have_nan_isoc="yes"],
 436       [have_nan_isoc="no"]
 437     )
 438   )
 439   if test "x$have_nan_isoc" = "xyes"
 440   then
 441    nan_type="isoc99"
 442    AC_DEFINE(NAN_STATIC_ISOC, 1,
 443      [Define if NAN is defined by __USE_ISOC99 and can initialize static variables.])
 444   fi
 445 fi
 446 if test "x$nan_type" = "xnone"; then
 447   AC_CACHE_CHECK([whether NAN can be defined by 0/0],
 448     [have_nan_zero],
 449     AC_RUN_IFELSE(
 450       AC_LANG_PROGRAM(
 451       [[
 452 #include <stdlib.h>
 453 #include <math.h>
 454 #define NAN (0.0 / 0.0)
 455 #ifndef isnan
 456 # define isnan(f) ((f) != (f))
 457 #endif
 458 static float foo = NAN;
 459       ]],
 460       [[
 461        if (isnan (foo))
 462         return 0;
 463        else
 464         return 1;
 465       ]]),
 466       [have_nan_zero="yes"],
 467       [have_nan_zero="no"]
 468     )
 469   )
 470   if test "x$have_nan_zero" = "xyes"
 471   then
 472    nan_type="zero"
 473    AC_DEFINE(NAN_ZERO_ZERO, 1,
 474      [Define if NAN can be defined as (0.0 / 0.0)])
 475   fi
 476 fi
 477 if test "x$nan_type" = "xnone"; then
 478   AC_MSG_ERROR([Didn't find out how to statically initialize variables to NAN. Sorry.])
 479 fi
 480
 481 # For mount interface
 482 #AC_CHECK_FUNCS(getfsent getvfsent)
 483
 484 have_getfsstat="no"
 485 AC_CHECK_FUNCS(getfsstat, [have_getfsstat="yes"])
 486 have_getvfsstat="no"
 487 AC_CHECK_FUNCS(getvfsstat, [have_getvfsstat="yes"])
 488 have_listmntent="no"
 489 AC_CHECK_FUNCS(listmntent, [have_listmntent="yes"])
 490
 491 have_getmntent="no"
 492 AC_CHECK_FUNCS(getmntent, [have_getmntent="c"])
 493 if test "x$have_getmntent" = "xno"; then
 494         AC_CHECK_LIB(sun, getmntent, [have_getmntent="sun"])
 495 fi
 496 if test "x$have_getmntent" = "xno"; then
 497         AC_CHECK_LIB(seq, getmntent, [have_getmntent="seq"])
 498 fi
 499 if test "x$have_getmntent" = "xno"; then
 500         AC_CHECK_LIB(gen, getmntent, [have_getmntent="gen"])
 501 fi
 502
 503 if test "x$have_getmntent" = "xc"; then
 504         AC_CACHE_CHECK([whether getmntent takes one argument],
 505                 [have_one_getmntent],
 506                 AC_COMPILE_IFELSE(
 507                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 508 #include <mntent.h>
 509 #include "$srcdir/src/utils_mount.h"]],
 510                                 [[
 511                                  FILE *fh;
 512                                  struct mntent *me;
 513                                  fh = setmntent ("/etc/mtab", "r");
 514                                  me = getmntent (fh);
 515                                 ]]
 516                         ),
 517                         [have_one_getmntent="yes"],
 518                         [have_one_getmntent="no"]
 519                 )
 520         )
 521         AC_CACHE_CHECK([whether getmntent takes two arguments],
 522                 [have_two_getmntent],
 523                 AC_COMPILE_IFELSE(
 524                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 525 #include <sys/mnttab.h>
 526 #include "$srcdir/src/utils_mount.h"]],
 527                                 [[
 528                                  FILE *fh;
 529                                  struct mnttab mt;
 530                                  int status;
 531                                  fh = fopen ("/etc/mnttab", "r");
 532                                  status = getmntent (fh, &mt);
 533                                 ]]
 534                         ),
 535                         [have_two_getmntent="yes"],
 536                         [have_two_getmntent="no"]
 537                 )
 538         )
 539 fi
 540
 541 # Check for different versions of `getmntent' here..
 542
 543 if test "x$have_getmntent" = "xc"; then
 544         if test "x$have_one_getmntent" = "xyes"; then
 545                 AC_DEFINE(HAVE_ONE_GETMNTENT, 1,
 546                           [Define if the function getmntent exists and takes one argument.])
 547         fi
 548         if test "x$have_two_getmntent" = "xyes"; then
 549                 AC_DEFINE(HAVE_TWO_GETMNTENT, 1,
 550                           [Define if the function getmntent exists and takes two arguments.])
 551         fi
 552 fi
 553 if test "x$have_getmntent" = "xsun"; then
 554         AC_DEFINE(HAVE_SUN_GETMNTENT, 1,
 555                   [Define if the function getmntent exists. It's the version from libsun.])
 556 fi
 557 if test "x$have_getmntent" = "xseq"; then
 558         AC_DEFINE(HAVE_SEQ_GETMNTENT, 1,
 559                   [Define if the function getmntent exists. It's the version from libseq.])
 560 fi
 561 if test "x$have_getmntent" = "xgen"; then
 562         AC_DEFINE(HAVE_GEN_GETMNTENT, 1,
 563                   [Define if the function getmntent exists. It's the version from libgen.])
 564 fi
 565
 566 # Check for structures
 567 AC_CHECK_MEMBERS([struct if_data.ifi_ibytes, struct if_data.ifi_opackets, struct if_data.ifi_ierrors],
 568         [AC_DEFINE(HAVE_STRUCT_IF_DATA, 1, [Define if struct if_data exists and is usable.])],
 569         [],
 570         [
 571         #include <sys/types.h>
 572         #include <sys/socket.h>
 573         #include <net/if.h>
 574         ])
 575 AC_CHECK_MEMBERS([struct net_device_stats.rx_bytes, struct net_device_stats.tx_packets, struct net_device_stats.rx_errors],
 576         [AC_DEFINE(HAVE_STRUCT_NET_DEVICE_STATS, 1, [Define if struct net_device_stats exists and is usable.])],
 577         [],
 578         [
 579         #include <sys/types.h>
 580         #include <sys/socket.h>
 581         #include <linux/if.h>
 582         #include <linux/netdevice.h>
 583         ])
 584
 585 AC_CHECK_MEMBERS([struct udphdr.uh_dport, struct udphdr.uh_sport], [], [],
 586 [#if HAVE_STDINT_H
 587 # include <stdint.h>
 588 #endif
 589 #if HAVE_SYS_TYPES_H
 590 # include <sys/types.h>
 591 #endif
 592 #if HAVE_NETINET_IN_SYSTM_H
 593 # include <netinet/in_systm.h>
 594 #endif
 595 #if HAVE_NETINET_IN_H
 596 # include <netinet/in.h>
 597 #endif
 598 #if HAVE_NETINET_IP_H
 599 # include <netinet/ip.h>
 600 #endif
 601 #if HAVE_NETINET_UDP_H
 602 # include <netinet/udp.h>
 603 #endif
 604 ])
 605 AC_CHECK_MEMBERS([struct udphdr.dest, struct udphdr.source], [], [],
 606 [#if HAVE_STDINT_H
 607 # include <stdint.h>
 608 #endif
 609 #if HAVE_SYS_TYPES_H
 610 # include <sys/types.h>
 611 #endif
 612 #if HAVE_NETINET_IN_SYSTM_H
 613 # include <netinet/in_systm.h>
 614 #endif
 615 #if HAVE_NETINET_IN_H
 616 # include <netinet/in.h>
 617 #endif
 618 #if HAVE_NETINET_IP_H
 619 # include <netinet/ip.h>
 620 #endif
 621 #if HAVE_NETINET_UDP_H
 622 # include <netinet/udp.h>
 623 #endif
 624 ])
 625
 626 AC_MSG_CHECKING([for kernel type ($host_os)])
 627 case $host_os in
 628         *linux*)
 629         AC_DEFINE([KERNEL_LINUX], 1, [True if program is to be compiled for a Linux kernel])
 630         ac_system="Linux"
 631         ;;
 632         *solaris*)
 633         AC_DEFINE([KERNEL_SOLARIS], 1, [True if program is to be compiled for a Solaris kernel])
 634         ac_system="Solaris"
 635         ;;
 636         *)
 637         ac_system="unknown"
 638 esac
 639 AC_MSG_RESULT([$ac_system])
 640
 641 with_libresolv="yes"
 642 AC_CHECK_LIB(resolv, res_search,
 643 [
 644         AC_DEFINE(HAVE_LIBRESOLV, 1, [Define to 1 if you have the 'resolv' library (-lresolv).])
 645 ],
 646 [with_libresolv="no"])
 647 AM_CONDITIONAL(BUILD_WITH_LIBRESOLV, test "x$with_libresolv" = "xyes")
 648
 649
 650 m4_divert_once([HELP_WITH], [
 651 collectd additional packages:])
 652
 653 # AC_ARG_WITH (package, help-string, [action-if-given], [action-if-not-given])
 654 AC_ARG_WITH(rrdtool, [AS_HELP_STRING([--with-rrdtool@<:@=PREFIX@:>@], [Path to rrdtool.])],
 655 [       if test "x$withval" != "xno" && test "x$withval" != "xyes"
 656         then
 657                 LDFLAGS="$LDFLAGS -L$withval/lib"
 658                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 659                 with_rrdtool="yes"
 660         fi
 661 ], [with_rrdtool="yes"])
 662 if test "x$with_rrdtool" = "xyes"
 663 then
 664         AC_CHECK_LIB(rrd, rrd_update,
 665         [
 666                 AC_DEFINE(HAVE_LIBRRD, 1, [Define to 1 if you have the rrd library (-lrrd).])
 667         ],
 668         [with_rrdtool="no (librrd not found)"], [-lm])
 669 fi
 670 if test "x$with_rrdtool" = "xyes"
 671 then
 672         AC_CHECK_HEADERS(rrd.h,, [with_rrdtool="no (rrd.h not found)"])
 673 fi
 674 if test "x$with_rrdtool" = "xyes"
 675 then
 676         collect_rrdtool=1
 677 else
 678         collect_rrdtool=0
 679 fi
 680 AC_DEFINE_UNQUOTED(COLLECT_RRDTOOL, [$collect_rrdtool],
 681         [Wether or not to use rrdtool library])
 682 AM_CONDITIONAL(BUILD_WITH_RRDTOOL, test "x$with_rrdtool" = "xyes")
 683
 684 AC_ARG_WITH(libpthread, [AS_HELP_STRING([--with-libpthread=@<:@=PREFIX@:>@], [Path to libpthread.])],
 685 [       if test "x$withval" != "xno" -a "x$withval" != "xyes"
 686         then
 687                 LDFLAGS="$LDFLAGS -L$withval/lib"
 688                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 689                 with_libpthread="yes"
 690         else
 691                 if test "x$withval" = "xno"
 692                 then
 693                         with_libpthread="no (disabled)"
 694                 fi
 695         fi
 696 ], [with_libpthread="yes"])
 697 if test "x$with_libpthread" = "xyes"
 698 then
 699         AC_CHECK_LIB(pthread, pthread_create, [with_libpthread="yes"], [with_libpthread="no (libpthread not found)"], [])
 700 fi
 701 if test "x$with_libpthread" = "xyes"
 702 then
 703         AC_CHECK_HEADERS(pthread.h,, [with_libpthread="no (pthread.h not found)"])
 704 fi
 705 if test "x$with_libpthread" = "xyes"
 706 then
 707         collect_pthread=1
 708 else
 709         collect_pthread=0
 710 fi
 711 AC_DEFINE_UNQUOTED(HAVE_LIBPTHREAD, [$collect_pthread],
 712         [Wether or not to use pthread (POSIX threads) library])
 713 AM_CONDITIONAL(BUILD_WITH_LIBPTHREAD, test "x$with_libpthread" = "xyes")
 714
 715 if test "$ac_system" = "Solaris"
 716 then
 717         with_kstat="yes"
 718         with_devinfo="yes"
 719 else
 720         with_kstat="no (Solaris only)"
 721         with_devinfo="no (Solaris only)"
 722 fi
 723
 724 if test "x$with_kstat" = "xyes"
 725 then
 726         AC_CHECK_LIB(kstat, kstat_open, [with_kstat="yes"], [with_kstat="no (libkstat not found)"], [])
 727 fi
 728 if test "x$with_kstat" = "xyes"
 729 then
 730         AC_CHECK_LIB(devinfo, di_init, [with_devinfo="yes"], [with_devinfo="no (not found)"], [])
 731         AC_CHECK_HEADERS(kstat.h,, [with_kstat="no (kstat.h not found)"])
 732 fi
 733 if test "x$with_kstat" = "xyes"
 734 then
 735         collect_kstat=1
 736 else
 737         collect_kstat=0
 738 fi
 739 AC_DEFINE_UNQUOTED(COLLECT_KSTAT, [$collect_kstat],
 740         [Wether or not to use kstat library (Solaris)])
 741 AM_CONDITIONAL(BUILD_WITH_LIBKSTAT, test "x$with_kstat" = "xyes")
 742 AM_CONDITIONAL(BUILD_WITH_LIBDEVINFO, test "x$with_devinfo" = "xyes")
 743
 744 ### BEGIN of check for libcurl ###
 745 with_curl_config="curl-config"
 746 with_curl_prefix=0
 747 with_curl_libs=""
 748 AC_ARG_WITH(libcurl, [AS_HELP_STRING([--with-libcurl@<:@=PREFIX@:>@], [Path to libcurl.])],
 749 [
 750         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 751         then
 752                 if test -x "$withval/bin/curl-config"
 753                 then
 754                         with_curl_config="$withval/bin/curl-config"
 755                         with_curl_prefix=1
 756                 fi
 757         fi
 758         if test "x$withval" = "xno"
 759         then
 760                 with_libcurl="no"
 761         else
 762                 with_libcurl="yes"
 763         fi
 764 ],
 765 [
 766         with_libcurl="yes"
 767 ])
 768 if test "x$with_libcurl" = "xyes"
 769 then
 770         with_curl_libs=`$with_curl_config --libs 2>/dev/null`
 771         curl_config_status=$?
 772
 773         if test $curl_config_status -ne 0
 774         then
 775                 with_libcurl="no"
 776         else
 777                 AC_CHECK_LIB(curl, curl_easy_init,
 778                 [
 779                         BUILD_WITH_LIBCURL_LIBS="$with_curl_libs"
 780                         AC_SUBST(BUILD_WITH_LIBCURL_LIBS)
 781                 ],
 782                 [
 783                         with_libcurl="no"
 784                 ],
 785                 [$with_curl_libs])
 786         fi
 787 fi
 788 if test "x$with_libcurl" = "xyes" -a $with_curl_prefix -ne 0
 789 then
 790         with_curl_prefix=`$with_curl_config --libs 2>/dev/null`
 791         curl_config_status=$?
 792
 793         if test $curl_config_status -ne 0
 794         then
 795                 with_libcurl="no"
 796         else
 797                 if test -d "$with_curl_prefix/include"
 798                 then
 799                         CPPFLAGS="$CPPFLAGS -I$with_curl_prefix/include"
 800                 fi
 801         fi
 802 fi
 803
 804 with_libcurl_numeric=0
 805 if test "x$with_libcurl" = "xyes"
 806 then
 807         with_libcurl_numeric=1
 808 fi
 809 AC_DEFINE_UNQUOTED(HAVE_LIBCURL, [$with_libcurl_numeric], [Define to 1 if you have the 'curl' library (-lcurl).])
 810 AM_CONDITIONAL(BUILD_WITH_LIBCURL, test "x$with_libcurl" = "xyes")
 811 ### END of check for libcurl ###
 812
 813 with_libiokit="no"
 814 collectd_libiokit=0
 815 AC_CHECK_LIB(IOKit, IOServiceGetMatchingServices,
 816 [
 817         with_libiokit="yes"
 818         collectd_libiokit=1
 819 ],
 820 [
 821         with_libiokit="no"
 822         collectd_libiokit=0
 823 ])
 824 AC_DEFINE_UNQUOTED(COLLECT_LIBIOKIT, [$collect_libiokit], [Wether or not to use the IOKit library])
 825 AM_CONDITIONAL(BUILD_WITH_LIBIOKIT, test "x$with_libiokit" = "xyes")
 826
 827 with_libstatgrab="yes"
 828 with_libdevstat="no"
 829 AC_ARG_WITH(libstatgrab, [AS_HELP_STRING([--with-libstatgrab@<:@=PREFIX@:>@], [Path to libstatgrab.])],
 830 [
 831         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 832         then
 833                 LDFLAGS="$LDFLAGS -L$withval/lib"
 834                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 835                 with_libstatgrab="yes"
 836         fi
 837 ],
 838 [
 839         if test "x$ac_system" == "xunknown"
 840         then
 841                 with_libstatgrab="yes"
 842         else
 843                 with_libstatgrab="no"
 844         fi
 845 ])
 846 if test "x$with_libstatgrab" = "xyes"
 847 then
 848         AC_CHECK_LIB(statgrab, sg_init, [with_libstatgrab="yes"], [with_libstatgrab="no (libstatgrab not found)"])
 849 fi
 850 if test "x$with_libstatgrab" = "xyes"
 851 then
 852         AC_CHECK_HEADERS(statgrab.h,,    [with_libstatgrab="no (statgrab.h not found)"])
 853 fi
 854 if test "x$with_libstatgrab" = "xyes"
 855 then
 856         AC_CHECK_LIB(devstat, getdevs, [with_libdevstat="yes"], [with_libdevstat="no"])
 857 fi
 858 if test "x$with_libstatgrab" = "xyes"
 859 then
 860         collect_libstatgrab=1
 861 else
 862         collect_libstatgrab=0
 863 fi
 864 AC_DEFINE_UNQUOTED(COLLECT_LIBSTATGRAB, [$collect_libstatgrab],
 865         [Wether or not to use statgrab library])
 866 AM_CONDITIONAL(BUILD_WITH_LIBSTATGRAB, test "x$with_libstatgrab" = "xyes")
 867 AM_CONDITIONAL(BUILD_WITH_LIBDEVSTAT,  test "x$with_libdevstat"  = "xyes")
 868
 869 AC_CHECK_LIB(kvm, kvm_getswapinfo, [with_libkvm="yes"], [with_libkvm="no"])
 870 if test "x$with_libkvm" = "xyes"
 871 then
 872         AC_DEFINE(HAVE_LIBKVM, 1, [Define to 1 if you have the 'kvm' library (-lkvm)])
 873 fi
 874 AM_CONDITIONAL(BUILD_WITH_LIBKVM, test "x$with_libkvm" = "xyes")
 875
 876 AC_ARG_WITH(lm-sensors, [AS_HELP_STRING([--with-lm-sensors@<:@=PREFIX@:>@], [Path to lm_sensors.])],
 877 [
 878         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 879         then
 880                 LDFLAGS="$LDFLAGS -L$withval/lib"
 881                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 882                 with_lm_sensors="yes"
 883         fi
 884 ],
 885 [
 886         if test "x$ac_system" = "xLinux"
 887         then
 888                 with_lm_sensors="yes"
 889         else
 890                 with_lm_sensors="no"
 891         fi
 892 ])
 893 if test "x$with_lm_sensors" = "xyes"
 894 then
 895         AC_CHECK_LIB(sensors, sensors_init,
 896         [
 897                 AC_DEFINE(HAVE_LIBSENSORS, 1, [Define to 1 if you have the sensors library (-lsensors).])
 898         ],
 899         [with_lm_sensors="no (libsensors not found)"])
 900 fi
 901 if test "x$with_lm_sensors" = "xyes"
 902 then
 903         AC_CHECK_HEADERS(sensors/sensors.h,
 904         [
 905                 AC_DEFINE(HAVE_SENSORS_SENSORS_H, 1, [Define to 1 if you have the <sensors/sensors.h> header file.])
 906         ],
 907         [with_lm_sensors="no (sensors/sensors.h not found)"])
 908 fi
 909 if test "x$with_lm_sensors" = "xyes"
 910 then
 911         collect_lm_sensors=1
 912 else
 913         collect_lm_sensors=0
 914 fi
 915 AC_DEFINE_UNQUOTED(COLLECT_LM_SENSORS, [$collect_lm_sensors],
 916         [Wether or not to use sensors library])
 917 AM_CONDITIONAL(BUILD_WITH_LM_SENSORS, test "x$with_lm_sensors" = "xyes")
 918
 919 AC_ARG_WITH(libmysql, [AS_HELP_STRING([--with-libmysql@<:@=PREFIX@:>@], [Path to libmysql.])],
 920 [
 921         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 922         then
 923                 LDFLAGS="$LDFLAGS -L$withval/lib"
 924                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 925                 with_libmysql="yes"
 926         fi
 927 ],
 928 [
 929         with_libmysql="yes"
 930 ])
 931 if test "x$with_libmysql" = "xyes"
 932 then
 933         AC_CHECK_LIB(mysqlclient, mysql_init,
 934         [
 935                 AC_DEFINE(HAVE_LIBMYSQLCLIENT, 1, [Define to 1 if you have the mysqlclient library (-lmysqlclient).])
 936         ], [with_libmysql="no (libmysql not found)"])
 937 fi
 938 if test "x$with_libmysql" = "xyes"
 939 then
 940         AC_CHECK_HEADERS(mysql/mysql.h,
 941         [
 942                 AC_DEFINE(HAVE_MYSQL_MYSQL_H, 1, [Define to 1 if you have the <mysql/mysql.h> header file.])
 943         ], [with_libmysql="no (mysql/mysql.h not found)"])
 944 fi
 945 if test "x$with_libmysql" = "xyes"
 946 then
 947         collect_libmysql=1
 948 else
 949         collect_libmysql=0
 950 fi
 951 AC_DEFINE_UNQUOTED(COLLECT_LIBMYSQL, [$collect_libmysql],
 952         [Wether or not to use mysql library])
 953 AM_CONDITIONAL(BUILD_WITH_LIBMYSQL, test "x$with_libmysql" = "xyes")
 954
 955 #with_liboping="yes"
 956 with_own_liboping="no"
 957 liboping_LDFLAGS="$LDFLAGS"
 958 liboping_CPPFLAGS="$CPPFLAGS"
 959 AC_ARG_WITH(liboping, [AS_HELP_STRING([--with-liboping@<:@=PREFIX@:>@], [Path to liboping.])],
 960 [
 961         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 962         then
 963                 if test -d "$withval/lib"
 964                 then
 965                         liboping_LDFLAGS="$LDFLAGS -L$withval/lib"
 966                 fi
 967                 if test -d "$withval/include"
 968                 then
 969                         liboping_CPPFLAGS="$CPPFLAGS -I$withval/include"
 970                 fi
 971         fi
 972         if test "x$withval" = "xno"
 973         then
 974                 with_liboping="no"
 975                 with_own_liboping="no"
 976         fi
 977 ],
 978 [
 979         #753
 980         with_liboping="yes"
 981 ])
 982
 983 if test "x$with_liboping" = "xyes"
 984 then
 985         save_LDFLAGS="$LDFLAGS"
 986         save_CPPFLAGS="$CPPFLAGS"
 987         LDFLAGS="$liboping_LDFLAGS"
 988         CPPFLAGS="$liboping_CPPFLAGS"
 989         AC_CHECK_LIB(oping, ping_construct,
 990         [
 991                 with_liboping="yes"
 992                 with_own_liboping="no"
 993         ],
 994         [
 995                 with_liboping="yes"
 996                 with_own_liboping="yes"
 997                 LDFLAGS="$save_LDFLAGS"
 998                 CPPFLAGS="$save_CPPFLAGS"
 999         ])
1000 fi
1001 AM_CONDITIONAL(BUILD_WITH_LIBOPING, test "x$with_liboping" = "xyes")
1002 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOPING, test "x$with_own_liboping" = "xyes")
1003 if test "x$with_liboping" = "xyes" -a "x$with_own_liboping" = "xyes"
1004 then
1005         with_liboping="yes (shipped version)"
1006 fi
1007
1008 AC_ARG_WITH(libpcap, [AS_HELP_STRING([--with-libpcap@<:@=PREFIX@:>@], [Path to libpcap.])],
1009 [
1010         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1011         then
1012                 LDFLAGS="$LDFLAGS -L$withval/lib"
1013                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1014                 with_libpcap="yes"
1015         fi
1016 ],
1017 [
1018         with_libpcap="yes"
1019 ])
1020 if test "x$with_libpcap" = "xyes"
1021 then
1022         AC_CHECK_LIB(pcap, pcap_open_live,
1023         [
1024                 AC_DEFINE(HAVE_LIBPCAP, 1, [Define to 1 if you have the pcap library (-lpcap).])
1025         ], [with_libpcap="no (libpcap not found)"])
1026 fi
1027 if test "x$with_libpcap" = "xyes"
1028 then
1029         AC_CHECK_HEADERS(pcap.h,
1030         [
1031                 AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1032         ], [with_libpcap="no (pcap.h not found)"])
1033 fi
1034 if test "x$with_libpcap" = "xyes"
1035 then
1036         collect_libpcap=1
1037 else
1038         collect_libpcap=0
1039 fi
1040 AC_DEFINE_UNQUOTED(COLLECT_LIBPCAP, [$collect_libpcap],
1041         [Wether or not to use the pcap library])
1042 AM_CONDITIONAL(BUILD_WITH_LIBPCAP, test "x$with_libpcap" = "xyes")
1043
1044 # Define `step' and `hearbeat' values..
1045 declare -i collectd_step=10
1046 declare -i collectd_heartbeat=25
1047 AC_ARG_WITH(step, [AS_HELP_STRING([--with-step=SECONDS], [Interval in which plugins are queried.])],
1048 [
1049         if test "x$withval" != "xno" -a "x$withval" != "xyes"
1050         then
1051                 declare -i tmp_collectd_step="$withval"
1052                 if test $tmp_collectd_step -gt 0
1053                 then
1054                         collectd_step=$tmp_collectd_step
1055                         let "collectd_heartbeat=$collectd_step*2"
1056                 fi
1057         fi
1058 ], [])
1059 AC_ARG_WITH(heartbeat, [AS_HELP_STRING([--with-heartbeat=SECONDS], [Heartbeat of the DS in generated RRD files.])],
1060 [
1061         if test "x$withval" != "xno" -a "x$withval" != "xyes"
1062         then
1063                 declare -i tmp_collectd_heartbeat="$withval"
1064                 if test $tmp_collectd_heartbeat -gt 0
1065                 then
1066                         collectd_heartbeat=$tmp_collectd_heartbeat
1067                 fi
1068         fi
1069 ], [])
1070
1071 if test $collectd_step -ne 10
1072 then
1073         AC_DEFINE_UNQUOTED(COLLECTD_STEP, "$collectd_step", [Interval in which plugins are queried.])
1074 fi
1075 if test $collectd_heartbeat -ne 25
1076 then
1077         AC_DEFINE_UNQUOTED(COLLECTD_HEARTBEAT, "$collectd_heartbeat", [Interval in which plugins are queried.])
1078 fi
1079
1080 # Check for enabled/disabled features
1081 #
1082
1083 # AC_COLLECTD(name, enable/disable, info-text, feature/module)
1084 # ------------------------------------------------------------
1085 dnl
1086 m4_define([my_toupper], [m4_translit([$1], m4_defn([m4_cr_letters]), m4_defn([m4_cr_LETTERS]))])
1087 dnl
1088 AC_DEFUN(
1089         [AC_COLLECTD],
1090         [
1091         m4_if([$1], [], [AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 1st argument must not be empty])])dnl
1092         m4_if(
1093                 [$2],
1094                 [enable],
1095                 [dnl
1096                 m4_define([EnDis],[disabled])dnl
1097                 m4_define([YesNo],[no])dnl
1098                 ],dnl
1099                 [m4_if(
1100                         [$2],
1101                         [disable],
1102                         [dnl
1103                         m4_define([EnDis],[enabled])dnl
1104                         m4_define([YesNo],[yes])dnl
1105                         ],
1106                         [dnl
1107                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 2nd argument must be either enable or disable])dnl
1108                         ]dnl
1109                 )]dnl
1110         )dnl
1111         m4_if([$3], [feature], [],
1112                 [m4_if(
1113                         [$3], [module], [],
1114                         [dnl
1115                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 3rd argument must be either feature or disable])dnl
1116                         ]dnl
1117                 )]dnl
1118         )dnl
1119         AC_ARG_ENABLE(
1120                 [$1],
1121                 AS_HELP_STRING([--$2-$1], [$2 $4 (EnDis by def)]),
1122                 [],
1123                 enable_$1='[YesNo]'dnl
1124         )# AC_ARG_ENABLE
1125 if test "x$enable_$1" = "xno"
1126 then
1127         collectd_$1=0
1128 else
1129         if test "x$enable_$1" = "xyes"
1130         then
1131                 collectd_$1=1
1132         else
1133                 AC_MSG_NOTICE([please specify either --enable-$1 or --disable-$1; enabling $1.])
1134                 collectd_$1=1
1135                 enable_$1='yes'
1136         fi
1137 fi
1138         AC_DEFINE_UNQUOTED([COLLECT_]my_toupper([$1]), [$collectd_$1], [wether or not to enable $3 $4])
1139         AM_CONDITIONAL([BUILD_]my_toupper([$3])[_]my_toupper([$1]), [test "x$enable_$1" = "xyes"])dnl
1140         ]dnl
1141 )# AC_COLLECTD(name, enable/disable, info-text, feature/module)
1142
1143 m4_divert_once([HELP_ENABLE], [
1144 collectd features:])
1145 AC_COLLECTD([debug],     [enable],  [feature], [debugging])
1146 AC_COLLECTD([daemon],    [disable], [feature], [daemon mode])
1147 AC_COLLECTD([getifaddrs],[enable],  [feature], [getifaddrs under Linux])
1148
1149 m4_divert_once([HELP_ENABLE], [
1150 collectd modules:])
1151 AC_COLLECTD([apache],    [disable], [module], [Apache httpd statistics])
1152 AC_COLLECTD([apcups],    [disable], [module], [Statistics of UPSes by APC])
1153 AC_COLLECTD([apple_sensors], [disable], [module], [Apple's hardware sensors])
1154 AC_COLLECTD([battery],   [disable], [module], [battery statistics])
1155 AC_COLLECTD([cpu],       [disable], [module], [cpu usage statistics])
1156 AC_COLLECTD([cpufreq],   [disable], [module], [system cpu frequency statistics])
1157 AC_COLLECTD([disk],      [disable], [module], [disk/partition statistics])
1158 AC_COLLECTD([csv],       [disable], [module], [csv output plugin])
1159 AC_COLLECTD([df],        [disable], [module], [df statistics])
1160 AC_COLLECTD([dns],       [disable], [module], [dns statistics])
1161 AC_COLLECTD([email],     [disable], [module], [email statistics])
1162 AC_COLLECTD([entropy],   [disable], [module], [entropy statistics])
1163 AC_COLLECTD([exec],      [disable], [module], [exec of external programs])
1164 AC_COLLECTD([hddtemp],   [disable], [module], [hdd temperature statistics])
1165 AC_COLLECTD([irq],       [disable], [module], [irq statistics])
1166 AC_COLLECTD([load],      [disable], [module], [system load statistics])
1167 AC_COLLECTD([mbmon],     [disable], [module], [motherboard monitor statistics])
1168 AC_COLLECTD([memory],    [disable], [module], [memory statistics])
1169 AC_COLLECTD([multimeter],[disable], [module], [multimeter statistics])
1170 AC_COLLECTD([mysql],     [disable], [module], [mysql statistics])
1171 AC_COLLECTD([network],   [disable], [module], [network functionality])
1172 AC_COLLECTD([nfs],       [disable], [module], [nfs statistics])
1173 AC_COLLECTD([ntpd],      [disable], [module], [ntpd statistics])
1174 AC_COLLECTD([ping],      [disable], [module], [ping statistics])
1175 AC_COLLECTD([processes], [disable], [module], [processes statistics])
1176 AC_COLLECTD([sensors],   [disable], [module], [lm_sensors statistics])
1177 AC_COLLECTD([serial],    [disable], [module], [serial statistics])
1178 AC_COLLECTD([swap],      [disable], [module], [swap statistics])
1179 AC_COLLECTD([syslog],    [disable], [module], [syslog log facility])
1180 AC_COLLECTD([tape],      [disable], [module], [tape statistics])
1181 AC_COLLECTD([traffic],   [disable], [module], [system traffic statistics])
1182 AC_COLLECTD([unixsock],  [disable], [module], [UNIX socket plugin])
1183 AC_COLLECTD([users],     [disable], [module], [user count statistics])
1184 AC_COLLECTD([vserver],   [disable], [module], [vserver statistics])
1185 AC_COLLECTD([wireless],  [disable], [module], [wireless link statistics])
1186
1187 AC_OUTPUT(Makefile src/Makefile src/collectd.conf src/liboconfig/Makefile src/liboping/Makefile)
1188
1189 cat <<EOF;
1190
1191 Configuration:
1192   Libraries:
1193     libcurl . . . . . . $with_libcurl
1194     libiokit  . . . . . $with_libiokit
1195     liboping  . . . . . $with_liboping
1196     librrd  . . . . . . $with_rrdtool
1197     lm_sensors  . . . . $with_lm_sensors
1198     libstatgrab . . . . $with_libstatgrab
1199     libkstat  . . . . . $with_kstat
1200     libmysql  . . . . . $with_libmysql
1201     libpcap . . . . . . $with_libpcap
1202     libpthread  . . . . $with_libpthread
1203
1204   Features:
1205     debug . . . . . . . $enable_debug
1206     daemon mode . . . . $enable_daemon
1207     step  . . . . . . . $collectd_step seconds
1208     heartbeat . . . . . $collectd_heartbeat seconds
1209
1210   Modules:
1211     apache  . . . . . . $enable_apache
1212     apcups  . . . . . . $enable_apcups
1213     apple_sensors . . . $enable_apple_sensors
1214     battery . . . . . . $enable_battery
1215     cpu . . . . . . . . $enable_cpu
1216     cpufreq . . . . . . $enable_cpufreq
1217     csv . . . . . . . . $enable_csv
1218     df  . . . . . . . . $enable_df
1219     disk  . . . . . . . $enable_disk
1220     dns . . . . . . . . $enable_dns
1221     email . . . . . . . $enable_email
1222     entropy . . . . . . $enable_entropy
1223     exec  . . . . . . . $enable_exec
1224     hddtemp . . . . . . $enable_hddtemp
1225     irq . . . . . . . . $enable_irq
1226     load  . . . . . . . $enable_load
1227     mbmon . . . . . . . $enable_mbmon
1228     memory  . . . . . . $enable_memory
1229     multimeter  . . . . $enable_multimeter
1230     mysql . . . . . . . $enable_mysql
1231     network . . . . . . $enable_network
1232     nfs . . . . . . . . $enable_nfs
1233     ntpd  . . . . . . . $enable_ntpd
1234     ping  . . . . . . . $enable_ping
1235     processes . . . . . $enable_processes
1236     sensors . . . . . . $enable_sensors
1237     serial  . . . . . . $enable_serial
1238     swap  . . . . . . . $enable_swap
1239     syslog  . . . . . . $enable_syslog
1240     tape  . . . . . . . $enable_tape
1241     traffic . . . . . . $enable_traffic
1242     unixsock  . . . . . $enable_unixsock
1243     users . . . . . . . $enable_users
1244     vserver . . . . . . $enable_vserver
1245     wireless  . . . . . $enable_wireless
1246
1247 EOF